contrib/llvm/lib/Target/WebAssembly/WebAssemblyInstrInteger.td

   1 // WebAssemblyInstrInteger.td-WebAssembly Integer codegen -------*- tablegen -*-
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 ///
  10 /// \file
  11 /// WebAssembly Integer operand code-gen constructs.
  12 ///
  13 //===----------------------------------------------------------------------===//
  14
  15 multiclass UnaryInt<SDNode node, string name, bits<32> i32Inst,
  16                     bits<32> i64Inst> {
  17   defm _I32 : I<(outs I32:$dst), (ins I32:$src), (outs), (ins),
  18                 [(set I32:$dst, (node I32:$src))],
  19                 !strconcat("i32.", !strconcat(name, "\t$dst, $src")),
  20                 !strconcat("i32.", name), i32Inst>;
  21   defm _I64 : I<(outs I64:$dst), (ins I64:$src), (outs), (ins),
  22                 [(set I64:$dst, (node I64:$src))],
  23                 !strconcat("i64.", !strconcat(name, "\t$dst, $src")),
  24                 !strconcat("i64.", name), i64Inst>;
  25 }
  26 multiclass BinaryInt<SDNode node, string name, bits<32> i32Inst,
  27                      bits<32> i64Inst> {
  28   defm _I32 : I<(outs I32:$dst), (ins I32:$lhs, I32:$rhs), (outs), (ins),
  29                 [(set I32:$dst, (node I32:$lhs, I32:$rhs))],
  30                 !strconcat("i32.", !strconcat(name, "\t$dst, $lhs, $rhs")),
  31                 !strconcat("i32.", name), i32Inst>;
  32   defm _I64 : I<(outs I64:$dst), (ins I64:$lhs, I64:$rhs), (outs), (ins),
  33                 [(set I64:$dst, (node I64:$lhs, I64:$rhs))],
  34                 !strconcat("i64.", !strconcat(name, "\t$dst, $lhs, $rhs")),
  35                 !strconcat("i64.", name), i64Inst>;
  36 }
  37 multiclass ComparisonInt<CondCode cond, string name, bits<32> i32Inst, bits<32> i64Inst> {
  38   defm _I32 : I<(outs I32:$dst), (ins I32:$lhs, I32:$rhs), (outs), (ins),
  39                 [(set I32:$dst, (setcc I32:$lhs, I32:$rhs, cond))],
  40                 !strconcat("i32.", !strconcat(name, "\t$dst, $lhs, $rhs")),
  41                 !strconcat("i32.", name), i32Inst>;
  42   defm _I64 : I<(outs I32:$dst), (ins I64:$lhs, I64:$rhs), (outs), (ins),
  43                 [(set I32:$dst, (setcc I64:$lhs, I64:$rhs, cond))],
  44                 !strconcat("i64.", !strconcat(name, "\t$dst, $lhs, $rhs")),
  45                 !strconcat("i64.", name), i64Inst>;
  46 }
  47
  48 // The spaces after the names are for aesthetic purposes only, to make
  49 // operands line up vertically after tab expansion.
  50 let isCommutable = 1 in
  51 defm ADD : BinaryInt<add, "add ", 0x6a, 0x7c>;
  52 defm SUB : BinaryInt<sub, "sub ", 0x6b, 0x7d>;
  53 let isCommutable = 1 in
  54 defm MUL : BinaryInt<mul, "mul ", 0x6c, 0x7e>;
  55 // Divide and remainder trap on a zero denominator.
  56 let hasSideEffects = 1 in {
  57 defm DIV_S : BinaryInt<sdiv, "div_s", 0x6d, 0x7f>;
  58 defm DIV_U : BinaryInt<udiv, "div_u", 0x6e, 0x80>;
  59 defm REM_S : BinaryInt<srem, "rem_s", 0x6f, 0x81>;
  60 defm REM_U : BinaryInt<urem, "rem_u", 0x70, 0x82>;
  61 } // hasSideEffects = 1
  62 let isCommutable = 1 in {
  63 defm AND : BinaryInt<and, "and ", 0x71, 0x83>;
  64 defm OR : BinaryInt<or, "or  ", 0x72, 0x84>;
  65 defm XOR : BinaryInt<xor, "xor ", 0x73, 0x85>;
  66 } // isCommutable = 1
  67 defm SHL : BinaryInt<shl, "shl ", 0x74, 0x86>;
  68 defm SHR_S : BinaryInt<sra, "shr_s", 0x75, 0x87>;
  69 defm SHR_U : BinaryInt<srl, "shr_u", 0x76, 0x88>;
  70 defm ROTL : BinaryInt<rotl, "rotl", 0x77, 0x89>;
  71 defm ROTR : BinaryInt<rotr, "rotr", 0x78, 0x8a>;
  72
  73 let isCommutable = 1 in {
  74 defm EQ : ComparisonInt<SETEQ, "eq  ", 0x46, 0x51>;
  75 defm NE : ComparisonInt<SETNE, "ne  ", 0x47, 0x52>;
  76 } // isCommutable = 1
  77 defm LT_S : ComparisonInt<SETLT,  "lt_s", 0x48, 0x53>;
  78 defm LT_U : ComparisonInt<SETULT, "lt_u", 0x49, 0x54>;
  79 defm GT_S : ComparisonInt<SETGT,  "gt_s", 0x4a, 0x55>;
  80 defm GT_U : ComparisonInt<SETUGT, "gt_u", 0x4b, 0x56>;
  81 defm LE_S : ComparisonInt<SETLE,  "le_s", 0x4c, 0x57>;
  82 defm LE_U : ComparisonInt<SETULE, "le_u", 0x4d, 0x58>;
  83 defm GE_S : ComparisonInt<SETGE,  "ge_s", 0x4e, 0x59>;
  84 defm GE_U : ComparisonInt<SETUGE, "ge_u", 0x4f, 0x5a>;
  85
  86 defm CLZ : UnaryInt<ctlz, "clz ", 0x67, 0x79>;
  87 defm CTZ : UnaryInt<cttz, "ctz ", 0x68, 0x7a>;
  88 defm POPCNT : UnaryInt<ctpop, "popcnt", 0x69, 0x7b>;
  89
  90 defm EQZ_I32 : I<(outs I32:$dst), (ins I32:$src), (outs), (ins),
  91                  [(set I32:$dst, (setcc I32:$src, 0, SETEQ))],
  92                  "i32.eqz \t$dst, $src", "i32.eqz", 0x45>;
  93 defm EQZ_I64 : I<(outs I32:$dst), (ins I64:$src), (outs), (ins),
  94                  [(set I32:$dst, (setcc I64:$src, 0, SETEQ))],
  95                  "i64.eqz \t$dst, $src", "i64.eqz", 0x50>;
  96
  97 // Optimize away an explicit mask on a rotate count.
  98 def : Pat<(rotl I32:$lhs, (and I32:$rhs, 31)), (ROTL_I32 I32:$lhs, I32:$rhs)>;
  99 def : Pat<(rotr I32:$lhs, (and I32:$rhs, 31)), (ROTR_I32 I32:$lhs, I32:$rhs)>;
 100 def : Pat<(rotl I64:$lhs, (and I64:$rhs, 63)), (ROTL_I64 I64:$lhs, I64:$rhs)>;
 101 def : Pat<(rotr I64:$lhs, (and I64:$rhs, 63)), (ROTR_I64 I64:$lhs, I64:$rhs)>;
 102
 103 defm SELECT_I32 : I<(outs I32:$dst), (ins I32:$lhs, I32:$rhs, I32:$cond),
 104                     (outs), (ins),
 105                     [(set I32:$dst, (select I32:$cond, I32:$lhs, I32:$rhs))],
 106                     "i32.select\t$dst, $lhs, $rhs, $cond", "i32.select", 0x1b>;
 107 defm SELECT_I64 : I<(outs I64:$dst), (ins I64:$lhs, I64:$rhs, I32:$cond),
 108                     (outs), (ins),
 109                     [(set I64:$dst, (select I32:$cond, I64:$lhs, I64:$rhs))],
 110                     "i64.select\t$dst, $lhs, $rhs, $cond", "i64.select", 0x1b>;
 111
 112 // ISD::SELECT requires its operand to conform to getBooleanContents, but
 113 // WebAssembly's select interprets any non-zero value as true, so we can fold
 114 // a setne with 0 into a select.
 115 def : Pat<(select (i32 (setne I32:$cond, 0)), I32:$lhs, I32:$rhs),
 116           (SELECT_I32 I32:$lhs, I32:$rhs, I32:$cond)>;
 117 def : Pat<(select (i32 (setne I32:$cond, 0)), I64:$lhs, I64:$rhs),
 118           (SELECT_I64 I64:$lhs, I64:$rhs, I32:$cond)>;
 119
 120 // And again, this time with seteq instead of setne and the arms reversed.
 121 def : Pat<(select (i32 (seteq I32:$cond, 0)), I32:$lhs, I32:$rhs),
 122           (SELECT_I32 I32:$rhs, I32:$lhs, I32:$cond)>;
 123 def : Pat<(select (i32 (seteq I32:$cond, 0)), I64:$lhs, I64:$rhs),
 124           (SELECT_I64 I64:$rhs, I64:$lhs, I32:$cond)>;