contrib/llvm/lib/Target/AMDGPU/VOP1Instructions.td

   1 //===-- VOP1Instructions.td - Vector Instruction Defintions ---------------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // VOP1 Classes
  12 //===----------------------------------------------------------------------===//
  13
  14 class VOP1e <bits<8> op, VOPProfile P> : Enc32 {
  15   bits<8> vdst;
  16   bits<9> src0;
  17
  18   let Inst{8-0}   = !if(P.HasSrc0, src0{8-0}, 0);
  19   let Inst{16-9}  = op;
  20   let Inst{24-17} = !if(P.EmitDst, vdst{7-0}, 0);
  21   let Inst{31-25} = 0x3f; //encoding
  22 }
  23
  24 class VOP1_SDWAe <bits<8> op, VOPProfile P> : VOP_SDWAe <P> {
  25   bits<8> vdst;
  26
  27   let Inst{8-0}   = 0xf9; // sdwa
  28   let Inst{16-9}  = op;
  29   let Inst{24-17} = !if(P.EmitDst, vdst{7-0}, 0);
  30   let Inst{31-25} = 0x3f; // encoding
  31 }
  32
  33 class VOP1_SDWA9Ae <bits<8> op, VOPProfile P> : VOP_SDWA9Ae <P> {
  34   bits<8> vdst;
  35
  36   let Inst{8-0}   = 0xf9; // sdwa
  37   let Inst{16-9}  = op;
  38   let Inst{24-17} = !if(P.EmitDst, vdst{7-0}, 0);
  39   let Inst{31-25} = 0x3f; // encoding
  40 }
  41
  42 class VOP1_Pseudo <string opName, VOPProfile P, list<dag> pattern=[], bit VOP1Only = 0> :
  43   InstSI <P.Outs32, P.Ins32, "", pattern>,
  44   VOP <opName>,
  45   SIMCInstr <!if(VOP1Only, opName, opName#"_e32"), SIEncodingFamily.NONE>,
  46   MnemonicAlias<!if(VOP1Only, opName, opName#"_e32"), opName> {
  47
  48   let isPseudo = 1;
  49   let isCodeGenOnly = 1;
  50   let UseNamedOperandTable = 1;
  51
  52   string Mnemonic = opName;
  53   string AsmOperands = P.Asm32;
  54
  55   let Size = 4;
  56   let mayLoad = 0;
  57   let mayStore = 0;
  58   let hasSideEffects = 0;
  59   let SubtargetPredicate = isGCN;
  60
  61   let VOP1 = 1;
  62   let VALU = 1;
  63   let Uses = [EXEC];
  64
  65   let AsmVariantName = AMDGPUAsmVariants.Default;
  66
  67   VOPProfile Pfl = P;
  68 }
  69
  70 class VOP1_Real <VOP1_Pseudo ps, int EncodingFamily> :
  71   InstSI <ps.OutOperandList, ps.InOperandList, ps.Mnemonic # ps.AsmOperands, []>,
  72   SIMCInstr <ps.PseudoInstr, EncodingFamily> {
  73
  74   let isPseudo = 0;
  75   let isCodeGenOnly = 0;
  76
  77   let Constraints     = ps.Constraints;
  78   let DisableEncoding = ps.DisableEncoding;
  79
  80   // copy relevant pseudo op flags
  81   let SubtargetPredicate = ps.SubtargetPredicate;
  82   let AsmMatchConverter  = ps.AsmMatchConverter;
  83   let AsmVariantName     = ps.AsmVariantName;
  84   let Constraints        = ps.Constraints;
  85   let DisableEncoding    = ps.DisableEncoding;
  86   let TSFlags            = ps.TSFlags;
  87   let UseNamedOperandTable = ps.UseNamedOperandTable;
  88   let Uses                 = ps.Uses;
  89 }
  90
  91 class VOP1_SDWA_Pseudo <string OpName, VOPProfile P, list<dag> pattern=[]> :
  92   VOP_SDWA_Pseudo <OpName, P, pattern> {
  93   let AsmMatchConverter = "cvtSdwaVOP1";
  94 }
  95
  96 class getVOP1Pat64 <SDPatternOperator node, VOPProfile P> : LetDummies {
  97   list<dag> ret =
  98     !if(P.HasModifiers,
  99         [(set P.DstVT:$vdst, (node (P.Src0VT (VOP3Mods0 P.Src0VT:$src0,
 100                                               i32:$src0_modifiers,
 101                                               i1:$clamp, i32:$omod))))],
 102         !if(P.HasOMod,
 103             [(set P.DstVT:$vdst, (node (P.Src0VT (VOP3OMods P.Src0VT:$src0,
 104                                                   i1:$clamp, i32:$omod))))],
 105             [(set P.DstVT:$vdst, (node P.Src0VT:$src0))]
 106         )
 107     );
 108 }
 109
 110 multiclass VOP1Inst <string opName, VOPProfile P,
 111                      SDPatternOperator node = null_frag> {
 112   def _e32 : VOP1_Pseudo <opName, P>;
 113   def _e64 : VOP3_Pseudo <opName, P, getVOP1Pat64<node, P>.ret>;
 114   def _sdwa : VOP1_SDWA_Pseudo <opName, P>;
 115 }
 116
 117 // Special profile for instructions which have clamp
 118 // and output modifiers (but have no input modifiers)
 119 class VOPProfileI2F<ValueType dstVt, ValueType srcVt> :
 120   VOPProfile<[dstVt, srcVt, untyped, untyped]> {
 121
 122   let Ins64 = (ins Src0RC64:$src0, clampmod:$clamp, omod:$omod);
 123   let Asm64 = "$vdst, $src0$clamp$omod";
 124
 125   let HasModifiers = 0;
 126   let HasClamp = 1;
 127   let HasOMod = 1;
 128 }
 129
 130 def VOP1_F64_I32 : VOPProfileI2F <f64, i32>;
 131 def VOP1_F32_I32 : VOPProfileI2F <f32, i32>;
 132 def VOP1_F16_I16 : VOPProfileI2F <f16, i16>;
 133
 134 //===----------------------------------------------------------------------===//
 135 // VOP1 Instructions
 136 //===----------------------------------------------------------------------===//
 137
 138 let VOPAsmPrefer32Bit = 1 in {
 139 defm V_NOP : VOP1Inst <"v_nop", VOP_NONE>;
 140 }
 141
 142 let isMoveImm = 1, isReMaterializable = 1, isAsCheapAsAMove = 1 in {
 143 defm V_MOV_B32 : VOP1Inst <"v_mov_b32", VOP_I32_I32>;
 144 } // End isMoveImm = 1
 145
 146 // FIXME: Specify SchedRW for READFIRSTLANE_B32
 147 // TODO: Make profile for this, there is VOP3 encoding also
 148 def V_READFIRSTLANE_B32 :
 149   InstSI <(outs SReg_32:$vdst),
 150     (ins VGPR_32:$src0),
 151     "v_readfirstlane_b32 $vdst, $src0",
 152     [(set i32:$vdst, (int_amdgcn_readfirstlane i32:$src0))]>,
 153   Enc32 {
 154
 155   let isCodeGenOnly = 0;
 156   let UseNamedOperandTable = 1;
 157
 158   let Size = 4;
 159   let mayLoad = 0;
 160   let mayStore = 0;
 161   let hasSideEffects = 0;
 162   let SubtargetPredicate = isGCN;
 163
 164   let VOP1 = 1;
 165   let VALU = 1;
 166   let Uses = [EXEC];
 167   let isConvergent = 1;
 168
 169   bits<8> vdst;
 170   bits<9> src0;
 171
 172   let Inst{8-0}   = src0;
 173   let Inst{16-9}  = 0x2;
 174   let Inst{24-17} = vdst;
 175   let Inst{31-25} = 0x3f; //encoding
 176 }
 177
 178 let SchedRW = [WriteQuarterRate32] in {
 179 defm V_CVT_I32_F64 : VOP1Inst <"v_cvt_i32_f64", VOP_I32_F64, fp_to_sint>;
 180 defm V_CVT_F64_I32 : VOP1Inst <"v_cvt_f64_i32", VOP1_F64_I32, sint_to_fp>;
 181 defm V_CVT_F32_I32 : VOP1Inst <"v_cvt_f32_i32", VOP1_F32_I32, sint_to_fp>;
 182 defm V_CVT_F32_U32 : VOP1Inst <"v_cvt_f32_u32", VOP1_F32_I32, uint_to_fp>;
 183 defm V_CVT_U32_F32 : VOP1Inst <"v_cvt_u32_f32", VOP_I32_F32, fp_to_uint>;
 184 defm V_CVT_I32_F32 : VOP1Inst <"v_cvt_i32_f32", VOP_I32_F32, fp_to_sint>;
 185 defm V_CVT_F16_F32 : VOP1Inst <"v_cvt_f16_f32", VOP_F16_F32, fpround>;
 186 defm V_CVT_F32_F16 : VOP1Inst <"v_cvt_f32_f16", VOP_F32_F16, fpextend>;
 187 defm V_CVT_RPI_I32_F32 : VOP1Inst <"v_cvt_rpi_i32_f32", VOP_I32_F32, cvt_rpi_i32_f32>;
 188 defm V_CVT_FLR_I32_F32 : VOP1Inst <"v_cvt_flr_i32_f32", VOP_I32_F32, cvt_flr_i32_f32>;
 189 defm V_CVT_OFF_F32_I4 : VOP1Inst  <"v_cvt_off_f32_i4", VOP1_F32_I32>;
 190 defm V_CVT_F32_F64 : VOP1Inst <"v_cvt_f32_f64", VOP_F32_F64, fpround>;
 191 defm V_CVT_F64_F32 : VOP1Inst <"v_cvt_f64_f32", VOP_F64_F32, fpextend>;
 192 defm V_CVT_F32_UBYTE0 : VOP1Inst <"v_cvt_f32_ubyte0", VOP1_F32_I32, AMDGPUcvt_f32_ubyte0>;
 193 defm V_CVT_F32_UBYTE1 : VOP1Inst <"v_cvt_f32_ubyte1", VOP1_F32_I32, AMDGPUcvt_f32_ubyte1>;
 194 defm V_CVT_F32_UBYTE2 : VOP1Inst <"v_cvt_f32_ubyte2", VOP1_F32_I32, AMDGPUcvt_f32_ubyte2>;
 195 defm V_CVT_F32_UBYTE3 : VOP1Inst <"v_cvt_f32_ubyte3", VOP1_F32_I32, AMDGPUcvt_f32_ubyte3>;
 196 defm V_CVT_U32_F64 : VOP1Inst <"v_cvt_u32_f64", VOP_I32_F64, fp_to_uint>;
 197 defm V_CVT_F64_U32 : VOP1Inst <"v_cvt_f64_u32", VOP1_F64_I32, uint_to_fp>;
 198 } // End SchedRW = [WriteQuarterRate32]
 199
 200 defm V_FRACT_F32 : VOP1Inst <"v_fract_f32", VOP_F32_F32, AMDGPUfract>;
 201 defm V_TRUNC_F32 : VOP1Inst <"v_trunc_f32", VOP_F32_F32, ftrunc>;
 202 defm V_CEIL_F32 : VOP1Inst <"v_ceil_f32", VOP_F32_F32, fceil>;
 203 defm V_RNDNE_F32 : VOP1Inst <"v_rndne_f32", VOP_F32_F32, frint>;
 204 defm V_FLOOR_F32 : VOP1Inst <"v_floor_f32", VOP_F32_F32, ffloor>;
 205 defm V_EXP_F32 : VOP1Inst <"v_exp_f32", VOP_F32_F32, fexp2>;
 206
 207 let SchedRW = [WriteQuarterRate32] in {
 208 defm V_LOG_F32 : VOP1Inst <"v_log_f32", VOP_F32_F32, flog2>;
 209 defm V_RCP_F32 : VOP1Inst <"v_rcp_f32", VOP_F32_F32, AMDGPUrcp>;
 210 defm V_RCP_IFLAG_F32 : VOP1Inst <"v_rcp_iflag_f32", VOP_F32_F32>;
 211 defm V_RSQ_F32 : VOP1Inst <"v_rsq_f32", VOP_F32_F32, AMDGPUrsq>;
 212 } // End SchedRW = [WriteQuarterRate32]
 213
 214 let SchedRW = [WriteDouble] in {
 215 defm V_RCP_F64 : VOP1Inst <"v_rcp_f64", VOP_F64_F64, AMDGPUrcp>;
 216 defm V_RSQ_F64 : VOP1Inst <"v_rsq_f64", VOP_F64_F64, AMDGPUrsq>;
 217 } // End SchedRW = [WriteDouble];
 218
 219 defm V_SQRT_F32 : VOP1Inst <"v_sqrt_f32", VOP_F32_F32, fsqrt>;
 220
 221 let SchedRW = [WriteDouble] in {
 222 defm V_SQRT_F64 : VOP1Inst <"v_sqrt_f64", VOP_F64_F64, fsqrt>;
 223 } // End SchedRW = [WriteDouble]
 224
 225 let SchedRW = [WriteQuarterRate32] in {
 226 defm V_SIN_F32 : VOP1Inst <"v_sin_f32", VOP_F32_F32, AMDGPUsin>;
 227 defm V_COS_F32 : VOP1Inst <"v_cos_f32", VOP_F32_F32, AMDGPUcos>;
 228 } // End SchedRW = [WriteQuarterRate32]
 229
 230 defm V_NOT_B32 : VOP1Inst <"v_not_b32", VOP_I32_I32>;
 231 defm V_BFREV_B32 : VOP1Inst <"v_bfrev_b32", VOP_I32_I32>;
 232 defm V_FFBH_U32 : VOP1Inst <"v_ffbh_u32", VOP_I32_I32>;
 233 defm V_FFBL_B32 : VOP1Inst <"v_ffbl_b32", VOP_I32_I32>;
 234 defm V_FFBH_I32 : VOP1Inst <"v_ffbh_i32", VOP_I32_I32>;
 235 defm V_FREXP_EXP_I32_F64 : VOP1Inst <"v_frexp_exp_i32_f64", VOP_I32_F64, int_amdgcn_frexp_exp>;
 236
 237 let SchedRW = [WriteDoubleAdd] in {
 238 defm V_FREXP_MANT_F64 : VOP1Inst <"v_frexp_mant_f64", VOP_F64_F64, int_amdgcn_frexp_mant>;
 239 defm V_FRACT_F64 : VOP1Inst <"v_fract_f64", VOP_F64_F64, AMDGPUfract>;
 240 } // End SchedRW = [WriteDoubleAdd]
 241
 242 defm V_FREXP_EXP_I32_F32 : VOP1Inst <"v_frexp_exp_i32_f32", VOP_I32_F32, int_amdgcn_frexp_exp>;
 243 defm V_FREXP_MANT_F32 : VOP1Inst <"v_frexp_mant_f32", VOP_F32_F32, int_amdgcn_frexp_mant>;
 244
 245 let VOPAsmPrefer32Bit = 1 in {
 246 defm V_CLREXCP : VOP1Inst <"v_clrexcp", VOP_NO_EXT<VOP_NONE>>;
 247 }
 248
 249 // Restrict src0 to be VGPR
 250 def VOP_I32_VI32_NO_EXT : VOPProfile<[i32, i32, untyped, untyped]> {
 251   let Src0RC32 = VRegSrc_32;
 252   let Src0RC64 = VRegSrc_32;
 253
 254   let HasExt = 0;
 255   let HasSDWA9 = 0;
 256 }
 257
 258 // Special case because there are no true output operands.  Hack vdst
 259 // to be a src operand. The custom inserter must add a tied implicit
 260 // def and use of the super register since there seems to be no way to
 261 // add an implicit def of a virtual register in tablegen.
 262 def VOP_MOVRELD : VOPProfile<[untyped, i32, untyped, untyped]> {
 263   let Src0RC32 = VOPDstOperand<VGPR_32>;
 264   let Src0RC64 = VOPDstOperand<VGPR_32>;
 265
 266   let Outs = (outs);
 267   let Ins32 = (ins Src0RC32:$vdst, VSrc_b32:$src0);
 268   let Ins64 = (ins Src0RC64:$vdst, VSrc_b32:$src0);
 269   let InsDPP = (ins Src0RC32:$vdst, Src0RC32:$src0, dpp_ctrl:$dpp_ctrl, row_mask:$row_mask,
 270                     bank_mask:$bank_mask, bound_ctrl:$bound_ctrl);
 271
 272   let InsSDWA = (ins Src0RC32:$vdst, Src0ModSDWA:$src0_modifiers, Src0SDWA:$src0,
 273                      clampmod:$clamp, omod:$omod, dst_sel:$dst_sel, dst_unused:$dst_unused,
 274                      src0_sel:$src0_sel);
 275
 276   let Asm32 = getAsm32<1, 1>.ret;
 277   let Asm64 = getAsm64<1, 1, 0, 1>.ret;
 278   let AsmDPP = getAsmDPP<1, 1, 0>.ret;
 279   let AsmSDWA = getAsmSDWA<1, 1>.ret;
 280   let AsmSDWA9 = getAsmSDWA9<1, 0, 1>.ret;
 281
 282   let HasExt = 0;
 283   let HasSDWA9 = 0;
 284   let HasDst = 0;
 285   let EmitDst = 1; // force vdst emission
 286 }
 287
 288 let SubtargetPredicate = HasMovrel, Uses = [M0, EXEC] in {
 289 // v_movreld_b32 is a special case because the destination output
 290  // register is really a source. It isn't actually read (but may be
 291  // written), and is only to provide the base register to start
 292  // indexing from. Tablegen seems to not let you define an implicit
 293  // virtual register output for the super register being written into,
 294  // so this must have an implicit def of the register added to it.
 295 defm V_MOVRELD_B32 : VOP1Inst <"v_movreld_b32", VOP_MOVRELD>;
 296 defm V_MOVRELS_B32 : VOP1Inst <"v_movrels_b32", VOP_I32_VI32_NO_EXT>;
 297 defm V_MOVRELSD_B32 : VOP1Inst <"v_movrelsd_b32", VOP_NO_EXT<VOP_I32_I32>>;
 298 } // End Uses = [M0, EXEC]
 299
 300 let SchedRW = [WriteQuarterRate32] in {
 301 defm V_MOV_FED_B32 : VOP1Inst <"v_mov_fed_b32", VOP_I32_I32>;
 302 }
 303
 304 // These instruction only exist on SI and CI
 305 let SubtargetPredicate = isSICI in {
 306
 307 let SchedRW = [WriteQuarterRate32] in {
 308 defm V_LOG_CLAMP_F32 : VOP1Inst <"v_log_clamp_f32", VOP_F32_F32, int_amdgcn_log_clamp>;
 309 defm V_RCP_CLAMP_F32 : VOP1Inst <"v_rcp_clamp_f32", VOP_F32_F32>;
 310 defm V_RCP_LEGACY_F32 : VOP1Inst <"v_rcp_legacy_f32", VOP_F32_F32, AMDGPUrcp_legacy>;
 311 defm V_RSQ_CLAMP_F32 : VOP1Inst <"v_rsq_clamp_f32", VOP_F32_F32, AMDGPUrsq_clamp>;
 312 defm V_RSQ_LEGACY_F32 : VOP1Inst <"v_rsq_legacy_f32", VOP_F32_F32, AMDGPUrsq_legacy>;
 313 } // End SchedRW = [WriteQuarterRate32]
 314
 315 let SchedRW = [WriteDouble] in {
 316 defm V_RCP_CLAMP_F64 : VOP1Inst <"v_rcp_clamp_f64", VOP_F64_F64>;
 317 defm V_RSQ_CLAMP_F64 : VOP1Inst <"v_rsq_clamp_f64", VOP_F64_F64, AMDGPUrsq_clamp>;
 318 } // End SchedRW = [WriteDouble]
 319
 320 } // End SubtargetPredicate = isSICI
 321
 322
 323 let SubtargetPredicate = isCIVI in {
 324
 325 let SchedRW = [WriteDoubleAdd] in {
 326 defm V_TRUNC_F64 : VOP1Inst <"v_trunc_f64", VOP_F64_F64, ftrunc>;
 327 defm V_CEIL_F64 : VOP1Inst <"v_ceil_f64", VOP_F64_F64, fceil>;
 328 defm V_FLOOR_F64 : VOP1Inst <"v_floor_f64", VOP_F64_F64, ffloor>;
 329 defm V_RNDNE_F64 : VOP1Inst <"v_rndne_f64", VOP_F64_F64, frint>;
 330 } // End SchedRW = [WriteDoubleAdd]
 331
 332 let SchedRW = [WriteQuarterRate32] in {
 333 defm V_LOG_LEGACY_F32 : VOP1Inst <"v_log_legacy_f32", VOP_F32_F32>;
 334 defm V_EXP_LEGACY_F32 : VOP1Inst <"v_exp_legacy_f32", VOP_F32_F32>;
 335 } // End SchedRW = [WriteQuarterRate32]
 336
 337 } // End SubtargetPredicate = isCIVI
 338
 339
 340 let SubtargetPredicate = Has16BitInsts in {
 341
 342 defm V_CVT_F16_U16 : VOP1Inst <"v_cvt_f16_u16", VOP1_F16_I16, uint_to_fp>;
 343 defm V_CVT_F16_I16 : VOP1Inst <"v_cvt_f16_i16", VOP1_F16_I16, sint_to_fp>;
 344 defm V_CVT_U16_F16 : VOP1Inst <"v_cvt_u16_f16", VOP_I16_F16, fp_to_uint>;
 345 defm V_CVT_I16_F16 : VOP1Inst <"v_cvt_i16_f16", VOP_I16_F16, fp_to_sint>;
 346 defm V_RCP_F16 : VOP1Inst <"v_rcp_f16", VOP_F16_F16, AMDGPUrcp>;
 347 defm V_SQRT_F16 : VOP1Inst <"v_sqrt_f16", VOP_F16_F16, fsqrt>;
 348 defm V_RSQ_F16 : VOP1Inst <"v_rsq_f16", VOP_F16_F16, AMDGPUrsq>;
 349 defm V_LOG_F16 : VOP1Inst <"v_log_f16", VOP_F16_F16, flog2>;
 350 defm V_EXP_F16 : VOP1Inst <"v_exp_f16", VOP_F16_F16, fexp2>;
 351 defm V_FREXP_MANT_F16 : VOP1Inst <"v_frexp_mant_f16", VOP_F16_F16, int_amdgcn_frexp_mant>;
 352 defm V_FREXP_EXP_I16_F16 : VOP1Inst <"v_frexp_exp_i16_f16", VOP_I16_F16, int_amdgcn_frexp_exp>;
 353 defm V_FLOOR_F16 : VOP1Inst <"v_floor_f16", VOP_F16_F16, ffloor>;
 354 defm V_CEIL_F16 : VOP1Inst <"v_ceil_f16", VOP_F16_F16, fceil>;
 355 defm V_TRUNC_F16 : VOP1Inst <"v_trunc_f16", VOP_F16_F16, ftrunc>;
 356 defm V_RNDNE_F16 : VOP1Inst <"v_rndne_f16", VOP_F16_F16, frint>;
 357 defm V_FRACT_F16 : VOP1Inst <"v_fract_f16", VOP_F16_F16, AMDGPUfract>;
 358 defm V_SIN_F16 : VOP1Inst <"v_sin_f16", VOP_F16_F16, AMDGPUsin>;
 359 defm V_COS_F16 : VOP1Inst <"v_cos_f16", VOP_F16_F16, AMDGPUcos>;
 360
 361 }
 362
 363 let Predicates = [Has16BitInsts] in {
 364
 365 def : Pat<
 366     (f32 (f16_to_fp i16:$src)),
 367     (V_CVT_F32_F16_e32 $src)
 368 >;
 369
 370 def : Pat<
 371     (i16 (AMDGPUfp_to_f16 f32:$src)),
 372     (V_CVT_F16_F32_e32 $src)
 373 >;
 374
 375 }
 376
 377 def VOP_SWAP_I32 : VOPProfile<[i32, i32, i32, untyped]> {
 378   let Outs32 = (outs VGPR_32:$vdst, VGPR_32:$vdst1);
 379   let Ins32 = (ins VGPR_32:$src0, VGPR_32:$src1);
 380   let Outs64 = Outs32;
 381   let Asm32 = " $vdst, $src0";
 382   let Asm64 = "";
 383   let Ins64 = (ins);
 384 }
 385
 386 let SubtargetPredicate = isGFX9 in {
 387   let Constraints = "$vdst = $src1, $vdst1 = $src0",
 388       DisableEncoding="$vdst1,$src1",
 389       SchedRW = [Write64Bit, Write64Bit] in {
 390 // Never VOP3. Takes as long as 2 v_mov_b32s
 391 def V_SWAP_B32 : VOP1_Pseudo <"v_swap_b32", VOP_SWAP_I32, [], 1>;
 392 }
 393
 394 } // End SubtargetPredicate = isGFX9
 395
 396 //===----------------------------------------------------------------------===//
 397 // Target
 398 //===----------------------------------------------------------------------===//
 399
 400 //===----------------------------------------------------------------------===//
 401 // SI
 402 //===----------------------------------------------------------------------===//
 403
 404 multiclass VOP1_Real_si <bits<9> op> {
 405   let AssemblerPredicates = [isSICI], DecoderNamespace = "SICI" in {
 406     def _e32_si :
 407       VOP1_Real<!cast<VOP1_Pseudo>(NAME#"_e32"), SIEncodingFamily.SI>,
 408       VOP1e<op{7-0}, !cast<VOP1_Pseudo>(NAME#"_e32").Pfl>;
 409     def _e64_si :
 410       VOP3_Real<!cast<VOP3_Pseudo>(NAME#"_e64"), SIEncodingFamily.SI>,
 411       VOP3e_si <{1, 1, op{6-0}}, !cast<VOP3_Pseudo>(NAME#"_e64").Pfl>;
 412   }
 413 }
 414
 415 defm V_NOP               : VOP1_Real_si <0x0>;
 416 defm V_MOV_B32           : VOP1_Real_si <0x1>;
 417 defm V_CVT_I32_F64       : VOP1_Real_si <0x3>;
 418 defm V_CVT_F64_I32       : VOP1_Real_si <0x4>;
 419 defm V_CVT_F32_I32       : VOP1_Real_si <0x5>;
 420 defm V_CVT_F32_U32       : VOP1_Real_si <0x6>;
 421 defm V_CVT_U32_F32       : VOP1_Real_si <0x7>;
 422 defm V_CVT_I32_F32       : VOP1_Real_si <0x8>;
 423 defm V_MOV_FED_B32       : VOP1_Real_si <0x9>;
 424 defm V_CVT_F16_F32       : VOP1_Real_si <0xa>;
 425 defm V_CVT_F32_F16       : VOP1_Real_si <0xb>;
 426 defm V_CVT_RPI_I32_F32   : VOP1_Real_si <0xc>;
 427 defm V_CVT_FLR_I32_F32   : VOP1_Real_si <0xd>;
 428 defm V_CVT_OFF_F32_I4    : VOP1_Real_si <0xe>;
 429 defm V_CVT_F32_F64       : VOP1_Real_si <0xf>;
 430 defm V_CVT_F64_F32       : VOP1_Real_si <0x10>;
 431 defm V_CVT_F32_UBYTE0    : VOP1_Real_si <0x11>;
 432 defm V_CVT_F32_UBYTE1    : VOP1_Real_si <0x12>;
 433 defm V_CVT_F32_UBYTE2    : VOP1_Real_si <0x13>;
 434 defm V_CVT_F32_UBYTE3    : VOP1_Real_si <0x14>;
 435 defm V_CVT_U32_F64       : VOP1_Real_si <0x15>;
 436 defm V_CVT_F64_U32       : VOP1_Real_si <0x16>;
 437 defm V_FRACT_F32         : VOP1_Real_si <0x20>;
 438 defm V_TRUNC_F32         : VOP1_Real_si <0x21>;
 439 defm V_CEIL_F32          : VOP1_Real_si <0x22>;
 440 defm V_RNDNE_F32         : VOP1_Real_si <0x23>;
 441 defm V_FLOOR_F32         : VOP1_Real_si <0x24>;
 442 defm V_EXP_F32           : VOP1_Real_si <0x25>;
 443 defm V_LOG_CLAMP_F32     : VOP1_Real_si <0x26>;
 444 defm V_LOG_F32           : VOP1_Real_si <0x27>;
 445 defm V_RCP_CLAMP_F32     : VOP1_Real_si <0x28>;
 446 defm V_RCP_LEGACY_F32    : VOP1_Real_si <0x29>;
 447 defm V_RCP_F32           : VOP1_Real_si <0x2a>;
 448 defm V_RCP_IFLAG_F32     : VOP1_Real_si <0x2b>;
 449 defm V_RSQ_CLAMP_F32     : VOP1_Real_si <0x2c>;
 450 defm V_RSQ_LEGACY_F32    : VOP1_Real_si <0x2d>;
 451 defm V_RSQ_F32           : VOP1_Real_si <0x2e>;
 452 defm V_RCP_F64           : VOP1_Real_si <0x2f>;
 453 defm V_RCP_CLAMP_F64     : VOP1_Real_si <0x30>;
 454 defm V_RSQ_F64           : VOP1_Real_si <0x31>;
 455 defm V_RSQ_CLAMP_F64     : VOP1_Real_si <0x32>;
 456 defm V_SQRT_F32          : VOP1_Real_si <0x33>;
 457 defm V_SQRT_F64          : VOP1_Real_si <0x34>;
 458 defm V_SIN_F32           : VOP1_Real_si <0x35>;
 459 defm V_COS_F32           : VOP1_Real_si <0x36>;
 460 defm V_NOT_B32           : VOP1_Real_si <0x37>;
 461 defm V_BFREV_B32         : VOP1_Real_si <0x38>;
 462 defm V_FFBH_U32          : VOP1_Real_si <0x39>;
 463 defm V_FFBL_B32          : VOP1_Real_si <0x3a>;
 464 defm V_FFBH_I32          : VOP1_Real_si <0x3b>;
 465 defm V_FREXP_EXP_I32_F64 : VOP1_Real_si <0x3c>;
 466 defm V_FREXP_MANT_F64    : VOP1_Real_si <0x3d>;
 467 defm V_FRACT_F64         : VOP1_Real_si <0x3e>;
 468 defm V_FREXP_EXP_I32_F32 : VOP1_Real_si <0x3f>;
 469 defm V_FREXP_MANT_F32    : VOP1_Real_si <0x40>;
 470 defm V_CLREXCP           : VOP1_Real_si <0x41>;
 471 defm V_MOVRELD_B32       : VOP1_Real_si <0x42>;
 472 defm V_MOVRELS_B32       : VOP1_Real_si <0x43>;
 473 defm V_MOVRELSD_B32      : VOP1_Real_si <0x44>;
 474
 475 //===----------------------------------------------------------------------===//
 476 // CI
 477 //===----------------------------------------------------------------------===//
 478
 479 multiclass VOP1_Real_ci <bits<9> op> {
 480   let AssemblerPredicates = [isCIOnly], DecoderNamespace = "CI" in {
 481     def _e32_ci :
 482       VOP1_Real<!cast<VOP1_Pseudo>(NAME#"_e32"), SIEncodingFamily.SI>,
 483       VOP1e<op{7-0}, !cast<VOP1_Pseudo>(NAME#"_e32").Pfl>;
 484     def _e64_ci :
 485       VOP3_Real<!cast<VOP3_Pseudo>(NAME#"_e64"), SIEncodingFamily.SI>,
 486       VOP3e_si <{1, 1, op{6-0}}, !cast<VOP3_Pseudo>(NAME#"_e64").Pfl>;
 487   }
 488 }
 489
 490 defm V_TRUNC_F64         : VOP1_Real_ci <0x17>;
 491 defm V_CEIL_F64          : VOP1_Real_ci <0x18>;
 492 defm V_FLOOR_F64         : VOP1_Real_ci <0x1A>;
 493 defm V_RNDNE_F64         : VOP1_Real_ci <0x19>;
 494 defm V_LOG_LEGACY_F32    : VOP1_Real_ci <0x45>;
 495 defm V_EXP_LEGACY_F32    : VOP1_Real_ci <0x46>;
 496
 497 //===----------------------------------------------------------------------===//
 498 // VI
 499 //===----------------------------------------------------------------------===//
 500
 501 class VOP1_DPP <bits<8> op, VOP1_Pseudo ps, VOPProfile P = ps.Pfl> :
 502   VOP_DPP <ps.OpName, P> {
 503   let Defs = ps.Defs;
 504   let Uses = ps.Uses;
 505   let SchedRW = ps.SchedRW;
 506   let hasSideEffects = ps.hasSideEffects;
 507   let Constraints = ps.Constraints;
 508   let DisableEncoding = ps.DisableEncoding;
 509
 510   bits<8> vdst;
 511   let Inst{8-0}   = 0xfa; // dpp
 512   let Inst{16-9}  = op;
 513   let Inst{24-17} = !if(P.EmitDst, vdst{7-0}, 0);
 514   let Inst{31-25} = 0x3f; //encoding
 515 }
 516
 517 multiclass VOP1Only_Real_vi <bits<10> op> {
 518   let AssemblerPredicates = [isVI], DecoderNamespace = "VI" in {
 519     def _vi :
 520       VOP1_Real<!cast<VOP1_Pseudo>(NAME), SIEncodingFamily.VI>,
 521       VOP1e<op{7-0}, !cast<VOP1_Pseudo>(NAME).Pfl>;
 522   }
 523 }
 524
 525 multiclass VOP1_Real_vi <bits<10> op> {
 526   let AssemblerPredicates = [isVI], DecoderNamespace = "VI" in {
 527     def _e32_vi :
 528       VOP1_Real<!cast<VOP1_Pseudo>(NAME#"_e32"), SIEncodingFamily.VI>,
 529       VOP1e<op{7-0}, !cast<VOP1_Pseudo>(NAME#"_e32").Pfl>;
 530     def _e64_vi :
 531       VOP3_Real<!cast<VOP3_Pseudo>(NAME#"_e64"), SIEncodingFamily.VI>,
 532       VOP3e_vi <!add(0x140, op), !cast<VOP3_Pseudo>(NAME#"_e64").Pfl>;
 533   }
 534
 535   def _sdwa_vi :
 536     VOP_SDWA_Real <!cast<VOP1_SDWA_Pseudo>(NAME#"_sdwa")>,
 537     VOP1_SDWAe <op{7-0}, !cast<VOP1_SDWA_Pseudo>(NAME#"_sdwa").Pfl>;
 538
 539   def _sdwa_gfx9 :
 540     VOP_SDWA9_Real <!cast<VOP1_SDWA_Pseudo>(NAME#"_sdwa")>,
 541     VOP1_SDWA9Ae <op{7-0}, !cast<VOP1_SDWA_Pseudo>(NAME#"_sdwa").Pfl>;
 542
 543   // For now left dpp only for asm/dasm
 544   // TODO: add corresponding pseudo
 545   def _dpp : VOP1_DPP<op{7-0}, !cast<VOP1_Pseudo>(NAME#"_e32")>;
 546 }
 547
 548 defm V_NOP               : VOP1_Real_vi <0x0>;
 549 defm V_MOV_B32           : VOP1_Real_vi <0x1>;
 550 defm V_CVT_I32_F64       : VOP1_Real_vi <0x3>;
 551 defm V_CVT_F64_I32       : VOP1_Real_vi <0x4>;
 552 defm V_CVT_F32_I32       : VOP1_Real_vi <0x5>;
 553 defm V_CVT_F32_U32       : VOP1_Real_vi <0x6>;
 554 defm V_CVT_U32_F32       : VOP1_Real_vi <0x7>;
 555 defm V_CVT_I32_F32       : VOP1_Real_vi <0x8>;
 556 defm V_MOV_FED_B32       : VOP1_Real_vi <0x9>;
 557 defm V_CVT_F16_F32       : VOP1_Real_vi <0xa>;
 558 defm V_CVT_F32_F16       : VOP1_Real_vi <0xb>;
 559 defm V_CVT_RPI_I32_F32   : VOP1_Real_vi <0xc>;
 560 defm V_CVT_FLR_I32_F32   : VOP1_Real_vi <0xd>;
 561 defm V_CVT_OFF_F32_I4    : VOP1_Real_vi <0xe>;
 562 defm V_CVT_F32_F64       : VOP1_Real_vi <0xf>;
 563 defm V_CVT_F64_F32       : VOP1_Real_vi <0x10>;
 564 defm V_CVT_F32_UBYTE0    : VOP1_Real_vi <0x11>;
 565 defm V_CVT_F32_UBYTE1    : VOP1_Real_vi <0x12>;
 566 defm V_CVT_F32_UBYTE2    : VOP1_Real_vi <0x13>;
 567 defm V_CVT_F32_UBYTE3    : VOP1_Real_vi <0x14>;
 568 defm V_CVT_U32_F64       : VOP1_Real_vi <0x15>;
 569 defm V_CVT_F64_U32       : VOP1_Real_vi <0x16>;
 570 defm V_FRACT_F32         : VOP1_Real_vi <0x1b>;
 571 defm V_TRUNC_F32         : VOP1_Real_vi <0x1c>;
 572 defm V_CEIL_F32          : VOP1_Real_vi <0x1d>;
 573 defm V_RNDNE_F32         : VOP1_Real_vi <0x1e>;
 574 defm V_FLOOR_F32         : VOP1_Real_vi <0x1f>;
 575 defm V_EXP_F32           : VOP1_Real_vi <0x20>;
 576 defm V_LOG_F32           : VOP1_Real_vi <0x21>;
 577 defm V_RCP_F32           : VOP1_Real_vi <0x22>;
 578 defm V_RCP_IFLAG_F32     : VOP1_Real_vi <0x23>;
 579 defm V_RSQ_F32           : VOP1_Real_vi <0x24>;
 580 defm V_RCP_F64           : VOP1_Real_vi <0x25>;
 581 defm V_RSQ_F64           : VOP1_Real_vi <0x26>;
 582 defm V_SQRT_F32          : VOP1_Real_vi <0x27>;
 583 defm V_SQRT_F64          : VOP1_Real_vi <0x28>;
 584 defm V_SIN_F32           : VOP1_Real_vi <0x29>;
 585 defm V_COS_F32           : VOP1_Real_vi <0x2a>;
 586 defm V_NOT_B32           : VOP1_Real_vi <0x2b>;
 587 defm V_BFREV_B32         : VOP1_Real_vi <0x2c>;
 588 defm V_FFBH_U32          : VOP1_Real_vi <0x2d>;
 589 defm V_FFBL_B32          : VOP1_Real_vi <0x2e>;
 590 defm V_FFBH_I32          : VOP1_Real_vi <0x2f>;
 591 defm V_FREXP_EXP_I32_F64 : VOP1_Real_vi <0x30>;
 592 defm V_FREXP_MANT_F64    : VOP1_Real_vi <0x31>;
 593 defm V_FRACT_F64         : VOP1_Real_vi <0x32>;
 594 defm V_FREXP_EXP_I32_F32 : VOP1_Real_vi <0x33>;
 595 defm V_FREXP_MANT_F32    : VOP1_Real_vi <0x34>;
 596 defm V_CLREXCP           : VOP1_Real_vi <0x35>;
 597 defm V_MOVRELD_B32       : VOP1_Real_vi <0x36>;
 598 defm V_MOVRELS_B32       : VOP1_Real_vi <0x37>;
 599 defm V_MOVRELSD_B32      : VOP1_Real_vi <0x38>;
 600 defm V_TRUNC_F64         : VOP1_Real_vi <0x17>;
 601 defm V_CEIL_F64          : VOP1_Real_vi <0x18>;
 602 defm V_FLOOR_F64         : VOP1_Real_vi <0x1A>;
 603 defm V_RNDNE_F64         : VOP1_Real_vi <0x19>;
 604 defm V_LOG_LEGACY_F32    : VOP1_Real_vi <0x4c>;
 605 defm V_EXP_LEGACY_F32    : VOP1_Real_vi <0x4b>;
 606 defm V_CVT_F16_U16       : VOP1_Real_vi <0x39>;
 607 defm V_CVT_F16_I16       : VOP1_Real_vi <0x3a>;
 608 defm V_CVT_U16_F16       : VOP1_Real_vi <0x3b>;
 609 defm V_CVT_I16_F16       : VOP1_Real_vi <0x3c>;
 610 defm V_RCP_F16           : VOP1_Real_vi <0x3d>;
 611 defm V_SQRT_F16          : VOP1_Real_vi <0x3e>;
 612 defm V_RSQ_F16           : VOP1_Real_vi <0x3f>;
 613 defm V_LOG_F16           : VOP1_Real_vi <0x40>;
 614 defm V_EXP_F16           : VOP1_Real_vi <0x41>;
 615 defm V_FREXP_MANT_F16    : VOP1_Real_vi <0x42>;
 616 defm V_FREXP_EXP_I16_F16 : VOP1_Real_vi <0x43>;
 617 defm V_FLOOR_F16         : VOP1_Real_vi <0x44>;
 618 defm V_CEIL_F16          : VOP1_Real_vi <0x45>;
 619 defm V_TRUNC_F16         : VOP1_Real_vi <0x46>;
 620 defm V_RNDNE_F16         : VOP1_Real_vi <0x47>;
 621 defm V_FRACT_F16         : VOP1_Real_vi <0x48>;
 622 defm V_SIN_F16           : VOP1_Real_vi <0x49>;
 623 defm V_COS_F16           : VOP1_Real_vi <0x4a>;
 624 defm V_SWAP_B32          : VOP1Only_Real_vi <0x51>;
 625
 626 // Copy of v_mov_b32 with $vdst as a use operand for use with VGPR
 627 // indexing mode. vdst can't be treated as a def for codegen purposes,
 628 // and an implicit use and def of the super register should be added.
 629 def V_MOV_B32_indirect : VPseudoInstSI<(outs),
 630   (ins getVALUDstForVT<i32>.ret:$vdst, getVOPSrc0ForVT<i32>.ret:$src0)>,
 631   PseudoInstExpansion<(V_MOV_B32_e32_vi getVALUDstForVT<i32>.ret:$vdst,
 632                                         getVOPSrc0ForVT<i32>.ret:$src0)> {
 633   let VOP1 = 1;
 634   let SubtargetPredicate = isVI;
 635 }
 636
 637 // This is a pseudo variant of the v_movreld_b32 instruction in which the
 638 // vector operand appears only twice, once as def and once as use. Using this
 639 // pseudo avoids problems with the Two Address instructions pass.
 640 class V_MOVRELD_B32_pseudo<RegisterClass rc> : VPseudoInstSI <
 641   (outs rc:$vdst),
 642   (ins rc:$vsrc, VSrc_b32:$val, i32imm:$offset)> {
 643   let VOP1 = 1;
 644
 645   let Constraints = "$vsrc = $vdst";
 646   let Uses = [M0, EXEC];
 647
 648   let SubtargetPredicate = HasMovrel;
 649 }
 650
 651 def V_MOVRELD_B32_V1 : V_MOVRELD_B32_pseudo<VGPR_32>;
 652 def V_MOVRELD_B32_V2 : V_MOVRELD_B32_pseudo<VReg_64>;
 653 def V_MOVRELD_B32_V4 : V_MOVRELD_B32_pseudo<VReg_128>;
 654 def V_MOVRELD_B32_V8 : V_MOVRELD_B32_pseudo<VReg_256>;
 655 def V_MOVRELD_B32_V16 : V_MOVRELD_B32_pseudo<VReg_512>;
 656
 657 let Predicates = [isVI] in {
 658
 659 def : Pat <
 660   (i32 (int_amdgcn_mov_dpp i32:$src, imm:$dpp_ctrl, imm:$row_mask, imm:$bank_mask,
 661                       imm:$bound_ctrl)),
 662   (V_MOV_B32_dpp $src, (as_i32imm $dpp_ctrl), (as_i32imm $row_mask),
 663                        (as_i32imm $bank_mask), (as_i1imm $bound_ctrl))
 664 >;
 665
 666
 667 def : Pat<
 668   (i32 (anyext i16:$src)),
 669   (COPY $src)
 670 >;
 671
 672 def : Pat<
 673    (i64 (anyext i16:$src)),
 674    (REG_SEQUENCE VReg_64,
 675      (i32 (COPY $src)), sub0,
 676      (V_MOV_B32_e32 (i32 0)), sub1)
 677 >;
 678
 679 def : Pat<
 680   (i16 (trunc i32:$src)),
 681   (COPY $src)
 682 >;
 683
 684 def : Pat <
 685   (i16 (trunc i64:$src)),
 686   (EXTRACT_SUBREG $src, sub0)
 687 >;
 688
 689 } // End Predicates = [isVI]