contrib/llvm/tools/lld/CMakeLists.txt

   1 # Check if lld is built as a standalone project.
   2 if(CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
   3   project(lld)
   4   cmake_minimum_required(VERSION 3.4.3)
   5
   6   set(CMAKE_INCLUDE_CURRENT_DIR ON)
   7   set(LLD_BUILT_STANDALONE TRUE)
   8
   9   find_program(LLVM_CONFIG_PATH "llvm-config" DOC "Path to llvm-config binary")
  10   if(NOT LLVM_CONFIG_PATH)
  11     message(FATAL_ERROR "llvm-config not found: specify LLVM_CONFIG_PATH")
  12   endif()
  13
  14   execute_process(COMMAND "${LLVM_CONFIG_PATH}" "--obj-root" "--includedir"
  15                           "--cmakedir"
  16                   RESULT_VARIABLE HAD_ERROR
  17                   OUTPUT_VARIABLE LLVM_CONFIG_OUTPUT
  18                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  19   if(HAD_ERROR)
  20     message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  21   endif()
  22
  23   string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" LLVM_CONFIG_OUTPUT "${LLVM_CONFIG_OUTPUT}")
  24
  25   list(GET LLVM_CONFIG_OUTPUT 0 OBJ_ROOT)
  26   list(GET LLVM_CONFIG_OUTPUT 1 MAIN_INCLUDE_DIR)
  27   list(GET LLVM_CONFIG_OUTPUT 2 LLVM_CMAKE_PATH)
  28
  29   set(LLVM_OBJ_ROOT ${OBJ_ROOT} CACHE PATH "path to LLVM build tree")
  30   set(LLVM_MAIN_INCLUDE_DIR ${MAIN_INCLUDE_DIR} CACHE PATH "path to llvm/include")
  31
  32   file(TO_CMAKE_PATH ${LLVM_OBJ_ROOT} LLVM_BINARY_DIR)
  33
  34   if(NOT EXISTS "${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
  35     message(FATAL_ERROR "LLVMConfig.cmake not found")
  36   endif()
  37   include("${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
  38
  39   list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
  40
  41   set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
  42   include_directories("${LLVM_BINARY_DIR}/include" ${LLVM_INCLUDE_DIRS})
  43   link_directories(${LLVM_LIBRARY_DIRS})
  44
  45   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
  46   set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  47   find_program(LLVM_TABLEGEN_EXE "llvm-tblgen" ${LLVM_TOOLS_BINARY_DIR} NO_DEFAULT_PATH)
  48
  49   include(AddLLVM)
  50   include(TableGen)
  51   include(HandleLLVMOptions)
  52 endif()
  53
  54 set(LLD_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  55 set(LLD_INCLUDE_DIR ${LLD_SOURCE_DIR}/include )
  56 set(LLD_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  57
  58 # Compute the LLD version from the LLVM version.
  59 string(REGEX MATCH "[0-9]+\\.[0-9]+(\\.[0-9]+)?" LLD_VERSION
  60   ${PACKAGE_VERSION})
  61 message(STATUS "LLD version: ${LLD_VERSION}")
  62
  63 string(REGEX REPLACE "([0-9]+)\\.[0-9]+(\\.[0-9]+)?" "\\1" LLD_VERSION_MAJOR
  64   ${LLD_VERSION})
  65 string(REGEX REPLACE "[0-9]+\\.([0-9]+)(\\.[0-9]+)?" "\\1" LLD_VERSION_MINOR
  66   ${LLD_VERSION})
  67
  68 # Determine LLD revision and repository.
  69 # TODO: Figure out a way to get the revision and the repository on windows.
  70 if ( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" )
  71   execute_process(COMMAND ${CMAKE_SOURCE_DIR}/utils/GetSourceVersion ${LLD_SOURCE_DIR}
  72                   OUTPUT_VARIABLE LLD_REVISION)
  73
  74   execute_process(COMMAND ${CMAKE_SOURCE_DIR}/utils/GetRepositoryPath ${LLD_SOURCE_DIR}
  75                   OUTPUT_VARIABLE LLD_REPOSITORY)
  76   if ( LLD_REPOSITORY )
  77     # Replace newline characters with spaces
  78     string(REGEX REPLACE "(\r?\n)+" " " LLD_REPOSITORY ${LLD_REPOSITORY})
  79     # Remove leading spaces
  80     STRING(REGEX REPLACE "^[ \t\r\n]+" "" LLD_REPOSITORY "${LLD_REPOSITORY}" )
  81     # Remove trailing spaces
  82     string(REGEX REPLACE "(\ )+$" "" LLD_REPOSITORY ${LLD_REPOSITORY})
  83   endif()
  84
  85   if ( LLD_REVISION )
  86     # Replace newline characters with spaces
  87     string(REGEX REPLACE "(\r?\n)+" " " LLD_REVISION ${LLD_REVISION})
  88     # Remove leading spaces
  89     STRING(REGEX REPLACE "^[ \t\r\n]+" "" LLD_REVISION "${LLD_REVISION}" )
  90     # Remove trailing spaces
  91     string(REGEX REPLACE "(\ )+$" "" LLD_REVISION ${LLD_REVISION})
  92   endif()
  93 endif ()
  94
  95 # Configure the Version.inc file.
  96 configure_file(
  97   ${CMAKE_CURRENT_SOURCE_DIR}/include/lld/Config/Version.inc.in
  98   ${CMAKE_CURRENT_BINARY_DIR}/include/lld/Config/Version.inc)
  99
 100
 101 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR)
 102   message(FATAL_ERROR "In-source builds are not allowed. CMake would overwrite "
 103 "the makefiles distributed with LLVM. Please create a directory and run cmake "
 104 "from there, passing the path to this source directory as the last argument. "
 105 "This process created the file `CMakeCache.txt' and the directory "
 106 "`CMakeFiles'. Please delete them.")
 107 endif()
 108
 109 list (APPEND CMAKE_MODULE_PATH "${LLD_SOURCE_DIR}/cmake/modules")
 110
 111 include(AddLLD)
 112
 113 option(LLD_USE_VTUNE
 114        "Enable VTune user task tracking."
 115        OFF)
 116 if (LLD_USE_VTUNE)
 117   find_package(VTune)
 118   if (VTUNE_FOUND)
 119     include_directories(${VTune_INCLUDE_DIRS})
 120     list(APPEND LLVM_COMMON_LIBS ${VTune_LIBRARIES})
 121     add_definitions(-DLLD_HAS_VTUNE)
 122   endif()
 123 endif()
 124
 125 option(LLD_BUILD_TOOLS
 126   "Build the lld tools. If OFF, just generate build targets." ON)
 127
 128 if (MSVC)
 129   add_definitions(-wd4530) # Suppress 'warning C4530: C++ exception handler used, but unwind semantics are not enabled.'
 130   add_definitions(-wd4062) # Suppress 'warning C4062: enumerator X in switch of enum Y is not handled' from system header.
 131 endif()
 132
 133 include_directories(BEFORE
 134   ${CMAKE_CURRENT_BINARY_DIR}/include
 135   ${CMAKE_CURRENT_SOURCE_DIR}/include
 136   )
 137
 138 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 139   install(DIRECTORY include/
 140     DESTINATION include
 141     FILES_MATCHING
 142     PATTERN "*.h"
 143     PATTERN ".svn" EXCLUDE
 144     )
 145 endif()
 146
 147 add_subdirectory(lib)
 148 add_subdirectory(tools/lld)
 149
 150 if (LLVM_INCLUDE_TESTS)
 151   add_subdirectory(test)
 152   add_subdirectory(unittests)
 153 endif()
 154
 155 add_subdirectory(docs)
 156 add_subdirectory(COFF)
 157 add_subdirectory(ELF)