contrib/llvm/lib/Target/X86/X86RegisterInfo.td

   1 //===- X86RegisterInfo.td - Describe the X86 Register File --*- tablegen -*-==//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 Register file, defining the registers themselves,
  11 // aliases between the registers, and the register classes built out of the
  12 // registers.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 class X86Reg<string n, bits<16> Enc, list<Register> subregs = []> : Register<n> {
  17   let Namespace = "X86";
  18   let HWEncoding = Enc;
  19   let SubRegs = subregs;
  20 }
  21
  22 // Subregister indices.
  23 let Namespace = "X86" in {
  24   def sub_8bit     : SubRegIndex<8>;
  25   def sub_8bit_hi  : SubRegIndex<8, 8>;
  26   def sub_8bit_hi_phony  : SubRegIndex<8, 8>;
  27   def sub_16bit    : SubRegIndex<16>;
  28   def sub_16bit_hi : SubRegIndex<16, 16>;
  29   def sub_32bit    : SubRegIndex<32>;
  30   def sub_xmm      : SubRegIndex<128>;
  31   def sub_ymm      : SubRegIndex<256>;
  32 }
  33
  34 //===----------------------------------------------------------------------===//
  35 //  Register definitions...
  36 //
  37
  38 // In the register alias definitions below, we define which registers alias
  39 // which others.  We only specify which registers the small registers alias,
  40 // because the register file generator is smart enough to figure out that
  41 // AL aliases AX if we tell it that AX aliased AL (for example).
  42
  43 // Dwarf numbering is different for 32-bit and 64-bit, and there are
  44 // variations by target as well. Currently the first entry is for X86-64,
  45 // second - for EH on X86-32/Darwin and third is 'generic' one (X86-32/Linux
  46 // and debug information on X86-32/Darwin)
  47
  48 // 8-bit registers
  49 // Low registers
  50 def AL : X86Reg<"al", 0>;
  51 def DL : X86Reg<"dl", 2>;
  52 def CL : X86Reg<"cl", 1>;
  53 def BL : X86Reg<"bl", 3>;
  54
  55 // High registers. On x86-64, these cannot be used in any instruction
  56 // with a REX prefix.
  57 def AH : X86Reg<"ah", 4>;
  58 def DH : X86Reg<"dh", 6>;
  59 def CH : X86Reg<"ch", 5>;
  60 def BH : X86Reg<"bh", 7>;
  61
  62 // X86-64 only, requires REX.
  63 let CostPerUse = 1 in {
  64 def SIL  : X86Reg<"sil",   6>;
  65 def DIL  : X86Reg<"dil",   7>;
  66 def BPL  : X86Reg<"bpl",   5>;
  67 def SPL  : X86Reg<"spl",   4>;
  68 def R8B  : X86Reg<"r8b",   8>;
  69 def R9B  : X86Reg<"r9b",   9>;
  70 def R10B : X86Reg<"r10b", 10>;
  71 def R11B : X86Reg<"r11b", 11>;
  72 def R12B : X86Reg<"r12b", 12>;
  73 def R13B : X86Reg<"r13b", 13>;
  74 def R14B : X86Reg<"r14b", 14>;
  75 def R15B : X86Reg<"r15b", 15>;
  76 }
  77
  78 let isArtificial = 1 in {
  79 // High byte of the low 16 bits of the super-register:
  80 def SIH   : X86Reg<"", -1>;
  81 def DIH   : X86Reg<"", -1>;
  82 def BPH   : X86Reg<"", -1>;
  83 def SPH   : X86Reg<"", -1>;
  84 def R8BH  : X86Reg<"", -1>;
  85 def R9BH  : X86Reg<"", -1>;
  86 def R10BH : X86Reg<"", -1>;
  87 def R11BH : X86Reg<"", -1>;
  88 def R12BH : X86Reg<"", -1>;
  89 def R13BH : X86Reg<"", -1>;
  90 def R14BH : X86Reg<"", -1>;
  91 def R15BH : X86Reg<"", -1>;
  92 // High word of the low 32 bits of the super-register:
  93 def HAX   : X86Reg<"", -1>;
  94 def HDX   : X86Reg<"", -1>;
  95 def HCX   : X86Reg<"", -1>;
  96 def HBX   : X86Reg<"", -1>;
  97 def HSI   : X86Reg<"", -1>;
  98 def HDI   : X86Reg<"", -1>;
  99 def HBP   : X86Reg<"", -1>;
 100 def HSP   : X86Reg<"", -1>;
 101 def HIP   : X86Reg<"", -1>;
 102 def R8WH  : X86Reg<"", -1>;
 103 def R9WH  : X86Reg<"", -1>;
 104 def R10WH : X86Reg<"", -1>;
 105 def R11WH : X86Reg<"", -1>;
 106 def R12WH : X86Reg<"", -1>;
 107 def R13WH : X86Reg<"", -1>;
 108 def R14WH : X86Reg<"", -1>;
 109 def R15WH : X86Reg<"", -1>;
 110 }
 111
 112 // 16-bit registers
 113 let SubRegIndices = [sub_8bit, sub_8bit_hi], CoveredBySubRegs = 1 in {
 114 def AX : X86Reg<"ax", 0, [AL,AH]>;
 115 def DX : X86Reg<"dx", 2, [DL,DH]>;
 116 def CX : X86Reg<"cx", 1, [CL,CH]>;
 117 def BX : X86Reg<"bx", 3, [BL,BH]>;
 118 }
 119 let SubRegIndices = [sub_8bit, sub_8bit_hi_phony], CoveredBySubRegs = 1 in {
 120 def SI : X86Reg<"si", 6, [SIL,SIH]>;
 121 def DI : X86Reg<"di", 7, [DIL,DIH]>;
 122 def BP : X86Reg<"bp", 5, [BPL,BPH]>;
 123 def SP : X86Reg<"sp", 4, [SPL,SPH]>;
 124 }
 125 def IP : X86Reg<"ip", 0>;
 126
 127 // X86-64 only, requires REX.
 128 let SubRegIndices = [sub_8bit, sub_8bit_hi_phony], CostPerUse = 1,
 129     CoveredBySubRegs = 1 in {
 130 def R8W  : X86Reg<"r8w",   8, [R8B,R8BH]>;
 131 def R9W  : X86Reg<"r9w",   9, [R9B,R9BH]>;
 132 def R10W : X86Reg<"r10w", 10, [R10B,R10BH]>;
 133 def R11W : X86Reg<"r11w", 11, [R11B,R11BH]>;
 134 def R12W : X86Reg<"r12w", 12, [R12B,R12BH]>;
 135 def R13W : X86Reg<"r13w", 13, [R13B,R13BH]>;
 136 def R14W : X86Reg<"r14w", 14, [R14B,R14BH]>;
 137 def R15W : X86Reg<"r15w", 15, [R15B,R15BH]>;
 138 }
 139
 140 // 32-bit registers
 141 let SubRegIndices = [sub_16bit, sub_16bit_hi], CoveredBySubRegs = 1 in {
 142 def EAX : X86Reg<"eax", 0, [AX, HAX]>, DwarfRegNum<[-2, 0, 0]>;
 143 def EDX : X86Reg<"edx", 2, [DX, HDX]>, DwarfRegNum<[-2, 2, 2]>;
 144 def ECX : X86Reg<"ecx", 1, [CX, HCX]>, DwarfRegNum<[-2, 1, 1]>;
 145 def EBX : X86Reg<"ebx", 3, [BX, HBX]>, DwarfRegNum<[-2, 3, 3]>;
 146 def ESI : X86Reg<"esi", 6, [SI, HSI]>, DwarfRegNum<[-2, 6, 6]>;
 147 def EDI : X86Reg<"edi", 7, [DI, HDI]>, DwarfRegNum<[-2, 7, 7]>;
 148 def EBP : X86Reg<"ebp", 5, [BP, HBP]>, DwarfRegNum<[-2, 4, 5]>;
 149 def ESP : X86Reg<"esp", 4, [SP, HSP]>, DwarfRegNum<[-2, 5, 4]>;
 150 def EIP : X86Reg<"eip", 0, [IP, HIP]>, DwarfRegNum<[-2, 8, 8]>;
 151 }
 152
 153 // X86-64 only, requires REX
 154 let SubRegIndices = [sub_16bit, sub_16bit_hi], CostPerUse = 1,
 155     CoveredBySubRegs = 1 in {
 156 def R8D  : X86Reg<"r8d",   8, [R8W,R8WH]>;
 157 def R9D  : X86Reg<"r9d",   9, [R9W,R9WH]>;
 158 def R10D : X86Reg<"r10d", 10, [R10W,R10WH]>;
 159 def R11D : X86Reg<"r11d", 11, [R11W,R11WH]>;
 160 def R12D : X86Reg<"r12d", 12, [R12W,R12WH]>;
 161 def R13D : X86Reg<"r13d", 13, [R13W,R13WH]>;
 162 def R14D : X86Reg<"r14d", 14, [R14W,R14WH]>;
 163 def R15D : X86Reg<"r15d", 15, [R15W,R15WH]>;
 164 }
 165
 166 // 64-bit registers, X86-64 only
 167 let SubRegIndices = [sub_32bit] in {
 168 def RAX : X86Reg<"rax", 0, [EAX]>, DwarfRegNum<[0, -2, -2]>;
 169 def RDX : X86Reg<"rdx", 2, [EDX]>, DwarfRegNum<[1, -2, -2]>;
 170 def RCX : X86Reg<"rcx", 1, [ECX]>, DwarfRegNum<[2, -2, -2]>;
 171 def RBX : X86Reg<"rbx", 3, [EBX]>, DwarfRegNum<[3, -2, -2]>;
 172 def RSI : X86Reg<"rsi", 6, [ESI]>, DwarfRegNum<[4, -2, -2]>;
 173 def RDI : X86Reg<"rdi", 7, [EDI]>, DwarfRegNum<[5, -2, -2]>;
 174 def RBP : X86Reg<"rbp", 5, [EBP]>, DwarfRegNum<[6, -2, -2]>;
 175 def RSP : X86Reg<"rsp", 4, [ESP]>, DwarfRegNum<[7, -2, -2]>;
 176
 177 // These also require REX.
 178 let CostPerUse = 1 in {
 179 def R8  : X86Reg<"r8",   8, [R8D]>,  DwarfRegNum<[ 8, -2, -2]>;
 180 def R9  : X86Reg<"r9",   9, [R9D]>,  DwarfRegNum<[ 9, -2, -2]>;
 181 def R10 : X86Reg<"r10", 10, [R10D]>, DwarfRegNum<[10, -2, -2]>;
 182 def R11 : X86Reg<"r11", 11, [R11D]>, DwarfRegNum<[11, -2, -2]>;
 183 def R12 : X86Reg<"r12", 12, [R12D]>, DwarfRegNum<[12, -2, -2]>;
 184 def R13 : X86Reg<"r13", 13, [R13D]>, DwarfRegNum<[13, -2, -2]>;
 185 def R14 : X86Reg<"r14", 14, [R14D]>, DwarfRegNum<[14, -2, -2]>;
 186 def R15 : X86Reg<"r15", 15, [R15D]>, DwarfRegNum<[15, -2, -2]>;
 187 def RIP : X86Reg<"rip",  0, [EIP]>,  DwarfRegNum<[16, -2, -2]>;
 188 }}
 189
 190 // MMX Registers. These are actually aliased to ST0 .. ST7
 191 def MM0 : X86Reg<"mm0", 0>, DwarfRegNum<[41, 29, 29]>;
 192 def MM1 : X86Reg<"mm1", 1>, DwarfRegNum<[42, 30, 30]>;
 193 def MM2 : X86Reg<"mm2", 2>, DwarfRegNum<[43, 31, 31]>;
 194 def MM3 : X86Reg<"mm3", 3>, DwarfRegNum<[44, 32, 32]>;
 195 def MM4 : X86Reg<"mm4", 4>, DwarfRegNum<[45, 33, 33]>;
 196 def MM5 : X86Reg<"mm5", 5>, DwarfRegNum<[46, 34, 34]>;
 197 def MM6 : X86Reg<"mm6", 6>, DwarfRegNum<[47, 35, 35]>;
 198 def MM7 : X86Reg<"mm7", 7>, DwarfRegNum<[48, 36, 36]>;
 199
 200 // Pseudo Floating Point registers
 201 def FP0 : X86Reg<"fp0", 0>;
 202 def FP1 : X86Reg<"fp1", 0>;
 203 def FP2 : X86Reg<"fp2", 0>;
 204 def FP3 : X86Reg<"fp3", 0>;
 205 def FP4 : X86Reg<"fp4", 0>;
 206 def FP5 : X86Reg<"fp5", 0>;
 207 def FP6 : X86Reg<"fp6", 0>;
 208 def FP7 : X86Reg<"fp7", 0>;
 209
 210 // XMM Registers, used by the various SSE instruction set extensions.
 211 def XMM0: X86Reg<"xmm0", 0>, DwarfRegNum<[17, 21, 21]>;
 212 def XMM1: X86Reg<"xmm1", 1>, DwarfRegNum<[18, 22, 22]>;
 213 def XMM2: X86Reg<"xmm2", 2>, DwarfRegNum<[19, 23, 23]>;
 214 def XMM3: X86Reg<"xmm3", 3>, DwarfRegNum<[20, 24, 24]>;
 215 def XMM4: X86Reg<"xmm4", 4>, DwarfRegNum<[21, 25, 25]>;
 216 def XMM5: X86Reg<"xmm5", 5>, DwarfRegNum<[22, 26, 26]>;
 217 def XMM6: X86Reg<"xmm6", 6>, DwarfRegNum<[23, 27, 27]>;
 218 def XMM7: X86Reg<"xmm7", 7>, DwarfRegNum<[24, 28, 28]>;
 219
 220 // X86-64 only
 221 let CostPerUse = 1 in {
 222 def XMM8:  X86Reg<"xmm8",   8>, DwarfRegNum<[25, -2, -2]>;
 223 def XMM9:  X86Reg<"xmm9",   9>, DwarfRegNum<[26, -2, -2]>;
 224 def XMM10: X86Reg<"xmm10", 10>, DwarfRegNum<[27, -2, -2]>;
 225 def XMM11: X86Reg<"xmm11", 11>, DwarfRegNum<[28, -2, -2]>;
 226 def XMM12: X86Reg<"xmm12", 12>, DwarfRegNum<[29, -2, -2]>;
 227 def XMM13: X86Reg<"xmm13", 13>, DwarfRegNum<[30, -2, -2]>;
 228 def XMM14: X86Reg<"xmm14", 14>, DwarfRegNum<[31, -2, -2]>;
 229 def XMM15: X86Reg<"xmm15", 15>, DwarfRegNum<[32, -2, -2]>;
 230
 231 def XMM16:  X86Reg<"xmm16", 16>, DwarfRegNum<[67, -2, -2]>;
 232 def XMM17:  X86Reg<"xmm17", 17>, DwarfRegNum<[68, -2, -2]>;
 233 def XMM18:  X86Reg<"xmm18", 18>, DwarfRegNum<[69, -2, -2]>;
 234 def XMM19:  X86Reg<"xmm19", 19>, DwarfRegNum<[70, -2, -2]>;
 235 def XMM20:  X86Reg<"xmm20", 20>, DwarfRegNum<[71, -2, -2]>;
 236 def XMM21:  X86Reg<"xmm21", 21>, DwarfRegNum<[72, -2, -2]>;
 237 def XMM22:  X86Reg<"xmm22", 22>, DwarfRegNum<[73, -2, -2]>;
 238 def XMM23:  X86Reg<"xmm23", 23>, DwarfRegNum<[74, -2, -2]>;
 239 def XMM24:  X86Reg<"xmm24", 24>, DwarfRegNum<[75, -2, -2]>;
 240 def XMM25:  X86Reg<"xmm25", 25>, DwarfRegNum<[76, -2, -2]>;
 241 def XMM26:  X86Reg<"xmm26", 26>, DwarfRegNum<[77, -2, -2]>;
 242 def XMM27:  X86Reg<"xmm27", 27>, DwarfRegNum<[78, -2, -2]>;
 243 def XMM28:  X86Reg<"xmm28", 28>, DwarfRegNum<[79, -2, -2]>;
 244 def XMM29:  X86Reg<"xmm29", 29>, DwarfRegNum<[80, -2, -2]>;
 245 def XMM30:  X86Reg<"xmm30", 30>, DwarfRegNum<[81, -2, -2]>;
 246 def XMM31:  X86Reg<"xmm31", 31>, DwarfRegNum<[82, -2, -2]>;
 247
 248 } // CostPerUse
 249
 250 // YMM0-15 registers, used by AVX instructions and
 251 // YMM16-31 registers, used by AVX-512 instructions.
 252 let SubRegIndices = [sub_xmm] in {
 253   foreach  Index = 0-31 in {
 254     def YMM#Index : X86Reg<"ymm"#Index, Index, [!cast<X86Reg>("XMM"#Index)]>,
 255                     DwarfRegAlias<!cast<X86Reg>("XMM"#Index)>;
 256   }
 257 }
 258
 259 // ZMM Registers, used by AVX-512 instructions.
 260 let SubRegIndices = [sub_ymm] in {
 261   foreach  Index = 0-31 in {
 262     def ZMM#Index : X86Reg<"zmm"#Index, Index, [!cast<X86Reg>("YMM"#Index)]>,
 263                     DwarfRegAlias<!cast<X86Reg>("XMM"#Index)>;
 264   }
 265 }
 266
 267 // Mask Registers, used by AVX-512 instructions.
 268 def K0 : X86Reg<"k0", 0>, DwarfRegNum<[118,  93,  93]>;
 269 def K1 : X86Reg<"k1", 1>, DwarfRegNum<[119,  94,  94]>;
 270 def K2 : X86Reg<"k2", 2>, DwarfRegNum<[120,  95,  95]>;
 271 def K3 : X86Reg<"k3", 3>, DwarfRegNum<[121,  96,  96]>;
 272 def K4 : X86Reg<"k4", 4>, DwarfRegNum<[122,  97,  97]>;
 273 def K5 : X86Reg<"k5", 5>, DwarfRegNum<[123,  98,  98]>;
 274 def K6 : X86Reg<"k6", 6>, DwarfRegNum<[124,  99,  99]>;
 275 def K7 : X86Reg<"k7", 7>, DwarfRegNum<[125, 100, 100]>;
 276
 277 // Floating point stack registers. These don't map one-to-one to the FP
 278 // pseudo registers, but we still mark them as aliasing FP registers. That
 279 // way both kinds can be live without exceeding the stack depth. ST registers
 280 // are only live around inline assembly.
 281 def ST0 : X86Reg<"st(0)", 0>, DwarfRegNum<[33, 12, 11]>;
 282 def ST1 : X86Reg<"st(1)", 1>, DwarfRegNum<[34, 13, 12]>;
 283 def ST2 : X86Reg<"st(2)", 2>, DwarfRegNum<[35, 14, 13]>;
 284 def ST3 : X86Reg<"st(3)", 3>, DwarfRegNum<[36, 15, 14]>;
 285 def ST4 : X86Reg<"st(4)", 4>, DwarfRegNum<[37, 16, 15]>;
 286 def ST5 : X86Reg<"st(5)", 5>, DwarfRegNum<[38, 17, 16]>;
 287 def ST6 : X86Reg<"st(6)", 6>, DwarfRegNum<[39, 18, 17]>;
 288 def ST7 : X86Reg<"st(7)", 7>, DwarfRegNum<[40, 19, 18]>;
 289
 290 // Floating-point status word
 291 def FPSW : X86Reg<"fpsr", 0>;
 292
 293 // Floating-point control word
 294 def FPCW : X86Reg<"fpcr", 0>;
 295
 296 // Status flags register.
 297 //
 298 // Note that some flags that are commonly thought of as part of the status
 299 // flags register are modeled separately. Typically this is due to instructions
 300 // reading and updating those flags independently of all the others. We don't
 301 // want to create false dependencies between these instructions and so we use
 302 // a separate register to model them.
 303 def EFLAGS : X86Reg<"flags", 0>;
 304
 305 // The direction flag.
 306 def DF : X86Reg<"dirflag", 0>;
 307
 308
 309 // Segment registers
 310 def CS : X86Reg<"cs", 1>;
 311 def DS : X86Reg<"ds", 3>;
 312 def SS : X86Reg<"ss", 2>;
 313 def ES : X86Reg<"es", 0>;
 314 def FS : X86Reg<"fs", 4>;
 315 def GS : X86Reg<"gs", 5>;
 316
 317 // Debug registers
 318 def DR0  : X86Reg<"dr0",   0>;
 319 def DR1  : X86Reg<"dr1",   1>;
 320 def DR2  : X86Reg<"dr2",   2>;
 321 def DR3  : X86Reg<"dr3",   3>;
 322 def DR4  : X86Reg<"dr4",   4>;
 323 def DR5  : X86Reg<"dr5",   5>;
 324 def DR6  : X86Reg<"dr6",   6>;
 325 def DR7  : X86Reg<"dr7",   7>;
 326 def DR8  : X86Reg<"dr8",   8>;
 327 def DR9  : X86Reg<"dr9",   9>;
 328 def DR10 : X86Reg<"dr10", 10>;
 329 def DR11 : X86Reg<"dr11", 11>;
 330 def DR12 : X86Reg<"dr12", 12>;
 331 def DR13 : X86Reg<"dr13", 13>;
 332 def DR14 : X86Reg<"dr14", 14>;
 333 def DR15 : X86Reg<"dr15", 15>;
 334
 335 // Control registers
 336 def CR0  : X86Reg<"cr0",   0>;
 337 def CR1  : X86Reg<"cr1",   1>;
 338 def CR2  : X86Reg<"cr2",   2>;
 339 def CR3  : X86Reg<"cr3",   3>;
 340 def CR4  : X86Reg<"cr4",   4>;
 341 def CR5  : X86Reg<"cr5",   5>;
 342 def CR6  : X86Reg<"cr6",   6>;
 343 def CR7  : X86Reg<"cr7",   7>;
 344 def CR8  : X86Reg<"cr8",   8>;
 345 def CR9  : X86Reg<"cr9",   9>;
 346 def CR10 : X86Reg<"cr10", 10>;
 347 def CR11 : X86Reg<"cr11", 11>;
 348 def CR12 : X86Reg<"cr12", 12>;
 349 def CR13 : X86Reg<"cr13", 13>;
 350 def CR14 : X86Reg<"cr14", 14>;
 351 def CR15 : X86Reg<"cr15", 15>;
 352
 353 // Pseudo index registers
 354 def EIZ : X86Reg<"eiz", 4>;
 355 def RIZ : X86Reg<"riz", 4>;
 356
 357 // Bound registers, used in MPX instructions
 358 def BND0 : X86Reg<"bnd0",   0>;
 359 def BND1 : X86Reg<"bnd1",   1>;
 360 def BND2 : X86Reg<"bnd2",   2>;
 361 def BND3 : X86Reg<"bnd3",   3>;
 362
 363 // CET registers - Shadow Stack Pointer
 364 def SSP : X86Reg<"ssp", 0>;
 365
 366 //===----------------------------------------------------------------------===//
 367 // Register Class Definitions... now that we have all of the pieces, define the
 368 // top-level register classes.  The order specified in the register list is
 369 // implicitly defined to be the register allocation order.
 370 //
 371
 372 // List call-clobbered registers before callee-save registers. RBX, RBP, (and
 373 // R12, R13, R14, and R15 for X86-64) are callee-save registers.
 374 // In 64-mode, there are 12 additional i8 registers, SIL, DIL, BPL, SPL, and
 375 // R8B, ... R15B.
 376 // Allocate R12 and R13 last, as these require an extra byte when
 377 // encoded in x86_64 instructions.
 378 // FIXME: Allow AH, CH, DH, BH to be used as general-purpose registers in
 379 // 64-bit mode. The main complication is that they cannot be encoded in an
 380 // instruction requiring a REX prefix, while SIL, DIL, BPL, R8D, etc.
 381 // require a REX prefix. For example, "addb %ah, %dil" and "movzbl %ah, %r8d"
 382 // cannot be encoded.
 383 def GR8 : RegisterClass<"X86", [i8],  8,
 384                         (add AL, CL, DL, AH, CH, DH, BL, BH, SIL, DIL, BPL, SPL,
 385                              R8B, R9B, R10B, R11B, R14B, R15B, R12B, R13B)> {
 386   let AltOrders = [(sub GR8, AH, BH, CH, DH)];
 387   let AltOrderSelect = [{
 388     return MF.getSubtarget<X86Subtarget>().is64Bit();
 389   }];
 390 }
 391
 392 let isAllocatable = 0 in
 393 def GRH8 : RegisterClass<"X86", [i8],  8,
 394                          (add SIH, DIH, BPH, SPH, R8BH, R9BH, R10BH, R11BH,
 395                               R12BH, R13BH, R14BH, R15BH)>;
 396
 397 def GR16 : RegisterClass<"X86", [i16], 16,
 398                          (add AX, CX, DX, SI, DI, BX, BP, SP,
 399                               R8W, R9W, R10W, R11W, R14W, R15W, R12W, R13W)>;
 400
 401 let isAllocatable = 0 in
 402 def GRH16 : RegisterClass<"X86", [i16], 16,
 403                           (add HAX, HCX, HDX, HSI, HDI, HBX, HBP, HSP, HIP,
 404                                R8WH, R9WH, R10WH, R11WH, R12WH, R13WH, R14WH,
 405                                R15WH)>;
 406
 407 def GR32 : RegisterClass<"X86", [i32], 32,
 408                          (add EAX, ECX, EDX, ESI, EDI, EBX, EBP, ESP,
 409                               R8D, R9D, R10D, R11D, R14D, R15D, R12D, R13D)>;
 410
 411 // GR64 - 64-bit GPRs. This oddly includes RIP, which isn't accurate, since
 412 // RIP isn't really a register and it can't be used anywhere except in an
 413 // address, but it doesn't cause trouble.
 414 // FIXME: it *does* cause trouble - CheckBaseRegAndIndexReg() has extra
 415 // tests because of the inclusion of RIP in this register class.
 416 def GR64 : RegisterClass<"X86", [i64], 64,
 417                          (add RAX, RCX, RDX, RSI, RDI, R8, R9, R10, R11,
 418                               RBX, R14, R15, R12, R13, RBP, RSP, RIP)>;
 419
 420 // Segment registers for use by MOV instructions (and others) that have a
 421 //   segment register as one operand.  Always contain a 16-bit segment
 422 //   descriptor.
 423 def SEGMENT_REG : RegisterClass<"X86", [i16], 16, (add CS, DS, SS, ES, FS, GS)>;
 424
 425 // Debug registers.
 426 def DEBUG_REG : RegisterClass<"X86", [i32], 32, (sequence "DR%u", 0, 15)>;
 427
 428 // Control registers.
 429 def CONTROL_REG : RegisterClass<"X86", [i64], 64, (sequence "CR%u", 0, 15)>;
 430
 431 // GR8_ABCD_L, GR8_ABCD_H, GR16_ABCD, GR32_ABCD, GR64_ABCD - Subclasses of
 432 // GR8, GR16, GR32, and GR64 which contain just the "a" "b", "c", and "d"
 433 // registers. On x86-32, GR16_ABCD and GR32_ABCD are classes for registers
 434 // that support 8-bit subreg operations. On x86-64, GR16_ABCD, GR32_ABCD,
 435 // and GR64_ABCD are classes for registers that support 8-bit h-register
 436 // operations.
 437 def GR8_ABCD_L : RegisterClass<"X86", [i8], 8, (add AL, CL, DL, BL)>;
 438 def GR8_ABCD_H : RegisterClass<"X86", [i8], 8, (add AH, CH, DH, BH)>;
 439 def GR16_ABCD : RegisterClass<"X86", [i16], 16, (add AX, CX, DX, BX)>;
 440 def GR32_ABCD : RegisterClass<"X86", [i32], 32, (add EAX, ECX, EDX, EBX)>;
 441 def GR64_ABCD : RegisterClass<"X86", [i64], 64, (add RAX, RCX, RDX, RBX)>;
 442 def GR32_TC   : RegisterClass<"X86", [i32], 32, (add EAX, ECX, EDX)>;
 443 def GR64_TC   : RegisterClass<"X86", [i64], 64, (add RAX, RCX, RDX, RSI, RDI,
 444                                                      R8, R9, R11, RIP)>;
 445 def GR64_TCW64 : RegisterClass<"X86", [i64], 64, (add RAX, RCX, RDX,
 446                                                       R8, R9, R10, R11, RIP)>;
 447
 448 // GR8_NOREX - GR8 registers which do not require a REX prefix.
 449 def GR8_NOREX : RegisterClass<"X86", [i8], 8,
 450                               (add AL, CL, DL, AH, CH, DH, BL, BH)> {
 451   let AltOrders = [(sub GR8_NOREX, AH, BH, CH, DH)];
 452   let AltOrderSelect = [{
 453     return MF.getSubtarget<X86Subtarget>().is64Bit();
 454   }];
 455 }
 456 // GR16_NOREX - GR16 registers which do not require a REX prefix.
 457 def GR16_NOREX : RegisterClass<"X86", [i16], 16,
 458                                (add AX, CX, DX, SI, DI, BX, BP, SP)>;
 459 // GR32_NOREX - GR32 registers which do not require a REX prefix.
 460 def GR32_NOREX : RegisterClass<"X86", [i32], 32,
 461                                (add EAX, ECX, EDX, ESI, EDI, EBX, EBP, ESP)>;
 462 // GR64_NOREX - GR64 registers which do not require a REX prefix.
 463 def GR64_NOREX : RegisterClass<"X86", [i64], 64,
 464                             (add RAX, RCX, RDX, RSI, RDI, RBX, RBP, RSP, RIP)>;
 465
 466 // GR32_NOSP - GR32 registers except ESP.
 467 def GR32_NOSP : RegisterClass<"X86", [i32], 32, (sub GR32, ESP)>;
 468
 469 // GR64_NOSP - GR64 registers except RSP (and RIP).
 470 def GR64_NOSP : RegisterClass<"X86", [i64], 64, (sub GR64, RSP, RIP)>;
 471
 472 // GR32_NOREX_NOSP - GR32 registers which do not require a REX prefix except
 473 // ESP.
 474 def GR32_NOREX_NOSP : RegisterClass<"X86", [i32], 32,
 475                                     (and GR32_NOREX, GR32_NOSP)>;
 476
 477 // GR64_NOREX_NOSP - GR64_NOREX registers except RSP.
 478 def GR64_NOREX_NOSP : RegisterClass<"X86", [i64], 64,
 479                                     (and GR64_NOREX, GR64_NOSP)>;
 480
 481 // Register classes used for ABIs that use 32-bit address accesses,
 482 // while using the whole x84_64 ISA.
 483
 484 // In such cases, it is fine to use RIP as we are sure the 32 high
 485 // bits are not set. We do not need variants for NOSP as RIP is not
 486 // allowed there.
 487 // RIP is not spilled anywhere for now, so stick to 32-bit alignment
 488 // to save on memory space.
 489 // FIXME: We could allow all 64bit registers, but we would need
 490 // something to check that the 32 high bits are not set,
 491 // which we do not have right now.
 492 def LOW32_ADDR_ACCESS : RegisterClass<"X86", [i32], 32, (add GR32, RIP)>;
 493
 494 // When RBP is used as a base pointer in a 32-bit addresses environement,
 495 // this is also safe to use the full register to access addresses.
 496 // Since RBP will never be spilled, stick to a 32 alignment to save
 497 // on memory consumption.
 498 def LOW32_ADDR_ACCESS_RBP : RegisterClass<"X86", [i32], 32,
 499                                           (add LOW32_ADDR_ACCESS, RBP)>;
 500
 501 // A class to support the 'A' assembler constraint: [ER]AX then [ER]DX.
 502 def GR32_AD : RegisterClass<"X86", [i32], 32, (add EAX, EDX)>;
 503 def GR64_AD : RegisterClass<"X86", [i64], 64, (add RAX, RDX)>;
 504
 505 // Scalar SSE2 floating point registers.
 506 def FR32 : RegisterClass<"X86", [f32], 32, (sequence "XMM%u", 0, 15)>;
 507
 508 def FR64 : RegisterClass<"X86", [f64], 64, (add FR32)>;
 509
 510
 511 // FIXME: This sets up the floating point register files as though they are f64
 512 // values, though they really are f80 values.  This will cause us to spill
 513 // values as 64-bit quantities instead of 80-bit quantities, which is much much
 514 // faster on common hardware.  In reality, this should be controlled by a
 515 // command line option or something.
 516
 517 def RFP32 : RegisterClass<"X86",[f32], 32, (sequence "FP%u", 0, 6)>;
 518 def RFP64 : RegisterClass<"X86",[f64], 32, (add RFP32)>;
 519 def RFP80 : RegisterClass<"X86",[f80], 32, (add RFP32)>;
 520
 521 // Floating point stack registers (these are not allocatable by the
 522 // register allocator - the floating point stackifier is responsible
 523 // for transforming FPn allocations to STn registers)
 524 def RST : RegisterClass<"X86", [f80, f64, f32], 32, (sequence "ST%u", 0, 7)> {
 525   let isAllocatable = 0;
 526 }
 527
 528 // Generic vector registers: VR64 and VR128.
 529 // Ensure that float types are declared first - only float is legal on SSE1.
 530 def VR64: RegisterClass<"X86", [x86mmx], 64, (sequence "MM%u", 0, 7)>;
 531 def VR128 : RegisterClass<"X86", [v4f32, v2f64, v16i8, v8i16, v4i32, v2i64, f128],
 532                           128, (add FR32)>;
 533 def VR256 : RegisterClass<"X86", [v8f32, v4f64, v32i8, v16i16, v8i32, v4i64],
 534                           256, (sequence "YMM%u", 0, 15)>;
 535
 536 // Special classes that help the assembly parser choose some alternate
 537 // instructions to favor 2-byte VEX encodings.
 538 def VR128L : RegisterClass<"X86", [v4f32, v2f64, v16i8, v8i16, v4i32, v2i64, f128],
 539                            128, (sequence "XMM%u", 0, 7)>;
 540 def VR128H : RegisterClass<"X86", [v4f32, v2f64, v16i8, v8i16, v4i32, v2i64, f128],
 541                            128, (sequence "XMM%u", 8, 15)>;
 542 def VR256L : RegisterClass<"X86", [v8f32, v4f64, v32i8, v16i16, v8i32, v4i64],
 543                            256, (sequence "YMM%u", 0, 7)>;
 544 def VR256H : RegisterClass<"X86", [v8f32, v4f64, v32i8, v16i16, v8i32, v4i64],
 545                            256, (sequence "YMM%u", 8, 15)>;
 546
 547 // Status flags registers.
 548 def CCR : RegisterClass<"X86", [i32], 32, (add EFLAGS)> {
 549   let CopyCost = -1;  // Don't allow copying of status registers.
 550   let isAllocatable = 0;
 551 }
 552 def FPCCR : RegisterClass<"X86", [i16], 16, (add FPSW)> {
 553   let CopyCost = -1;  // Don't allow copying of status registers.
 554   let isAllocatable = 0;
 555 }
 556 def DFCCR : RegisterClass<"X86", [i32], 32, (add DF)> {
 557   let CopyCost = -1;  // Don't allow copying of status registers.
 558   let isAllocatable = 0;
 559 }
 560
 561 // AVX-512 vector/mask registers.
 562 def VR512 : RegisterClass<"X86", [v16f32, v8f64, v64i8, v32i16, v16i32, v8i64],
 563                           512, (sequence "ZMM%u", 0, 31)>;
 564
 565 // Scalar AVX-512 floating point registers.
 566 def FR32X : RegisterClass<"X86", [f32], 32, (sequence "XMM%u", 0, 31)>;
 567
 568 def FR64X : RegisterClass<"X86", [f64], 64, (add FR32X)>;
 569
 570 // Extended VR128 and VR256 for AVX-512 instructions
 571 def VR128X : RegisterClass<"X86", [v4f32, v2f64, v16i8, v8i16, v4i32, v2i64, f128],
 572                            128, (add FR32X)>;
 573 def VR256X : RegisterClass<"X86", [v8f32, v4f64, v32i8, v16i16, v8i32, v4i64],
 574                            256, (sequence "YMM%u", 0, 31)>;
 575
 576 // Mask registers
 577 def VK1     : RegisterClass<"X86", [v1i1],  16,  (sequence "K%u", 0, 7)> {let Size = 16;}
 578 def VK2     : RegisterClass<"X86", [v2i1],  16,  (add VK1)> {let Size = 16;}
 579 def VK4     : RegisterClass<"X86", [v4i1],  16,  (add VK2)> {let Size = 16;}
 580 def VK8     : RegisterClass<"X86", [v8i1],  16,  (add VK4)> {let Size = 16;}
 581 def VK16    : RegisterClass<"X86", [v16i1], 16, (add VK8)> {let Size = 16;}
 582 def VK32    : RegisterClass<"X86", [v32i1], 32, (add VK16)> {let Size = 32;}
 583 def VK64    : RegisterClass<"X86", [v64i1], 64, (add VK32)> {let Size = 64;}
 584
 585 def VK1WM   : RegisterClass<"X86", [v1i1],  16,  (sub VK1, K0)> {let Size = 16;}
 586 def VK2WM   : RegisterClass<"X86", [v2i1],  16,  (sub VK2, K0)> {let Size = 16;}
 587 def VK4WM   : RegisterClass<"X86", [v4i1],  16,  (sub VK4, K0)> {let Size = 16;}
 588 def VK8WM   : RegisterClass<"X86", [v8i1],  16,  (sub VK8, K0)> {let Size = 16;}
 589 def VK16WM  : RegisterClass<"X86", [v16i1], 16, (add VK8WM)>   {let Size = 16;}
 590 def VK32WM  : RegisterClass<"X86", [v32i1], 32, (add VK16WM)> {let Size = 32;}
 591 def VK64WM  : RegisterClass<"X86", [v64i1], 64, (add VK32WM)> {let Size = 64;}
 592
 593 // Bound registers
 594 def BNDR : RegisterClass<"X86", [v2i64], 128, (sequence "BND%u", 0, 3)>;