contrib/llvm-project/llvm/lib/Target/WebAssembly/WebAssemblyInstrControl.td

   1 //===- WebAssemblyInstrControl.td-WebAssembly control-flow ------*- tablegen -*-
   2 //
   3 // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
   4 // See https://llvm.org/LICENSE.txt for license information.
   5 // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
   6 //
   7 //===----------------------------------------------------------------------===//
   8 ///
   9 /// \file
  10 /// WebAssembly control-flow code-gen constructs.
  11 ///
  12 //===----------------------------------------------------------------------===//
  13
  14 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in {
  15 // The condition operand is a boolean value which WebAssembly represents as i32.
  16 defm BR_IF : I<(outs), (ins bb_op:$dst, I32:$cond),
  17                (outs), (ins bb_op:$dst),
  18                [(brcond I32:$cond, bb:$dst)],
  19                 "br_if   \t$dst, $cond", "br_if   \t$dst", 0x0d>;
  20 let isCodeGenOnly = 1 in
  21 defm BR_UNLESS : I<(outs), (ins bb_op:$dst, I32:$cond),
  22                    (outs), (ins bb_op:$dst), []>;
  23 let isBarrier = 1 in
  24 defm BR   : NRI<(outs), (ins bb_op:$dst),
  25                 [(br bb:$dst)],
  26                 "br      \t$dst", 0x0c>;
  27 } // isBranch = 1, isTerminator = 1, hasCtrlDep = 1
  28
  29 def : Pat<(brcond (i32 (setne I32:$cond, 0)), bb:$dst),
  30           (BR_IF bb_op:$dst, I32:$cond)>;
  31 def : Pat<(brcond (i32 (seteq I32:$cond, 0)), bb:$dst),
  32           (BR_UNLESS bb_op:$dst, I32:$cond)>;
  33
  34 // A list of branch targets enclosed in {} and separated by comma.
  35 // Used by br_table only.
  36 def BrListAsmOperand : AsmOperandClass { let Name = "BrList"; }
  37 let OperandNamespace = "WebAssembly", OperandType = "OPERAND_BRLIST" in
  38 def brlist : Operand<i32> {
  39   let ParserMatchClass = BrListAsmOperand;
  40   let PrintMethod = "printBrList";
  41 }
  42
  43 // TODO: SelectionDAG's lowering insists on using a pointer as the index for
  44 // jump tables, so in practice we don't ever use BR_TABLE_I64 in wasm32 mode
  45 // currently.
  46 let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
  47 defm BR_TABLE_I32 : I<(outs), (ins I32:$index, variable_ops),
  48                       (outs), (ins brlist:$brl),
  49                       [(WebAssemblybr_table I32:$index)],
  50                       "br_table \t$index", "br_table \t$brl",
  51                       0x0e>;
  52 defm BR_TABLE_I64 : I<(outs), (ins I64:$index, variable_ops),
  53                       (outs), (ins brlist:$brl),
  54                       [(WebAssemblybr_table I64:$index)],
  55                       "br_table \t$index", "br_table \t$brl",
  56                       0x0e>;
  57 } // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
  58
  59 // This is technically a control-flow instruction, since all it affects is the
  60 // IP.
  61 defm NOP : NRI<(outs), (ins), [], "nop", 0x01>;
  62
  63 // Placemarkers to indicate the start or end of a block or loop scope.
  64 // These use/clobber VALUE_STACK to prevent them from being moved into the
  65 // middle of an expression tree.
  66 let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
  67 defm BLOCK : NRI<(outs), (ins Signature:$sig), [], "block   \t$sig", 0x02>;
  68 defm LOOP  : NRI<(outs), (ins Signature:$sig), [], "loop    \t$sig", 0x03>;
  69
  70 defm IF : I<(outs), (ins Signature:$sig, I32:$cond),
  71             (outs), (ins Signature:$sig),
  72             [], "if    \t$sig, $cond", "if    \t$sig", 0x04>;
  73 defm ELSE : NRI<(outs), (ins), [], "else", 0x05>;
  74
  75 // END_BLOCK, END_LOOP, END_IF and END_FUNCTION are represented with the same
  76 // opcode in wasm.
  77 defm END_BLOCK : NRI<(outs), (ins), [], "end_block", 0x0b>;
  78 defm END_LOOP  : NRI<(outs), (ins), [], "end_loop", 0x0b>;
  79 defm END_IF    : NRI<(outs), (ins), [], "end_if", 0x0b>;
  80 // Generic instruction, for disassembler.
  81 let IsCanonical = 1 in
  82 defm END       : NRI<(outs), (ins), [], "end", 0x0b>;
  83 let isTerminator = 1, isBarrier = 1 in
  84 defm END_FUNCTION : NRI<(outs), (ins), [], "end_function", 0x0b>;
  85 } // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
  86
  87
  88 let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
  89
  90 let isReturn = 1 in {
  91
  92 defm RETURN : I<(outs), (ins variable_ops), (outs), (ins),
  93                 [(WebAssemblyreturn)],
  94                 "return", "return", 0x0f>;
  95 // Equivalent to RETURN, for use at the end of a function when wasm
  96 // semantics return by falling off the end of the block.
  97 let isCodeGenOnly = 1 in
  98 defm FALLTHROUGH_RETURN : I<(outs), (ins variable_ops), (outs), (ins), []>;
  99
 100 } // isReturn = 1
 101
 102 defm UNREACHABLE : NRI<(outs), (ins), [(trap)], "unreachable", 0x00>;
 103 } // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
 104
 105 //===----------------------------------------------------------------------===//
 106 // Exception handling instructions
 107 //===----------------------------------------------------------------------===//
 108
 109 let Predicates = [HasExceptionHandling] in {
 110
 111 // Throwing an exception: throw / rethrow
 112 let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
 113 defm THROW : I<(outs), (ins event_op:$tag, variable_ops),
 114                (outs), (ins event_op:$tag),
 115                [(WebAssemblythrow (WebAssemblywrapper texternalsym:$tag))],
 116                "throw   \t$tag", "throw   \t$tag", 0x08>;
 117 defm RETHROW : I<(outs), (ins EXNREF:$exn), (outs), (ins), [],
 118                  "rethrow \t$exn", "rethrow", 0x09>;
 119 // Pseudo instruction to be the lowering target of int_wasm_rethrow_in_catch
 120 // intrinsic. Will be converted to the real rethrow instruction later.
 121 let isPseudo = 1 in
 122 defm RETHROW_IN_CATCH : NRI<(outs), (ins), [(int_wasm_rethrow_in_catch)],
 123                             "rethrow_in_catch", 0>;
 124 } // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
 125
 126 // Region within which an exception is caught: try / end_try
 127 let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
 128 defm TRY     : NRI<(outs), (ins Signature:$sig), [], "try     \t$sig", 0x06>;
 129 defm END_TRY : NRI<(outs), (ins), [], "end_try", 0x0b>;
 130 } // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
 131
 132 // Catching an exception: catch / extract_exception
 133 let hasCtrlDep = 1, hasSideEffects = 1 in
 134 defm CATCH : I<(outs EXNREF:$dst), (ins), (outs), (ins), [],
 135                "catch   \t$dst", "catch", 0x07>;
 136
 137 // Querying / extracing exception: br_on_exn
 138 // br_on_exn queries an exnref to see if it matches the corresponding exception
 139 // tag index. If true it branches to the given label and pushes the
 140 // corresponding argument values of the exception onto the stack.
 141 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in
 142 defm BR_ON_EXN : I<(outs), (ins bb_op:$dst, event_op:$tag, EXNREF:$exn),
 143                    (outs), (ins bb_op:$dst, event_op:$tag), [],
 144                    "br_on_exn \t$dst, $tag, $exn", "br_on_exn \t$dst, $tag",
 145                    0x0a>;
 146 // This is a pseudo instruction that simulates popping a value from stack, which
 147 // has been pushed by br_on_exn
 148 let isCodeGenOnly = 1, hasSideEffects = 1 in
 149 defm EXTRACT_EXCEPTION_I32 : NRI<(outs I32:$dst), (ins),
 150                                  [(set I32:$dst, (int_wasm_extract_exception))],
 151                                  "extract_exception\t$dst">;
 152
 153 // Pseudo instructions: cleanupret / catchret
 154 let isTerminator = 1, hasSideEffects = 1, isBarrier = 1, hasCtrlDep = 1,
 155     isPseudo = 1, isEHScopeReturn = 1 in {
 156   defm CLEANUPRET : NRI<(outs), (ins), [(cleanupret)], "cleanupret", 0>;
 157   defm CATCHRET : NRI<(outs), (ins bb_op:$dst, bb_op:$from),
 158                       [(catchret bb:$dst, bb:$from)], "catchret", 0>;
 159 } // isTerminator = 1, hasSideEffects = 1, isBarrier = 1, hasCtrlDep = 1,
 160   // isPseudo = 1, isEHScopeReturn = 1
 161 } // Predicates = [HasExceptionHandling]