contrib/llvm/lib/Target/WebAssembly/WebAssemblyInstrInteger.td

   1 // WebAssemblyInstrInteger.td-WebAssembly Integer codegen -------*- tablegen -*-
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 ///
  10 /// \file
  11 /// \brief WebAssembly Integer operand code-gen constructs.
  12 ///
  13 //===----------------------------------------------------------------------===//
  14
  15 let Defs = [ARGUMENTS] in {
  16
  17 // The spaces after the names are for aesthetic purposes only, to make
  18 // operands line up vertically after tab expansion.
  19 let isCommutable = 1 in
  20 defm ADD : BinaryInt<add, "add ">;
  21 defm SUB : BinaryInt<sub, "sub ">;
  22 let isCommutable = 1 in
  23 defm MUL : BinaryInt<mul, "mul ">;
  24 // Divide and remainder trap on a zero denominator.
  25 let hasSideEffects = 1 in {
  26 defm DIV_S : BinaryInt<sdiv, "div_s">;
  27 defm DIV_U : BinaryInt<udiv, "div_u">;
  28 defm REM_S : BinaryInt<srem, "rem_s">;
  29 defm REM_U : BinaryInt<urem, "rem_u">;
  30 } // hasSideEffects = 1
  31 let isCommutable = 1 in {
  32 defm AND : BinaryInt<and, "and ">;
  33 defm OR : BinaryInt<or, "or  ">;
  34 defm XOR : BinaryInt<xor, "xor ">;
  35 } // isCommutable = 1
  36 defm SHL : BinaryInt<shl, "shl ">;
  37 defm SHR_U : BinaryInt<srl, "shr_u">;
  38 defm SHR_S : BinaryInt<sra, "shr_s">;
  39 defm ROTL : BinaryInt<rotl, "rotl">;
  40 defm ROTR : BinaryInt<rotr, "rotr">;
  41
  42 let isCommutable = 1 in {
  43 defm EQ : ComparisonInt<SETEQ, "eq  ">;
  44 defm NE : ComparisonInt<SETNE, "ne  ">;
  45 } // isCommutable = 1
  46 defm LT_S : ComparisonInt<SETLT, "lt_s">;
  47 defm LE_S : ComparisonInt<SETLE, "le_s">;
  48 defm LT_U : ComparisonInt<SETULT, "lt_u">;
  49 defm LE_U : ComparisonInt<SETULE, "le_u">;
  50 defm GT_S : ComparisonInt<SETGT, "gt_s">;
  51 defm GE_S : ComparisonInt<SETGE, "ge_s">;
  52 defm GT_U : ComparisonInt<SETUGT, "gt_u">;
  53 defm GE_U : ComparisonInt<SETUGE, "ge_u">;
  54
  55 defm CLZ : UnaryInt<ctlz, "clz ">;
  56 defm CTZ : UnaryInt<cttz, "ctz ">;
  57 defm POPCNT : UnaryInt<ctpop, "popcnt">;
  58
  59 def EQZ_I32 : I<(outs I32:$dst), (ins I32:$src),
  60                 [(set I32:$dst, (setcc I32:$src, 0, SETEQ))],
  61                 "i32.eqz \t$dst, $src">;
  62 def EQZ_I64 : I<(outs I32:$dst), (ins I64:$src),
  63                 [(set I32:$dst, (setcc I64:$src, 0, SETEQ))],
  64                 "i64.eqz \t$dst, $src">;
  65
  66 } // Defs = [ARGUMENTS]
  67
  68 // Optimize away an explicit mask on a rotate count.
  69 def : Pat<(rotl I32:$lhs, (and I32:$rhs, 31)), (ROTL_I32 I32:$lhs, I32:$rhs)>;
  70 def : Pat<(rotr I32:$lhs, (and I32:$rhs, 31)), (ROTR_I32 I32:$lhs, I32:$rhs)>;
  71 def : Pat<(rotl I64:$lhs, (and I64:$rhs, 63)), (ROTL_I64 I64:$lhs, I64:$rhs)>;
  72 def : Pat<(rotr I64:$lhs, (and I64:$rhs, 63)), (ROTR_I64 I64:$lhs, I64:$rhs)>;
  73
  74 let Defs = [ARGUMENTS] in {
  75
  76 def SELECT_I32 : I<(outs I32:$dst), (ins I32:$lhs, I32:$rhs, I32:$cond),
  77                    [(set I32:$dst, (select I32:$cond, I32:$lhs, I32:$rhs))],
  78                    "i32.select\t$dst, $lhs, $rhs, $cond">;
  79 def SELECT_I64 : I<(outs I64:$dst), (ins I64:$lhs, I64:$rhs, I32:$cond),
  80                    [(set I64:$dst, (select I32:$cond, I64:$lhs, I64:$rhs))],
  81                    "i64.select\t$dst, $lhs, $rhs, $cond">;
  82
  83 } // Defs = [ARGUMENTS]
  84
  85 // ISD::SELECT requires its operand to conform to getBooleanContents, but
  86 // WebAssembly's select interprets any non-zero value as true, so we can fold
  87 // a setne with 0 into a select.
  88 def : Pat<(select (i32 (setne I32:$cond, 0)), I32:$lhs, I32:$rhs),
  89           (SELECT_I32 I32:$lhs, I32:$rhs, I32:$cond)>;
  90 def : Pat<(select (i32 (setne I32:$cond, 0)), I64:$lhs, I64:$rhs),
  91           (SELECT_I64 I64:$lhs, I64:$rhs, I32:$cond)>;
  92
  93 // And again, this time with seteq instead of setne and the arms reversed.
  94 def : Pat<(select (i32 (seteq I32:$cond, 0)), I32:$lhs, I32:$rhs),
  95           (SELECT_I32 I32:$rhs, I32:$lhs, I32:$cond)>;
  96 def : Pat<(select (i32 (seteq I32:$cond, 0)), I64:$lhs, I64:$rhs),
  97           (SELECT_I64 I64:$rhs, I64:$lhs, I32:$cond)>;