contrib/llvm/lib/Target/X86/X86InstrXOP.td

   1 //===-- X86InstrXOP.td - XOP Instruction Set ---------------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes XOP (eXtended OPerations)
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 multiclass xop2op<bits<8> opc, string OpcodeStr, Intrinsic Int, PatFrag memop> {
  15   def rr : IXOP<opc, MRMSrcReg, (outs VR128:$dst), (ins VR128:$src),
  16            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  17            [(set VR128:$dst, (Int VR128:$src))]>, XOP;
  18   def rm : IXOP<opc, MRMSrcMem, (outs VR128:$dst), (ins i128mem:$src),
  19            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  20            [(set VR128:$dst, (Int (bitconvert (memop addr:$src))))]>, XOP;
  21 }
  22
  23 let ExeDomain = SSEPackedInt in {
  24   defm VPHSUBWD  : xop2op<0xE2, "vphsubwd", int_x86_xop_vphsubwd, loadv2i64>;
  25   defm VPHSUBDQ  : xop2op<0xE3, "vphsubdq", int_x86_xop_vphsubdq, loadv2i64>;
  26   defm VPHSUBBW  : xop2op<0xE1, "vphsubbw", int_x86_xop_vphsubbw, loadv2i64>;
  27   defm VPHADDWQ  : xop2op<0xC7, "vphaddwq", int_x86_xop_vphaddwq, loadv2i64>;
  28   defm VPHADDWD  : xop2op<0xC6, "vphaddwd", int_x86_xop_vphaddwd, loadv2i64>;
  29   defm VPHADDUWQ : xop2op<0xD7, "vphadduwq", int_x86_xop_vphadduwq, loadv2i64>;
  30   defm VPHADDUWD : xop2op<0xD6, "vphadduwd", int_x86_xop_vphadduwd, loadv2i64>;
  31   defm VPHADDUDQ : xop2op<0xDB, "vphaddudq", int_x86_xop_vphaddudq, loadv2i64>;
  32   defm VPHADDUBW : xop2op<0xD1, "vphaddubw", int_x86_xop_vphaddubw, loadv2i64>;
  33   defm VPHADDUBQ : xop2op<0xD3, "vphaddubq", int_x86_xop_vphaddubq, loadv2i64>;
  34   defm VPHADDUBD : xop2op<0xD2, "vphaddubd", int_x86_xop_vphaddubd, loadv2i64>;
  35   defm VPHADDDQ  : xop2op<0xCB, "vphadddq", int_x86_xop_vphadddq, loadv2i64>;
  36   defm VPHADDBW  : xop2op<0xC1, "vphaddbw", int_x86_xop_vphaddbw, loadv2i64>;
  37   defm VPHADDBQ  : xop2op<0xC3, "vphaddbq", int_x86_xop_vphaddbq, loadv2i64>;
  38   defm VPHADDBD  : xop2op<0xC2, "vphaddbd", int_x86_xop_vphaddbd, loadv2i64>;
  39 }
  40
  41 // Scalar load 2 addr operand instructions
  42 multiclass xop2opsld<bits<8> opc, string OpcodeStr, Intrinsic Int,
  43                      Operand memop, ComplexPattern mem_cpat> {
  44   def rr : IXOP<opc, MRMSrcReg, (outs VR128:$dst), (ins VR128:$src),
  45            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  46            [(set VR128:$dst, (Int VR128:$src))]>, XOP;
  47   def rm : IXOP<opc, MRMSrcMem, (outs VR128:$dst), (ins memop:$src),
  48            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  49            [(set VR128:$dst, (Int (bitconvert mem_cpat:$src)))]>, XOP;
  50 }
  51
  52 multiclass xop2op128<bits<8> opc, string OpcodeStr, Intrinsic Int,
  53                      PatFrag memop> {
  54   def rr : IXOP<opc, MRMSrcReg, (outs VR128:$dst), (ins VR128:$src),
  55            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  56            [(set VR128:$dst, (Int VR128:$src))]>, XOP;
  57   def rm : IXOP<opc, MRMSrcMem, (outs VR128:$dst), (ins f128mem:$src),
  58            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  59            [(set VR128:$dst, (Int (bitconvert (memop addr:$src))))]>, XOP;
  60 }
  61
  62 multiclass xop2op256<bits<8> opc, string OpcodeStr, Intrinsic Int,
  63                      PatFrag memop> {
  64   def rrY : IXOP<opc, MRMSrcReg, (outs VR256:$dst), (ins VR256:$src),
  65            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  66            [(set VR256:$dst, (Int VR256:$src))]>, XOP, VEX_L;
  67   def rmY : IXOP<opc, MRMSrcMem, (outs VR256:$dst), (ins f256mem:$src),
  68            !strconcat(OpcodeStr, "\t{$src, $dst|$dst, $src}"),
  69            [(set VR256:$dst, (Int (bitconvert (memop addr:$src))))]>, XOP, VEX_L;
  70 }
  71
  72 let ExeDomain = SSEPackedSingle in {
  73   defm VFRCZSS : xop2opsld<0x82, "vfrczss", int_x86_xop_vfrcz_ss,
  74                            ssmem, sse_load_f32>;
  75   defm VFRCZPS : xop2op128<0x80, "vfrczps", int_x86_xop_vfrcz_ps, loadv4f32>;
  76   defm VFRCZPS : xop2op256<0x80, "vfrczps", int_x86_xop_vfrcz_ps_256, loadv8f32>;
  77 }
  78
  79 let ExeDomain = SSEPackedDouble in {
  80   defm VFRCZSD : xop2opsld<0x83, "vfrczsd", int_x86_xop_vfrcz_sd,
  81                            sdmem, sse_load_f64>;
  82   defm VFRCZPD : xop2op128<0x81, "vfrczpd", int_x86_xop_vfrcz_pd, loadv2f64>;
  83   defm VFRCZPD : xop2op256<0x81, "vfrczpd", int_x86_xop_vfrcz_pd_256, loadv4f64>;
  84 }
  85
  86 multiclass xop3op<bits<8> opc, string OpcodeStr, SDNode OpNode,
  87                   ValueType vt128> {
  88   def rr : IXOP<opc, MRMSrcReg4VOp3, (outs VR128:$dst),
  89            (ins VR128:$src1, VR128:$src2),
  90            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
  91            [(set VR128:$dst,
  92               (vt128 (OpNode (vt128 VR128:$src1), (vt128 VR128:$src2))))]>,
  93            XOP, Sched<[WriteVarVecShift]>;
  94   def rm : IXOP<opc, MRMSrcMem, (outs VR128:$dst),
  95            (ins VR128:$src1, i128mem:$src2),
  96            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
  97            [(set VR128:$dst,
  98               (vt128 (OpNode (vt128 VR128:$src1),
  99                              (vt128 (bitconvert (loadv2i64 addr:$src2))))))]>,
 100            XOP_4V, VEX_W, Sched<[WriteVarVecShift, ReadAfterLd]>;
 101   def mr : IXOP<opc, MRMSrcMem4VOp3, (outs VR128:$dst),
 102            (ins i128mem:$src1, VR128:$src2),
 103            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 104            [(set VR128:$dst,
 105               (vt128 (OpNode (vt128 (bitconvert (loadv2i64 addr:$src1))),
 106                              (vt128 VR128:$src2))))]>,
 107              XOP, Sched<[WriteVarVecShift, ReadAfterLd]>;
 108   // For disassembler
 109   let isCodeGenOnly = 1, ForceDisassemble = 1, hasSideEffects = 0 in
 110   def rr_REV : IXOP<opc, MRMSrcReg, (outs VR128:$dst),
 111                (ins VR128:$src1, VR128:$src2),
 112                !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 113                []>,
 114                XOP_4V, VEX_W, Sched<[WriteVarVecShift]>;
 115 }
 116
 117 let ExeDomain = SSEPackedInt in {
 118   defm VPROTB : xop3op<0x90, "vprotb", X86vprot, v16i8>;
 119   defm VPROTD : xop3op<0x92, "vprotd", X86vprot, v4i32>;
 120   defm VPROTQ : xop3op<0x93, "vprotq", X86vprot, v2i64>;
 121   defm VPROTW : xop3op<0x91, "vprotw", X86vprot, v8i16>;
 122   defm VPSHAB : xop3op<0x98, "vpshab", X86vpsha, v16i8>;
 123   defm VPSHAD : xop3op<0x9A, "vpshad", X86vpsha, v4i32>;
 124   defm VPSHAQ : xop3op<0x9B, "vpshaq", X86vpsha, v2i64>;
 125   defm VPSHAW : xop3op<0x99, "vpshaw", X86vpsha, v8i16>;
 126   defm VPSHLB : xop3op<0x94, "vpshlb", X86vpshl, v16i8>;
 127   defm VPSHLD : xop3op<0x96, "vpshld", X86vpshl, v4i32>;
 128   defm VPSHLQ : xop3op<0x97, "vpshlq", X86vpshl, v2i64>;
 129   defm VPSHLW : xop3op<0x95, "vpshlw", X86vpshl, v8i16>;
 130 }
 131
 132 multiclass xop3opimm<bits<8> opc, string OpcodeStr, SDNode OpNode,
 133                      ValueType vt128> {
 134   def ri : IXOPi8<opc, MRMSrcReg, (outs VR128:$dst),
 135            (ins VR128:$src1, u8imm:$src2),
 136            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 137            [(set VR128:$dst,
 138               (vt128 (OpNode (vt128 VR128:$src1), imm:$src2)))]>, XOP;
 139   def mi : IXOPi8<opc, MRMSrcMem, (outs VR128:$dst),
 140            (ins i128mem:$src1, u8imm:$src2),
 141            !strconcat(OpcodeStr, "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 142            [(set VR128:$dst,
 143               (vt128 (OpNode (vt128 (bitconvert (loadv2i64 addr:$src1))), imm:$src2)))]>, XOP;
 144 }
 145
 146 let ExeDomain = SSEPackedInt in {
 147   defm VPROTB : xop3opimm<0xC0, "vprotb", X86vproti, v16i8>;
 148   defm VPROTD : xop3opimm<0xC2, "vprotd", X86vproti, v4i32>;
 149   defm VPROTQ : xop3opimm<0xC3, "vprotq", X86vproti, v2i64>;
 150   defm VPROTW : xop3opimm<0xC1, "vprotw", X86vproti, v8i16>;
 151 }
 152
 153 // Instruction where second source can be memory, but third must be register
 154 multiclass xop4opm2<bits<8> opc, string OpcodeStr, Intrinsic Int> {
 155   let isCommutable = 1 in
 156   def rr : IXOPi8Reg<opc, MRMSrcReg, (outs VR128:$dst),
 157            (ins VR128:$src1, VR128:$src2, VR128:$src3),
 158            !strconcat(OpcodeStr,
 159            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 160            [(set VR128:$dst,
 161               (Int VR128:$src1, VR128:$src2, VR128:$src3))]>, XOP_4V;
 162   def rm : IXOPi8Reg<opc, MRMSrcMem, (outs VR128:$dst),
 163            (ins VR128:$src1, i128mem:$src2, VR128:$src3),
 164            !strconcat(OpcodeStr,
 165            "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 166            [(set VR128:$dst,
 167               (Int VR128:$src1, (bitconvert (loadv2i64 addr:$src2)),
 168               VR128:$src3))]>, XOP_4V;
 169 }
 170
 171 let ExeDomain = SSEPackedInt in {
 172   defm VPMADCSWD  : xop4opm2<0xB6, "vpmadcswd", int_x86_xop_vpmadcswd>;
 173   defm VPMADCSSWD : xop4opm2<0xA6, "vpmadcsswd", int_x86_xop_vpmadcsswd>;
 174   defm VPMACSWW   : xop4opm2<0x95, "vpmacsww", int_x86_xop_vpmacsww>;
 175   defm VPMACSWD   : xop4opm2<0x96, "vpmacswd", int_x86_xop_vpmacswd>;
 176   defm VPMACSSWW  : xop4opm2<0x85, "vpmacssww", int_x86_xop_vpmacssww>;
 177   defm VPMACSSWD  : xop4opm2<0x86, "vpmacsswd", int_x86_xop_vpmacsswd>;
 178   defm VPMACSSDQL : xop4opm2<0x87, "vpmacssdql", int_x86_xop_vpmacssdql>;
 179   defm VPMACSSDQH : xop4opm2<0x8F, "vpmacssdqh", int_x86_xop_vpmacssdqh>;
 180   defm VPMACSSDD  : xop4opm2<0x8E, "vpmacssdd", int_x86_xop_vpmacssdd>;
 181   defm VPMACSDQL  : xop4opm2<0x97, "vpmacsdql", int_x86_xop_vpmacsdql>;
 182   defm VPMACSDQH  : xop4opm2<0x9F, "vpmacsdqh", int_x86_xop_vpmacsdqh>;
 183   defm VPMACSDD   : xop4opm2<0x9E, "vpmacsdd", int_x86_xop_vpmacsdd>;
 184 }
 185
 186 // Instruction where second source can be memory, third must be imm8
 187 multiclass xopvpcom<bits<8> opc, string Suffix, SDNode OpNode, ValueType vt128> {
 188   let isCommutable = 1 in
 189   def ri : IXOPi8<opc, MRMSrcReg, (outs VR128:$dst),
 190            (ins VR128:$src1, VR128:$src2, XOPCC:$cc),
 191            !strconcat("vpcom${cc}", Suffix,
 192            "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 193            [(set VR128:$dst,
 194               (vt128 (OpNode (vt128 VR128:$src1), (vt128 VR128:$src2),
 195                              i8immZExt3:$cc)))]>,
 196            XOP_4V;
 197   def mi : IXOPi8<opc, MRMSrcMem, (outs VR128:$dst),
 198            (ins VR128:$src1, i128mem:$src2, XOPCC:$cc),
 199            !strconcat("vpcom${cc}", Suffix,
 200            "\t{$src2, $src1, $dst|$dst, $src1, $src2}"),
 201            [(set VR128:$dst,
 202               (vt128 (OpNode (vt128 VR128:$src1),
 203                              (vt128 (bitconvert (loadv2i64 addr:$src2))),
 204                               i8immZExt3:$cc)))]>,
 205            XOP_4V;
 206   let isAsmParserOnly = 1, hasSideEffects = 0 in {
 207     def ri_alt : IXOPi8<opc, MRMSrcReg, (outs VR128:$dst),
 208                  (ins VR128:$src1, VR128:$src2, u8imm:$src3),
 209                  !strconcat("vpcom", Suffix,
 210                  "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 211                  []>, XOP_4V;
 212     let mayLoad = 1 in
 213     def mi_alt : IXOPi8<opc, MRMSrcMem, (outs VR128:$dst),
 214                  (ins VR128:$src1, i128mem:$src2, u8imm:$src3),
 215                  !strconcat("vpcom", Suffix,
 216                  "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 217                  []>, XOP_4V;
 218   }
 219 }
 220
 221 let ExeDomain = SSEPackedInt in { // SSE integer instructions
 222   defm VPCOMB  : xopvpcom<0xCC, "b", X86vpcom, v16i8>;
 223   defm VPCOMW  : xopvpcom<0xCD, "w", X86vpcom, v8i16>;
 224   defm VPCOMD  : xopvpcom<0xCE, "d", X86vpcom, v4i32>;
 225   defm VPCOMQ  : xopvpcom<0xCF, "q", X86vpcom, v2i64>;
 226   defm VPCOMUB : xopvpcom<0xEC, "ub", X86vpcomu, v16i8>;
 227   defm VPCOMUW : xopvpcom<0xED, "uw", X86vpcomu, v8i16>;
 228   defm VPCOMUD : xopvpcom<0xEE, "ud", X86vpcomu, v4i32>;
 229   defm VPCOMUQ : xopvpcom<0xEF, "uq", X86vpcomu, v2i64>;
 230 }
 231
 232 multiclass xop4op<bits<8> opc, string OpcodeStr, SDNode OpNode,
 233                   ValueType vt128> {
 234   def rrr : IXOPi8Reg<opc, MRMSrcReg, (outs VR128:$dst),
 235             (ins VR128:$src1, VR128:$src2, VR128:$src3),
 236             !strconcat(OpcodeStr,
 237             "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 238             [(set VR128:$dst,
 239               (vt128 (OpNode (vt128 VR128:$src1), (vt128 VR128:$src2),
 240                              (vt128 VR128:$src3))))]>,
 241             XOP_4V;
 242   def rrm : IXOPi8Reg<opc, MRMSrcMemOp4, (outs VR128:$dst),
 243             (ins VR128:$src1, VR128:$src2, i128mem:$src3),
 244             !strconcat(OpcodeStr,
 245             "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 246             [(set VR128:$dst,
 247               (vt128 (OpNode (vt128 VR128:$src1), (vt128 VR128:$src2),
 248                              (vt128 (bitconvert (loadv2i64 addr:$src3))))))]>,
 249             XOP_4V, VEX_W;
 250   def rmr : IXOPi8Reg<opc, MRMSrcMem, (outs VR128:$dst),
 251             (ins VR128:$src1, i128mem:$src2, VR128:$src3),
 252             !strconcat(OpcodeStr,
 253             "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 254             [(set VR128:$dst,
 255               (v16i8 (OpNode (vt128 VR128:$src1), (vt128 (bitconvert (loadv2i64 addr:$src2))),
 256                              (vt128 VR128:$src3))))]>,
 257             XOP_4V;
 258   // For disassembler
 259   let isCodeGenOnly = 1, ForceDisassemble = 1, hasSideEffects = 0 in
 260   def rrr_REV : IXOPi8Reg<opc, MRMSrcRegOp4, (outs VR128:$dst),
 261                 (ins VR128:$src1, VR128:$src2, VR128:$src3),
 262                 !strconcat(OpcodeStr,
 263                 "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 264                 []>, XOP_4V, VEX_W;
 265 }
 266
 267 let ExeDomain = SSEPackedInt in {
 268   defm VPPERM : xop4op<0xA3, "vpperm", X86vpperm, v16i8>;
 269 }
 270
 271 // Instruction where either second or third source can be memory
 272 multiclass xop4op_int<bits<8> opc, string OpcodeStr,
 273                       Intrinsic Int128, Intrinsic Int256> {
 274   // 128-bit Instruction
 275   def rrr : IXOPi8Reg<opc, MRMSrcReg, (outs VR128:$dst),
 276             (ins VR128:$src1, VR128:$src2, VR128:$src3),
 277             !strconcat(OpcodeStr,
 278             "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 279             [(set VR128:$dst, (Int128 VR128:$src1, VR128:$src2, VR128:$src3))]>,
 280             XOP_4V;
 281   def rrm : IXOPi8Reg<opc, MRMSrcMemOp4, (outs VR128:$dst),
 282             (ins VR128:$src1, VR128:$src2, i128mem:$src3),
 283             !strconcat(OpcodeStr,
 284             "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 285             [(set VR128:$dst,
 286               (Int128 VR128:$src1, VR128:$src2,
 287                (bitconvert (loadv2i64 addr:$src3))))]>,
 288             XOP_4V, VEX_W;
 289   def rmr : IXOPi8Reg<opc, MRMSrcMem, (outs VR128:$dst),
 290             (ins VR128:$src1, i128mem:$src2, VR128:$src3),
 291             !strconcat(OpcodeStr,
 292             "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 293             [(set VR128:$dst,
 294               (Int128 VR128:$src1, (bitconvert (loadv2i64 addr:$src2)),
 295                VR128:$src3))]>,
 296             XOP_4V;
 297   // For disassembler
 298   let isCodeGenOnly = 1, ForceDisassemble = 1, hasSideEffects = 0 in
 299   def rrr_REV : IXOPi8Reg<opc, MRMSrcRegOp4, (outs VR128:$dst),
 300             (ins VR128:$src1, VR128:$src2, VR128:$src3),
 301             !strconcat(OpcodeStr,
 302             "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 303             []>, XOP_4V, VEX_W;
 304
 305   // 256-bit Instruction
 306   def rrrY : IXOPi8Reg<opc, MRMSrcReg, (outs VR256:$dst),
 307              (ins VR256:$src1, VR256:$src2, VR256:$src3),
 308              !strconcat(OpcodeStr,
 309              "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 310              [(set VR256:$dst, (Int256 VR256:$src1, VR256:$src2, VR256:$src3))]>,
 311              XOP_4V, VEX_L;
 312   def rrmY : IXOPi8Reg<opc, MRMSrcMemOp4, (outs VR256:$dst),
 313              (ins VR256:$src1, VR256:$src2, i256mem:$src3),
 314              !strconcat(OpcodeStr,
 315              "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 316              [(set VR256:$dst,
 317                (Int256 VR256:$src1, VR256:$src2,
 318                (bitconvert (loadv4i64 addr:$src3))))]>,
 319              XOP_4V, VEX_W, VEX_L;
 320   def rmrY : IXOPi8Reg<opc, MRMSrcMem, (outs VR256:$dst),
 321              (ins VR256:$src1, f256mem:$src2, VR256:$src3),
 322              !strconcat(OpcodeStr,
 323              "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 324              [(set VR256:$dst,
 325                (Int256 VR256:$src1, (bitconvert (loadv4i64 addr:$src2)),
 326                 VR256:$src3))]>,
 327              XOP_4V, VEX_L;
 328   // For disassembler
 329   let isCodeGenOnly = 1, ForceDisassemble = 1, hasSideEffects = 0 in
 330   def rrrY_REV : IXOPi8Reg<opc, MRMSrcRegOp4, (outs VR256:$dst),
 331             (ins VR256:$src1, VR256:$src2, VR256:$src3),
 332             !strconcat(OpcodeStr,
 333             "\t{$src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3}"),
 334             []>, XOP_4V, VEX_W, VEX_L;
 335 }
 336
 337 let ExeDomain = SSEPackedInt in {
 338   defm VPCMOV : xop4op_int<0xA2, "vpcmov",
 339                            int_x86_xop_vpcmov, int_x86_xop_vpcmov_256>;
 340 }
 341
 342 let Predicates = [HasXOP] in {
 343   def : Pat<(v2i64 (or (and VR128:$src3, VR128:$src1),
 344                        (X86andnp VR128:$src3, VR128:$src2))),
 345             (VPCMOVrrr VR128:$src1, VR128:$src2, VR128:$src3)>;
 346
 347   def : Pat<(v4i64 (or (and VR256:$src3, VR256:$src1),
 348                        (X86andnp VR256:$src3, VR256:$src2))),
 349             (VPCMOVrrrY VR256:$src1, VR256:$src2, VR256:$src3)>;
 350 }
 351
 352 multiclass xop5op<bits<8> opc, string OpcodeStr, SDNode OpNode,
 353                   ValueType vt128, ValueType vt256,
 354                   ValueType id128, ValueType id256,
 355                   PatFrag ld_128, PatFrag ld_256> {
 356   def rr : IXOP5<opc, MRMSrcReg, (outs VR128:$dst),
 357         (ins VR128:$src1, VR128:$src2, VR128:$src3, u8imm:$src4),
 358         !strconcat(OpcodeStr,
 359         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 360         [(set VR128:$dst,
 361            (vt128 (OpNode (vt128 VR128:$src1), (vt128 VR128:$src2),
 362                           (id128 VR128:$src3), (i8 imm:$src4))))]>;
 363   def rm : IXOP5<opc, MRMSrcMemOp4, (outs VR128:$dst),
 364         (ins VR128:$src1, VR128:$src2, i128mem:$src3, u8imm:$src4),
 365         !strconcat(OpcodeStr,
 366         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 367         [(set VR128:$dst,
 368            (vt128 (OpNode (vt128 VR128:$src1), (vt128 VR128:$src2),
 369                           (id128 (bitconvert (loadv2i64 addr:$src3))),
 370                           (i8 imm:$src4))))]>,
 371         VEX_W;
 372   def mr : IXOP5<opc, MRMSrcMem, (outs VR128:$dst),
 373         (ins VR128:$src1, f128mem:$src2, VR128:$src3, u8imm:$src4),
 374         !strconcat(OpcodeStr,
 375         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 376         [(set VR128:$dst,
 377            (vt128 (OpNode (vt128 VR128:$src1),
 378                           (vt128 (bitconvert (ld_128 addr:$src2))),
 379                           (id128 VR128:$src3), (i8 imm:$src4))))]>;
 380   // For disassembler
 381   let isCodeGenOnly = 1, ForceDisassemble = 1, hasSideEffects = 0 in
 382   def rr_REV : IXOP5<opc, MRMSrcRegOp4, (outs VR128:$dst),
 383         (ins VR128:$src1, VR128:$src2, VR128:$src3, u8imm:$src4),
 384         !strconcat(OpcodeStr,
 385         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 386         []>, VEX_W;
 387
 388   def rrY : IXOP5<opc, MRMSrcReg, (outs VR256:$dst),
 389         (ins VR256:$src1, VR256:$src2, VR256:$src3, u8imm:$src4),
 390         !strconcat(OpcodeStr,
 391         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 392         [(set VR256:$dst,
 393            (vt256 (OpNode (vt256 VR256:$src1), (vt256 VR256:$src2),
 394                           (id256 VR256:$src3), (i8 imm:$src4))))]>, VEX_L;
 395   def rmY : IXOP5<opc, MRMSrcMemOp4, (outs VR256:$dst),
 396         (ins VR256:$src1, VR256:$src2, i256mem:$src3, u8imm:$src4),
 397         !strconcat(OpcodeStr,
 398         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 399         [(set VR256:$dst,
 400            (vt256 (OpNode (vt256 VR256:$src1), (vt256 VR256:$src2),
 401                           (id256 (bitconvert (loadv4i64 addr:$src3))),
 402                           (i8 imm:$src4))))]>, VEX_W, VEX_L;
 403   def mrY : IXOP5<opc, MRMSrcMem, (outs VR256:$dst),
 404         (ins VR256:$src1, f256mem:$src2, VR256:$src3, u8imm:$src4),
 405         !strconcat(OpcodeStr,
 406         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 407         [(set VR256:$dst,
 408            (vt256 (OpNode (vt256 VR256:$src1),
 409                           (vt256 (bitconvert (ld_256 addr:$src2))),
 410                           (id256 VR256:$src3), (i8 imm:$src4))))]>, VEX_L;
 411   // For disassembler
 412   let isCodeGenOnly = 1, ForceDisassemble = 1, hasSideEffects = 0 in
 413   def rrY_REV : IXOP5<opc, MRMSrcRegOp4, (outs VR256:$dst),
 414         (ins VR256:$src1, VR256:$src2, VR256:$src3, u8imm:$src4),
 415         !strconcat(OpcodeStr,
 416         "\t{$src4, $src3, $src2, $src1, $dst|$dst, $src1, $src2, $src3, $src4}"),
 417         []>, VEX_W, VEX_L;
 418 }
 419
 420 let ExeDomain = SSEPackedDouble in
 421   defm VPERMIL2PD : xop5op<0x49, "vpermil2pd", X86vpermil2, v2f64, v4f64,
 422                            v2i64, v4i64, loadv2f64, loadv4f64>;
 423
 424 let ExeDomain = SSEPackedSingle in
 425   defm VPERMIL2PS : xop5op<0x48, "vpermil2ps", X86vpermil2, v4f32, v8f32,
 426                            v4i32, v8i32, loadv4f32, loadv8f32>;
 427