contrib/lutok/m4/compiler-flags.m4

   1 dnl Copyright 2010 Google Inc.
   2 dnl All rights reserved.
   3 dnl
   4 dnl Redistribution and use in source and binary forms, with or without
   5 dnl modification, are permitted provided that the following conditions are
   6 dnl met:
   7 dnl
   8 dnl * Redistributions of source code must retain the above copyright
   9 dnl   notice, this list of conditions and the following disclaimer.
  10 dnl * Redistributions in binary form must reproduce the above copyright
  11 dnl   notice, this list of conditions and the following disclaimer in the
  12 dnl   documentation and/or other materials provided with the distribution.
  13 dnl * Neither the name of Google Inc. nor the names of its contributors
  14 dnl   may be used to endorse or promote products derived from this software
  15 dnl   without specific prior written permission.
  16 dnl
  17 dnl THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  18 dnl "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  19 dnl LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  20 dnl A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  21 dnl OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  22 dnl SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  23 dnl LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  24 dnl DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  25 dnl THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  26 dnl (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  27 dnl OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  28
  29 dnl \file compiler-flags.m4
  30 dnl
  31 dnl Macros to check for the existence of compiler flags.  The macros in this
  32 dnl file support both C and C++.
  33 dnl
  34 dnl Be aware that, in order to detect a flag accurately, we may need to enable
  35 dnl strict warning checking in the compiler (i.e. enable -Werror).  Some
  36 dnl compilers, e.g. Clang, report unknown -W flags as warnings unless -Werror is
  37 dnl selected.  This fact would confuse the flag checks below because we would
  38 dnl conclude that a flag is valid while in reality it is not.  To resolve this,
  39 dnl the macros below will pass -Werror to the compiler along with any other flag
  40 dnl being checked.
  41
  42
  43 dnl Checks for a compiler flag and sets a result variable.
  44 dnl
  45 dnl This is an auxiliary macro for the implementation of _KYUA_FLAG.
  46 dnl
  47 dnl \param 1 The shell variable containing the compiler name.  Used for
  48 dnl     reporting purposes only.  C or CXX.
  49 dnl \param 2 The shell variable containing the flags for the compiler.
  50 dnl     CFLAGS or CXXFLAGS.
  51 dnl \param 3 The name of the compiler flag to check for.
  52 dnl \param 4 The shell variable to set with the result of the test.  Will
  53 dnl     be set to 'yes' if the flag is valid, 'no' otherwise.
  54 dnl \param 5 Additional, optional flags to pass to the C compiler while
  55 dnl     looking for the flag in $3.  We use this here to pass -Werror to the
  56 dnl     flag checks (unless we are checking for -Werror already).
  57 AC_DEFUN([_KYUA_FLAG_AUX], [
  58     if test x"${$4-unset}" = xunset; then
  59         AC_MSG_CHECKING(whether ${$1} supports $3)
  60         saved_flags="${$2}"
  61         $4=no
  62         $2="${$2} $5 $3"
  63         AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
  64                        AC_MSG_RESULT(yes)
  65                        $4=yes,
  66                        AC_MSG_RESULT(no))
  67         $2="${saved_flags}"
  68     fi
  69 ])
  70
  71
  72 dnl Checks for a compiler flag and appends it to a result variable.
  73 dnl
  74 dnl \param 1 The shell variable containing the compiler name.  Used for
  75 dnl     reporting purposes only.  CC or CXX.
  76 dnl \param 2 The shell variable containing the flags for the compiler.
  77 dnl     CFLAGS or CXXFLAGS.
  78 dnl \param 3 The name of the compiler flag to check for.
  79 dnl \param 4 The shell variable to which to append $3 if the flag is valid.
  80 AC_DEFUN([_KYUA_FLAG], [
  81     _KYUA_FLAG_AUX([$1], [$2], [-Werror], [kyua_$1_has_werror])
  82     if test "$3" = "-Werror"; then
  83         found=${kyua_$1_has_werror}
  84     else
  85         found=unset
  86         if test ${kyua_$1_has_werror} = yes; then
  87             _KYUA_FLAG_AUX([$1], [$2], [$3], [found], [-Werror])
  88         else
  89             _KYUA_FLAG_AUX([$1], [$2], [$3], [found], [])
  90         fi
  91     fi
  92     if test ${found} = yes; then
  93         $4="${$4} $3"
  94     fi
  95 ])
  96
  97
  98 dnl Checks for a C compiler flag and appends it to a variable.
  99 dnl
 100 dnl \pre The current language is C.
 101 dnl
 102 dnl \param 1 The name of the compiler flag to check for.
 103 dnl \param 2 The shell variable to which to append $1 if the flag is valid.
 104 AC_DEFUN([KYUA_CC_FLAG], [
 105     AC_LANG_ASSERT([C])
 106     _KYUA_FLAG([CC], [CFLAGS], [$1], [$2])
 107 ])
 108
 109
 110 dnl Checks for a C++ compiler flag and appends it to a variable.
 111 dnl
 112 dnl \pre The current language is C++.
 113 dnl
 114 dnl \param 1 The name of the compiler flag to check for.
 115 dnl \param 2 The shell variable to which to append $1 if the flag is valid.
 116 AC_DEFUN([KYUA_CXX_FLAG], [
 117     AC_LANG_ASSERT([C++])
 118     _KYUA_FLAG([CXX], [CXXFLAGS], [$1], [$2])
 119 ])
 120
 121
 122 dnl Checks for a set of C compiler flags and appends them to CFLAGS.
 123 dnl
 124 dnl The checks are performed independently and only when all the checks are
 125 dnl done, the output variable is modified.
 126 dnl
 127 dnl \param 1 Whitespace-separated list of C flags to check.
 128 AC_DEFUN([KYUA_CC_FLAGS], [
 129     AC_LANG_PUSH([C])
 130     valid_cflags=
 131     for f in $1; do
 132         KYUA_CC_FLAG(${f}, valid_cflags)
 133     done
 134     if test -n "${valid_cflags}"; then
 135         CFLAGS="${CFLAGS} ${valid_cflags}"
 136     fi
 137     AC_LANG_POP([C])
 138 ])
 139
 140
 141 dnl Checks for a set of C++ compiler flags and appends them to CXXFLAGS.
 142 dnl
 143 dnl The checks are performed independently and only when all the checks are
 144 dnl done, the output variable is modified.
 145 dnl
 146 dnl \pre The current language is C++.
 147 dnl
 148 dnl \param 1 Whitespace-separated list of C flags to check.
 149 AC_DEFUN([KYUA_CXX_FLAGS], [
 150     AC_LANG_PUSH([C++])
 151     valid_cxxflags=
 152     for f in $1; do
 153         KYUA_CXX_FLAG(${f}, valid_cxxflags)
 154     done
 155     if test -n "${valid_cxxflags}"; then
 156         CXXFLAGS="${CXXFLAGS} ${valid_cxxflags}"
 157     fi
 158     AC_LANG_POP([C++])
 159 ])