contrib/llvm-project/llvm/lib/Target/AArch64/AArch64SchedA53.td

   1 //==- AArch64SchedA53.td - Cortex-A53 Scheduling Definitions -*- tablegen -*-=//
   2 //
   3 // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
   4 // See https://llvm.org/LICENSE.txt for license information.
   5 // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
   6 //
   7 //===----------------------------------------------------------------------===//
   8 //
   9 // This file defines the itinerary class data for the ARM Cortex A53 processors.
  10 //
  11 //===----------------------------------------------------------------------===//
  12
  13 // ===---------------------------------------------------------------------===//
  14 // The following definitions describe the simpler per-operand machine model.
  15 // This works with MachineScheduler. See MCSchedule.h for details.
  16
  17 // Cortex-A53 machine model for scheduling and other instruction cost heuristics.
  18 def CortexA53Model : SchedMachineModel {
  19   let MicroOpBufferSize = 0; // Explicitly set to zero since A53 is in-order.
  20   let IssueWidth = 2;        // 2 micro-ops are dispatched per cycle.
  21   let LoadLatency = 3;       // Optimistic load latency assuming bypass.
  22                              // This is overriden by OperandCycles if the
  23                              // Itineraries are queried instead.
  24   let MispredictPenalty = 9; // Based on "Cortex-A53 Software Optimisation
  25                              // Specification - Instruction Timings"
  26                              // v 1.0 Spreadsheet
  27   let CompleteModel = 1;
  28
  29   list<Predicate> UnsupportedFeatures = SVEUnsupported.F;
  30 }
  31
  32
  33 //===----------------------------------------------------------------------===//
  34 // Define each kind of processor resource and number available.
  35
  36 // Modeling each pipeline as a ProcResource using the BufferSize = 0 since
  37 // Cortex-A53 is in-order.
  38
  39 def A53UnitALU    : ProcResource<2> { let BufferSize = 0; } // Int ALU
  40 def A53UnitMAC    : ProcResource<1> { let BufferSize = 0; } // Int MAC
  41 def A53UnitDiv    : ProcResource<1> { let BufferSize = 0; } // Int Division
  42 def A53UnitLdSt   : ProcResource<1> { let BufferSize = 0; } // Load/Store
  43 def A53UnitB      : ProcResource<1> { let BufferSize = 0; } // Branch
  44 def A53UnitFPALU  : ProcResource<1> { let BufferSize = 0; } // FP ALU
  45 def A53UnitFPMDS  : ProcResource<1> { let BufferSize = 0; } // FP Mult/Div/Sqrt
  46
  47
  48 //===----------------------------------------------------------------------===//
  49 // Subtarget-specific SchedWrite types which both map the ProcResources and
  50 // set the latency.
  51
  52 let SchedModel = CortexA53Model in {
  53
  54 // ALU - Despite having a full latency of 4, most of the ALU instructions can
  55 //       forward a cycle earlier and then two cycles earlier in the case of a
  56 //       shift-only instruction. These latencies will be incorrect when the
  57 //       result cannot be forwarded, but modeling isn't rocket surgery.
  58 def : WriteRes<WriteImm, [A53UnitALU]> { let Latency = 3; }
  59 def : WriteRes<WriteI, [A53UnitALU]> { let Latency = 3; }
  60 def : WriteRes<WriteISReg, [A53UnitALU]> { let Latency = 3; }
  61 def : WriteRes<WriteIEReg, [A53UnitALU]> { let Latency = 3; }
  62 def : WriteRes<WriteIS, [A53UnitALU]> { let Latency = 2; }
  63 def : WriteRes<WriteExtr, [A53UnitALU]> { let Latency = 3; }
  64
  65 // MAC
  66 def : WriteRes<WriteIM32, [A53UnitMAC]> { let Latency = 4; }
  67 def : WriteRes<WriteIM64, [A53UnitMAC]> { let Latency = 4; }
  68
  69 // Div
  70 def : WriteRes<WriteID32, [A53UnitDiv]> { let Latency = 4; }
  71 def : WriteRes<WriteID64, [A53UnitDiv]> { let Latency = 4; }
  72
  73 // Load
  74 def : WriteRes<WriteLD, [A53UnitLdSt]> { let Latency = 4; }
  75 def : WriteRes<WriteLDIdx, [A53UnitLdSt]> { let Latency = 4; }
  76 def : WriteRes<WriteLDHi, [A53UnitLdSt]> { let Latency = 4; }
  77
  78 // Vector Load - Vector loads take 1-5 cycles to issue. For the WriteVecLd
  79 //               below, choosing the median of 3 which makes the latency 6.
  80 //               May model this more carefully in the future. The remaining
  81 //               A53WriteVLD# types represent the 1-5 cycle issues explicitly.
  82 def : WriteRes<WriteVLD, [A53UnitLdSt]> { let Latency = 6;
  83                                           let ResourceCycles = [3]; }
  84 def A53WriteVLD1 : SchedWriteRes<[A53UnitLdSt]> { let Latency = 4; }
  85 def A53WriteVLD2 : SchedWriteRes<[A53UnitLdSt]> { let Latency = 5;
  86                                                   let ResourceCycles = [2]; }
  87 def A53WriteVLD3 : SchedWriteRes<[A53UnitLdSt]> { let Latency = 6;
  88                                                   let ResourceCycles = [3]; }
  89 def A53WriteVLD4 : SchedWriteRes<[A53UnitLdSt]> { let Latency = 7;
  90                                                   let ResourceCycles = [4]; }
  91 def A53WriteVLD5 : SchedWriteRes<[A53UnitLdSt]> { let Latency = 8;
  92                                                   let ResourceCycles = [5]; }
  93
  94 // Pre/Post Indexing - Performed as part of address generation which is already
  95 //                     accounted for in the WriteST* latencies below
  96 def : WriteRes<WriteAdr, []> { let Latency = 0; }
  97
  98 // Store
  99 def : WriteRes<WriteST, [A53UnitLdSt]> { let Latency = 4; }
 100 def : WriteRes<WriteSTP, [A53UnitLdSt]> { let Latency = 4; }
 101 def : WriteRes<WriteSTIdx, [A53UnitLdSt]> { let Latency = 4; }
 102 def : WriteRes<WriteSTX, [A53UnitLdSt]> { let Latency = 4; }
 103
 104 // Vector Store - Similar to vector loads, can take 1-3 cycles to issue.
 105 def : WriteRes<WriteVST, [A53UnitLdSt]> { let Latency = 5;
 106                                           let ResourceCycles = [2];}
 107 def A53WriteVST1 : SchedWriteRes<[A53UnitLdSt]> { let Latency = 4; }
 108 def A53WriteVST2 : SchedWriteRes<[A53UnitLdSt]> { let Latency = 5;
 109                                                   let ResourceCycles = [2]; }
 110 def A53WriteVST3 : SchedWriteRes<[A53UnitLdSt]> { let Latency = 6;
 111                                                   let ResourceCycles = [3]; }
 112
 113 def : WriteRes<WriteAtomic, []> { let Unsupported = 1; }
 114
 115 // Branch
 116 def : WriteRes<WriteBr, [A53UnitB]>;
 117 def : WriteRes<WriteBrReg, [A53UnitB]>;
 118 def : WriteRes<WriteSys, [A53UnitB]>;
 119 def : WriteRes<WriteBarrier, [A53UnitB]>;
 120 def : WriteRes<WriteHint, [A53UnitB]>;
 121
 122 // FP ALU
 123 def : WriteRes<WriteF, [A53UnitFPALU]> { let Latency = 6; }
 124 def : WriteRes<WriteFCmp, [A53UnitFPALU]> { let Latency = 6; }
 125 def : WriteRes<WriteFCvt, [A53UnitFPALU]> { let Latency = 6; }
 126 def : WriteRes<WriteFCopy, [A53UnitFPALU]> { let Latency = 6; }
 127 def : WriteRes<WriteFImm, [A53UnitFPALU]> { let Latency = 6; }
 128 def : WriteRes<WriteV, [A53UnitFPALU]> { let Latency = 6; }
 129
 130 // FP Mul, Div, Sqrt
 131 def : WriteRes<WriteFMul, [A53UnitFPMDS]> { let Latency = 6; }
 132 def : WriteRes<WriteFDiv, [A53UnitFPMDS]> { let Latency = 33;
 133                                             let ResourceCycles = [29]; }
 134 def A53WriteFMAC : SchedWriteRes<[A53UnitFPMDS]> { let Latency = 10; }
 135 def A53WriteFDivSP : SchedWriteRes<[A53UnitFPMDS]> { let Latency = 18;
 136                                                      let ResourceCycles = [14]; }
 137 def A53WriteFDivDP : SchedWriteRes<[A53UnitFPMDS]> { let Latency = 33;
 138                                                      let ResourceCycles = [29]; }
 139 def A53WriteFSqrtSP : SchedWriteRes<[A53UnitFPMDS]> { let Latency = 17;
 140                                                       let ResourceCycles = [13]; }
 141 def A53WriteFSqrtDP : SchedWriteRes<[A53UnitFPMDS]> { let Latency = 32;
 142                                                       let ResourceCycles = [28]; }
 143
 144 //===----------------------------------------------------------------------===//
 145 // Subtarget-specific SchedRead types.
 146
 147 // No forwarding for these reads.
 148 def : ReadAdvance<ReadExtrHi, 0>;
 149 def : ReadAdvance<ReadAdrBase, 0>;
 150 def : ReadAdvance<ReadVLD, 0>;
 151
 152 // ALU - Most operands in the ALU pipes are not needed for two cycles. Shiftable
 153 //       operands are needed one cycle later if and only if they are to be
 154 //       shifted. Otherwise, they too are needed two cycles later. This same
 155 //       ReadAdvance applies to Extended registers as well, even though there is
 156 //       a separate SchedPredicate for them.
 157 def : ReadAdvance<ReadI, 2, [WriteImm,WriteI,
 158                              WriteISReg, WriteIEReg,WriteIS,
 159                              WriteID32,WriteID64,
 160                              WriteIM32,WriteIM64]>;
 161 def A53ReadShifted : SchedReadAdvance<1, [WriteImm,WriteI,
 162                                           WriteISReg, WriteIEReg,WriteIS,
 163                                           WriteID32,WriteID64,
 164                                           WriteIM32,WriteIM64]>;
 165 def A53ReadNotShifted : SchedReadAdvance<2, [WriteImm,WriteI,
 166                                              WriteISReg, WriteIEReg,WriteIS,
 167                                              WriteID32,WriteID64,
 168                                              WriteIM32,WriteIM64]>;
 169 def A53ReadISReg : SchedReadVariant<[
 170         SchedVar<RegShiftedPred, [A53ReadShifted]>,
 171         SchedVar<NoSchedPred, [A53ReadNotShifted]>]>;
 172 def : SchedAlias<ReadISReg, A53ReadISReg>;
 173
 174 def A53ReadIEReg : SchedReadVariant<[
 175         SchedVar<RegExtendedPred, [A53ReadShifted]>,
 176         SchedVar<NoSchedPred, [A53ReadNotShifted]>]>;
 177 def : SchedAlias<ReadIEReg, A53ReadIEReg>;
 178
 179 // MAC - Operands are generally needed one cycle later in the MAC pipe.
 180 //       Accumulator operands are needed two cycles later.
 181 def : ReadAdvance<ReadIM, 1, [WriteImm,WriteI,
 182                               WriteISReg, WriteIEReg,WriteIS,
 183                               WriteID32,WriteID64,
 184                               WriteIM32,WriteIM64]>;
 185 def : ReadAdvance<ReadIMA, 2, [WriteImm,WriteI,
 186                                WriteISReg, WriteIEReg,WriteIS,
 187                                WriteID32,WriteID64,
 188                                WriteIM32,WriteIM64]>;
 189
 190 // Div
 191 def : ReadAdvance<ReadID, 1, [WriteImm,WriteI,
 192                               WriteISReg, WriteIEReg,WriteIS,
 193                               WriteID32,WriteID64,
 194                               WriteIM32,WriteIM64]>;
 195
 196 //===----------------------------------------------------------------------===//
 197 // Subtarget-specific InstRWs.
 198
 199 //---
 200 // Miscellaneous
 201 //---
 202 def : InstRW<[WriteI], (instrs COPY)>;
 203
 204 //---
 205 // Vector Loads
 206 //---
 207 def : InstRW<[A53WriteVLD1], (instregex "LD1i(8|16|32|64)$")>;
 208 def : InstRW<[A53WriteVLD1], (instregex "LD1Rv(8b|4h|2s|1d|16b|8h|4s|2d)$")>;
 209 def : InstRW<[A53WriteVLD1], (instregex "LD1Onev(8b|4h|2s|1d|16b|8h|4s|2d)$")>;
 210 def : InstRW<[A53WriteVLD2], (instregex "LD1Twov(8b|4h|2s|1d|16b|8h|4s|2d)$")>;
 211 def : InstRW<[A53WriteVLD3], (instregex "LD1Threev(8b|4h|2s|1d|16b|8h|4s|2d)$")>;
 212 def : InstRW<[A53WriteVLD4], (instregex "LD1Fourv(8b|4h|2s|1d|16b|8h|4s|2d)$")>;
 213 def : InstRW<[A53WriteVLD1, WriteAdr], (instregex "LD1i(8|16|32|64)_POST$")>;
 214 def : InstRW<[A53WriteVLD1, WriteAdr], (instregex "LD1Rv(8b|4h|2s|1d|16b|8h|4s|2d)_POST$")>;
 215 def : InstRW<[A53WriteVLD1, WriteAdr], (instregex "LD1Onev(8b|4h|2s|1d|16b|8h|4s|2d)_POST$")>;
 216 def : InstRW<[A53WriteVLD2, WriteAdr], (instregex "LD1Twov(8b|4h|2s|1d|16b|8h|4s|2d)_POST$")>;
 217 def : InstRW<[A53WriteVLD3, WriteAdr], (instregex "LD1Threev(8b|4h|2s|1d|16b|8h|4s|2d)_POST$")>;
 218 def : InstRW<[A53WriteVLD4, WriteAdr], (instregex "LD1Fourv(8b|4h|2s|1d|16b|8h|4s|2d)_POST$")>;
 219
 220 def : InstRW<[A53WriteVLD1], (instregex "LD2i(8|16|32|64)$")>;
 221 def : InstRW<[A53WriteVLD1], (instregex "LD2Rv(8b|4h|2s|1d|16b|8h|4s|2d)$")>;
 222 def : InstRW<[A53WriteVLD2], (instregex "LD2Twov(8b|4h|2s)$")>;
 223 def : InstRW<[A53WriteVLD4], (instregex "LD2Twov(16b|8h|4s|2d)$")>;
 224 def : InstRW<[A53WriteVLD1, WriteAdr], (instregex "LD2i(8|16|32|64)_POST$")>;
 225 def : InstRW<[A53WriteVLD1, WriteAdr], (instregex "LD2Rv(8b|4h|2s|1d|16b|8h|4s|2d)_POST$")>;
 226 def : InstRW<[A53WriteVLD2, WriteAdr], (instregex "LD2Twov(8b|4h|2s)_POST$")>;
 227 def : InstRW<[A53WriteVLD4, WriteAdr], (instregex "LD2Twov(16b|8h|4s|2d)_POST$")>;
 228
 229 def : InstRW<[A53WriteVLD2], (instregex "LD3i(8|16|32|64)$")>;
 230 def : InstRW<[A53WriteVLD2], (instregex "LD3Rv(8b|4h|2s|1d|16b|8h|4s|2d)$")>;
 231 def : InstRW<[A53WriteVLD4], (instregex "LD3Threev(8b|4h|2s|1d|16b|8h|4s)$")>;
 232 def : InstRW<[A53WriteVLD3], (instregex "LD3Threev2d$")>;
 233 def : InstRW<[A53WriteVLD2, WriteAdr], (instregex "LD3i(8|16|32|64)_POST$")>;
 234 def : InstRW<[A53WriteVLD2, WriteAdr], (instregex "LD3Rv(8b|4h|2s|1d|16b|8h|4s|2d)_POST$")>;
 235 def : InstRW<[A53WriteVLD4, WriteAdr], (instregex "LD3Threev(8b|4h|2s|1d|16b|8h|4s)_POST$")>;
 236 def : InstRW<[A53WriteVLD3, WriteAdr], (instregex "LD3Threev2d_POST$")>;
 237
 238 def : InstRW<[A53WriteVLD2], (instregex "LD4i(8|16|32|64)$")>;
 239 def : InstRW<[A53WriteVLD2], (instregex "LD4Rv(8b|4h|2s|1d|16b|8h|4s|2d)$")>;
 240 def : InstRW<[A53WriteVLD5], (instregex "LD4Fourv(8b|4h|2s|1d|16b|8h|4s)$")>;
 241 def : InstRW<[A53WriteVLD4], (instregex "LD4Fourv(2d)$")>;
 242 def : InstRW<[A53WriteVLD2, WriteAdr], (instregex "LD4i(8|16|32|64)_POST$")>;
 243 def : InstRW<[A53WriteVLD2, WriteAdr], (instregex "LD4Rv(8b|4h|2s|1d|16b|8h|4s|2d)_POST$")>;
 244 def : InstRW<[A53WriteVLD5, WriteAdr], (instregex "LD4Fourv(8b|4h|2s|1d|16b|8h|4s)_POST$")>;
 245 def : InstRW<[A53WriteVLD4, WriteAdr], (instregex "LD4Fourv(2d)_POST$")>;
 246
 247 //---
 248 // Vector Stores
 249 //---
 250 def : InstRW<[A53WriteVST1], (instregex "ST1i(8|16|32|64)$")>;
 251 def : InstRW<[A53WriteVST1], (instregex "ST1Onev(8b|4h|2s|1d|16b|8h|4s|2d)$")>;
 252 def : InstRW<[A53WriteVST1], (instregex "ST1Twov(8b|4h|2s|1d|16b|8h|4s|2d)$")>;
 253 def : InstRW<[A53WriteVST2], (instregex "ST1Threev(8b|4h|2s|1d|16b|8h|4s|2d)$")>;
 254 def : InstRW<[A53WriteVST2], (instregex "ST1Fourv(8b|4h|2s|1d|16b|8h|4s|2d)$")>;
 255 def : InstRW<[A53WriteVST1, WriteAdr], (instregex "ST1i(8|16|32|64)_POST$")>;
 256 def : InstRW<[A53WriteVST1, WriteAdr], (instregex "ST1Onev(8b|4h|2s|1d|16b|8h|4s|2d)_POST$")>;
 257 def : InstRW<[A53WriteVST1, WriteAdr], (instregex "ST1Twov(8b|4h|2s|1d|16b|8h|4s|2d)_POST$")>;
 258 def : InstRW<[A53WriteVST2, WriteAdr], (instregex "ST1Threev(8b|4h|2s|1d|16b|8h|4s|2d)_POST$")>;
 259 def : InstRW<[A53WriteVST2, WriteAdr], (instregex "ST1Fourv(8b|4h|2s|1d|16b|8h|4s|2d)_POST$")>;
 260
 261 def : InstRW<[A53WriteVST1], (instregex "ST2i(8|16|32|64)$")>;
 262 def : InstRW<[A53WriteVST1], (instregex "ST2Twov(8b|4h|2s)$")>;
 263 def : InstRW<[A53WriteVST2], (instregex "ST2Twov(16b|8h|4s|2d)$")>;
 264 def : InstRW<[A53WriteVST1, WriteAdr], (instregex "ST2i(8|16|32|64)_POST$")>;
 265 def : InstRW<[A53WriteVST1, WriteAdr], (instregex "ST2Twov(8b|4h|2s)_POST$")>;
 266 def : InstRW<[A53WriteVST2, WriteAdr], (instregex "ST2Twov(16b|8h|4s|2d)_POST$")>;
 267
 268 def : InstRW<[A53WriteVST2], (instregex "ST3i(8|16|32|64)$")>;
 269 def : InstRW<[A53WriteVST3], (instregex "ST3Threev(8b|4h|2s|1d|16b|8h|4s)$")>;
 270 def : InstRW<[A53WriteVST2], (instregex "ST3Threev(2d)$")>;
 271 def : InstRW<[A53WriteVST2, WriteAdr], (instregex "ST3i(8|16|32|64)_POST$")>;
 272 def : InstRW<[A53WriteVST3, WriteAdr], (instregex "ST3Threev(8b|4h|2s|1d|16b|8h|4s)_POST$")>;
 273 def : InstRW<[A53WriteVST2, WriteAdr], (instregex "ST3Threev(2d)_POST$")>;
 274
 275 def : InstRW<[A53WriteVST2], (instregex "ST4i(8|16|32|64)$")>;
 276 def : InstRW<[A53WriteVST3], (instregex "ST4Fourv(8b|4h|2s|1d|16b|8h|4s)$")>;
 277 def : InstRW<[A53WriteVST2], (instregex "ST4Fourv(2d)$")>;
 278 def : InstRW<[A53WriteVST2, WriteAdr], (instregex "ST4i(8|16|32|64)_POST$")>;
 279 def : InstRW<[A53WriteVST3, WriteAdr], (instregex "ST4Fourv(8b|4h|2s|1d|16b|8h|4s)_POST$")>;
 280 def : InstRW<[A53WriteVST2, WriteAdr], (instregex "ST4Fourv(2d)_POST$")>;
 281
 282 //---
 283 // Floating Point MAC, DIV, SQRT
 284 //---
 285 def : InstRW<[A53WriteFMAC], (instregex "^FN?M(ADD|SUB).*")>;
 286 def : InstRW<[A53WriteFMAC], (instregex "^FML(A|S).*")>;
 287 def : InstRW<[A53WriteFDivSP], (instrs FDIVSrr)>;
 288 def : InstRW<[A53WriteFDivDP], (instrs FDIVDrr)>;
 289 def : InstRW<[A53WriteFDivSP], (instregex "^FDIVv.*32$")>;
 290 def : InstRW<[A53WriteFDivDP], (instregex "^FDIVv.*64$")>;
 291 def : InstRW<[A53WriteFSqrtSP], (instregex "^.*SQRT.*32$")>;
 292 def : InstRW<[A53WriteFSqrtDP], (instregex "^.*SQRT.*64$")>;
 293
 294 }