contrib/llvm-project/llvm/lib/Target/X86/X86RegisterInfo.td

   1 //===- X86RegisterInfo.td - Describe the X86 Register File --*- tablegen -*-==//
   2 //
   3 // Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
   4 // See https://llvm.org/LICENSE.txt for license information.
   5 // SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
   6 //
   7 //===----------------------------------------------------------------------===//
   8 //
   9 // This file describes the X86 Register file, defining the registers themselves,
  10 // aliases between the registers, and the register classes built out of the
  11 // registers.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 class X86Reg<string n, bits<16> Enc, list<Register> subregs = []> : Register<n> {
  16   let Namespace = "X86";
  17   let HWEncoding = Enc;
  18   let SubRegs = subregs;
  19 }
  20
  21 // Subregister indices.
  22 let Namespace = "X86" in {
  23   def sub_8bit     : SubRegIndex<8>;
  24   def sub_8bit_hi  : SubRegIndex<8, 8>;
  25   def sub_8bit_hi_phony  : SubRegIndex<8, 8>;
  26   def sub_16bit    : SubRegIndex<16>;
  27   def sub_16bit_hi : SubRegIndex<16, 16>;
  28   def sub_32bit    : SubRegIndex<32>;
  29   def sub_xmm      : SubRegIndex<128>;
  30   def sub_ymm      : SubRegIndex<256>;
  31   def sub_mask_0   : SubRegIndex<-1>;
  32   def sub_mask_1   : SubRegIndex<-1, -1>;
  33 }
  34
  35 //===----------------------------------------------------------------------===//
  36 //  Register definitions...
  37 //
  38
  39 // In the register alias definitions below, we define which registers alias
  40 // which others.  We only specify which registers the small registers alias,
  41 // because the register file generator is smart enough to figure out that
  42 // AL aliases AX if we tell it that AX aliased AL (for example).
  43
  44 // Dwarf numbering is different for 32-bit and 64-bit, and there are
  45 // variations by target as well. Currently the first entry is for X86-64,
  46 // second - for EH on X86-32/Darwin and third is 'generic' one (X86-32/Linux
  47 // and debug information on X86-32/Darwin)
  48
  49 // 8-bit registers
  50 // Low registers
  51 def AL : X86Reg<"al", 0>;
  52 def DL : X86Reg<"dl", 2>;
  53 def CL : X86Reg<"cl", 1>;
  54 def BL : X86Reg<"bl", 3>;
  55
  56 // High registers. On x86-64, these cannot be used in any instruction
  57 // with a REX prefix.
  58 def AH : X86Reg<"ah", 4>;
  59 def DH : X86Reg<"dh", 6>;
  60 def CH : X86Reg<"ch", 5>;
  61 def BH : X86Reg<"bh", 7>;
  62
  63 // X86-64 only, requires REX.
  64 let CostPerUse = 1 in {
  65 def SIL  : X86Reg<"sil",   6>;
  66 def DIL  : X86Reg<"dil",   7>;
  67 def BPL  : X86Reg<"bpl",   5>;
  68 def SPL  : X86Reg<"spl",   4>;
  69 def R8B  : X86Reg<"r8b",   8>;
  70 def R9B  : X86Reg<"r9b",   9>;
  71 def R10B : X86Reg<"r10b", 10>;
  72 def R11B : X86Reg<"r11b", 11>;
  73 def R12B : X86Reg<"r12b", 12>;
  74 def R13B : X86Reg<"r13b", 13>;
  75 def R14B : X86Reg<"r14b", 14>;
  76 def R15B : X86Reg<"r15b", 15>;
  77 }
  78
  79 let isArtificial = 1 in {
  80 // High byte of the low 16 bits of the super-register:
  81 def SIH   : X86Reg<"", -1>;
  82 def DIH   : X86Reg<"", -1>;
  83 def BPH   : X86Reg<"", -1>;
  84 def SPH   : X86Reg<"", -1>;
  85 def R8BH  : X86Reg<"", -1>;
  86 def R9BH  : X86Reg<"", -1>;
  87 def R10BH : X86Reg<"", -1>;
  88 def R11BH : X86Reg<"", -1>;
  89 def R12BH : X86Reg<"", -1>;
  90 def R13BH : X86Reg<"", -1>;
  91 def R14BH : X86Reg<"", -1>;
  92 def R15BH : X86Reg<"", -1>;
  93 // High word of the low 32 bits of the super-register:
  94 def HAX   : X86Reg<"", -1>;
  95 def HDX   : X86Reg<"", -1>;
  96 def HCX   : X86Reg<"", -1>;
  97 def HBX   : X86Reg<"", -1>;
  98 def HSI   : X86Reg<"", -1>;
  99 def HDI   : X86Reg<"", -1>;
 100 def HBP   : X86Reg<"", -1>;
 101 def HSP   : X86Reg<"", -1>;
 102 def HIP   : X86Reg<"", -1>;
 103 def R8WH  : X86Reg<"", -1>;
 104 def R9WH  : X86Reg<"", -1>;
 105 def R10WH : X86Reg<"", -1>;
 106 def R11WH : X86Reg<"", -1>;
 107 def R12WH : X86Reg<"", -1>;
 108 def R13WH : X86Reg<"", -1>;
 109 def R14WH : X86Reg<"", -1>;
 110 def R15WH : X86Reg<"", -1>;
 111 }
 112
 113 // 16-bit registers
 114 let SubRegIndices = [sub_8bit, sub_8bit_hi], CoveredBySubRegs = 1 in {
 115 def AX : X86Reg<"ax", 0, [AL,AH]>;
 116 def DX : X86Reg<"dx", 2, [DL,DH]>;
 117 def CX : X86Reg<"cx", 1, [CL,CH]>;
 118 def BX : X86Reg<"bx", 3, [BL,BH]>;
 119 }
 120 let SubRegIndices = [sub_8bit, sub_8bit_hi_phony], CoveredBySubRegs = 1 in {
 121 def SI : X86Reg<"si", 6, [SIL,SIH]>;
 122 def DI : X86Reg<"di", 7, [DIL,DIH]>;
 123 def BP : X86Reg<"bp", 5, [BPL,BPH]>;
 124 def SP : X86Reg<"sp", 4, [SPL,SPH]>;
 125 }
 126 def IP : X86Reg<"ip", 0>;
 127
 128 // X86-64 only, requires REX.
 129 let SubRegIndices = [sub_8bit, sub_8bit_hi_phony], CostPerUse = 1,
 130     CoveredBySubRegs = 1 in {
 131 def R8W  : X86Reg<"r8w",   8, [R8B,R8BH]>;
 132 def R9W  : X86Reg<"r9w",   9, [R9B,R9BH]>;
 133 def R10W : X86Reg<"r10w", 10, [R10B,R10BH]>;
 134 def R11W : X86Reg<"r11w", 11, [R11B,R11BH]>;
 135 def R12W : X86Reg<"r12w", 12, [R12B,R12BH]>;
 136 def R13W : X86Reg<"r13w", 13, [R13B,R13BH]>;
 137 def R14W : X86Reg<"r14w", 14, [R14B,R14BH]>;
 138 def R15W : X86Reg<"r15w", 15, [R15B,R15BH]>;
 139 }
 140
 141 // 32-bit registers
 142 let SubRegIndices = [sub_16bit, sub_16bit_hi], CoveredBySubRegs = 1 in {
 143 def EAX : X86Reg<"eax", 0, [AX, HAX]>, DwarfRegNum<[-2, 0, 0]>;
 144 def EDX : X86Reg<"edx", 2, [DX, HDX]>, DwarfRegNum<[-2, 2, 2]>;
 145 def ECX : X86Reg<"ecx", 1, [CX, HCX]>, DwarfRegNum<[-2, 1, 1]>;
 146 def EBX : X86Reg<"ebx", 3, [BX, HBX]>, DwarfRegNum<[-2, 3, 3]>;
 147 def ESI : X86Reg<"esi", 6, [SI, HSI]>, DwarfRegNum<[-2, 6, 6]>;
 148 def EDI : X86Reg<"edi", 7, [DI, HDI]>, DwarfRegNum<[-2, 7, 7]>;
 149 def EBP : X86Reg<"ebp", 5, [BP, HBP]>, DwarfRegNum<[-2, 4, 5]>;
 150 def ESP : X86Reg<"esp", 4, [SP, HSP]>, DwarfRegNum<[-2, 5, 4]>;
 151 def EIP : X86Reg<"eip", 0, [IP, HIP]>, DwarfRegNum<[-2, 8, 8]>;
 152 }
 153
 154 // X86-64 only, requires REX
 155 let SubRegIndices = [sub_16bit, sub_16bit_hi], CostPerUse = 1,
 156     CoveredBySubRegs = 1 in {
 157 def R8D  : X86Reg<"r8d",   8, [R8W,R8WH]>;
 158 def R9D  : X86Reg<"r9d",   9, [R9W,R9WH]>;
 159 def R10D : X86Reg<"r10d", 10, [R10W,R10WH]>;
 160 def R11D : X86Reg<"r11d", 11, [R11W,R11WH]>;
 161 def R12D : X86Reg<"r12d", 12, [R12W,R12WH]>;
 162 def R13D : X86Reg<"r13d", 13, [R13W,R13WH]>;
 163 def R14D : X86Reg<"r14d", 14, [R14W,R14WH]>;
 164 def R15D : X86Reg<"r15d", 15, [R15W,R15WH]>;
 165 }
 166
 167 // 64-bit registers, X86-64 only
 168 let SubRegIndices = [sub_32bit] in {
 169 def RAX : X86Reg<"rax", 0, [EAX]>, DwarfRegNum<[0, -2, -2]>;
 170 def RDX : X86Reg<"rdx", 2, [EDX]>, DwarfRegNum<[1, -2, -2]>;
 171 def RCX : X86Reg<"rcx", 1, [ECX]>, DwarfRegNum<[2, -2, -2]>;
 172 def RBX : X86Reg<"rbx", 3, [EBX]>, DwarfRegNum<[3, -2, -2]>;
 173 def RSI : X86Reg<"rsi", 6, [ESI]>, DwarfRegNum<[4, -2, -2]>;
 174 def RDI : X86Reg<"rdi", 7, [EDI]>, DwarfRegNum<[5, -2, -2]>;
 175 def RBP : X86Reg<"rbp", 5, [EBP]>, DwarfRegNum<[6, -2, -2]>;
 176 def RSP : X86Reg<"rsp", 4, [ESP]>, DwarfRegNum<[7, -2, -2]>;
 177
 178 // These also require REX.
 179 let CostPerUse = 1 in {
 180 def R8  : X86Reg<"r8",   8, [R8D]>,  DwarfRegNum<[ 8, -2, -2]>;
 181 def R9  : X86Reg<"r9",   9, [R9D]>,  DwarfRegNum<[ 9, -2, -2]>;
 182 def R10 : X86Reg<"r10", 10, [R10D]>, DwarfRegNum<[10, -2, -2]>;
 183 def R11 : X86Reg<"r11", 11, [R11D]>, DwarfRegNum<[11, -2, -2]>;
 184 def R12 : X86Reg<"r12", 12, [R12D]>, DwarfRegNum<[12, -2, -2]>;
 185 def R13 : X86Reg<"r13", 13, [R13D]>, DwarfRegNum<[13, -2, -2]>;
 186 def R14 : X86Reg<"r14", 14, [R14D]>, DwarfRegNum<[14, -2, -2]>;
 187 def R15 : X86Reg<"r15", 15, [R15D]>, DwarfRegNum<[15, -2, -2]>;
 188 def RIP : X86Reg<"rip",  0, [EIP]>,  DwarfRegNum<[16, -2, -2]>;
 189 }}
 190
 191 // MMX Registers. These are actually aliased to ST0 .. ST7
 192 def MM0 : X86Reg<"mm0", 0>, DwarfRegNum<[41, 29, 29]>;
 193 def MM1 : X86Reg<"mm1", 1>, DwarfRegNum<[42, 30, 30]>;
 194 def MM2 : X86Reg<"mm2", 2>, DwarfRegNum<[43, 31, 31]>;
 195 def MM3 : X86Reg<"mm3", 3>, DwarfRegNum<[44, 32, 32]>;
 196 def MM4 : X86Reg<"mm4", 4>, DwarfRegNum<[45, 33, 33]>;
 197 def MM5 : X86Reg<"mm5", 5>, DwarfRegNum<[46, 34, 34]>;
 198 def MM6 : X86Reg<"mm6", 6>, DwarfRegNum<[47, 35, 35]>;
 199 def MM7 : X86Reg<"mm7", 7>, DwarfRegNum<[48, 36, 36]>;
 200
 201 // Pseudo Floating Point registers
 202 def FP0 : X86Reg<"fp0", 0>;
 203 def FP1 : X86Reg<"fp1", 0>;
 204 def FP2 : X86Reg<"fp2", 0>;
 205 def FP3 : X86Reg<"fp3", 0>;
 206 def FP4 : X86Reg<"fp4", 0>;
 207 def FP5 : X86Reg<"fp5", 0>;
 208 def FP6 : X86Reg<"fp6", 0>;
 209 def FP7 : X86Reg<"fp7", 0>;
 210
 211 // XMM Registers, used by the various SSE instruction set extensions.
 212 def XMM0: X86Reg<"xmm0", 0>, DwarfRegNum<[17, 21, 21]>;
 213 def XMM1: X86Reg<"xmm1", 1>, DwarfRegNum<[18, 22, 22]>;
 214 def XMM2: X86Reg<"xmm2", 2>, DwarfRegNum<[19, 23, 23]>;
 215 def XMM3: X86Reg<"xmm3", 3>, DwarfRegNum<[20, 24, 24]>;
 216 def XMM4: X86Reg<"xmm4", 4>, DwarfRegNum<[21, 25, 25]>;
 217 def XMM5: X86Reg<"xmm5", 5>, DwarfRegNum<[22, 26, 26]>;
 218 def XMM6: X86Reg<"xmm6", 6>, DwarfRegNum<[23, 27, 27]>;
 219 def XMM7: X86Reg<"xmm7", 7>, DwarfRegNum<[24, 28, 28]>;
 220
 221 // X86-64 only
 222 let CostPerUse = 1 in {
 223 def XMM8:  X86Reg<"xmm8",   8>, DwarfRegNum<[25, -2, -2]>;
 224 def XMM9:  X86Reg<"xmm9",   9>, DwarfRegNum<[26, -2, -2]>;
 225 def XMM10: X86Reg<"xmm10", 10>, DwarfRegNum<[27, -2, -2]>;
 226 def XMM11: X86Reg<"xmm11", 11>, DwarfRegNum<[28, -2, -2]>;
 227 def XMM12: X86Reg<"xmm12", 12>, DwarfRegNum<[29, -2, -2]>;
 228 def XMM13: X86Reg<"xmm13", 13>, DwarfRegNum<[30, -2, -2]>;
 229 def XMM14: X86Reg<"xmm14", 14>, DwarfRegNum<[31, -2, -2]>;
 230 def XMM15: X86Reg<"xmm15", 15>, DwarfRegNum<[32, -2, -2]>;
 231
 232 def XMM16:  X86Reg<"xmm16", 16>, DwarfRegNum<[67, -2, -2]>;
 233 def XMM17:  X86Reg<"xmm17", 17>, DwarfRegNum<[68, -2, -2]>;
 234 def XMM18:  X86Reg<"xmm18", 18>, DwarfRegNum<[69, -2, -2]>;
 235 def XMM19:  X86Reg<"xmm19", 19>, DwarfRegNum<[70, -2, -2]>;
 236 def XMM20:  X86Reg<"xmm20", 20>, DwarfRegNum<[71, -2, -2]>;
 237 def XMM21:  X86Reg<"xmm21", 21>, DwarfRegNum<[72, -2, -2]>;
 238 def XMM22:  X86Reg<"xmm22", 22>, DwarfRegNum<[73, -2, -2]>;
 239 def XMM23:  X86Reg<"xmm23", 23>, DwarfRegNum<[74, -2, -2]>;
 240 def XMM24:  X86Reg<"xmm24", 24>, DwarfRegNum<[75, -2, -2]>;
 241 def XMM25:  X86Reg<"xmm25", 25>, DwarfRegNum<[76, -2, -2]>;
 242 def XMM26:  X86Reg<"xmm26", 26>, DwarfRegNum<[77, -2, -2]>;
 243 def XMM27:  X86Reg<"xmm27", 27>, DwarfRegNum<[78, -2, -2]>;
 244 def XMM28:  X86Reg<"xmm28", 28>, DwarfRegNum<[79, -2, -2]>;
 245 def XMM29:  X86Reg<"xmm29", 29>, DwarfRegNum<[80, -2, -2]>;
 246 def XMM30:  X86Reg<"xmm30", 30>, DwarfRegNum<[81, -2, -2]>;
 247 def XMM31:  X86Reg<"xmm31", 31>, DwarfRegNum<[82, -2, -2]>;
 248
 249 } // CostPerUse
 250
 251 // YMM0-15 registers, used by AVX instructions and
 252 // YMM16-31 registers, used by AVX-512 instructions.
 253 let SubRegIndices = [sub_xmm] in {
 254   foreach  Index = 0-31 in {
 255     def YMM#Index : X86Reg<"ymm"#Index, Index, [!cast<X86Reg>("XMM"#Index)]>,
 256                     DwarfRegAlias<!cast<X86Reg>("XMM"#Index)>;
 257   }
 258 }
 259
 260 // ZMM Registers, used by AVX-512 instructions.
 261 let SubRegIndices = [sub_ymm] in {
 262   foreach  Index = 0-31 in {
 263     def ZMM#Index : X86Reg<"zmm"#Index, Index, [!cast<X86Reg>("YMM"#Index)]>,
 264                     DwarfRegAlias<!cast<X86Reg>("XMM"#Index)>;
 265   }
 266 }
 267
 268 // Tile "registers".
 269 def TMM0:  X86Reg<"tmm0",   0>;
 270 def TMM1:  X86Reg<"tmm1",   1>;
 271 def TMM2:  X86Reg<"tmm2",   2>;
 272 def TMM3:  X86Reg<"tmm3",   3>;
 273 def TMM4:  X86Reg<"tmm4",   4>;
 274 def TMM5:  X86Reg<"tmm5",   5>;
 275 def TMM6:  X86Reg<"tmm6",   6>;
 276 def TMM7:  X86Reg<"tmm7",   7>;
 277
 278 // Mask Registers, used by AVX-512 instructions.
 279 def K0 : X86Reg<"k0", 0>, DwarfRegNum<[118,  93,  93]>;
 280 def K1 : X86Reg<"k1", 1>, DwarfRegNum<[119,  94,  94]>;
 281 def K2 : X86Reg<"k2", 2>, DwarfRegNum<[120,  95,  95]>;
 282 def K3 : X86Reg<"k3", 3>, DwarfRegNum<[121,  96,  96]>;
 283 def K4 : X86Reg<"k4", 4>, DwarfRegNum<[122,  97,  97]>;
 284 def K5 : X86Reg<"k5", 5>, DwarfRegNum<[123,  98,  98]>;
 285 def K6 : X86Reg<"k6", 6>, DwarfRegNum<[124,  99,  99]>;
 286 def K7 : X86Reg<"k7", 7>, DwarfRegNum<[125, 100, 100]>;
 287
 288 // Floating point stack registers. These don't map one-to-one to the FP
 289 // pseudo registers, but we still mark them as aliasing FP registers. That
 290 // way both kinds can be live without exceeding the stack depth. ST registers
 291 // are only live around inline assembly.
 292 def ST0 : X86Reg<"st", 0>, DwarfRegNum<[33, 12, 11]>;
 293 def ST1 : X86Reg<"st(1)", 1>, DwarfRegNum<[34, 13, 12]>;
 294 def ST2 : X86Reg<"st(2)", 2>, DwarfRegNum<[35, 14, 13]>;
 295 def ST3 : X86Reg<"st(3)", 3>, DwarfRegNum<[36, 15, 14]>;
 296 def ST4 : X86Reg<"st(4)", 4>, DwarfRegNum<[37, 16, 15]>;
 297 def ST5 : X86Reg<"st(5)", 5>, DwarfRegNum<[38, 17, 16]>;
 298 def ST6 : X86Reg<"st(6)", 6>, DwarfRegNum<[39, 18, 17]>;
 299 def ST7 : X86Reg<"st(7)", 7>, DwarfRegNum<[40, 19, 18]>;
 300
 301 // Floating-point status word
 302 def FPSW : X86Reg<"fpsr", 0>;
 303
 304 // Floating-point control word
 305 def FPCW : X86Reg<"fpcr", 0>;
 306
 307 // SIMD Floating-point control register.
 308 // Note: We only model the "Uses" of the control bits: current rounding modes,
 309 // DAZ, FTZ and exception masks. We don't model the "Defs" of flag bits.
 310 def MXCSR : X86Reg<"mxcsr", 0>;
 311
 312 // Status flags register.
 313 //
 314 // Note that some flags that are commonly thought of as part of the status
 315 // flags register are modeled separately. Typically this is due to instructions
 316 // reading and updating those flags independently of all the others. We don't
 317 // want to create false dependencies between these instructions and so we use
 318 // a separate register to model them.
 319 def EFLAGS : X86Reg<"flags", 0>;
 320
 321 // The direction flag.
 322 def DF : X86Reg<"dirflag", 0>;
 323
 324
 325 // Segment registers
 326 def CS : X86Reg<"cs", 1>;
 327 def DS : X86Reg<"ds", 3>;
 328 def SS : X86Reg<"ss", 2>;
 329 def ES : X86Reg<"es", 0>;
 330 def FS : X86Reg<"fs", 4>;
 331 def GS : X86Reg<"gs", 5>;
 332
 333 // Debug registers
 334 def DR0  : X86Reg<"dr0",   0>;
 335 def DR1  : X86Reg<"dr1",   1>;
 336 def DR2  : X86Reg<"dr2",   2>;
 337 def DR3  : X86Reg<"dr3",   3>;
 338 def DR4  : X86Reg<"dr4",   4>;
 339 def DR5  : X86Reg<"dr5",   5>;
 340 def DR6  : X86Reg<"dr6",   6>;
 341 def DR7  : X86Reg<"dr7",   7>;
 342 def DR8  : X86Reg<"dr8",   8>;
 343 def DR9  : X86Reg<"dr9",   9>;
 344 def DR10 : X86Reg<"dr10", 10>;
 345 def DR11 : X86Reg<"dr11", 11>;
 346 def DR12 : X86Reg<"dr12", 12>;
 347 def DR13 : X86Reg<"dr13", 13>;
 348 def DR14 : X86Reg<"dr14", 14>;
 349 def DR15 : X86Reg<"dr15", 15>;
 350
 351 // Control registers
 352 def CR0  : X86Reg<"cr0",   0>;
 353 def CR1  : X86Reg<"cr1",   1>;
 354 def CR2  : X86Reg<"cr2",   2>;
 355 def CR3  : X86Reg<"cr3",   3>;
 356 def CR4  : X86Reg<"cr4",   4>;
 357 def CR5  : X86Reg<"cr5",   5>;
 358 def CR6  : X86Reg<"cr6",   6>;
 359 def CR7  : X86Reg<"cr7",   7>;
 360 def CR8  : X86Reg<"cr8",   8>;
 361 def CR9  : X86Reg<"cr9",   9>;
 362 def CR10 : X86Reg<"cr10", 10>;
 363 def CR11 : X86Reg<"cr11", 11>;
 364 def CR12 : X86Reg<"cr12", 12>;
 365 def CR13 : X86Reg<"cr13", 13>;
 366 def CR14 : X86Reg<"cr14", 14>;
 367 def CR15 : X86Reg<"cr15", 15>;
 368
 369 // Pseudo index registers
 370 def EIZ : X86Reg<"eiz", 4>;
 371 def RIZ : X86Reg<"riz", 4>;
 372
 373 // Bound registers, used in MPX instructions
 374 def BND0 : X86Reg<"bnd0",   0>;
 375 def BND1 : X86Reg<"bnd1",   1>;
 376 def BND2 : X86Reg<"bnd2",   2>;
 377 def BND3 : X86Reg<"bnd3",   3>;
 378
 379 // CET registers - Shadow Stack Pointer
 380 def SSP : X86Reg<"ssp", 0>;
 381
 382 //===----------------------------------------------------------------------===//
 383 // Register Class Definitions... now that we have all of the pieces, define the
 384 // top-level register classes.  The order specified in the register list is
 385 // implicitly defined to be the register allocation order.
 386 //
 387
 388 // List call-clobbered registers before callee-save registers. RBX, RBP, (and
 389 // R12, R13, R14, and R15 for X86-64) are callee-save registers.
 390 // In 64-mode, there are 12 additional i8 registers, SIL, DIL, BPL, SPL, and
 391 // R8B, ... R15B.
 392 // Allocate R12 and R13 last, as these require an extra byte when
 393 // encoded in x86_64 instructions.
 394 // FIXME: Allow AH, CH, DH, BH to be used as general-purpose registers in
 395 // 64-bit mode. The main complication is that they cannot be encoded in an
 396 // instruction requiring a REX prefix, while SIL, DIL, BPL, R8D, etc.
 397 // require a REX prefix. For example, "addb %ah, %dil" and "movzbl %ah, %r8d"
 398 // cannot be encoded.
 399 def GR8 : RegisterClass<"X86", [i8],  8,
 400                         (add AL, CL, DL, AH, CH, DH, BL, BH, SIL, DIL, BPL, SPL,
 401                              R8B, R9B, R10B, R11B, R14B, R15B, R12B, R13B)> {
 402   let AltOrders = [(sub GR8, AH, BH, CH, DH)];
 403   let AltOrderSelect = [{
 404     return MF.getSubtarget<X86Subtarget>().is64Bit();
 405   }];
 406 }
 407
 408 let isAllocatable = 0 in
 409 def GRH8 : RegisterClass<"X86", [i8],  8,
 410                          (add SIH, DIH, BPH, SPH, R8BH, R9BH, R10BH, R11BH,
 411                               R12BH, R13BH, R14BH, R15BH)>;
 412
 413 def GR16 : RegisterClass<"X86", [i16], 16,
 414                          (add AX, CX, DX, SI, DI, BX, BP, SP,
 415                               R8W, R9W, R10W, R11W, R14W, R15W, R12W, R13W)>;
 416
 417 let isAllocatable = 0 in
 418 def GRH16 : RegisterClass<"X86", [i16], 16,
 419                           (add HAX, HCX, HDX, HSI, HDI, HBX, HBP, HSP, HIP,
 420                                R8WH, R9WH, R10WH, R11WH, R12WH, R13WH, R14WH,
 421                                R15WH)>;
 422
 423 def GR32 : RegisterClass<"X86", [i32], 32,
 424                          (add EAX, ECX, EDX, ESI, EDI, EBX, EBP, ESP,
 425                               R8D, R9D, R10D, R11D, R14D, R15D, R12D, R13D)>;
 426
 427 // GR64 - 64-bit GPRs. This oddly includes RIP, which isn't accurate, since
 428 // RIP isn't really a register and it can't be used anywhere except in an
 429 // address, but it doesn't cause trouble.
 430 // FIXME: it *does* cause trouble - CheckBaseRegAndIndexReg() has extra
 431 // tests because of the inclusion of RIP in this register class.
 432 def GR64 : RegisterClass<"X86", [i64], 64,
 433                          (add RAX, RCX, RDX, RSI, RDI, R8, R9, R10, R11,
 434                               RBX, R14, R15, R12, R13, RBP, RSP, RIP)>;
 435
 436 // Segment registers for use by MOV instructions (and others) that have a
 437 //   segment register as one operand.  Always contain a 16-bit segment
 438 //   descriptor.
 439 def SEGMENT_REG : RegisterClass<"X86", [i16], 16, (add CS, DS, SS, ES, FS, GS)>;
 440
 441 // Debug registers.
 442 def DEBUG_REG : RegisterClass<"X86", [i32], 32, (sequence "DR%u", 0, 15)>;
 443
 444 // Control registers.
 445 def CONTROL_REG : RegisterClass<"X86", [i64], 64, (sequence "CR%u", 0, 15)>;
 446
 447 // GR8_ABCD_L, GR8_ABCD_H, GR16_ABCD, GR32_ABCD, GR64_ABCD - Subclasses of
 448 // GR8, GR16, GR32, and GR64 which contain just the "a" "b", "c", and "d"
 449 // registers. On x86-32, GR16_ABCD and GR32_ABCD are classes for registers
 450 // that support 8-bit subreg operations. On x86-64, GR16_ABCD, GR32_ABCD,
 451 // and GR64_ABCD are classes for registers that support 8-bit h-register
 452 // operations.
 453 def GR8_ABCD_L : RegisterClass<"X86", [i8], 8, (add AL, CL, DL, BL)>;
 454 def GR8_ABCD_H : RegisterClass<"X86", [i8], 8, (add AH, CH, DH, BH)>;
 455 def GR16_ABCD : RegisterClass<"X86", [i16], 16, (add AX, CX, DX, BX)>;
 456 def GR32_ABCD : RegisterClass<"X86", [i32], 32, (add EAX, ECX, EDX, EBX)>;
 457 def GR64_ABCD : RegisterClass<"X86", [i64], 64, (add RAX, RCX, RDX, RBX)>;
 458 def GR32_TC   : RegisterClass<"X86", [i32], 32, (add EAX, ECX, EDX, ESP)>;
 459 def GR64_TC   : RegisterClass<"X86", [i64], 64, (add RAX, RCX, RDX, RSI, RDI,
 460                                                      R8, R9, R11, RIP, RSP)>;
 461 def GR64_TCW64 : RegisterClass<"X86", [i64], 64, (add RAX, RCX, RDX,
 462                                                       R8, R9, R10, R11,
 463                                                       RIP, RSP)>;
 464
 465 // GR8_NOREX - GR8 registers which do not require a REX prefix.
 466 def GR8_NOREX : RegisterClass<"X86", [i8], 8,
 467                               (add AL, CL, DL, AH, CH, DH, BL, BH)> {
 468   let AltOrders = [(sub GR8_NOREX, AH, BH, CH, DH)];
 469   let AltOrderSelect = [{
 470     return MF.getSubtarget<X86Subtarget>().is64Bit();
 471   }];
 472 }
 473 // GR16_NOREX - GR16 registers which do not require a REX prefix.
 474 def GR16_NOREX : RegisterClass<"X86", [i16], 16,
 475                                (add AX, CX, DX, SI, DI, BX, BP, SP)>;
 476 // GR32_NOREX - GR32 registers which do not require a REX prefix.
 477 def GR32_NOREX : RegisterClass<"X86", [i32], 32,
 478                                (add EAX, ECX, EDX, ESI, EDI, EBX, EBP, ESP)>;
 479 // GR64_NOREX - GR64 registers which do not require a REX prefix.
 480 def GR64_NOREX : RegisterClass<"X86", [i64], 64,
 481                             (add RAX, RCX, RDX, RSI, RDI, RBX, RBP, RSP, RIP)>;
 482
 483 // GR32_NOSP - GR32 registers except ESP.
 484 def GR32_NOSP : RegisterClass<"X86", [i32], 32, (sub GR32, ESP)>;
 485
 486 // GR64_NOSP - GR64 registers except RSP (and RIP).
 487 def GR64_NOSP : RegisterClass<"X86", [i64], 64, (sub GR64, RSP, RIP)>;
 488
 489 // GR32_NOREX_NOSP - GR32 registers which do not require a REX prefix except
 490 // ESP.
 491 def GR32_NOREX_NOSP : RegisterClass<"X86", [i32], 32,
 492                                     (and GR32_NOREX, GR32_NOSP)>;
 493
 494 // GR64_NOREX_NOSP - GR64_NOREX registers except RSP.
 495 def GR64_NOREX_NOSP : RegisterClass<"X86", [i64], 64,
 496                                     (and GR64_NOREX, GR64_NOSP)>;
 497
 498 // Register classes used for ABIs that use 32-bit address accesses,
 499 // while using the whole x84_64 ISA.
 500
 501 // In such cases, it is fine to use RIP as we are sure the 32 high
 502 // bits are not set. We do not need variants for NOSP as RIP is not
 503 // allowed there.
 504 // RIP is not spilled anywhere for now, so stick to 32-bit alignment
 505 // to save on memory space.
 506 // FIXME: We could allow all 64bit registers, but we would need
 507 // something to check that the 32 high bits are not set,
 508 // which we do not have right now.
 509 def LOW32_ADDR_ACCESS : RegisterClass<"X86", [i32], 32, (add GR32, RIP)>;
 510
 511 // When RBP is used as a base pointer in a 32-bit addresses environment,
 512 // this is also safe to use the full register to access addresses.
 513 // Since RBP will never be spilled, stick to a 32 alignment to save
 514 // on memory consumption.
 515 def LOW32_ADDR_ACCESS_RBP : RegisterClass<"X86", [i32], 32,
 516                                           (add LOW32_ADDR_ACCESS, RBP)>;
 517
 518 // A class to support the 'A' assembler constraint: [ER]AX then [ER]DX.
 519 def GR32_AD : RegisterClass<"X86", [i32], 32, (add EAX, EDX)>;
 520 def GR64_AD : RegisterClass<"X86", [i64], 64, (add RAX, RDX)>;
 521
 522 // Classes to support the 64-bit assembler constraint tied to a fixed
 523 // register in 32-bit mode. The second register is always the next in
 524 // the list. Wrap around causes an error.
 525 def GR32_DC : RegisterClass<"X86", [i32], 32, (add EDX, ECX)>;
 526 def GR32_CB : RegisterClass<"X86", [i32], 32, (add ECX, EBX)>;
 527 def GR32_BSI : RegisterClass<"X86", [i32], 32, (add EBX, ESI)>;
 528 def GR32_SIDI : RegisterClass<"X86", [i32], 32, (add ESI, EDI)>;
 529 def GR32_DIBP : RegisterClass<"X86", [i32], 32, (add EDI, EBP)>;
 530 def GR32_BPSP : RegisterClass<"X86", [i32], 32, (add EBP, ESP)>;
 531
 532 // Scalar SSE2 floating point registers.
 533 def FR32 : RegisterClass<"X86", [f32], 32, (sequence "XMM%u", 0, 15)>;
 534
 535 def FR64 : RegisterClass<"X86", [f64], 64, (add FR32)>;
 536
 537
 538 // FIXME: This sets up the floating point register files as though they are f64
 539 // values, though they really are f80 values.  This will cause us to spill
 540 // values as 64-bit quantities instead of 80-bit quantities, which is much much
 541 // faster on common hardware.  In reality, this should be controlled by a
 542 // command line option or something.
 543
 544
 545 def RFP32 : RegisterClass<"X86",[f32], 32, (sequence "FP%u", 0, 6)>;
 546 def RFP64 : RegisterClass<"X86",[f64], 32, (add RFP32)>;
 547 def RFP80 : RegisterClass<"X86",[f80], 32, (add RFP32)>;
 548
 549 // st(7) may be is not allocatable.
 550 def RFP80_7 : RegisterClass<"X86",[f80], 32, (add FP7)> {
 551   let isAllocatable = 0;
 552 }
 553
 554 // Floating point stack registers (these are not allocatable by the
 555 // register allocator - the floating point stackifier is responsible
 556 // for transforming FPn allocations to STn registers)
 557 def RST : RegisterClass<"X86", [f80, f64, f32], 32, (sequence "ST%u", 0, 7)> {
 558   let isAllocatable = 0;
 559 }
 560
 561 // Helper to allow %st to print as %st(0) when its encoded in the instruction.
 562 def RSTi : RegisterOperand<RST, "printSTiRegOperand">;
 563
 564 // Generic vector registers: VR64 and VR128.
 565 // Ensure that float types are declared first - only float is legal on SSE1.
 566 def VR64: RegisterClass<"X86", [x86mmx], 64, (sequence "MM%u", 0, 7)>;
 567 def VR128 : RegisterClass<"X86", [v4f32, v2f64, v16i8, v8i16, v4i32, v2i64, f128],
 568                           128, (add FR32)>;
 569 def VR256 : RegisterClass<"X86", [v8f32, v4f64, v32i8, v16i16, v8i32, v4i64],
 570                           256, (sequence "YMM%u", 0, 15)>;
 571
 572 // Status flags registers.
 573 def CCR : RegisterClass<"X86", [i32], 32, (add EFLAGS)> {
 574   let CopyCost = -1;  // Don't allow copying of status registers.
 575   let isAllocatable = 0;
 576 }
 577 def FPCCR : RegisterClass<"X86", [i16], 16, (add FPSW)> {
 578   let CopyCost = -1;  // Don't allow copying of status registers.
 579   let isAllocatable = 0;
 580 }
 581 def DFCCR : RegisterClass<"X86", [i32], 32, (add DF)> {
 582   let CopyCost = -1;  // Don't allow copying of status registers.
 583   let isAllocatable = 0;
 584 }
 585
 586 // AVX-512 vector/mask registers.
 587 def VR512 : RegisterClass<"X86", [v16f32, v8f64, v64i8, v32i16, v16i32, v8i64],
 588                           512, (sequence "ZMM%u", 0, 31)>;
 589
 590 // Represents the lower 16 registers that have VEX/legacy encodable subregs.
 591 def VR512_0_15 : RegisterClass<"X86", [v16f32, v8f64, v64i8, v32i16, v16i32, v8i64],
 592                                512, (sequence "ZMM%u", 0, 15)>;
 593
 594 // Scalar AVX-512 floating point registers.
 595 def FR32X : RegisterClass<"X86", [f32], 32, (sequence "XMM%u", 0, 31)>;
 596
 597 def FR64X : RegisterClass<"X86", [f64], 64, (add FR32X)>;
 598
 599 // Extended VR128 and VR256 for AVX-512 instructions
 600 def VR128X : RegisterClass<"X86", [v4f32, v2f64, v16i8, v8i16, v4i32, v2i64, f128],
 601                            128, (add FR32X)>;
 602 def VR256X : RegisterClass<"X86", [v8f32, v4f64, v32i8, v16i16, v8i32, v4i64],
 603                            256, (sequence "YMM%u", 0, 31)>;
 604
 605 // Mask registers
 606 def VK1     : RegisterClass<"X86", [v1i1],  16,  (sequence "K%u", 0, 7)> {let Size = 16;}
 607 def VK2     : RegisterClass<"X86", [v2i1],  16,  (add VK1)> {let Size = 16;}
 608 def VK4     : RegisterClass<"X86", [v4i1],  16,  (add VK2)> {let Size = 16;}
 609 def VK8     : RegisterClass<"X86", [v8i1],  16,  (add VK4)> {let Size = 16;}
 610 def VK16    : RegisterClass<"X86", [v16i1], 16, (add VK8)> {let Size = 16;}
 611 def VK32    : RegisterClass<"X86", [v32i1], 32, (add VK16)> {let Size = 32;}
 612 def VK64    : RegisterClass<"X86", [v64i1], 64, (add VK32)> {let Size = 64;}
 613
 614 // Mask register pairs
 615 def KPAIRS : RegisterTuples<[sub_mask_0, sub_mask_1],
 616                              [(add K0, K2, K4, K6), (add K1, K3, K5, K7)]>;
 617
 618 def VK1PAIR   : RegisterClass<"X86", [untyped], 16, (add KPAIRS)> {let Size = 32;}
 619 def VK2PAIR   : RegisterClass<"X86", [untyped], 16, (add KPAIRS)> {let Size = 32;}
 620 def VK4PAIR   : RegisterClass<"X86", [untyped], 16, (add KPAIRS)> {let Size = 32;}
 621 def VK8PAIR   : RegisterClass<"X86", [untyped], 16, (add KPAIRS)> {let Size = 32;}
 622 def VK16PAIR  : RegisterClass<"X86", [untyped], 16, (add KPAIRS)> {let Size = 32;}
 623
 624 def VK1WM   : RegisterClass<"X86", [v1i1],  16,  (sub VK1, K0)> {let Size = 16;}
 625 def VK2WM   : RegisterClass<"X86", [v2i1],  16,  (sub VK2, K0)> {let Size = 16;}
 626 def VK4WM   : RegisterClass<"X86", [v4i1],  16,  (sub VK4, K0)> {let Size = 16;}
 627 def VK8WM   : RegisterClass<"X86", [v8i1],  16,  (sub VK8, K0)> {let Size = 16;}
 628 def VK16WM  : RegisterClass<"X86", [v16i1], 16, (add VK8WM)>   {let Size = 16;}
 629 def VK32WM  : RegisterClass<"X86", [v32i1], 32, (add VK16WM)> {let Size = 32;}
 630 def VK64WM  : RegisterClass<"X86", [v64i1], 64, (add VK32WM)> {let Size = 64;}
 631
 632 // Bound registers
 633 def BNDR : RegisterClass<"X86", [v2i64], 128, (sequence "BND%u", 0, 3)>;
 634
 635 // Tiles
 636 let isAllocatable = 0 in
 637 def TILE : RegisterClass<"X86", [untyped], 0,
 638                          (sequence "TMM%u", 0, 7)> {let Size = 8192;}