contrib/llvm-project/llvm/lib/Target/PowerPC/PPCInstrAltivec.td

   1 //===-- PPCInstrAltivec.td - The PowerPC Altivec Extension -*- tablegen -*-===//
   2 //
   3 // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
   4 // See https://llvm.org/LICENSE.txt for license information.
   5 // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
   6 //
   7 //===----------------------------------------------------------------------===//
   8 //
   9 // This file describes the Altivec extension to the PowerPC instruction set.
  10 //
  11 //===----------------------------------------------------------------------===//
  12
  13 // *********************************** NOTE ***********************************
  14 // ** For POWER8 Little Endian, the VSX swap optimization relies on knowing  **
  15 // ** which VMX and VSX instructions are lane-sensitive and which are not.   **
  16 // ** A lane-sensitive instruction relies, implicitly or explicitly, on      **
  17 // ** whether lanes are numbered from left to right.  An instruction like    **
  18 // ** VADDFP is not lane-sensitive, because each lane of the result vector   **
  19 // ** relies only on the corresponding lane of the source vectors.  However, **
  20 // ** an instruction like VMULESB is lane-sensitive, because "even" and      **
  21 // ** "odd" lanes are different for big-endian and little-endian numbering.  **
  22 // **                                                                        **
  23 // ** When adding new VMX and VSX instructions, please consider whether they **
  24 // ** are lane-sensitive.  If so, they must be added to a switch statement   **
  25 // ** in PPCVSXSwapRemoval::gatherVectorInstructions().                      **
  26 // ****************************************************************************
  27
  28
  29 //===----------------------------------------------------------------------===//
  30 // Altivec transformation functions and pattern fragments.
  31 //
  32
  33 // Since we canonicalize buildvectors to v16i8, all vnots "-1" operands will be
  34 // of that type.
  35 def vnot_ppc : PatFrag<(ops node:$in),
  36                        (xor node:$in, (bitconvert (v16i8 immAllOnesV)))>;
  37
  38 def vpkuhum_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  39                               (vector_shuffle node:$lhs, node:$rhs), [{
  40   return PPC::isVPKUHUMShuffleMask(cast<ShuffleVectorSDNode>(N), 0, *CurDAG);
  41 }]>;
  42 def vpkuwum_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  43                               (vector_shuffle node:$lhs, node:$rhs), [{
  44   return PPC::isVPKUWUMShuffleMask(cast<ShuffleVectorSDNode>(N), 0, *CurDAG);
  45 }]>;
  46 def vpkudum_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  47                               (vector_shuffle node:$lhs, node:$rhs), [{
  48   return PPC::isVPKUDUMShuffleMask(cast<ShuffleVectorSDNode>(N), 0, *CurDAG);
  49 }]>;
  50 def vpkuhum_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  51                                     (vector_shuffle node:$lhs, node:$rhs), [{
  52   return PPC::isVPKUHUMShuffleMask(cast<ShuffleVectorSDNode>(N), 1, *CurDAG);
  53 }]>;
  54 def vpkuwum_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  55                                     (vector_shuffle node:$lhs, node:$rhs), [{
  56   return PPC::isVPKUWUMShuffleMask(cast<ShuffleVectorSDNode>(N), 1, *CurDAG);
  57 }]>;
  58 def vpkudum_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  59                                     (vector_shuffle node:$lhs, node:$rhs), [{
  60   return PPC::isVPKUDUMShuffleMask(cast<ShuffleVectorSDNode>(N), 1, *CurDAG);
  61 }]>;
  62
  63 // These fragments are provided for little-endian, where the inputs must be
  64 // swapped for correct semantics.
  65 def vpkuhum_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  66                                       (vector_shuffle node:$lhs, node:$rhs), [{
  67   return PPC::isVPKUHUMShuffleMask(cast<ShuffleVectorSDNode>(N), 2, *CurDAG);
  68 }]>;
  69 def vpkuwum_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  70                                       (vector_shuffle node:$lhs, node:$rhs), [{
  71   return PPC::isVPKUWUMShuffleMask(cast<ShuffleVectorSDNode>(N), 2, *CurDAG);
  72 }]>;
  73 def vpkudum_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  74                                       (vector_shuffle node:$lhs, node:$rhs), [{
  75   return PPC::isVPKUDUMShuffleMask(cast<ShuffleVectorSDNode>(N), 2, *CurDAG);
  76 }]>;
  77
  78 def vmrglb_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  79                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  80   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 1, 0, *CurDAG);
  81 }]>;
  82 def vmrglh_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  83                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  84   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 2, 0, *CurDAG);
  85 }]>;
  86 def vmrglw_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  87                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  88   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 4, 0, *CurDAG);
  89 }]>;
  90 def vmrghb_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  91                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  92   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 1, 0, *CurDAG);
  93 }]>;
  94 def vmrghh_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  95                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  96   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 2, 0, *CurDAG);
  97 }]>;
  98 def vmrghw_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  99                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
 100   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 4, 0, *CurDAG);
 101 }]>;
 102
 103
 104 def vmrglb_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 105                                (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
 106   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 1, 1, *CurDAG);
 107 }]>;
 108 def vmrglh_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 109                                    (vector_shuffle node:$lhs, node:$rhs), [{
 110   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 2, 1, *CurDAG);
 111 }]>;
 112 def vmrglw_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 113                                    (vector_shuffle node:$lhs, node:$rhs), [{
 114   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 4, 1, *CurDAG);
 115 }]>;
 116 def vmrghb_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 117                                    (vector_shuffle node:$lhs, node:$rhs), [{
 118   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 1, 1, *CurDAG);
 119 }]>;
 120 def vmrghh_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 121                                    (vector_shuffle node:$lhs, node:$rhs), [{
 122   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 2, 1, *CurDAG);
 123 }]>;
 124 def vmrghw_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 125                                    (vector_shuffle node:$lhs, node:$rhs), [{
 126   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 4, 1, *CurDAG);
 127 }]>;
 128
 129
 130 // These fragments are provided for little-endian, where the inputs must be
 131 // swapped for correct semantics.
 132 def vmrglb_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 133                                (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
 134   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 1, 2, *CurDAG);
 135 }]>;
 136 def vmrglh_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 137                                    (vector_shuffle node:$lhs, node:$rhs), [{
 138   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 2, 2, *CurDAG);
 139 }]>;
 140 def vmrglw_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 141                                    (vector_shuffle node:$lhs, node:$rhs), [{
 142   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 4, 2, *CurDAG);
 143 }]>;
 144 def vmrghb_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 145                                    (vector_shuffle node:$lhs, node:$rhs), [{
 146   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 1, 2, *CurDAG);
 147 }]>;
 148 def vmrghh_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 149                                    (vector_shuffle node:$lhs, node:$rhs), [{
 150   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 2, 2, *CurDAG);
 151 }]>;
 152 def vmrghw_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 153                                    (vector_shuffle node:$lhs, node:$rhs), [{
 154   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 4, 2, *CurDAG);
 155 }]>;
 156
 157
 158 def vmrgew_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 159                              (vector_shuffle node:$lhs, node:$rhs), [{
 160   return PPC::isVMRGEOShuffleMask(cast<ShuffleVectorSDNode>(N), true, 0, *CurDAG);
 161 }]>;
 162 def vmrgow_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 163                              (vector_shuffle node:$lhs, node:$rhs), [{
 164   return PPC::isVMRGEOShuffleMask(cast<ShuffleVectorSDNode>(N), false, 0, *CurDAG);
 165 }]>;
 166 def vmrgew_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 167                                    (vector_shuffle node:$lhs, node:$rhs), [{
 168   return PPC::isVMRGEOShuffleMask(cast<ShuffleVectorSDNode>(N), true, 1, *CurDAG);
 169 }]>;
 170 def vmrgow_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 171                                    (vector_shuffle node:$lhs, node:$rhs), [{
 172   return PPC::isVMRGEOShuffleMask(cast<ShuffleVectorSDNode>(N), false, 1, *CurDAG);
 173 }]>;
 174 def vmrgew_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 175                                      (vector_shuffle node:$lhs, node:$rhs), [{
 176   return PPC::isVMRGEOShuffleMask(cast<ShuffleVectorSDNode>(N), true, 2, *CurDAG);
 177 }]>;
 178 def vmrgow_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 179                                      (vector_shuffle node:$lhs, node:$rhs), [{
 180   return PPC::isVMRGEOShuffleMask(cast<ShuffleVectorSDNode>(N), false, 2, *CurDAG);
 181 }]>;
 182
 183
 184
 185 def VSLDOI_get_imm : SDNodeXForm<vector_shuffle, [{
 186   return getI32Imm(PPC::isVSLDOIShuffleMask(N, 0, *CurDAG), SDLoc(N));
 187 }]>;
 188 def vsldoi_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 189                              (vector_shuffle node:$lhs, node:$rhs), [{
 190   return PPC::isVSLDOIShuffleMask(N, 0, *CurDAG) != -1;
 191 }], VSLDOI_get_imm>;
 192
 193
 194 /// VSLDOI_unary* - These are used to match vsldoi(X,X), which is turned into
 195 /// vector_shuffle(X,undef,mask) by the dag combiner.
 196 def VSLDOI_unary_get_imm : SDNodeXForm<vector_shuffle, [{
 197   return getI32Imm(PPC::isVSLDOIShuffleMask(N, 1, *CurDAG), SDLoc(N));
 198 }]>;
 199 def vsldoi_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 200                                    (vector_shuffle node:$lhs, node:$rhs), [{
 201   return PPC::isVSLDOIShuffleMask(N, 1, *CurDAG) != -1;
 202 }], VSLDOI_unary_get_imm>;
 203
 204
 205 /// VSLDOI_swapped* - These fragments are provided for little-endian, where
 206 /// the inputs must be swapped for correct semantics.
 207 def VSLDOI_swapped_get_imm : SDNodeXForm<vector_shuffle, [{
 208   return getI32Imm(PPC::isVSLDOIShuffleMask(N, 2, *CurDAG), SDLoc(N));
 209 }]>;
 210 def vsldoi_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 211                                      (vector_shuffle node:$lhs, node:$rhs), [{
 212   return PPC::isVSLDOIShuffleMask(N, 2, *CurDAG) != -1;
 213 }], VSLDOI_get_imm>;
 214
 215
 216 // VSPLT*_get_imm xform function: convert vector_shuffle mask to VSPLT* imm.
 217 def VSPLTB_get_imm : SDNodeXForm<vector_shuffle, [{
 218   return getI32Imm(PPC::getSplatIdxForPPCMnemonics(N, 1, *CurDAG), SDLoc(N));
 219 }]>;
 220 def vspltb_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 221                              (vector_shuffle node:$lhs, node:$rhs), [{
 222   return PPC::isSplatShuffleMask(cast<ShuffleVectorSDNode>(N), 1);
 223 }], VSPLTB_get_imm>;
 224 def VSPLTH_get_imm : SDNodeXForm<vector_shuffle, [{
 225   return getI32Imm(PPC::getSplatIdxForPPCMnemonics(N, 2, *CurDAG), SDLoc(N));
 226 }]>;
 227 def vsplth_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 228                              (vector_shuffle node:$lhs, node:$rhs), [{
 229   return PPC::isSplatShuffleMask(cast<ShuffleVectorSDNode>(N), 2);
 230 }], VSPLTH_get_imm>;
 231 def VSPLTW_get_imm : SDNodeXForm<vector_shuffle, [{
 232   return getI32Imm(PPC::getSplatIdxForPPCMnemonics(N, 4, *CurDAG), SDLoc(N));
 233 }]>;
 234 def vspltw_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 235                              (vector_shuffle node:$lhs, node:$rhs), [{
 236   return PPC::isSplatShuffleMask(cast<ShuffleVectorSDNode>(N), 4);
 237 }], VSPLTW_get_imm>;
 238
 239
 240 // VSPLTISB_get_imm xform function: convert build_vector to VSPLTISB imm.
 241 def VSPLTISB_get_imm : SDNodeXForm<build_vector, [{
 242   return PPC::get_VSPLTI_elt(N, 1, *CurDAG);
 243 }]>;
 244 def vecspltisb : PatLeaf<(build_vector), [{
 245   return PPC::get_VSPLTI_elt(N, 1, *CurDAG).getNode() != nullptr;
 246 }], VSPLTISB_get_imm>;
 247
 248 // VSPLTISH_get_imm xform function: convert build_vector to VSPLTISH imm.
 249 def VSPLTISH_get_imm : SDNodeXForm<build_vector, [{
 250   return PPC::get_VSPLTI_elt(N, 2, *CurDAG);
 251 }]>;
 252 def vecspltish : PatLeaf<(build_vector), [{
 253   return PPC::get_VSPLTI_elt(N, 2, *CurDAG).getNode() != nullptr;
 254 }], VSPLTISH_get_imm>;
 255
 256 // VSPLTISW_get_imm xform function: convert build_vector to VSPLTISW imm.
 257 def VSPLTISW_get_imm : SDNodeXForm<build_vector, [{
 258   return PPC::get_VSPLTI_elt(N, 4, *CurDAG);
 259 }]>;
 260 def vecspltisw : PatLeaf<(build_vector), [{
 261   return PPC::get_VSPLTI_elt(N, 4, *CurDAG).getNode() != nullptr;
 262 }], VSPLTISW_get_imm>;
 263
 264 def immEQOneV : PatLeaf<(build_vector), [{
 265   if (ConstantSDNode *C = cast<BuildVectorSDNode>(N)->getConstantSplatNode())
 266     return C->isOne();
 267   return false;
 268 }]>;
 269 //===----------------------------------------------------------------------===//
 270 // Helpers for defining instructions that directly correspond to intrinsics.
 271
 272 // VA1a_Int_Ty - A VAForm_1a intrinsic definition of specific type.
 273 class VA1a_Int_Ty<bits<6> xo, string opc, Intrinsic IntID, ValueType Ty>
 274   : VAForm_1a<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB, vrrc:$vC),
 275               !strconcat(opc, " $vD, $vA, $vB, $vC"), IIC_VecFP,
 276                        [(set Ty:$vD, (IntID Ty:$vA, Ty:$vB, Ty:$vC))]>;
 277
 278 // VA1a_Int_Ty2 - A VAForm_1a intrinsic definition where the type of the
 279 // inputs doesn't match the type of the output.
 280 class VA1a_Int_Ty2<bits<6> xo, string opc, Intrinsic IntID, ValueType OutTy,
 281                    ValueType InTy>
 282   : VAForm_1a<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB, vrrc:$vC),
 283               !strconcat(opc, " $vD, $vA, $vB, $vC"), IIC_VecFP,
 284                        [(set OutTy:$vD, (IntID InTy:$vA, InTy:$vB, InTy:$vC))]>;
 285
 286 // VA1a_Int_Ty3 - A VAForm_1a intrinsic definition where there are two
 287 // input types and an output type.
 288 class VA1a_Int_Ty3<bits<6> xo, string opc, Intrinsic IntID, ValueType OutTy,
 289                    ValueType In1Ty, ValueType In2Ty>
 290   : VAForm_1a<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB, vrrc:$vC),
 291               !strconcat(opc, " $vD, $vA, $vB, $vC"), IIC_VecFP,
 292                        [(set OutTy:$vD,
 293                          (IntID In1Ty:$vA, In1Ty:$vB, In2Ty:$vC))]>;
 294
 295 // VX1_Int_Ty - A VXForm_1 intrinsic definition of specific type.
 296 class VX1_Int_Ty<bits<11> xo, string opc, Intrinsic IntID, ValueType Ty>
 297   : VXForm_1<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 298              !strconcat(opc, " $vD, $vA, $vB"), IIC_VecFP,
 299              [(set Ty:$vD, (IntID Ty:$vA, Ty:$vB))]>;
 300
 301 // VX1_Int_Ty2 - A VXForm_1 intrinsic definition where the type of the
 302 // inputs doesn't match the type of the output.
 303 class VX1_Int_Ty2<bits<11> xo, string opc, Intrinsic IntID, ValueType OutTy,
 304                   ValueType InTy>
 305   : VXForm_1<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 306              !strconcat(opc, " $vD, $vA, $vB"), IIC_VecFP,
 307              [(set OutTy:$vD, (IntID InTy:$vA, InTy:$vB))]>;
 308
 309 // VX1_Int_Ty3 - A VXForm_1 intrinsic definition where there are two
 310 // input types and an output type.
 311 class VX1_Int_Ty3<bits<11> xo, string opc, Intrinsic IntID, ValueType OutTy,
 312                   ValueType In1Ty, ValueType In2Ty>
 313   : VXForm_1<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 314              !strconcat(opc, " $vD, $vA, $vB"), IIC_VecFP,
 315              [(set OutTy:$vD, (IntID In1Ty:$vA, In2Ty:$vB))]>;
 316
 317 // VX2_Int_SP - A VXForm_2 intrinsic definition of vector single-precision type.
 318 class VX2_Int_SP<bits<11> xo, string opc, Intrinsic IntID>
 319   : VXForm_2<xo, (outs vrrc:$vD), (ins vrrc:$vB),
 320              !strconcat(opc, " $vD, $vB"), IIC_VecFP,
 321              [(set v4f32:$vD, (IntID v4f32:$vB))]>;
 322
 323 // VX2_Int_Ty2 - A VXForm_2 intrinsic definition where the type of the
 324 // inputs doesn't match the type of the output.
 325 class VX2_Int_Ty2<bits<11> xo, string opc, Intrinsic IntID, ValueType OutTy,
 326                   ValueType InTy>
 327   : VXForm_2<xo, (outs vrrc:$vD), (ins vrrc:$vB),
 328              !strconcat(opc, " $vD, $vB"), IIC_VecFP,
 329              [(set OutTy:$vD, (IntID InTy:$vB))]>;
 330
 331 class VXBX_Int_Ty<bits<11> xo, string opc, Intrinsic IntID, ValueType Ty>
 332   : VXForm_BX<xo, (outs vrrc:$vD), (ins vrrc:$vA),
 333              !strconcat(opc, " $vD, $vA"), IIC_VecFP,
 334              [(set Ty:$vD, (IntID Ty:$vA))]>;
 335
 336 class VXCR_Int_Ty<bits<11> xo, string opc, Intrinsic IntID, ValueType Ty>
 337   : VXForm_CR<xo, (outs vrrc:$vD), (ins vrrc:$vA, u1imm:$ST, u4imm:$SIX),
 338               !strconcat(opc, " $vD, $vA, $ST, $SIX"), IIC_VecFP,
 339               [(set Ty:$vD, (IntID Ty:$vA, timm:$ST, timm:$SIX))]>;
 340
 341 //===----------------------------------------------------------------------===//
 342 // Instruction Definitions.
 343
 344 def HasAltivec : Predicate<"PPCSubTarget->hasAltivec()">;
 345 let Predicates = [HasAltivec] in {
 346
 347 def DSS      : DSS_Form<0, 822, (outs), (ins u5imm:$STRM),
 348                         "dss $STRM", IIC_LdStLoad /*FIXME*/, [(int_ppc_altivec_dss imm:$STRM)]>,
 349                         Deprecated<DeprecatedDST> {
 350   let A = 0;
 351   let B = 0;
 352 }
 353
 354 def DSSALL   : DSS_Form<1, 822, (outs), (ins),
 355                         "dssall", IIC_LdStLoad /*FIXME*/, [(int_ppc_altivec_dssall)]>,
 356                         Deprecated<DeprecatedDST> {
 357   let STRM = 0;
 358   let A = 0;
 359   let B = 0;
 360 }
 361
 362 def DST      : DSS_Form<0, 342, (outs), (ins u5imm:$STRM, gprc:$rA, gprc:$rB),
 363                         "dst $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 364                         [(int_ppc_altivec_dst i32:$rA, i32:$rB, imm:$STRM)]>,
 365                         Deprecated<DeprecatedDST>;
 366
 367 def DSTT     : DSS_Form<1, 342, (outs), (ins u5imm:$STRM, gprc:$rA, gprc:$rB),
 368                         "dstt $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 369                         [(int_ppc_altivec_dstt i32:$rA, i32:$rB, imm:$STRM)]>,
 370                         Deprecated<DeprecatedDST>;
 371
 372 def DSTST    : DSS_Form<0, 374, (outs), (ins u5imm:$STRM, gprc:$rA, gprc:$rB),
 373                         "dstst $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 374                         [(int_ppc_altivec_dstst i32:$rA, i32:$rB, imm:$STRM)]>,
 375                         Deprecated<DeprecatedDST>;
 376
 377 def DSTSTT   : DSS_Form<1, 374, (outs), (ins u5imm:$STRM, gprc:$rA, gprc:$rB),
 378                         "dststt $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 379                         [(int_ppc_altivec_dststt i32:$rA, i32:$rB, imm:$STRM)]>,
 380                         Deprecated<DeprecatedDST>;
 381
 382 let isCodeGenOnly = 1 in {
 383   // The very same instructions as above, but formally matching 64bit registers.
 384   def DST64    : DSS_Form<0, 342, (outs), (ins u5imm:$STRM, g8rc:$rA, gprc:$rB),
 385                           "dst $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 386                           [(int_ppc_altivec_dst i64:$rA, i32:$rB, imm:$STRM)]>,
 387                           Deprecated<DeprecatedDST>;
 388
 389   def DSTT64   : DSS_Form<1, 342, (outs), (ins u5imm:$STRM, g8rc:$rA, gprc:$rB),
 390                           "dstt $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 391                           [(int_ppc_altivec_dstt i64:$rA, i32:$rB, imm:$STRM)]>,
 392                           Deprecated<DeprecatedDST>;
 393
 394   def DSTST64  : DSS_Form<0, 374, (outs), (ins u5imm:$STRM, g8rc:$rA, gprc:$rB),
 395                           "dstst $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 396                           [(int_ppc_altivec_dstst i64:$rA, i32:$rB,
 397                                                   imm:$STRM)]>,
 398                           Deprecated<DeprecatedDST>;
 399
 400   def DSTSTT64 : DSS_Form<1, 374, (outs), (ins u5imm:$STRM, g8rc:$rA, gprc:$rB),
 401                           "dststt $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 402                           [(int_ppc_altivec_dststt i64:$rA, i32:$rB,
 403                                                    imm:$STRM)]>,
 404                           Deprecated<DeprecatedDST>;
 405 }
 406
 407 def MFVSCR : VXForm_4<1540, (outs vrrc:$vD), (ins),
 408                       "mfvscr $vD", IIC_LdStStore,
 409                       [(set v8i16:$vD, (int_ppc_altivec_mfvscr))]>;
 410 def MTVSCR : VXForm_5<1604, (outs), (ins vrrc:$vB),
 411                       "mtvscr $vB", IIC_LdStLoad,
 412                       [(int_ppc_altivec_mtvscr v4i32:$vB)]>;
 413
 414 let PPC970_Unit = 2, mayLoad = 1, mayStore = 0 in {  // Loads.
 415 def LVEBX: XForm_1_memOp<31,   7, (outs vrrc:$vD), (ins memrr:$src),
 416                    "lvebx $vD, $src", IIC_LdStLoad,
 417                    [(set v16i8:$vD, (int_ppc_altivec_lvebx xoaddr:$src))]>;
 418 def LVEHX: XForm_1_memOp<31,  39, (outs vrrc:$vD), (ins memrr:$src),
 419                    "lvehx $vD, $src", IIC_LdStLoad,
 420                    [(set v8i16:$vD, (int_ppc_altivec_lvehx xoaddr:$src))]>;
 421 def LVEWX: XForm_1_memOp<31,  71, (outs vrrc:$vD), (ins memrr:$src),
 422                    "lvewx $vD, $src", IIC_LdStLoad,
 423                    [(set v4i32:$vD, (int_ppc_altivec_lvewx xoaddr:$src))]>;
 424 def LVX  : XForm_1_memOp<31, 103, (outs vrrc:$vD), (ins memrr:$src),
 425                    "lvx $vD, $src", IIC_LdStLoad,
 426                    [(set v4i32:$vD, (int_ppc_altivec_lvx xoaddr:$src))]>;
 427 def LVXL : XForm_1_memOp<31, 359, (outs vrrc:$vD), (ins memrr:$src),
 428                    "lvxl $vD, $src", IIC_LdStLoad,
 429                    [(set v4i32:$vD, (int_ppc_altivec_lvxl xoaddr:$src))]>;
 430 }
 431
 432 def LVSL : XForm_1_memOp<31,   6, (outs vrrc:$vD), (ins memrr:$src),
 433                    "lvsl $vD, $src", IIC_LdStLoad,
 434                    [(set v16i8:$vD, (int_ppc_altivec_lvsl xoaddr:$src))]>,
 435                    PPC970_Unit_LSU;
 436 def LVSR : XForm_1_memOp<31,  38, (outs vrrc:$vD), (ins memrr:$src),
 437                    "lvsr $vD, $src", IIC_LdStLoad,
 438                    [(set v16i8:$vD, (int_ppc_altivec_lvsr xoaddr:$src))]>,
 439                    PPC970_Unit_LSU;
 440
 441 let PPC970_Unit = 2, mayStore = 1, mayLoad = 0 in {   // Stores.
 442 def STVEBX: XForm_8_memOp<31, 135, (outs), (ins vrrc:$rS, memrr:$dst),
 443                    "stvebx $rS, $dst", IIC_LdStStore,
 444                    [(int_ppc_altivec_stvebx v16i8:$rS, xoaddr:$dst)]>;
 445 def STVEHX: XForm_8_memOp<31, 167, (outs), (ins vrrc:$rS, memrr:$dst),
 446                    "stvehx $rS, $dst", IIC_LdStStore,
 447                    [(int_ppc_altivec_stvehx v8i16:$rS, xoaddr:$dst)]>;
 448 def STVEWX: XForm_8_memOp<31, 199, (outs), (ins vrrc:$rS, memrr:$dst),
 449                    "stvewx $rS, $dst", IIC_LdStStore,
 450                    [(int_ppc_altivec_stvewx v4i32:$rS, xoaddr:$dst)]>;
 451 def STVX  : XForm_8_memOp<31, 231, (outs), (ins vrrc:$rS, memrr:$dst),
 452                    "stvx $rS, $dst", IIC_LdStStore,
 453                    [(int_ppc_altivec_stvx v4i32:$rS, xoaddr:$dst)]>;
 454 def STVXL : XForm_8_memOp<31, 487, (outs), (ins vrrc:$rS, memrr:$dst),
 455                    "stvxl $rS, $dst", IIC_LdStStore,
 456                    [(int_ppc_altivec_stvxl v4i32:$rS, xoaddr:$dst)]>;
 457 }
 458
 459 let PPC970_Unit = 5 in {  // VALU Operations.
 460 // VA-Form instructions.  3-input AltiVec ops.
 461 let isCommutable = 1 in {
 462 def VMADDFP : VAForm_1<46, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vC, vrrc:$vB),
 463                        "vmaddfp $vD, $vA, $vC, $vB", IIC_VecFP,
 464                        [(set v4f32:$vD,
 465                         (fma v4f32:$vA, v4f32:$vC, v4f32:$vB))]>;
 466
 467 // FIXME: The fma+fneg pattern won't match because fneg is not legal.
 468 def VNMSUBFP: VAForm_1<47, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vC, vrrc:$vB),
 469                        "vnmsubfp $vD, $vA, $vC, $vB", IIC_VecFP,
 470                        [(set v4f32:$vD, (fneg (fma v4f32:$vA, v4f32:$vC,
 471                                                   (fneg v4f32:$vB))))]>;
 472
 473 def VMHADDSHS  : VA1a_Int_Ty<32, "vmhaddshs", int_ppc_altivec_vmhaddshs, v8i16>;
 474 def VMHRADDSHS : VA1a_Int_Ty<33, "vmhraddshs", int_ppc_altivec_vmhraddshs,
 475                              v8i16>;
 476 def VMLADDUHM  : VA1a_Int_Ty<34, "vmladduhm", int_ppc_altivec_vmladduhm, v8i16>;
 477 } // isCommutable
 478
 479 def VPERM      : VA1a_Int_Ty3<43, "vperm", int_ppc_altivec_vperm,
 480                               v4i32, v4i32, v16i8>;
 481 def VSEL       : VA1a_Int_Ty<42, "vsel",  int_ppc_altivec_vsel, v4i32>;
 482
 483 // Shuffles.
 484 def VSLDOI  : VAForm_2<44, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB, u4imm:$SH),
 485                        "vsldoi $vD, $vA, $vB, $SH", IIC_VecFP,
 486                        [(set v16i8:$vD,
 487                          (PPCvecshl v16i8:$vA, v16i8:$vB, imm32SExt16:$SH))]>;
 488
 489 // VX-Form instructions.  AltiVec arithmetic ops.
 490 let isCommutable = 1 in {
 491 def VADDFP : VXForm_1<10, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 492                       "vaddfp $vD, $vA, $vB", IIC_VecFP,
 493                       [(set v4f32:$vD, (fadd v4f32:$vA, v4f32:$vB))]>;
 494
 495 def VADDUBM : VXForm_1<0, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 496                       "vaddubm $vD, $vA, $vB", IIC_VecGeneral,
 497                       [(set v16i8:$vD, (add v16i8:$vA, v16i8:$vB))]>;
 498 def VADDUHM : VXForm_1<64, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 499                       "vadduhm $vD, $vA, $vB", IIC_VecGeneral,
 500                       [(set v8i16:$vD, (add v8i16:$vA, v8i16:$vB))]>;
 501 def VADDUWM : VXForm_1<128, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 502                       "vadduwm $vD, $vA, $vB", IIC_VecGeneral,
 503                       [(set v4i32:$vD, (add v4i32:$vA, v4i32:$vB))]>;
 504
 505 def VADDCUW : VX1_Int_Ty<384, "vaddcuw", int_ppc_altivec_vaddcuw, v4i32>;
 506 def VADDSBS : VX1_Int_Ty<768, "vaddsbs", int_ppc_altivec_vaddsbs, v16i8>;
 507 def VADDSHS : VX1_Int_Ty<832, "vaddshs", int_ppc_altivec_vaddshs, v8i16>;
 508 def VADDSWS : VX1_Int_Ty<896, "vaddsws", int_ppc_altivec_vaddsws, v4i32>;
 509 def VADDUBS : VX1_Int_Ty<512, "vaddubs", int_ppc_altivec_vaddubs, v16i8>;
 510 def VADDUHS : VX1_Int_Ty<576, "vadduhs", int_ppc_altivec_vadduhs, v8i16>;
 511 def VADDUWS : VX1_Int_Ty<640, "vadduws", int_ppc_altivec_vadduws, v4i32>;
 512 } // isCommutable
 513
 514 let isCommutable = 1 in
 515 def VAND : VXForm_1<1028, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 516                     "vand $vD, $vA, $vB", IIC_VecFP,
 517                     [(set v4i32:$vD, (and v4i32:$vA, v4i32:$vB))]>;
 518 def VANDC : VXForm_1<1092, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 519                      "vandc $vD, $vA, $vB", IIC_VecFP,
 520                      [(set v4i32:$vD, (and v4i32:$vA,
 521                                            (vnot_ppc v4i32:$vB)))]>;
 522
 523 def VCFSX  : VXForm_1<842, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 524                       "vcfsx $vD, $vB, $UIMM", IIC_VecFP,
 525                       [(set v4f32:$vD,
 526                              (int_ppc_altivec_vcfsx v4i32:$vB, timm:$UIMM))]>;
 527 def VCFUX  : VXForm_1<778, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 528                       "vcfux $vD, $vB, $UIMM", IIC_VecFP,
 529                       [(set v4f32:$vD,
 530                              (int_ppc_altivec_vcfux v4i32:$vB, timm:$UIMM))]>;
 531 def VCTSXS : VXForm_1<970, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 532                       "vctsxs $vD, $vB, $UIMM", IIC_VecFP,
 533                       [(set v4i32:$vD,
 534                              (int_ppc_altivec_vctsxs v4f32:$vB, timm:$UIMM))]>;
 535 def VCTUXS : VXForm_1<906, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 536                       "vctuxs $vD, $vB, $UIMM", IIC_VecFP,
 537                       [(set v4i32:$vD,
 538                              (int_ppc_altivec_vctuxs v4f32:$vB, timm:$UIMM))]>;
 539
 540 // Defines with the UIM field set to 0 for floating-point
 541 // to integer (fp_to_sint/fp_to_uint) conversions and integer
 542 // to floating-point (sint_to_fp/uint_to_fp) conversions.
 543 let isCodeGenOnly = 1, VA = 0 in {
 544 def VCFSX_0 : VXForm_1<842, (outs vrrc:$vD), (ins vrrc:$vB),
 545                        "vcfsx $vD, $vB, 0", IIC_VecFP,
 546                        [(set v4f32:$vD,
 547                              (int_ppc_altivec_vcfsx v4i32:$vB, 0))]>;
 548 def VCTUXS_0 : VXForm_1<906, (outs vrrc:$vD), (ins vrrc:$vB),
 549                         "vctuxs $vD, $vB, 0", IIC_VecFP,
 550                         [(set v4i32:$vD,
 551                                (int_ppc_altivec_vctuxs v4f32:$vB, 0))]>;
 552 def VCFUX_0 : VXForm_1<778, (outs vrrc:$vD), (ins vrrc:$vB),
 553                        "vcfux $vD, $vB, 0", IIC_VecFP,
 554                        [(set v4f32:$vD,
 555                                (int_ppc_altivec_vcfux v4i32:$vB, 0))]>;
 556 def VCTSXS_0 : VXForm_1<970, (outs vrrc:$vD), (ins vrrc:$vB),
 557                       "vctsxs $vD, $vB, 0", IIC_VecFP,
 558                       [(set v4i32:$vD,
 559                              (int_ppc_altivec_vctsxs v4f32:$vB, 0))]>;
 560 }
 561 def VEXPTEFP : VX2_Int_SP<394, "vexptefp", int_ppc_altivec_vexptefp>;
 562 def VLOGEFP  : VX2_Int_SP<458, "vlogefp",  int_ppc_altivec_vlogefp>;
 563
 564 let isCommutable = 1 in {
 565 def VAVGSB : VX1_Int_Ty<1282, "vavgsb", int_ppc_altivec_vavgsb, v16i8>;
 566 def VAVGSH : VX1_Int_Ty<1346, "vavgsh", int_ppc_altivec_vavgsh, v8i16>;
 567 def VAVGSW : VX1_Int_Ty<1410, "vavgsw", int_ppc_altivec_vavgsw, v4i32>;
 568 def VAVGUB : VX1_Int_Ty<1026, "vavgub", int_ppc_altivec_vavgub, v16i8>;
 569 def VAVGUH : VX1_Int_Ty<1090, "vavguh", int_ppc_altivec_vavguh, v8i16>;
 570 def VAVGUW : VX1_Int_Ty<1154, "vavguw", int_ppc_altivec_vavguw, v4i32>;
 571
 572 def VMAXFP : VX1_Int_Ty<1034, "vmaxfp", int_ppc_altivec_vmaxfp, v4f32>;
 573 def VMAXSB : VX1_Int_Ty< 258, "vmaxsb", int_ppc_altivec_vmaxsb, v16i8>;
 574 def VMAXSH : VX1_Int_Ty< 322, "vmaxsh", int_ppc_altivec_vmaxsh, v8i16>;
 575 def VMAXSW : VX1_Int_Ty< 386, "vmaxsw", int_ppc_altivec_vmaxsw, v4i32>;
 576 def VMAXUB : VX1_Int_Ty<   2, "vmaxub", int_ppc_altivec_vmaxub, v16i8>;
 577 def VMAXUH : VX1_Int_Ty<  66, "vmaxuh", int_ppc_altivec_vmaxuh, v8i16>;
 578 def VMAXUW : VX1_Int_Ty< 130, "vmaxuw", int_ppc_altivec_vmaxuw, v4i32>;
 579 def VMINFP : VX1_Int_Ty<1098, "vminfp", int_ppc_altivec_vminfp, v4f32>;
 580 def VMINSB : VX1_Int_Ty< 770, "vminsb", int_ppc_altivec_vminsb, v16i8>;
 581 def VMINSH : VX1_Int_Ty< 834, "vminsh", int_ppc_altivec_vminsh, v8i16>;
 582 def VMINSW : VX1_Int_Ty< 898, "vminsw", int_ppc_altivec_vminsw, v4i32>;
 583 def VMINUB : VX1_Int_Ty< 514, "vminub", int_ppc_altivec_vminub, v16i8>;
 584 def VMINUH : VX1_Int_Ty< 578, "vminuh", int_ppc_altivec_vminuh, v8i16>;
 585 def VMINUW : VX1_Int_Ty< 642, "vminuw", int_ppc_altivec_vminuw, v4i32>;
 586 } // isCommutable
 587
 588 def VMRGHB : VXForm_1< 12, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 589                       "vmrghb $vD, $vA, $vB", IIC_VecFP,
 590                       [(set v16i8:$vD, (vmrghb_shuffle v16i8:$vA, v16i8:$vB))]>;
 591 def VMRGHH : VXForm_1< 76, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 592                       "vmrghh $vD, $vA, $vB", IIC_VecFP,
 593                       [(set v16i8:$vD, (vmrghh_shuffle v16i8:$vA, v16i8:$vB))]>;
 594 def VMRGHW : VXForm_1<140, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 595                       "vmrghw $vD, $vA, $vB", IIC_VecFP,
 596                       [(set v16i8:$vD, (vmrghw_shuffle v16i8:$vA, v16i8:$vB))]>;
 597 def VMRGLB : VXForm_1<268, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 598                       "vmrglb $vD, $vA, $vB", IIC_VecFP,
 599                       [(set v16i8:$vD, (vmrglb_shuffle v16i8:$vA, v16i8:$vB))]>;
 600 def VMRGLH : VXForm_1<332, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 601                       "vmrglh $vD, $vA, $vB", IIC_VecFP,
 602                       [(set v16i8:$vD, (vmrglh_shuffle v16i8:$vA, v16i8:$vB))]>;
 603 def VMRGLW : VXForm_1<396, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 604                       "vmrglw $vD, $vA, $vB", IIC_VecFP,
 605                       [(set v16i8:$vD, (vmrglw_shuffle v16i8:$vA, v16i8:$vB))]>;
 606
 607 def VMSUMMBM : VA1a_Int_Ty3<37, "vmsummbm", int_ppc_altivec_vmsummbm,
 608                             v4i32, v16i8, v4i32>;
 609 def VMSUMSHM : VA1a_Int_Ty3<40, "vmsumshm", int_ppc_altivec_vmsumshm,
 610                             v4i32, v8i16, v4i32>;
 611 def VMSUMSHS : VA1a_Int_Ty3<41, "vmsumshs", int_ppc_altivec_vmsumshs,
 612                             v4i32, v8i16, v4i32>;
 613 def VMSUMUBM : VA1a_Int_Ty3<36, "vmsumubm", int_ppc_altivec_vmsumubm,
 614                             v4i32, v16i8, v4i32>;
 615 def VMSUMUHM : VA1a_Int_Ty3<38, "vmsumuhm", int_ppc_altivec_vmsumuhm,
 616                             v4i32, v8i16, v4i32>;
 617 def VMSUMUHS : VA1a_Int_Ty3<39, "vmsumuhs", int_ppc_altivec_vmsumuhs,
 618                             v4i32, v8i16, v4i32>;
 619
 620 let isCommutable = 1 in {
 621 def VMULESB : VX1_Int_Ty2<776, "vmulesb", int_ppc_altivec_vmulesb,
 622                           v8i16, v16i8>;
 623 def VMULESH : VX1_Int_Ty2<840, "vmulesh", int_ppc_altivec_vmulesh,
 624                           v4i32, v8i16>;
 625 def VMULEUB : VX1_Int_Ty2<520, "vmuleub", int_ppc_altivec_vmuleub,
 626                           v8i16, v16i8>;
 627 def VMULEUH : VX1_Int_Ty2<584, "vmuleuh", int_ppc_altivec_vmuleuh,
 628                           v4i32, v8i16>;
 629 def VMULOSB : VX1_Int_Ty2<264, "vmulosb", int_ppc_altivec_vmulosb,
 630                           v8i16, v16i8>;
 631 def VMULOSH : VX1_Int_Ty2<328, "vmulosh", int_ppc_altivec_vmulosh,
 632                           v4i32, v8i16>;
 633 def VMULOUB : VX1_Int_Ty2<  8, "vmuloub", int_ppc_altivec_vmuloub,
 634                           v8i16, v16i8>;
 635 def VMULOUH : VX1_Int_Ty2< 72, "vmulouh", int_ppc_altivec_vmulouh,
 636                           v4i32, v8i16>;
 637 } // isCommutable
 638
 639 def VREFP     : VX2_Int_SP<266, "vrefp",     int_ppc_altivec_vrefp>;
 640 def VRFIM     : VX2_Int_SP<714, "vrfim",     int_ppc_altivec_vrfim>;
 641 def VRFIN     : VX2_Int_SP<522, "vrfin",     int_ppc_altivec_vrfin>;
 642 def VRFIP     : VX2_Int_SP<650, "vrfip",     int_ppc_altivec_vrfip>;
 643 def VRFIZ     : VX2_Int_SP<586, "vrfiz",     int_ppc_altivec_vrfiz>;
 644 def VRSQRTEFP : VX2_Int_SP<330, "vrsqrtefp", int_ppc_altivec_vrsqrtefp>;
 645
 646 def VSUBCUW : VX1_Int_Ty<1408, "vsubcuw", int_ppc_altivec_vsubcuw, v4i32>;
 647
 648 def VSUBFP  : VXForm_1<74, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 649                       "vsubfp $vD, $vA, $vB", IIC_VecGeneral,
 650                       [(set v4f32:$vD, (fsub v4f32:$vA, v4f32:$vB))]>;
 651 def VSUBUBM : VXForm_1<1024, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 652                       "vsububm $vD, $vA, $vB", IIC_VecGeneral,
 653                       [(set v16i8:$vD, (sub v16i8:$vA, v16i8:$vB))]>;
 654 def VSUBUHM : VXForm_1<1088, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 655                       "vsubuhm $vD, $vA, $vB", IIC_VecGeneral,
 656                       [(set v8i16:$vD, (sub v8i16:$vA, v8i16:$vB))]>;
 657 def VSUBUWM : VXForm_1<1152, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 658                       "vsubuwm $vD, $vA, $vB", IIC_VecGeneral,
 659                       [(set v4i32:$vD, (sub v4i32:$vA, v4i32:$vB))]>;
 660
 661 def VSUBSBS : VX1_Int_Ty<1792, "vsubsbs" , int_ppc_altivec_vsubsbs, v16i8>;
 662 def VSUBSHS : VX1_Int_Ty<1856, "vsubshs" , int_ppc_altivec_vsubshs, v8i16>;
 663 def VSUBSWS : VX1_Int_Ty<1920, "vsubsws" , int_ppc_altivec_vsubsws, v4i32>;
 664 def VSUBUBS : VX1_Int_Ty<1536, "vsububs" , int_ppc_altivec_vsububs, v16i8>;
 665 def VSUBUHS : VX1_Int_Ty<1600, "vsubuhs" , int_ppc_altivec_vsubuhs, v8i16>;
 666 def VSUBUWS : VX1_Int_Ty<1664, "vsubuws" , int_ppc_altivec_vsubuws, v4i32>;
 667
 668 def VSUMSWS : VX1_Int_Ty<1928, "vsumsws" , int_ppc_altivec_vsumsws, v4i32>;
 669 def VSUM2SWS: VX1_Int_Ty<1672, "vsum2sws", int_ppc_altivec_vsum2sws, v4i32>;
 670
 671 def VSUM4SBS: VX1_Int_Ty3<1800, "vsum4sbs", int_ppc_altivec_vsum4sbs,
 672                           v4i32, v16i8, v4i32>;
 673 def VSUM4SHS: VX1_Int_Ty3<1608, "vsum4shs", int_ppc_altivec_vsum4shs,
 674                           v4i32, v8i16, v4i32>;
 675 def VSUM4UBS: VX1_Int_Ty3<1544, "vsum4ubs", int_ppc_altivec_vsum4ubs,
 676                           v4i32, v16i8, v4i32>;
 677
 678 def VNOR : VXForm_1<1284, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 679                     "vnor $vD, $vA, $vB", IIC_VecFP,
 680                     [(set v4i32:$vD, (vnot_ppc (or v4i32:$vA,
 681                                                    v4i32:$vB)))]>;
 682 let isCommutable = 1 in {
 683 def VOR : VXForm_1<1156, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 684                       "vor $vD, $vA, $vB", IIC_VecFP,
 685                       [(set v4i32:$vD, (or v4i32:$vA, v4i32:$vB))]>;
 686 def VXOR : VXForm_1<1220, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 687                       "vxor $vD, $vA, $vB", IIC_VecFP,
 688                       [(set v4i32:$vD, (xor v4i32:$vA, v4i32:$vB))]>;
 689 } // isCommutable
 690
 691 def VRLB   : VX1_Int_Ty<   4, "vrlb", int_ppc_altivec_vrlb, v16i8>;
 692 def VRLH   : VX1_Int_Ty<  68, "vrlh", int_ppc_altivec_vrlh, v8i16>;
 693 def VRLW   : VX1_Int_Ty< 132, "vrlw", int_ppc_altivec_vrlw, v4i32>;
 694
 695 def VSL    : VX1_Int_Ty< 452, "vsl" , int_ppc_altivec_vsl,  v4i32 >;
 696 def VSLO   : VX1_Int_Ty<1036, "vslo", int_ppc_altivec_vslo, v4i32>;
 697
 698 def VSLB   : VX1_Int_Ty< 260, "vslb", int_ppc_altivec_vslb, v16i8>;
 699 def VSLH   : VX1_Int_Ty< 324, "vslh", int_ppc_altivec_vslh, v8i16>;
 700 def VSLW   : VX1_Int_Ty< 388, "vslw", int_ppc_altivec_vslw, v4i32>;
 701
 702 def VSPLTB : VXForm_1<524, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 703                       "vspltb $vD, $vB, $UIMM", IIC_VecPerm,
 704                       [(set v16i8:$vD,
 705                         (vspltb_shuffle:$UIMM v16i8:$vB, (undef)))]>;
 706 def VSPLTH : VXForm_1<588, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 707                       "vsplth $vD, $vB, $UIMM", IIC_VecPerm,
 708                       [(set v16i8:$vD,
 709                         (vsplth_shuffle:$UIMM v16i8:$vB, (undef)))]>;
 710 def VSPLTW : VXForm_1<652, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 711                       "vspltw $vD, $vB, $UIMM", IIC_VecPerm,
 712                       [(set v16i8:$vD,
 713                         (vspltw_shuffle:$UIMM v16i8:$vB, (undef)))]>;
 714 let isCodeGenOnly = 1, hasSideEffects = 0 in {
 715   def VSPLTBs : VXForm_1<524, (outs vrrc:$vD), (ins u5imm:$UIMM, vfrc:$vB),
 716                          "vspltb $vD, $vB, $UIMM", IIC_VecPerm, []>;
 717   def VSPLTHs : VXForm_1<588, (outs vrrc:$vD), (ins u5imm:$UIMM, vfrc:$vB),
 718                          "vsplth $vD, $vB, $UIMM", IIC_VecPerm, []>;
 719 }
 720
 721 def VSR    : VX1_Int_Ty< 708, "vsr"  , int_ppc_altivec_vsr,  v4i32>;
 722 def VSRO   : VX1_Int_Ty<1100, "vsro" , int_ppc_altivec_vsro, v4i32>;
 723
 724 def VSRAB  : VX1_Int_Ty< 772, "vsrab", int_ppc_altivec_vsrab, v16i8>;
 725 def VSRAH  : VX1_Int_Ty< 836, "vsrah", int_ppc_altivec_vsrah, v8i16>;
 726 def VSRAW  : VX1_Int_Ty< 900, "vsraw", int_ppc_altivec_vsraw, v4i32>;
 727 def VSRB   : VX1_Int_Ty< 516, "vsrb" , int_ppc_altivec_vsrb , v16i8>;
 728 def VSRH   : VX1_Int_Ty< 580, "vsrh" , int_ppc_altivec_vsrh , v8i16>;
 729 def VSRW   : VX1_Int_Ty< 644, "vsrw" , int_ppc_altivec_vsrw , v4i32>;
 730
 731
 732 def VSPLTISB : VXForm_3<780, (outs vrrc:$vD), (ins s5imm:$SIMM),
 733                        "vspltisb $vD, $SIMM", IIC_VecPerm,
 734                        [(set v16i8:$vD, (v16i8 vecspltisb:$SIMM))]>;
 735 def VSPLTISH : VXForm_3<844, (outs vrrc:$vD), (ins s5imm:$SIMM),
 736                        "vspltish $vD, $SIMM", IIC_VecPerm,
 737                        [(set v8i16:$vD, (v8i16 vecspltish:$SIMM))]>;
 738 def VSPLTISW : VXForm_3<908, (outs vrrc:$vD), (ins s5imm:$SIMM),
 739                        "vspltisw $vD, $SIMM", IIC_VecPerm,
 740                        [(set v4i32:$vD, (v4i32 vecspltisw:$SIMM))]>;
 741
 742 // Vector Pack.
 743 def VPKPX   : VX1_Int_Ty2<782, "vpkpx", int_ppc_altivec_vpkpx,
 744                           v8i16, v4i32>;
 745 def VPKSHSS : VX1_Int_Ty2<398, "vpkshss", int_ppc_altivec_vpkshss,
 746                           v16i8, v8i16>;
 747 def VPKSHUS : VX1_Int_Ty2<270, "vpkshus", int_ppc_altivec_vpkshus,
 748                           v16i8, v8i16>;
 749 def VPKSWSS : VX1_Int_Ty2<462, "vpkswss", int_ppc_altivec_vpkswss,
 750                           v8i16, v4i32>;
 751 def VPKSWUS : VX1_Int_Ty2<334, "vpkswus", int_ppc_altivec_vpkswus,
 752                           v8i16, v4i32>;
 753 def VPKUHUM : VXForm_1<14, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 754                        "vpkuhum $vD, $vA, $vB", IIC_VecFP,
 755                        [(set v16i8:$vD,
 756                          (vpkuhum_shuffle v16i8:$vA, v16i8:$vB))]>;
 757 def VPKUHUS : VX1_Int_Ty2<142, "vpkuhus", int_ppc_altivec_vpkuhus,
 758                           v16i8, v8i16>;
 759 def VPKUWUM : VXForm_1<78, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 760                        "vpkuwum $vD, $vA, $vB", IIC_VecFP,
 761                        [(set v16i8:$vD,
 762                          (vpkuwum_shuffle v16i8:$vA, v16i8:$vB))]>;
 763 def VPKUWUS : VX1_Int_Ty2<206, "vpkuwus", int_ppc_altivec_vpkuwus,
 764                           v8i16, v4i32>;
 765
 766 // Vector Unpack.
 767 def VUPKHPX : VX2_Int_Ty2<846, "vupkhpx", int_ppc_altivec_vupkhpx,
 768                           v4i32, v8i16>;
 769 def VUPKHSB : VX2_Int_Ty2<526, "vupkhsb", int_ppc_altivec_vupkhsb,
 770                           v8i16, v16i8>;
 771 def VUPKHSH : VX2_Int_Ty2<590, "vupkhsh", int_ppc_altivec_vupkhsh,
 772                           v4i32, v8i16>;
 773 def VUPKLPX : VX2_Int_Ty2<974, "vupklpx", int_ppc_altivec_vupklpx,
 774                           v4i32, v8i16>;
 775 def VUPKLSB : VX2_Int_Ty2<654, "vupklsb", int_ppc_altivec_vupklsb,
 776                           v8i16, v16i8>;
 777 def VUPKLSH : VX2_Int_Ty2<718, "vupklsh", int_ppc_altivec_vupklsh,
 778                           v4i32, v8i16>;
 779
 780
 781 // Altivec Comparisons.
 782
 783 class VCMP<bits<10> xo, string asmstr, ValueType Ty>
 784   : VXRForm_1<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB), asmstr,
 785               IIC_VecFPCompare,
 786               [(set Ty:$vD, (Ty (PPCvcmp Ty:$vA, Ty:$vB, xo)))]>;
 787 class VCMPo<bits<10> xo, string asmstr, ValueType Ty>
 788   : VXRForm_1<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB), asmstr,
 789               IIC_VecFPCompare,
 790               [(set Ty:$vD, (Ty (PPCvcmp_o Ty:$vA, Ty:$vB, xo)))]> {
 791   let Defs = [CR6];
 792   let RC = 1;
 793 }
 794
 795 // f32 element comparisons.0
 796 def VCMPBFP   : VCMP <966, "vcmpbfp $vD, $vA, $vB"  , v4f32>;
 797 def VCMPBFP_rec  : VCMPo<966, "vcmpbfp. $vD, $vA, $vB" , v4f32>;
 798 def VCMPEQFP  : VCMP <198, "vcmpeqfp $vD, $vA, $vB" , v4f32>;
 799 def VCMPEQFP_rec : VCMPo<198, "vcmpeqfp. $vD, $vA, $vB", v4f32>;
 800 def VCMPGEFP  : VCMP <454, "vcmpgefp $vD, $vA, $vB" , v4f32>;
 801 def VCMPGEFP_rec : VCMPo<454, "vcmpgefp. $vD, $vA, $vB", v4f32>;
 802 def VCMPGTFP  : VCMP <710, "vcmpgtfp $vD, $vA, $vB" , v4f32>;
 803 def VCMPGTFP_rec : VCMPo<710, "vcmpgtfp. $vD, $vA, $vB", v4f32>;
 804
 805 // i8 element comparisons.
 806 def VCMPEQUB  : VCMP <  6, "vcmpequb $vD, $vA, $vB" , v16i8>;
 807 def VCMPEQUB_rec : VCMPo<  6, "vcmpequb. $vD, $vA, $vB", v16i8>;
 808 def VCMPGTSB  : VCMP <774, "vcmpgtsb $vD, $vA, $vB" , v16i8>;
 809 def VCMPGTSB_rec : VCMPo<774, "vcmpgtsb. $vD, $vA, $vB", v16i8>;
 810 def VCMPGTUB  : VCMP <518, "vcmpgtub $vD, $vA, $vB" , v16i8>;
 811 def VCMPGTUB_rec : VCMPo<518, "vcmpgtub. $vD, $vA, $vB", v16i8>;
 812
 813 // i16 element comparisons.
 814 def VCMPEQUH  : VCMP < 70, "vcmpequh $vD, $vA, $vB" , v8i16>;
 815 def VCMPEQUH_rec : VCMPo< 70, "vcmpequh. $vD, $vA, $vB", v8i16>;
 816 def VCMPGTSH  : VCMP <838, "vcmpgtsh $vD, $vA, $vB" , v8i16>;
 817 def VCMPGTSH_rec : VCMPo<838, "vcmpgtsh. $vD, $vA, $vB", v8i16>;
 818 def VCMPGTUH  : VCMP <582, "vcmpgtuh $vD, $vA, $vB" , v8i16>;
 819 def VCMPGTUH_rec : VCMPo<582, "vcmpgtuh. $vD, $vA, $vB", v8i16>;
 820
 821 // i32 element comparisons.
 822 def VCMPEQUW  : VCMP <134, "vcmpequw $vD, $vA, $vB" , v4i32>;
 823 def VCMPEQUW_rec : VCMPo<134, "vcmpequw. $vD, $vA, $vB", v4i32>;
 824 def VCMPGTSW  : VCMP <902, "vcmpgtsw $vD, $vA, $vB" , v4i32>;
 825 def VCMPGTSW_rec : VCMPo<902, "vcmpgtsw. $vD, $vA, $vB", v4i32>;
 826 def VCMPGTUW  : VCMP <646, "vcmpgtuw $vD, $vA, $vB" , v4i32>;
 827 def VCMPGTUW_rec : VCMPo<646, "vcmpgtuw. $vD, $vA, $vB", v4i32>;
 828
 829 let isCodeGenOnly = 1, isMoveImm = 1, isAsCheapAsAMove = 1,
 830     isReMaterializable = 1 in {
 831
 832 def V_SET0B : VXForm_setzero<1220, (outs vrrc:$vD), (ins),
 833                       "vxor $vD, $vD, $vD", IIC_VecFP,
 834                       [(set v16i8:$vD, (v16i8 immAllZerosV))]>;
 835 def V_SET0H : VXForm_setzero<1220, (outs vrrc:$vD), (ins),
 836                       "vxor $vD, $vD, $vD", IIC_VecFP,
 837                       [(set v8i16:$vD, (v8i16 immAllZerosV))]>;
 838 def V_SET0  : VXForm_setzero<1220, (outs vrrc:$vD), (ins),
 839                       "vxor $vD, $vD, $vD", IIC_VecFP,
 840                       [(set v4i32:$vD, (v4i32 immAllZerosV))]>;
 841
 842 let IMM=-1 in {
 843 def V_SETALLONESB : VXForm_3<908, (outs vrrc:$vD), (ins),
 844                       "vspltisw $vD, -1", IIC_VecFP,
 845                       [(set v16i8:$vD, (v16i8 immAllOnesV))]>;
 846 def V_SETALLONESH : VXForm_3<908, (outs vrrc:$vD), (ins),
 847                       "vspltisw $vD, -1", IIC_VecFP,
 848                       [(set v8i16:$vD, (v8i16 immAllOnesV))]>;
 849 def V_SETALLONES  : VXForm_3<908, (outs vrrc:$vD), (ins),
 850                       "vspltisw $vD, -1", IIC_VecFP,
 851                       [(set v4i32:$vD, (v4i32 immAllOnesV))]>;
 852 }
 853 }
 854 } // VALU Operations.
 855
 856 //===----------------------------------------------------------------------===//
 857 // Additional Altivec Patterns
 858 //
 859
 860 // Extended mnemonics
 861 def : InstAlias<"vmr $vD, $vA", (VOR vrrc:$vD, vrrc:$vA, vrrc:$vA)>;
 862 def : InstAlias<"vnot $vD, $vA", (VNOR vrrc:$vD, vrrc:$vA, vrrc:$vA)>;
 863
 864 // Rotates.
 865 def : Pat<(v16i8 (rotl v16i8:$vA, v16i8:$vB)),
 866           (v16i8 (VRLB v16i8:$vA, v16i8:$vB))>;
 867 def : Pat<(v8i16 (rotl v8i16:$vA, v8i16:$vB)),
 868           (v8i16 (VRLH v8i16:$vA, v8i16:$vB))>;
 869 def : Pat<(v4i32 (rotl v4i32:$vA, v4i32:$vB)),
 870           (v4i32 (VRLW v4i32:$vA, v4i32:$vB))>;
 871
 872 // Loads.
 873 def : Pat<(v4i32 (load xoaddr:$src)), (LVX xoaddr:$src)>;
 874
 875 // Stores.
 876 def : Pat<(store v4i32:$rS, xoaddr:$dst),
 877           (STVX $rS, xoaddr:$dst)>;
 878
 879 // Bit conversions.
 880 def : Pat<(v16i8 (bitconvert (v8i16 VRRC:$src))), (v16i8 VRRC:$src)>;
 881 def : Pat<(v16i8 (bitconvert (v4i32 VRRC:$src))), (v16i8 VRRC:$src)>;
 882 def : Pat<(v16i8 (bitconvert (v4f32 VRRC:$src))), (v16i8 VRRC:$src)>;
 883 def : Pat<(v16i8 (bitconvert (v2i64 VRRC:$src))), (v16i8 VRRC:$src)>;
 884 def : Pat<(v16i8 (bitconvert (v1i128 VRRC:$src))), (v16i8 VRRC:$src)>;
 885
 886 def : Pat<(v8i16 (bitconvert (v16i8 VRRC:$src))), (v8i16 VRRC:$src)>;
 887 def : Pat<(v8i16 (bitconvert (v4i32 VRRC:$src))), (v8i16 VRRC:$src)>;
 888 def : Pat<(v8i16 (bitconvert (v4f32 VRRC:$src))), (v8i16 VRRC:$src)>;
 889 def : Pat<(v8i16 (bitconvert (v2i64 VRRC:$src))), (v8i16 VRRC:$src)>;
 890 def : Pat<(v8i16 (bitconvert (v1i128 VRRC:$src))), (v8i16 VRRC:$src)>;
 891
 892 def : Pat<(v4i32 (bitconvert (v16i8 VRRC:$src))), (v4i32 VRRC:$src)>;
 893 def : Pat<(v4i32 (bitconvert (v8i16 VRRC:$src))), (v4i32 VRRC:$src)>;
 894 def : Pat<(v4i32 (bitconvert (v4f32 VRRC:$src))), (v4i32 VRRC:$src)>;
 895 def : Pat<(v4i32 (bitconvert (v2i64 VRRC:$src))), (v4i32 VRRC:$src)>;
 896 def : Pat<(v4i32 (bitconvert (v1i128 VRRC:$src))), (v4i32 VRRC:$src)>;
 897
 898 def : Pat<(v4f32 (bitconvert (v16i8 VRRC:$src))), (v4f32 VRRC:$src)>;
 899 def : Pat<(v4f32 (bitconvert (v8i16 VRRC:$src))), (v4f32 VRRC:$src)>;
 900 def : Pat<(v4f32 (bitconvert (v4i32 VRRC:$src))), (v4f32 VRRC:$src)>;
 901 def : Pat<(v4f32 (bitconvert (v2i64 VRRC:$src))), (v4f32 VRRC:$src)>;
 902 def : Pat<(v4f32 (bitconvert (v1i128 VRRC:$src))), (v4f32 VRRC:$src)>;
 903
 904 def : Pat<(v2i64 (bitconvert (v16i8 VRRC:$src))), (v2i64 VRRC:$src)>;
 905 def : Pat<(v2i64 (bitconvert (v8i16 VRRC:$src))), (v2i64 VRRC:$src)>;
 906 def : Pat<(v2i64 (bitconvert (v4i32 VRRC:$src))), (v2i64 VRRC:$src)>;
 907 def : Pat<(v2i64 (bitconvert (v4f32 VRRC:$src))), (v2i64 VRRC:$src)>;
 908 def : Pat<(v2i64 (bitconvert (v1i128 VRRC:$src))), (v2i64 VRRC:$src)>;
 909
 910 def : Pat<(v1i128 (bitconvert (v16i8 VRRC:$src))), (v1i128 VRRC:$src)>;
 911 def : Pat<(v1i128 (bitconvert (v8i16 VRRC:$src))), (v1i128 VRRC:$src)>;
 912 def : Pat<(v1i128 (bitconvert (v4i32 VRRC:$src))), (v1i128 VRRC:$src)>;
 913 def : Pat<(v1i128 (bitconvert (v4f32 VRRC:$src))), (v1i128 VRRC:$src)>;
 914 def : Pat<(v1i128 (bitconvert (v2i64 VRRC:$src))), (v1i128 VRRC:$src)>;
 915
 916 // Max/Min
 917 def : Pat<(v16i8 (umax v16i8:$src1, v16i8:$src2)),
 918           (v16i8 (VMAXUB $src1, $src2))>;
 919 def : Pat<(v16i8 (smax v16i8:$src1, v16i8:$src2)),
 920           (v16i8 (VMAXSB $src1, $src2))>;
 921 def : Pat<(v8i16 (umax v8i16:$src1, v8i16:$src2)),
 922           (v8i16 (VMAXUH $src1, $src2))>;
 923 def : Pat<(v8i16 (smax v8i16:$src1, v8i16:$src2)),
 924           (v8i16 (VMAXSH $src1, $src2))>;
 925 def : Pat<(v4i32 (umax v4i32:$src1, v4i32:$src2)),
 926           (v4i32 (VMAXUW $src1, $src2))>;
 927 def : Pat<(v4i32 (smax v4i32:$src1, v4i32:$src2)),
 928           (v4i32 (VMAXSW $src1, $src2))>;
 929 def : Pat<(v16i8 (umin v16i8:$src1, v16i8:$src2)),
 930           (v16i8 (VMINUB $src1, $src2))>;
 931 def : Pat<(v16i8 (smin v16i8:$src1, v16i8:$src2)),
 932           (v16i8 (VMINSB $src1, $src2))>;
 933 def : Pat<(v8i16 (umin v8i16:$src1, v8i16:$src2)),
 934           (v8i16 (VMINUH $src1, $src2))>;
 935 def : Pat<(v8i16 (smin v8i16:$src1, v8i16:$src2)),
 936           (v8i16 (VMINSH $src1, $src2))>;
 937 def : Pat<(v4i32 (umin v4i32:$src1, v4i32:$src2)),
 938           (v4i32 (VMINUW $src1, $src2))>;
 939 def : Pat<(v4i32 (smin v4i32:$src1, v4i32:$src2)),
 940           (v4i32 (VMINSW $src1, $src2))>;
 941
 942 // Shuffles.
 943
 944 // Match vsldoi(x,x), vpkuwum(x,x), vpkuhum(x,x)
 945 def:Pat<(vsldoi_unary_shuffle:$in v16i8:$vA, undef),
 946         (VSLDOI $vA, $vA, (VSLDOI_unary_get_imm $in))>;
 947 def:Pat<(vpkuwum_unary_shuffle v16i8:$vA, undef),
 948         (VPKUWUM $vA, $vA)>;
 949 def:Pat<(vpkuhum_unary_shuffle v16i8:$vA, undef),
 950         (VPKUHUM $vA, $vA)>;
 951 def:Pat<(vsldoi_shuffle:$SH v16i8:$vA, v16i8:$vB),
 952         (VSLDOI v16i8:$vA, v16i8:$vB, (VSLDOI_get_imm $SH))>;
 953
 954
 955 // Match vsldoi(y,x), vpkuwum(y,x), vpkuhum(y,x), i.e., swapped operands.
 956 // These fragments are matched for little-endian, where the inputs must
 957 // be swapped for correct semantics.
 958 def:Pat<(vsldoi_swapped_shuffle:$in v16i8:$vA, v16i8:$vB),
 959         (VSLDOI $vB, $vA, (VSLDOI_swapped_get_imm $in))>;
 960 def:Pat<(vpkuwum_swapped_shuffle v16i8:$vA, v16i8:$vB),
 961         (VPKUWUM $vB, $vA)>;
 962 def:Pat<(vpkuhum_swapped_shuffle v16i8:$vA, v16i8:$vB),
 963         (VPKUHUM $vB, $vA)>;
 964
 965 // Match vmrg*(x,x)
 966 def:Pat<(vmrglb_unary_shuffle v16i8:$vA, undef),
 967         (VMRGLB $vA, $vA)>;
 968 def:Pat<(vmrglh_unary_shuffle v16i8:$vA, undef),
 969         (VMRGLH $vA, $vA)>;
 970 def:Pat<(vmrglw_unary_shuffle v16i8:$vA, undef),
 971         (VMRGLW $vA, $vA)>;
 972 def:Pat<(vmrghb_unary_shuffle v16i8:$vA, undef),
 973         (VMRGHB $vA, $vA)>;
 974 def:Pat<(vmrghh_unary_shuffle v16i8:$vA, undef),
 975         (VMRGHH $vA, $vA)>;
 976 def:Pat<(vmrghw_unary_shuffle v16i8:$vA, undef),
 977         (VMRGHW $vA, $vA)>;
 978
 979 // Match vmrg*(y,x), i.e., swapped operands.  These fragments
 980 // are matched for little-endian, where the inputs must be
 981 // swapped for correct semantics.
 982 def:Pat<(vmrglb_swapped_shuffle v16i8:$vA, v16i8:$vB),
 983         (VMRGLB $vB, $vA)>;
 984 def:Pat<(vmrglh_swapped_shuffle v16i8:$vA, v16i8:$vB),
 985         (VMRGLH $vB, $vA)>;
 986 def:Pat<(vmrglw_swapped_shuffle v16i8:$vA, v16i8:$vB),
 987         (VMRGLW $vB, $vA)>;
 988 def:Pat<(vmrghb_swapped_shuffle v16i8:$vA, v16i8:$vB),
 989         (VMRGHB $vB, $vA)>;
 990 def:Pat<(vmrghh_swapped_shuffle v16i8:$vA, v16i8:$vB),
 991         (VMRGHH $vB, $vA)>;
 992 def:Pat<(vmrghw_swapped_shuffle v16i8:$vA, v16i8:$vB),
 993         (VMRGHW $vB, $vA)>;
 994
 995 // Logical Operations
 996 def : Pat<(vnot_ppc v4i32:$vA), (VNOR $vA, $vA)>;
 997
 998 def : Pat<(vnot_ppc (or v4i32:$A, v4i32:$B)),
 999           (VNOR $A, $B)>;
1000 def : Pat<(and v4i32:$A, (vnot_ppc v4i32:$B)),
1001           (VANDC $A, $B)>;
1002
1003 def : Pat<(fmul v4f32:$vA, v4f32:$vB),
1004           (VMADDFP $vA, $vB,
1005              (v4i32 (VSLW (v4i32 (V_SETALLONES)), (v4i32 (V_SETALLONES)))))>;
1006
1007 // Fused multiply add and multiply sub for packed float.  These are represented
1008 // separately from the real instructions above, for operations that must have
1009 // the additional precision, such as Newton-Rhapson (used by divide, sqrt)
1010 def : Pat<(PPCvmaddfp v4f32:$A, v4f32:$B, v4f32:$C),
1011           (VMADDFP $A, $B, $C)>;
1012 def : Pat<(PPCvnmsubfp v4f32:$A, v4f32:$B, v4f32:$C),
1013           (VNMSUBFP $A, $B, $C)>;
1014
1015 def : Pat<(int_ppc_altivec_vmaddfp v4f32:$A, v4f32:$B, v4f32:$C),
1016           (VMADDFP $A, $B, $C)>;
1017 def : Pat<(int_ppc_altivec_vnmsubfp v4f32:$A, v4f32:$B, v4f32:$C),
1018           (VNMSUBFP $A, $B, $C)>;
1019
1020 def : Pat<(PPCvperm v16i8:$vA, v16i8:$vB, v16i8:$vC),
1021           (VPERM $vA, $vB, $vC)>;
1022
1023 def : Pat<(PPCfre v4f32:$A), (VREFP $A)>;
1024 def : Pat<(PPCfrsqrte v4f32:$A), (VRSQRTEFP $A)>;
1025
1026 // Vector shifts
1027 def : Pat<(v16i8 (shl v16i8:$vA, v16i8:$vB)),
1028           (v16i8 (VSLB $vA, $vB))>;
1029 def : Pat<(v8i16 (shl v8i16:$vA, v8i16:$vB)),
1030           (v8i16 (VSLH $vA, $vB))>;
1031 def : Pat<(v4i32 (shl v4i32:$vA, v4i32:$vB)),
1032           (v4i32 (VSLW $vA, $vB))>;
1033 def : Pat<(v1i128 (shl v1i128:$vA, v1i128:$vB)),
1034           (v1i128 (VSL (v16i8 (VSLO $vA, $vB)), (v16i8 (VSPLTB 15, $vB))))>;
1035 def : Pat<(v16i8 (PPCshl v16i8:$vA, v16i8:$vB)),
1036           (v16i8 (VSLB $vA, $vB))>;
1037 def : Pat<(v8i16 (PPCshl v8i16:$vA, v8i16:$vB)),
1038           (v8i16 (VSLH $vA, $vB))>;
1039 def : Pat<(v4i32 (PPCshl v4i32:$vA, v4i32:$vB)),
1040           (v4i32 (VSLW $vA, $vB))>;
1041 def : Pat<(v1i128 (PPCshl v1i128:$vA, v1i128:$vB)),
1042           (v1i128 (VSL (v16i8 (VSLO $vA, $vB)), (v16i8 (VSPLTB 15, $vB))))>;
1043
1044 def : Pat<(v16i8 (srl v16i8:$vA, v16i8:$vB)),
1045           (v16i8 (VSRB $vA, $vB))>;
1046 def : Pat<(v8i16 (srl v8i16:$vA, v8i16:$vB)),
1047           (v8i16 (VSRH $vA, $vB))>;
1048 def : Pat<(v4i32 (srl v4i32:$vA, v4i32:$vB)),
1049           (v4i32 (VSRW $vA, $vB))>;
1050 def : Pat<(v1i128 (srl v1i128:$vA, v1i128:$vB)),
1051           (v1i128 (VSR (v16i8 (VSRO $vA, $vB)), (v16i8 (VSPLTB 15, $vB))))>;
1052 def : Pat<(v16i8 (PPCsrl v16i8:$vA, v16i8:$vB)),
1053           (v16i8 (VSRB $vA, $vB))>;
1054 def : Pat<(v8i16 (PPCsrl v8i16:$vA, v8i16:$vB)),
1055           (v8i16 (VSRH $vA, $vB))>;
1056 def : Pat<(v4i32 (PPCsrl v4i32:$vA, v4i32:$vB)),
1057           (v4i32 (VSRW $vA, $vB))>;
1058 def : Pat<(v1i128 (PPCsrl v1i128:$vA, v1i128:$vB)),
1059           (v1i128 (VSR (v16i8 (VSRO $vA, $vB)), (v16i8 (VSPLTB 15, $vB))))>;
1060
1061 def : Pat<(v16i8 (sra v16i8:$vA, v16i8:$vB)),
1062           (v16i8 (VSRAB $vA, $vB))>;
1063 def : Pat<(v8i16 (sra v8i16:$vA, v8i16:$vB)),
1064           (v8i16 (VSRAH $vA, $vB))>;
1065 def : Pat<(v4i32 (sra v4i32:$vA, v4i32:$vB)),
1066           (v4i32 (VSRAW $vA, $vB))>;
1067 def : Pat<(v16i8 (PPCsra v16i8:$vA, v16i8:$vB)),
1068           (v16i8 (VSRAB $vA, $vB))>;
1069 def : Pat<(v8i16 (PPCsra v8i16:$vA, v8i16:$vB)),
1070           (v8i16 (VSRAH $vA, $vB))>;
1071 def : Pat<(v4i32 (PPCsra v4i32:$vA, v4i32:$vB)),
1072           (v4i32 (VSRAW $vA, $vB))>;
1073
1074 // Float to integer and integer to float conversions
1075 def : Pat<(v4i32 (fp_to_sint v4f32:$vA)),
1076            (VCTSXS_0 $vA)>;
1077 def : Pat<(v4i32 (fp_to_uint v4f32:$vA)),
1078            (VCTUXS_0 $vA)>;
1079 def : Pat<(v4f32 (sint_to_fp v4i32:$vA)),
1080            (VCFSX_0 $vA)>;
1081 def : Pat<(v4f32 (uint_to_fp v4i32:$vA)),
1082            (VCFUX_0 $vA)>;
1083
1084 // Floating-point rounding
1085 def : Pat<(v4f32 (ffloor v4f32:$vA)),
1086           (VRFIM $vA)>;
1087 def : Pat<(v4f32 (fceil v4f32:$vA)),
1088           (VRFIP $vA)>;
1089 def : Pat<(v4f32 (ftrunc v4f32:$vA)),
1090           (VRFIZ $vA)>;
1091 def : Pat<(v4f32 (fnearbyint v4f32:$vA)),
1092           (VRFIN $vA)>;
1093
1094 // Vector selection
1095 def : Pat<(v16i8 (vselect v16i8:$vA, v16i8:$vB, v16i8:$vC)),
1096           (VSEL $vC, $vB, $vA)>;
1097 def : Pat<(v8i16 (vselect v8i16:$vA, v8i16:$vB, v8i16:$vC)),
1098           (VSEL $vC, $vB, $vA)>;
1099 def : Pat<(v4i32 (vselect v4i32:$vA, v4i32:$vB, v4i32:$vC)),
1100           (VSEL $vC, $vB, $vA)>;
1101 def : Pat<(v2i64 (vselect v2i64:$vA, v2i64:$vB, v2i64:$vC)),
1102           (VSEL $vC, $vB, $vA)>;
1103 def : Pat<(v4f32 (vselect v4i32:$vA, v4f32:$vB, v4f32:$vC)),
1104           (VSEL $vC, $vB, $vA)>;
1105 def : Pat<(v2f64 (vselect v2i64:$vA, v2f64:$vB, v2f64:$vC)),
1106           (VSEL $vC, $vB, $vA)>;
1107
1108 // Vector Integer Average Instructions
1109 def : Pat<(v4i32 (sra (sub v4i32:$vA, (vnot_ppc v4i32:$vB)),
1110           (v4i32 (immEQOneV)))), (v4i32 (VAVGSW $vA, $vB))>;
1111 def : Pat<(v8i16 (sra (sub v8i16:$vA, (v8i16 (bitconvert(vnot_ppc v4i32:$vB)))),
1112           (v8i16 (immEQOneV)))), (v8i16 (VAVGSH $vA, $vB))>;
1113 def : Pat<(v16i8 (sra (sub v16i8:$vA, (v16i8 (bitconvert(vnot_ppc v4i32:$vB)))),
1114           (v16i8 (immEQOneV)))), (v16i8 (VAVGSB $vA, $vB))>;
1115 def : Pat<(v4i32 (srl (sub v4i32:$vA, (vnot_ppc v4i32:$vB)),
1116           (v4i32 (immEQOneV)))), (v4i32 (VAVGUW $vA, $vB))>;
1117 def : Pat<(v8i16 (srl (sub v8i16:$vA, (v8i16 (bitconvert(vnot_ppc v4i32:$vB)))),
1118           (v8i16 (immEQOneV)))), (v8i16 (VAVGUH $vA, $vB))>;
1119 def : Pat<(v16i8 (srl (sub v16i8:$vA, (v16i8 (bitconvert(vnot_ppc v4i32:$vB)))),
1120           (v16i8 (immEQOneV)))), (v16i8 (VAVGUB $vA, $vB))>;
1121
1122 } // end HasAltivec
1123
1124 def HasP8Altivec : Predicate<"PPCSubTarget->hasP8Altivec()">;
1125 def HasP8Crypto : Predicate<"PPCSubTarget->hasP8Crypto()">;
1126 let Predicates = [HasP8Altivec] in {
1127
1128 let isCommutable = 1 in {
1129 def VMULESW : VX1_Int_Ty2<904, "vmulesw", int_ppc_altivec_vmulesw,
1130                           v2i64, v4i32>;
1131 def VMULEUW : VX1_Int_Ty2<648, "vmuleuw", int_ppc_altivec_vmuleuw,
1132                           v2i64, v4i32>;
1133 def VMULOSW : VX1_Int_Ty2<392, "vmulosw", int_ppc_altivec_vmulosw,
1134                           v2i64, v4i32>;
1135 def VMULOUW : VX1_Int_Ty2<136, "vmulouw", int_ppc_altivec_vmulouw,
1136                           v2i64, v4i32>;
1137 def VMULUWM : VXForm_1<137, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1138                        "vmuluwm $vD, $vA, $vB", IIC_VecGeneral,
1139                        [(set v4i32:$vD, (mul v4i32:$vA, v4i32:$vB))]>;
1140 def VMAXSD : VX1_Int_Ty<450, "vmaxsd", int_ppc_altivec_vmaxsd, v2i64>;
1141 def VMAXUD : VX1_Int_Ty<194, "vmaxud", int_ppc_altivec_vmaxud, v2i64>;
1142 def VMINSD : VX1_Int_Ty<962, "vminsd", int_ppc_altivec_vminsd, v2i64>;
1143 def VMINUD : VX1_Int_Ty<706, "vminud", int_ppc_altivec_vminud, v2i64>;
1144 } // isCommutable
1145
1146 // Vector merge
1147 def VMRGEW : VXForm_1<1932, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1148                       "vmrgew $vD, $vA, $vB", IIC_VecFP,
1149                       [(set v16i8:$vD,
1150                             (v16i8 (vmrgew_shuffle v16i8:$vA, v16i8:$vB)))]>;
1151 def VMRGOW : VXForm_1<1676, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1152                       "vmrgow $vD, $vA, $vB", IIC_VecFP,
1153                       [(set v16i8:$vD,
1154                             (v16i8 (vmrgow_shuffle v16i8:$vA, v16i8:$vB)))]>;
1155
1156 // Match vmrgew(x,x) and vmrgow(x,x)
1157 def:Pat<(vmrgew_unary_shuffle v16i8:$vA, undef),
1158         (VMRGEW $vA, $vA)>;
1159 def:Pat<(vmrgow_unary_shuffle v16i8:$vA, undef),
1160         (VMRGOW $vA, $vA)>;
1161
1162 // Match vmrgew(y,x) and vmrgow(y,x), i.e., swapped operands.  These fragments
1163 // are matched for little-endian, where the inputs must be swapped for correct
1164 // semantics.w
1165 def:Pat<(vmrgew_swapped_shuffle v16i8:$vA, v16i8:$vB),
1166         (VMRGEW $vB, $vA)>;
1167 def:Pat<(vmrgow_swapped_shuffle v16i8:$vA, v16i8:$vB),
1168         (VMRGOW $vB, $vA)>;
1169
1170 // Vector rotates.
1171 def VRLD : VX1_Int_Ty<196, "vrld", int_ppc_altivec_vrld, v2i64>;
1172
1173 def : Pat<(v2i64 (rotl v2i64:$vA, v2i64:$vB)),
1174           (v2i64 (VRLD v2i64:$vA, v2i64:$vB))>;
1175
1176 // Vector shifts
1177 def VSLD : VXForm_1<1476, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1178                     "vsld $vD, $vA, $vB", IIC_VecGeneral, []>;
1179 def VSRD : VXForm_1<1732, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1180                    "vsrd $vD, $vA, $vB", IIC_VecGeneral, []>;
1181 def VSRAD : VXForm_1<964, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1182                     "vsrad $vD, $vA, $vB", IIC_VecGeneral, []>;
1183
1184 def : Pat<(v2i64 (shl v2i64:$vA, v2i64:$vB)),
1185           (v2i64 (VSLD $vA, $vB))>;
1186 def : Pat<(v2i64 (PPCshl v2i64:$vA, v2i64:$vB)),
1187           (v2i64 (VSLD $vA, $vB))>;
1188 def : Pat<(v2i64 (srl v2i64:$vA, v2i64:$vB)),
1189           (v2i64 (VSRD $vA, $vB))>;
1190 def : Pat<(v2i64 (PPCsrl v2i64:$vA, v2i64:$vB)),
1191           (v2i64 (VSRD $vA, $vB))>;
1192 def : Pat<(v2i64 (sra v2i64:$vA, v2i64:$vB)),
1193           (v2i64 (VSRAD $vA, $vB))>;
1194 def : Pat<(v2i64 (PPCsra v2i64:$vA, v2i64:$vB)),
1195           (v2i64 (VSRAD $vA, $vB))>;
1196
1197 // Vector Integer Arithmetic Instructions
1198 let isCommutable = 1 in {
1199 def VADDUDM : VXForm_1<192, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1200                        "vaddudm $vD, $vA, $vB", IIC_VecGeneral,
1201                        [(set v2i64:$vD, (add v2i64:$vA, v2i64:$vB))]>;
1202 def VADDUQM : VXForm_1<256, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1203                        "vadduqm $vD, $vA, $vB", IIC_VecGeneral,
1204                        [(set v1i128:$vD, (add v1i128:$vA, v1i128:$vB))]>;
1205 } // isCommutable
1206
1207 // Vector Quadword Add
1208 def VADDEUQM : VA1a_Int_Ty<60, "vaddeuqm", int_ppc_altivec_vaddeuqm, v1i128>;
1209 def VADDCUQ  : VX1_Int_Ty<320, "vaddcuq", int_ppc_altivec_vaddcuq, v1i128>;
1210 def VADDECUQ : VA1a_Int_Ty<61, "vaddecuq", int_ppc_altivec_vaddecuq, v1i128>;
1211
1212 // Vector Doubleword Subtract
1213 def VSUBUDM : VXForm_1<1216, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1214                        "vsubudm $vD, $vA, $vB", IIC_VecGeneral,
1215                        [(set v2i64:$vD, (sub v2i64:$vA, v2i64:$vB))]>;
1216
1217 // Vector Quadword Subtract
1218 def VSUBUQM : VXForm_1<1280, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1219                        "vsubuqm $vD, $vA, $vB", IIC_VecGeneral,
1220                        [(set v1i128:$vD, (sub v1i128:$vA, v1i128:$vB))]>;
1221 def VSUBEUQM : VA1a_Int_Ty<62, "vsubeuqm", int_ppc_altivec_vsubeuqm, v1i128>;
1222 def VSUBCUQ  : VX1_Int_Ty<1344, "vsubcuq", int_ppc_altivec_vsubcuq, v1i128>;
1223 def VSUBECUQ : VA1a_Int_Ty<63, "vsubecuq", int_ppc_altivec_vsubecuq, v1i128>;
1224
1225 // Count Leading Zeros
1226 def VCLZB : VXForm_2<1794, (outs vrrc:$vD), (ins vrrc:$vB),
1227                      "vclzb $vD, $vB", IIC_VecGeneral,
1228                      [(set v16i8:$vD, (ctlz v16i8:$vB))]>;
1229 def VCLZH : VXForm_2<1858, (outs vrrc:$vD), (ins vrrc:$vB),
1230                      "vclzh $vD, $vB", IIC_VecGeneral,
1231                      [(set v8i16:$vD, (ctlz v8i16:$vB))]>;
1232 def VCLZW : VXForm_2<1922, (outs vrrc:$vD), (ins vrrc:$vB),
1233                      "vclzw $vD, $vB", IIC_VecGeneral,
1234                      [(set v4i32:$vD, (ctlz v4i32:$vB))]>;
1235 def VCLZD : VXForm_2<1986, (outs vrrc:$vD), (ins vrrc:$vB),
1236                      "vclzd $vD, $vB", IIC_VecGeneral,
1237                      [(set v2i64:$vD, (ctlz v2i64:$vB))]>;
1238
1239 // Population Count
1240 def VPOPCNTB : VXForm_2<1795, (outs vrrc:$vD), (ins vrrc:$vB),
1241                         "vpopcntb $vD, $vB", IIC_VecGeneral,
1242                         [(set v16i8:$vD, (ctpop v16i8:$vB))]>;
1243 def VPOPCNTH : VXForm_2<1859, (outs vrrc:$vD), (ins vrrc:$vB),
1244                         "vpopcnth $vD, $vB", IIC_VecGeneral,
1245                         [(set v8i16:$vD, (ctpop v8i16:$vB))]>;
1246 def VPOPCNTW : VXForm_2<1923, (outs vrrc:$vD), (ins vrrc:$vB),
1247                         "vpopcntw $vD, $vB", IIC_VecGeneral,
1248                         [(set v4i32:$vD, (ctpop v4i32:$vB))]>;
1249 def VPOPCNTD : VXForm_2<1987, (outs vrrc:$vD), (ins vrrc:$vB),
1250                         "vpopcntd $vD, $vB", IIC_VecGeneral,
1251                         [(set v2i64:$vD, (ctpop v2i64:$vB))]>;
1252
1253 let isCommutable = 1 in {
1254 // FIXME: Use AddedComplexity > 400 to ensure these patterns match before the
1255 //        VSX equivalents. We need to fix this up at some point. Two possible
1256 //        solutions for this problem:
1257 //        1. Disable Altivec patterns that compete with VSX patterns using the
1258 //           !HasVSX predicate. This essentially favours VSX over Altivec, in
1259 //           hopes of reducing register pressure (larger register set using VSX
1260 //           instructions than VMX instructions)
1261 //        2. Employ a more disciplined use of AddedComplexity, which would provide
1262 //           more fine-grained control than option 1. This would be beneficial
1263 //           if we find situations where Altivec is really preferred over VSX.
1264 def VEQV  : VXForm_1<1668, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1265                      "veqv $vD, $vA, $vB", IIC_VecGeneral,
1266                      [(set v4i32:$vD, (vnot_ppc (xor v4i32:$vA, v4i32:$vB)))]>;
1267 def VNAND : VXForm_1<1412, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1268                      "vnand $vD, $vA, $vB", IIC_VecGeneral,
1269                      [(set v4i32:$vD, (vnot_ppc (and v4i32:$vA, v4i32:$vB)))]>;
1270 } // isCommutable
1271
1272 def VORC : VXForm_1<1348, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1273                       "vorc $vD, $vA, $vB", IIC_VecGeneral,
1274                       [(set v4i32:$vD, (or v4i32:$vA,
1275                                            (vnot_ppc v4i32:$vB)))]>;
1276
1277 // i64 element comparisons.
1278 def VCMPEQUD  : VCMP <199, "vcmpequd $vD, $vA, $vB" , v2i64>;
1279 def VCMPEQUD_rec : VCMPo<199, "vcmpequd. $vD, $vA, $vB", v2i64>;
1280 def VCMPGTSD  : VCMP <967, "vcmpgtsd $vD, $vA, $vB" , v2i64>;
1281 def VCMPGTSD_rec : VCMPo<967, "vcmpgtsd. $vD, $vA, $vB", v2i64>;
1282 def VCMPGTUD  : VCMP <711, "vcmpgtud $vD, $vA, $vB" , v2i64>;
1283 def VCMPGTUD_rec : VCMPo<711, "vcmpgtud. $vD, $vA, $vB", v2i64>;
1284
1285 // The cryptography instructions that do not require Category:Vector.Crypto
1286 def VPMSUMB : VX1_Int_Ty<1032, "vpmsumb",
1287                          int_ppc_altivec_crypto_vpmsumb, v16i8>;
1288 def VPMSUMH : VX1_Int_Ty<1096, "vpmsumh",
1289                          int_ppc_altivec_crypto_vpmsumh, v8i16>;
1290 def VPMSUMW : VX1_Int_Ty<1160, "vpmsumw",
1291                          int_ppc_altivec_crypto_vpmsumw, v4i32>;
1292 def VPMSUMD : VX1_Int_Ty<1224, "vpmsumd",
1293                          int_ppc_altivec_crypto_vpmsumd, v2i64>;
1294 def VPERMXOR : VA1a_Int_Ty<45, "vpermxor",
1295                          int_ppc_altivec_crypto_vpermxor, v16i8>;
1296
1297 // Vector doubleword integer pack and unpack.
1298 def VPKSDSS : VX1_Int_Ty2<1486, "vpksdss", int_ppc_altivec_vpksdss,
1299                           v4i32, v2i64>;
1300 def VPKSDUS : VX1_Int_Ty2<1358, "vpksdus", int_ppc_altivec_vpksdus,
1301                           v4i32, v2i64>;
1302 def VPKUDUM : VXForm_1<1102, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1303                        "vpkudum $vD, $vA, $vB", IIC_VecFP,
1304                        [(set v16i8:$vD,
1305                          (vpkudum_shuffle v16i8:$vA, v16i8:$vB))]>;
1306 def VPKUDUS : VX1_Int_Ty2<1230, "vpkudus", int_ppc_altivec_vpkudus,
1307                           v4i32, v2i64>;
1308 def VUPKHSW : VX2_Int_Ty2<1614, "vupkhsw", int_ppc_altivec_vupkhsw,
1309                           v2i64, v4i32>;
1310 def VUPKLSW : VX2_Int_Ty2<1742, "vupklsw", int_ppc_altivec_vupklsw,
1311                           v2i64, v4i32>;
1312
1313 // Shuffle patterns for unary and swapped (LE) vector pack modulo.
1314 def:Pat<(vpkudum_unary_shuffle v16i8:$vA, undef),
1315         (VPKUDUM $vA, $vA)>;
1316 def:Pat<(vpkudum_swapped_shuffle v16i8:$vA, v16i8:$vB),
1317         (VPKUDUM $vB, $vA)>;
1318
1319 def VGBBD : VX2_Int_Ty2<1292, "vgbbd", int_ppc_altivec_vgbbd, v16i8, v16i8>;
1320 def VBPERMQ : VX1_Int_Ty2<1356, "vbpermq", int_ppc_altivec_vbpermq,
1321                           v2i64, v16i8>;
1322 } // end HasP8Altivec
1323
1324 // Crypto instructions (from builtins)
1325 let Predicates = [HasP8Crypto] in {
1326 def VSHASIGMAW : VXCR_Int_Ty<1666, "vshasigmaw",
1327                               int_ppc_altivec_crypto_vshasigmaw, v4i32>;
1328 def VSHASIGMAD : VXCR_Int_Ty<1730, "vshasigmad",
1329                               int_ppc_altivec_crypto_vshasigmad, v2i64>;
1330 def VCIPHER : VX1_Int_Ty<1288, "vcipher", int_ppc_altivec_crypto_vcipher,
1331                          v2i64>;
1332 def VCIPHERLAST : VX1_Int_Ty<1289, "vcipherlast",
1333                               int_ppc_altivec_crypto_vcipherlast, v2i64>;
1334 def VNCIPHER : VX1_Int_Ty<1352, "vncipher",
1335                           int_ppc_altivec_crypto_vncipher, v2i64>;
1336 def VNCIPHERLAST : VX1_Int_Ty<1353, "vncipherlast",
1337                               int_ppc_altivec_crypto_vncipherlast, v2i64>;
1338 def VSBOX : VXBX_Int_Ty<1480, "vsbox", int_ppc_altivec_crypto_vsbox, v2i64>;
1339 } // HasP8Crypto
1340
1341 // The following altivec instructions were introduced in Power ISA 3.0
1342 def HasP9Altivec : Predicate<"PPCSubTarget->hasP9Altivec()">;
1343 let Predicates = [HasP9Altivec] in {
1344
1345 // Vector Multiply-Sum
1346 def VMSUMUDM : VA1a_Int_Ty3<35, "vmsumudm", int_ppc_altivec_vmsumudm,
1347                             v1i128, v2i64, v1i128>;
1348
1349 // i8 element comparisons.
1350 def VCMPNEB   : VCMP   <  7, "vcmpneb $vD, $vA, $vB"  , v16i8>;
1351 def VCMPNEB_rec  : VCMPo  <  7, "vcmpneb. $vD, $vA, $vB" , v16i8>;
1352 def VCMPNEZB  : VCMP <263, "vcmpnezb $vD, $vA, $vB" , v16i8>;
1353 def VCMPNEZB_rec : VCMPo<263, "vcmpnezb. $vD, $vA, $vB", v16i8>;
1354
1355 // i16 element comparisons.
1356 def VCMPNEH   : VCMP < 71, "vcmpneh $vD, $vA, $vB"  , v8i16>;
1357 def VCMPNEH_rec  : VCMPo< 71, "vcmpneh. $vD, $vA, $vB" , v8i16>;
1358 def VCMPNEZH  : VCMP <327, "vcmpnezh $vD, $vA, $vB" , v8i16>;
1359 def VCMPNEZH_rec : VCMPo<327, "vcmpnezh. $vD, $vA, $vB", v8i16>;
1360
1361 // i32 element comparisons.
1362 def VCMPNEW   : VCMP <135, "vcmpnew $vD, $vA, $vB"  , v4i32>;
1363 def VCMPNEW_rec  : VCMPo<135, "vcmpnew. $vD, $vA, $vB" , v4i32>;
1364 def VCMPNEZW  : VCMP <391, "vcmpnezw $vD, $vA, $vB" , v4i32>;
1365 def VCMPNEZW_rec : VCMPo<391, "vcmpnezw. $vD, $vA, $vB", v4i32>;
1366
1367 // VX-Form: [PO VRT / UIM VRB XO].
1368 // We use VXForm_1 to implement it, that is, we use "VRA" (5 bit) to represent
1369 // "/ UIM" (1 + 4 bit)
1370 class VX1_VT5_UIM5_VB5<bits<11> xo, string opc, list<dag> pattern>
1371   : VXForm_1<xo, (outs vrrc:$vD), (ins u4imm:$UIMM, vrrc:$vB),
1372              !strconcat(opc, " $vD, $vB, $UIMM"), IIC_VecGeneral, pattern>;
1373
1374 class VX1_RT5_RA5_VB5<bits<11> xo, string opc, list<dag> pattern>
1375   : VXForm_1<xo, (outs g8rc:$rD), (ins g8rc:$rA, vrrc:$vB),
1376              !strconcat(opc, " $rD, $rA, $vB"), IIC_VecGeneral, pattern>;
1377
1378 // Vector Extract Unsigned
1379 def VEXTRACTUB : VX1_VT5_UIM5_VB5<525, "vextractub", []>;
1380 def VEXTRACTUH : VX1_VT5_UIM5_VB5<589, "vextractuh", []>;
1381 def VEXTRACTUW : VX1_VT5_UIM5_VB5<653, "vextractuw", []>;
1382 def VEXTRACTD  : VX1_VT5_UIM5_VB5<717, "vextractd" , []>;
1383
1384 // Vector Extract Unsigned Byte/Halfword/Word Left/Right-Indexed
1385 let hasSideEffects = 0 in {
1386 def VEXTUBLX : VX1_RT5_RA5_VB5<1549, "vextublx", []>;
1387 def VEXTUBRX : VX1_RT5_RA5_VB5<1805, "vextubrx", []>;
1388 def VEXTUHLX : VX1_RT5_RA5_VB5<1613, "vextuhlx", []>;
1389 def VEXTUHRX : VX1_RT5_RA5_VB5<1869, "vextuhrx", []>;
1390 def VEXTUWLX : VX1_RT5_RA5_VB5<1677, "vextuwlx", []>;
1391 def VEXTUWRX : VX1_RT5_RA5_VB5<1933, "vextuwrx", []>;
1392 }
1393
1394 // Vector Insert Element Instructions
1395 def VINSERTB : VXForm_1<781, (outs vrrc:$vD),
1396                         (ins vrrc:$vDi, u4imm:$UIM, vrrc:$vB),
1397                         "vinsertb $vD, $vB, $UIM", IIC_VecGeneral,
1398                         [(set v16i8:$vD, (PPCvecinsert v16i8:$vDi, v16i8:$vB,
1399                                                       imm32SExt16:$UIM))]>,
1400                         RegConstraint<"$vDi = $vD">, NoEncode<"$vDi">;
1401 def VINSERTH : VXForm_1<845, (outs vrrc:$vD),
1402                         (ins vrrc:$vDi, u4imm:$UIM, vrrc:$vB),
1403                         "vinserth $vD, $vB, $UIM", IIC_VecGeneral,
1404                         [(set v8i16:$vD, (PPCvecinsert v8i16:$vDi, v8i16:$vB,
1405                                                       imm32SExt16:$UIM))]>,
1406                         RegConstraint<"$vDi = $vD">, NoEncode<"$vDi">;
1407 def VINSERTW : VX1_VT5_UIM5_VB5<909, "vinsertw", []>;
1408 def VINSERTD : VX1_VT5_UIM5_VB5<973, "vinsertd", []>;
1409
1410 class VX_VT5_EO5_VB5<bits<11> xo, bits<5> eo, string opc, list<dag> pattern>
1411   : VXForm_RD5_XO5_RS5<xo, eo, (outs vrrc:$vD), (ins vrrc:$vB),
1412                        !strconcat(opc, " $vD, $vB"), IIC_VecGeneral, pattern>;
1413 class VX_VT5_EO5_VB5s<bits<11> xo, bits<5> eo, string opc, list<dag> pattern>
1414   : VXForm_RD5_XO5_RS5<xo, eo, (outs vfrc:$vD), (ins vfrc:$vB),
1415                        !strconcat(opc, " $vD, $vB"), IIC_VecGeneral, pattern>;
1416
1417 // Vector Count Leading/Trailing Zero LSB. Result is placed into GPR[rD]
1418 def VCLZLSBB : VXForm_RD5_XO5_RS5<1538, 0, (outs gprc:$rD), (ins vrrc:$vB),
1419                                   "vclzlsbb $rD, $vB", IIC_VecGeneral,
1420                                   [(set i32:$rD, (int_ppc_altivec_vclzlsbb
1421                                      v16i8:$vB))]>;
1422 def VCTZLSBB : VXForm_RD5_XO5_RS5<1538, 1, (outs gprc:$rD), (ins vrrc:$vB),
1423                                   "vctzlsbb $rD, $vB", IIC_VecGeneral,
1424                                   [(set i32:$rD, (int_ppc_altivec_vctzlsbb
1425                                      v16i8:$vB))]>;
1426 // Vector Count Trailing Zeros
1427 def VCTZB : VX_VT5_EO5_VB5<1538, 28, "vctzb",
1428                            [(set v16i8:$vD, (cttz v16i8:$vB))]>;
1429 def VCTZH : VX_VT5_EO5_VB5<1538, 29, "vctzh",
1430                            [(set v8i16:$vD, (cttz v8i16:$vB))]>;
1431 def VCTZW : VX_VT5_EO5_VB5<1538, 30, "vctzw",
1432                            [(set v4i32:$vD, (cttz v4i32:$vB))]>;
1433 def VCTZD : VX_VT5_EO5_VB5<1538, 31, "vctzd",
1434                            [(set v2i64:$vD, (cttz v2i64:$vB))]>;
1435
1436 // Vector Extend Sign
1437 def VEXTSB2W : VX_VT5_EO5_VB5<1538, 16, "vextsb2w", []>;
1438 def VEXTSH2W : VX_VT5_EO5_VB5<1538, 17, "vextsh2w", []>;
1439 def VEXTSB2D : VX_VT5_EO5_VB5<1538, 24, "vextsb2d", []>;
1440 def VEXTSH2D : VX_VT5_EO5_VB5<1538, 25, "vextsh2d", []>;
1441 def VEXTSW2D : VX_VT5_EO5_VB5<1538, 26, "vextsw2d", []>;
1442 let isCodeGenOnly = 1 in {
1443   def VEXTSB2Ws : VX_VT5_EO5_VB5s<1538, 16, "vextsb2w", []>;
1444   def VEXTSH2Ws : VX_VT5_EO5_VB5s<1538, 17, "vextsh2w", []>;
1445   def VEXTSB2Ds : VX_VT5_EO5_VB5s<1538, 24, "vextsb2d", []>;
1446   def VEXTSH2Ds : VX_VT5_EO5_VB5s<1538, 25, "vextsh2d", []>;
1447   def VEXTSW2Ds : VX_VT5_EO5_VB5s<1538, 26, "vextsw2d", []>;
1448 }
1449
1450 def : Pat<(v4i32 (sext_inreg v4i32:$VRB, v4i8)), (v4i32 (VEXTSB2W $VRB))>;
1451 def : Pat<(v4i32 (sext_inreg v4i32:$VRB, v4i16)), (v4i32 (VEXTSH2W $VRB))>;
1452 def : Pat<(v2i64 (sext_inreg v2i64:$VRB, v2i8)), (v2i64 (VEXTSB2D $VRB))>;
1453 def : Pat<(v2i64 (sext_inreg v2i64:$VRB, v2i16)), (v2i64 (VEXTSH2D $VRB))>;
1454 def : Pat<(v2i64 (sext_inreg v2i64:$VRB, v2i32)), (v2i64 (VEXTSW2D $VRB))>;
1455
1456 // Vector Integer Negate
1457 def VNEGW : VX_VT5_EO5_VB5<1538, 6, "vnegw",
1458                            [(set v4i32:$vD,
1459                             (sub (v4i32 immAllZerosV), v4i32:$vB))]>;
1460
1461 def VNEGD : VX_VT5_EO5_VB5<1538, 7, "vnegd",
1462                            [(set v2i64:$vD,
1463                             (sub (v2i64 (bitconvert (v4i32 immAllZerosV))),
1464                                   v2i64:$vB))]>;
1465
1466 // Vector Parity Byte
1467 def VPRTYBW : VX_VT5_EO5_VB5<1538, 8, "vprtybw", [(set v4i32:$vD,
1468                             (int_ppc_altivec_vprtybw v4i32:$vB))]>;
1469 def VPRTYBD : VX_VT5_EO5_VB5<1538,  9, "vprtybd", [(set v2i64:$vD,
1470                             (int_ppc_altivec_vprtybd v2i64:$vB))]>;
1471 def VPRTYBQ : VX_VT5_EO5_VB5<1538, 10, "vprtybq", [(set v1i128:$vD,
1472                             (int_ppc_altivec_vprtybq v1i128:$vB))]>;
1473
1474 // Vector (Bit) Permute (Right-indexed)
1475 def VBPERMD : VXForm_1<1484, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1476                        "vbpermd $vD, $vA, $vB", IIC_VecFP, []>;
1477 def VPERMR : VAForm_1a<59, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB, vrrc:$vC),
1478                        "vpermr $vD, $vA, $vB, $vC", IIC_VecFP, []>;
1479
1480 class VX1_VT5_VA5_VB5<bits<11> xo, string opc, list<dag> pattern>
1481   : VXForm_1<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1482              !strconcat(opc, " $vD, $vA, $vB"), IIC_VecFP, pattern>;
1483
1484 // Vector Rotate Left Mask/Mask-Insert
1485 def VRLWNM : VX1_VT5_VA5_VB5<389, "vrlwnm",
1486                              [(set v4i32:$vD,
1487                                  (int_ppc_altivec_vrlwnm v4i32:$vA,
1488                                                          v4i32:$vB))]>;
1489 def VRLWMI : VXForm_1<133, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB, vrrc:$vDi),
1490                       "vrlwmi $vD, $vA, $vB", IIC_VecFP,
1491                       [(set v4i32:$vD,
1492                          (int_ppc_altivec_vrlwmi v4i32:$vA, v4i32:$vB,
1493                                                  v4i32:$vDi))]>,
1494                       RegConstraint<"$vDi = $vD">, NoEncode<"$vDi">;
1495 def VRLDNM : VX1_VT5_VA5_VB5<453, "vrldnm",
1496                              [(set v2i64:$vD,
1497                                  (int_ppc_altivec_vrldnm v2i64:$vA,
1498                                                          v2i64:$vB))]>;
1499 def VRLDMI : VXForm_1<197, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB, vrrc:$vDi),
1500                       "vrldmi $vD, $vA, $vB", IIC_VecFP,
1501                       [(set v2i64:$vD,
1502                          (int_ppc_altivec_vrldmi v2i64:$vA, v2i64:$vB,
1503                                                  v2i64:$vDi))]>,
1504                       RegConstraint<"$vDi = $vD">, NoEncode<"$vDi">;
1505
1506 // Vector Shift Left/Right
1507 def VSLV : VX1_VT5_VA5_VB5<1860, "vslv",
1508                            [(set v16i8 : $vD, (int_ppc_altivec_vslv v16i8 : $vA, v16i8 : $vB))]>;
1509 def VSRV : VX1_VT5_VA5_VB5<1796, "vsrv",
1510                            [(set v16i8 : $vD, (int_ppc_altivec_vsrv v16i8 : $vA, v16i8 : $vB))]>;
1511
1512 // Vector Multiply-by-10 (& Write Carry) Unsigned Quadword
1513 def VMUL10UQ   : VXForm_BX<513, (outs vrrc:$vD), (ins vrrc:$vA),
1514                            "vmul10uq $vD, $vA", IIC_VecFP, []>;
1515 def VMUL10CUQ  : VXForm_BX<  1, (outs vrrc:$vD), (ins vrrc:$vA),
1516                            "vmul10cuq $vD, $vA", IIC_VecFP, []>;
1517
1518 // Vector Multiply-by-10 Extended (& Write Carry) Unsigned Quadword
1519 def VMUL10EUQ  : VX1_VT5_VA5_VB5<577, "vmul10euq" , []>;
1520 def VMUL10ECUQ : VX1_VT5_VA5_VB5< 65, "vmul10ecuq", []>;
1521
1522 // Decimal Integer Format Conversion Instructions
1523
1524 // [PO VRT EO VRB 1 PS XO], "_o" means CR6 is set.
1525 class VX_VT5_EO5_VB5_PS1_XO9_o<bits<5> eo, bits<9> xo, string opc,
1526                                list<dag> pattern>
1527   : VX_RD5_EO5_RS5_PS1_XO9<eo, xo, (outs vrrc:$vD), (ins vrrc:$vB, u1imm:$PS),
1528                         !strconcat(opc, " $vD, $vB, $PS"), IIC_VecFP, pattern> {
1529   let Defs = [CR6];
1530 }
1531
1532 // [PO VRT EO VRB 1 / XO]
1533 class VX_VT5_EO5_VB5_XO9_o<bits<5> eo, bits<9> xo, string opc,
1534                            list<dag> pattern>
1535   : VX_RD5_EO5_RS5_PS1_XO9<eo, xo, (outs vrrc:$vD), (ins vrrc:$vB),
1536                            !strconcat(opc, " $vD, $vB"), IIC_VecFP, pattern> {
1537   let Defs = [CR6];
1538   let PS = 0;
1539 }
1540
1541 // Decimal Convert From/to National/Zoned/Signed-QWord
1542 def BCDCFN_rec  : VX_VT5_EO5_VB5_PS1_XO9_o<7, 385, "bcdcfn." , []>;
1543 def BCDCFZ_rec  : VX_VT5_EO5_VB5_PS1_XO9_o<6, 385, "bcdcfz." , []>;
1544 def BCDCTN_rec  : VX_VT5_EO5_VB5_XO9_o    <5, 385, "bcdctn." , []>;
1545 def BCDCTZ_rec  : VX_VT5_EO5_VB5_PS1_XO9_o<4, 385, "bcdctz." , []>;
1546 def BCDCFSQ_rec : VX_VT5_EO5_VB5_PS1_XO9_o<2, 385, "bcdcfsq.", []>;
1547 def BCDCTSQ_rec : VX_VT5_EO5_VB5_XO9_o    <0, 385, "bcdctsq.", []>;
1548
1549 // Decimal Copy-Sign/Set-Sign
1550 let Defs = [CR6] in
1551 def BCDCPSGN_rec : VX1_VT5_VA5_VB5<833, "bcdcpsgn.", []>;
1552
1553 def BCDSETSGN_rec : VX_VT5_EO5_VB5_PS1_XO9_o<31, 385, "bcdsetsgn.", []>;
1554
1555 // [PO VRT VRA VRB 1 PS XO], "_o" means CR6 is set.
1556 class VX_VT5_VA5_VB5_PS1_XO9_o<bits<9> xo, string opc, list<dag> pattern>
1557   : VX_RD5_RSp5_PS1_XO9<xo,
1558                    (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB, u1imm:$PS),
1559                    !strconcat(opc, " $vD, $vA, $vB, $PS"), IIC_VecFP, pattern> {
1560   let Defs = [CR6];
1561 }
1562
1563 // [PO VRT VRA VRB 1 / XO]
1564 class VX_VT5_VA5_VB5_XO9_o<bits<9> xo, string opc, list<dag> pattern>
1565   : VX_RD5_RSp5_PS1_XO9<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1566                         !strconcat(opc, " $vD, $vA, $vB"), IIC_VecFP, pattern> {
1567   let Defs = [CR6];
1568   let PS = 0;
1569 }
1570
1571 // Decimal Shift/Unsigned-Shift/Shift-and-Round
1572 def BCDS_rec :  VX_VT5_VA5_VB5_PS1_XO9_o<193, "bcds." , []>;
1573 def BCDUS_rec : VX_VT5_VA5_VB5_XO9_o    <129, "bcdus.", []>;
1574 def BCDSR_rec : VX_VT5_VA5_VB5_PS1_XO9_o<449, "bcdsr.", []>;
1575
1576 // Decimal (Unsigned) Truncate
1577 def BCDTRUNC_rec :  VX_VT5_VA5_VB5_PS1_XO9_o<257, "bcdtrunc." , []>;
1578 def BCDUTRUNC_rec : VX_VT5_VA5_VB5_XO9_o    <321, "bcdutrunc.", []>;
1579
1580 // Absolute Difference
1581 def VABSDUB : VXForm_1<1027, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1582                        "vabsdub $vD, $vA, $vB", IIC_VecGeneral,
1583                        [(set v16i8:$vD, (int_ppc_altivec_vabsdub v16i8:$vA, v16i8:$vB))]>;
1584 def VABSDUH : VXForm_1<1091, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1585                        "vabsduh $vD, $vA, $vB", IIC_VecGeneral,
1586                        [(set v8i16:$vD, (int_ppc_altivec_vabsduh v8i16:$vA, v8i16:$vB))]>;
1587 def VABSDUW : VXForm_1<1155, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1588                        "vabsduw $vD, $vA, $vB", IIC_VecGeneral,
1589                        [(set v4i32:$vD, (int_ppc_altivec_vabsduw v4i32:$vA, v4i32:$vB))]>;
1590
1591 } // end HasP9Altivec