contrib/llvm/lib/Target/WebAssembly/WebAssemblyInstrInteger.td

   1 // WebAssemblyInstrInteger.td-WebAssembly Integer codegen -------*- tablegen -*-
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 ///
  10 /// \file
  11 /// WebAssembly Integer operand code-gen constructs.
  12 ///
  13 //===----------------------------------------------------------------------===//
  14
  15 let Defs = [ARGUMENTS] in {
  16
  17 // The spaces after the names are for aesthetic purposes only, to make
  18 // operands line up vertically after tab expansion.
  19 let isCommutable = 1 in
  20 defm ADD : BinaryInt<add, "add ", 0x6a, 0x7c>;
  21 defm SUB : BinaryInt<sub, "sub ", 0x6b, 0x7d>;
  22 let isCommutable = 1 in
  23 defm MUL : BinaryInt<mul, "mul ", 0x6c, 0x7e>;
  24 // Divide and remainder trap on a zero denominator.
  25 let hasSideEffects = 1 in {
  26 defm DIV_S : BinaryInt<sdiv, "div_s", 0x6d, 0x7f>;
  27 defm DIV_U : BinaryInt<udiv, "div_u", 0x6e, 0x80>;
  28 defm REM_S : BinaryInt<srem, "rem_s", 0x6f, 0x81>;
  29 defm REM_U : BinaryInt<urem, "rem_u", 0x70, 0x82>;
  30 } // hasSideEffects = 1
  31 let isCommutable = 1 in {
  32 defm AND : BinaryInt<and, "and ", 0x71, 0x83>;
  33 defm OR : BinaryInt<or, "or  ", 0x72, 0x84>;
  34 defm XOR : BinaryInt<xor, "xor ", 0x73, 0x85>;
  35 } // isCommutable = 1
  36 defm SHL : BinaryInt<shl, "shl ", 0x74, 0x86>;
  37 defm SHR_S : BinaryInt<sra, "shr_s", 0x75, 0x87>;
  38 defm SHR_U : BinaryInt<srl, "shr_u", 0x76, 0x88>;
  39 defm ROTL : BinaryInt<rotl, "rotl", 0x77, 0x89>;
  40 defm ROTR : BinaryInt<rotr, "rotr", 0x78, 0x8a>;
  41
  42 let isCommutable = 1 in {
  43 defm EQ : ComparisonInt<SETEQ, "eq  ", 0x46, 0x51>;
  44 defm NE : ComparisonInt<SETNE, "ne  ", 0x47, 0x52>;
  45 } // isCommutable = 1
  46 defm LT_S : ComparisonInt<SETLT,  "lt_s", 0x48, 0x53>;
  47 defm LT_U : ComparisonInt<SETULT, "lt_u", 0x49, 0x54>;
  48 defm GT_S : ComparisonInt<SETGT,  "gt_s", 0x4a, 0x55>;
  49 defm GT_U : ComparisonInt<SETUGT, "gt_u", 0x4b, 0x56>;
  50 defm LE_S : ComparisonInt<SETLE,  "le_s", 0x4c, 0x57>;
  51 defm LE_U : ComparisonInt<SETULE, "le_u", 0x4d, 0x58>;
  52 defm GE_S : ComparisonInt<SETGE,  "ge_s", 0x4e, 0x59>;
  53 defm GE_U : ComparisonInt<SETUGE, "ge_u", 0x4f, 0x5a>;
  54
  55 defm CLZ : UnaryInt<ctlz, "clz ", 0x67, 0x79>;
  56 defm CTZ : UnaryInt<cttz, "ctz ", 0x68, 0x7a>;
  57 defm POPCNT : UnaryInt<ctpop, "popcnt", 0x69, 0x7b>;
  58
  59 defm EQZ_I32 : I<(outs I32:$dst), (ins I32:$src), (outs), (ins),
  60                  [(set I32:$dst, (setcc I32:$src, 0, SETEQ))],
  61                  "i32.eqz \t$dst, $src", "i32.eqz", 0x45>;
  62 defm EQZ_I64 : I<(outs I32:$dst), (ins I64:$src), (outs), (ins),
  63                  [(set I32:$dst, (setcc I64:$src, 0, SETEQ))],
  64                  "i64.eqz \t$dst, $src", "i64.eqz", 0x50>;
  65
  66 } // Defs = [ARGUMENTS]
  67
  68 // Optimize away an explicit mask on a rotate count.
  69 def : Pat<(rotl I32:$lhs, (and I32:$rhs, 31)), (ROTL_I32 I32:$lhs, I32:$rhs)>;
  70 def : Pat<(rotr I32:$lhs, (and I32:$rhs, 31)), (ROTR_I32 I32:$lhs, I32:$rhs)>;
  71 def : Pat<(rotl I64:$lhs, (and I64:$rhs, 63)), (ROTL_I64 I64:$lhs, I64:$rhs)>;
  72 def : Pat<(rotr I64:$lhs, (and I64:$rhs, 63)), (ROTR_I64 I64:$lhs, I64:$rhs)>;
  73
  74 let Defs = [ARGUMENTS] in {
  75
  76 defm SELECT_I32 : I<(outs I32:$dst), (ins I32:$lhs, I32:$rhs, I32:$cond),
  77                     (outs), (ins),
  78                     [(set I32:$dst, (select I32:$cond, I32:$lhs, I32:$rhs))],
  79                     "i32.select\t$dst, $lhs, $rhs, $cond", "i32.select", 0x1b>;
  80 defm SELECT_I64 : I<(outs I64:$dst), (ins I64:$lhs, I64:$rhs, I32:$cond),
  81                     (outs), (ins),
  82                     [(set I64:$dst, (select I32:$cond, I64:$lhs, I64:$rhs))],
  83                     "i64.select\t$dst, $lhs, $rhs, $cond", "i64.select", 0x1b>;
  84
  85 } // Defs = [ARGUMENTS]
  86
  87 // ISD::SELECT requires its operand to conform to getBooleanContents, but
  88 // WebAssembly's select interprets any non-zero value as true, so we can fold
  89 // a setne with 0 into a select.
  90 def : Pat<(select (i32 (setne I32:$cond, 0)), I32:$lhs, I32:$rhs),
  91           (SELECT_I32 I32:$lhs, I32:$rhs, I32:$cond)>;
  92 def : Pat<(select (i32 (setne I32:$cond, 0)), I64:$lhs, I64:$rhs),
  93           (SELECT_I64 I64:$lhs, I64:$rhs, I32:$cond)>;
  94
  95 // And again, this time with seteq instead of setne and the arms reversed.
  96 def : Pat<(select (i32 (seteq I32:$cond, 0)), I32:$lhs, I32:$rhs),
  97           (SELECT_I32 I32:$rhs, I32:$lhs, I32:$cond)>;
  98 def : Pat<(select (i32 (seteq I32:$cond, 0)), I64:$lhs, I64:$rhs),
  99           (SELECT_I64 I64:$rhs, I64:$lhs, I32:$cond)>;