contrib/llvm-project/lld/Common/CMakeLists.txt

   1 if(NOT LLD_BUILT_STANDALONE)
   2   set(tablegen_deps intrinsics_gen)
   3 endif()
   4
   5 find_first_existing_vc_file("${LLVM_MAIN_SRC_DIR}" llvm_vc)
   6 find_first_existing_vc_file("${LLD_SOURCE_DIR}" lld_vc)
   7
   8 set(version_inc "${CMAKE_CURRENT_BINARY_DIR}/VCSVersion.inc")
   9 set(generate_vcs_version_script "${LLVM_CMAKE_PATH}/GenerateVersionFromVCS.cmake")
  10
  11 if(lld_vc)
  12   set(lld_source_dir ${LLD_SOURCE_DIR})
  13 endif()
  14
  15 add_custom_command(OUTPUT "${version_inc}"
  16   DEPENDS "${lld_vc}" "${generate_vcs_version_script}"
  17   COMMAND ${CMAKE_COMMAND} "-DNAMES=LLD"
  18   "-DLLD_SOURCE_DIR=${LLD_SOURCE_DIR}"
  19   "-DHEADER_FILE=${version_inc}"
  20   -P "${generate_vcs_version_script}")
  21
  22 # Mark the generated header as being generated.
  23 set_source_files_properties("${version_inc}"
  24   PROPERTIES GENERATED TRUE
  25   HEADER_FILE_ONLY TRUE)
  26
  27 set_property(SOURCE Version.cpp APPEND PROPERTY
  28   COMPILE_DEFINITIONS "HAVE_VCS_VERSION_INC")
  29
  30 add_lld_library(lldCommon
  31   Args.cpp
  32   ErrorHandler.cpp
  33   Filesystem.cpp
  34   Memory.cpp
  35   Reproduce.cpp
  36   Strings.cpp
  37   TargetOptionsCommandFlags.cpp
  38   Threads.cpp
  39   Timer.cpp
  40   VCSVersion.inc
  41   Version.cpp
  42
  43   ADDITIONAL_HEADER_DIRS
  44   ${LLD_INCLUDE_DIR}/lld/Common
  45
  46   LINK_COMPONENTS
  47   Codegen
  48   Core
  49   Demangle
  50   MC
  51   Option
  52   Support
  53   Target
  54
  55   LINK_LIBS
  56   ${LLVM_PTHREAD_LIB}
  57
  58   DEPENDS
  59   ${tablegen_deps}
  60   )