contrib/llvm/tools/lld/CMakeLists.txt

   1 # Check if lld is built as a standalone project.
   2 if(CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
   3   project(lld)
   4   cmake_minimum_required(VERSION 3.4.3)
   5
   6   set(CMAKE_INCLUDE_CURRENT_DIR ON)
   7   set(LLD_BUILT_STANDALONE TRUE)
   8
   9   find_program(LLVM_CONFIG_PATH "llvm-config" DOC "Path to llvm-config binary")
  10   if(NOT LLVM_CONFIG_PATH)
  11     message(FATAL_ERROR "llvm-config not found: specify LLVM_CONFIG_PATH")
  12   endif()
  13
  14   execute_process(COMMAND "${LLVM_CONFIG_PATH}" "--obj-root" "--includedir"
  15                   RESULT_VARIABLE HAD_ERROR
  16                   OUTPUT_VARIABLE LLVM_CONFIG_OUTPUT
  17                   OUTPUT_STRIP_TRAILING_WHITESPACE)
  18   if(HAD_ERROR)
  19     message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  20   endif()
  21
  22   string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" LLVM_CONFIG_OUTPUT "${LLVM_CONFIG_OUTPUT}")
  23
  24   list(GET LLVM_CONFIG_OUTPUT 0 OBJ_ROOT)
  25   list(GET LLVM_CONFIG_OUTPUT 1 MAIN_INCLUDE_DIR)
  26
  27   set(LLVM_OBJ_ROOT ${OBJ_ROOT} CACHE PATH "path to LLVM build tree")
  28   set(LLVM_MAIN_INCLUDE_DIR ${MAIN_INCLUDE_DIR} CACHE PATH "path to llvm/include")
  29
  30   file(TO_CMAKE_PATH ${LLVM_OBJ_ROOT} LLVM_BINARY_DIR)
  31   set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX}/cmake/llvm")
  32
  33   if(NOT EXISTS "${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
  34     message(FATAL_ERROR "LLVMConfig.cmake not found")
  35   endif()
  36   include("${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
  37
  38   list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
  39
  40   set(PACKAGE_VERSION "${LLVM_PACKAGE_VERSION}")
  41   include_directories("${LLVM_BINARY_DIR}/include" ${LLVM_INCLUDE_DIRS})
  42   link_directories(${LLVM_LIBRARY_DIRS})
  43
  44   set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
  45   find_program(LLVM_TABLEGEN_EXE "llvm-tblgen" ${LLVM_TOOLS_BINARY_DIR} NO_DEFAULT_PATH)
  46
  47   include(AddLLVM)
  48   include(TableGen)
  49   include(HandleLLVMOptions)
  50 endif()
  51
  52 set(LLD_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  53 set(LLD_INCLUDE_DIR ${LLD_SOURCE_DIR}/include )
  54 set(LLD_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  55
  56 # Compute the LLD version from the LLVM version.
  57 string(REGEX MATCH "[0-9]+\\.[0-9]+(\\.[0-9]+)?" LLD_VERSION
  58   ${PACKAGE_VERSION})
  59 message(STATUS "LLD version: ${LLD_VERSION}")
  60
  61 string(REGEX REPLACE "([0-9]+)\\.[0-9]+(\\.[0-9]+)?" "\\1" LLD_VERSION_MAJOR
  62   ${LLD_VERSION})
  63 string(REGEX REPLACE "[0-9]+\\.([0-9]+)(\\.[0-9]+)?" "\\1" LLD_VERSION_MINOR
  64   ${LLD_VERSION})
  65
  66 # Determine LLD revision and repository.
  67 # TODO: Figure out a way to get the revision and the repository on windows.
  68 if ( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" )
  69   execute_process(COMMAND ${CMAKE_SOURCE_DIR}/utils/GetSourceVersion ${LLD_SOURCE_DIR}
  70                   OUTPUT_VARIABLE LLD_REVISION)
  71
  72   execute_process(COMMAND ${CMAKE_SOURCE_DIR}/utils/GetRepositoryPath ${LLD_SOURCE_DIR}
  73                   OUTPUT_VARIABLE LLD_REPOSITORY)
  74   if ( LLD_REPOSITORY )
  75     # Replace newline characters with spaces
  76     string(REGEX REPLACE "(\r?\n)+" " " LLD_REPOSITORY ${LLD_REPOSITORY})
  77     # Remove leading spaces
  78     STRING(REGEX REPLACE "^[ \t\r\n]+" "" LLD_REPOSITORY "${LLD_REPOSITORY}" )
  79     # Remove trailing spaces
  80     string(REGEX REPLACE "(\ )+$" "" LLD_REPOSITORY ${LLD_REPOSITORY})
  81   endif()
  82
  83   if ( LLD_REVISION )
  84     # Replace newline characters with spaces
  85     string(REGEX REPLACE "(\r?\n)+" " " LLD_REVISION ${LLD_REVISION})
  86     # Remove leading spaces
  87     STRING(REGEX REPLACE "^[ \t\r\n]+" "" LLD_REVISION "${LLD_REVISION}" )
  88     # Remove trailing spaces
  89     string(REGEX REPLACE "(\ )+$" "" LLD_REVISION ${LLD_REVISION})
  90   endif()
  91 endif ()
  92
  93 # Configure the Version.inc file.
  94 configure_file(
  95   ${CMAKE_CURRENT_SOURCE_DIR}/include/lld/Config/Version.inc.in
  96   ${CMAKE_CURRENT_BINARY_DIR}/include/lld/Config/Version.inc)
  97
  98
  99 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR)
 100   message(FATAL_ERROR "In-source builds are not allowed. CMake would overwrite "
 101 "the makefiles distributed with LLVM. Please create a directory and run cmake "
 102 "from there, passing the path to this source directory as the last argument. "
 103 "This process created the file `CMakeCache.txt' and the directory "
 104 "`CMakeFiles'. Please delete them.")
 105 endif()
 106
 107 list (APPEND CMAKE_MODULE_PATH "${LLD_SOURCE_DIR}/cmake/modules")
 108
 109 include(AddLLD)
 110
 111 option(LLD_USE_VTUNE
 112        "Enable VTune user task tracking."
 113        OFF)
 114 if (LLD_USE_VTUNE)
 115   find_package(VTune)
 116   if (VTUNE_FOUND)
 117     include_directories(${VTune_INCLUDE_DIRS})
 118     list(APPEND LLVM_COMMON_LIBS ${VTune_LIBRARIES})
 119     add_definitions(-DLLD_HAS_VTUNE)
 120   endif()
 121 endif()
 122
 123 option(LLD_BUILD_TOOLS
 124   "Build the lld tools. If OFF, just generate build targets." ON)
 125
 126 if (MSVC)
 127   add_definitions(-wd4530) # Suppress 'warning C4530: C++ exception handler used, but unwind semantics are not enabled.'
 128   add_definitions(-wd4062) # Suppress 'warning C4062: enumerator X in switch of enum Y is not handled' from system header.
 129 endif()
 130
 131 include_directories(BEFORE
 132   ${CMAKE_CURRENT_BINARY_DIR}/include
 133   ${CMAKE_CURRENT_SOURCE_DIR}/include
 134   )
 135
 136 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 137   install(DIRECTORY include/
 138     DESTINATION include
 139     FILES_MATCHING
 140     PATTERN "*.h"
 141     PATTERN ".svn" EXCLUDE
 142     )
 143 endif()
 144
 145 add_subdirectory(lib)
 146 add_subdirectory(tools/lld)
 147
 148 if (LLVM_INCLUDE_TESTS)
 149   add_subdirectory(test)
 150   add_subdirectory(unittests)
 151 endif()
 152
 153 add_subdirectory(docs)
 154 add_subdirectory(COFF)
 155 add_subdirectory(ELF)