contrib/llvm-project/compiler-rt/lib/builtins/i386/floatundidf.S

   1 //===-- floatundidf.S - Implement __floatundidf for i386 ------------------===//
   2 //
   3 // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
   4 // See https://llvm.org/LICENSE.txt for license information.
   5 // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
   6 //
   7 //===----------------------------------------------------------------------===//
   8 //
   9 // This file implements __floatundidf for the compiler_rt library.
  10 //
  11 //===----------------------------------------------------------------------===//
  12
  13 #include "../assembly.h"
  14
  15 // double __floatundidf(du_int a);
  16
  17 #ifdef __i386__
  18
  19 CONST_SECTION
  20
  21         .balign 16
  22 twop52:
  23         .quad 0x4330000000000000
  24
  25         .balign 16
  26 twop84_plus_twop52:
  27         .quad 0x4530000000100000
  28
  29         .balign 16
  30 twop84:
  31         .quad 0x4530000000000000
  32
  33 #define REL_ADDR(_a)    (_a)-0b(%eax)
  34
  35 .text
  36 .balign 4
  37 DEFINE_COMPILERRT_FUNCTION(__floatundidf)
  38         movss   8(%esp),                                                %xmm1 // high 32 bits of a
  39         movss   4(%esp),                                                %xmm0 // low 32 bits of a
  40         calll   0f
  41 0:      popl    %eax
  42         orpd    REL_ADDR(twop84),                               %xmm1 // 0x1p84 + a_hi (no rounding occurs)
  43         subsd   REL_ADDR(twop84_plus_twop52),   %xmm1 // a_hi - 0x1p52 (no rounding occurs)
  44         orpd    REL_ADDR(twop52),                               %xmm0 // 0x1p52 + a_lo (no rounding occurs)
  45         addsd   %xmm1,                                                  %xmm0 // a_hi + a_lo   (round happens here)
  46         movsd   %xmm0,                                             4(%esp)
  47         fldl   4(%esp)
  48         ret
  49 END_COMPILERRT_FUNCTION(__floatundidf)
  50
  51 #endif // __i386__
  52
  53 NO_EXEC_STACK_DIRECTIVE
  54