contrib/sqlite3/configure.ac

   1
   2 #-----------------------------------------------------------------------
   3 # Supports the following non-standard switches.
   4 #
   5 #   --enable-threadsafe
   6 #   --enable-readline
   7 #   --enable-editline
   8 #   --enable-static-shell
   9 #   --enable-dynamic-extensions
  10 #
  11
  12 AC_PREREQ(2.61)
  13 AC_INIT(sqlite, 3.35.5, http://www.sqlite.org)
  14 AC_CONFIG_SRCDIR([sqlite3.c])
  15 AC_CONFIG_AUX_DIR([.])
  16
  17 # Use automake.
  18 AM_INIT_AUTOMAKE([foreign])
  19
  20 AC_SYS_LARGEFILE
  21
  22 # Check for required programs.
  23 AC_PROG_CC
  24 AC_PROG_LIBTOOL
  25 AC_PROG_MKDIR_P
  26
  27 # Check for library functions that SQLite can optionally use.
  28 AC_CHECK_FUNCS([fdatasync usleep fullfsync localtime_r gmtime_r])
  29 AC_FUNC_STRERROR_R
  30
  31 AC_CONFIG_FILES([Makefile sqlite3.pc])
  32 BUILD_CFLAGS=
  33 AC_SUBST(BUILD_CFLAGS)
  34
  35 #-------------------------------------------------------------------------
  36 # Two options to enable readline compatible libraries:
  37 #
  38 #   --enable-editline
  39 #   --enable-readline
  40 #
  41 # Both are enabled by default. If, after command line processing both are
  42 # still enabled, the script searches for editline first and automatically
  43 # disables readline if it is found. So, to use readline explicitly, the
  44 # user must pass "--disable-editline". To disable command line editing
  45 # support altogether, "--disable-editline --disable-readline".
  46 #
  47 # When searching for either library, check for headers before libraries
  48 # as some distros supply packages that contain libraries but not header
  49 # files, which come as a separate development package.
  50 #
  51 AC_ARG_ENABLE(editline, [AS_HELP_STRING([--enable-editline],[use BSD libedit])])
  52 AC_ARG_ENABLE(readline, [AS_HELP_STRING([--enable-readline],[use readline])])
  53
  54 AS_IF([ test x"$enable_editline" != xno ],[
  55   AC_CHECK_HEADERS([editline/readline.h],[
  56     sLIBS=$LIBS
  57     LIBS=""
  58     AC_SEARCH_LIBS([readline],[edit],[
  59       AC_DEFINE([HAVE_EDITLINE],1,Define to use BSD editline)
  60       READLINE_LIBS="$LIBS -ltinfo"
  61       enable_readline=no
  62     ],[],[-ltinfo])
  63     AS_UNSET(ac_cv_search_readline)
  64     LIBS=$sLIBS
  65   ])
  66 ])
  67
  68 AS_IF([ test x"$enable_readline" != xno ],[
  69   AC_CHECK_HEADERS([readline/readline.h],[
  70     sLIBS=$LIBS
  71     LIBS=""
  72     AC_SEARCH_LIBS(tgetent, termcap curses ncurses ncursesw, [], [])
  73     AC_SEARCH_LIBS(readline,[readline edit], [
  74       AC_DEFINE([HAVE_READLINE],1,Define to use readline or wrapper)
  75       READLINE_LIBS=$LIBS
  76     ])
  77     LIBS=$sLIBS
  78   ])
  79 ])
  80
  81 AC_SUBST(READLINE_LIBS)
  82 #-----------------------------------------------------------------------
  83
  84 #-----------------------------------------------------------------------
  85 #   --enable-threadsafe
  86 #
  87 AC_ARG_ENABLE(threadsafe, [AS_HELP_STRING(
  88   [--enable-threadsafe], [build a thread-safe library [default=yes]])],
  89   [], [enable_threadsafe=yes])
  90 if test x"$enable_threadsafe" == "xno"; then
  91   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_THREADSAFE=0"
  92 else
  93   BUILD_CFLAGS="$BUILD_CFLAGS -D_REENTRANT=1 -DSQLITE_THREADSAFE=1"
  94   AC_SEARCH_LIBS(pthread_create, pthread)
  95   AC_SEARCH_LIBS(pthread_mutexattr_init, pthread)
  96 fi
  97 #-----------------------------------------------------------------------
  98
  99 #-----------------------------------------------------------------------
 100 #   --enable-dynamic-extensions
 101 #
 102 AC_ARG_ENABLE(dynamic-extensions, [AS_HELP_STRING(
 103   [--enable-dynamic-extensions], [support loadable extensions [default=yes]])],
 104   [], [enable_dynamic_extensions=yes])
 105 if test x"$enable_dynamic_extensions" != "xno"; then
 106   AC_SEARCH_LIBS(dlopen, dl)
 107 else
 108   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_OMIT_LOAD_EXTENSION=1"
 109 fi
 110 AC_MSG_CHECKING([for whether to support dynamic extensions])
 111 AC_MSG_RESULT($enable_dynamic_extensions)
 112 #-----------------------------------------------------------------------
 113
 114 #-----------------------------------------------------------------------
 115 #   --enable-math
 116 #
 117 AC_ARG_ENABLE(math, [AS_HELP_STRING(
 118   [--enable-math], [SQL math functions [default=yes]])],
 119   [], [enable_math=yes])
 120 AC_MSG_CHECKING([SQL math functions])
 121 if test x"$enable_math" = "xyes"; then
 122   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_MATH_FUNCTIONS"
 123   AC_MSG_RESULT([enabled])
 124   AC_SEARCH_LIBS(ceil, m)
 125 else
 126   AC_MSG_RESULT([disabled])
 127 fi
 128 #-----------------------------------------------------------------------
 129
 130 #-----------------------------------------------------------------------
 131 #   --enable-fts4
 132 #
 133 AC_ARG_ENABLE(fts4, [AS_HELP_STRING(
 134   [--enable-fts4], [include fts4 support [default=yes]])],
 135   [], [enable_fts4=yes])
 136 AC_MSG_CHECKING([FTS4 extension])
 137 if test x"$enable_fts4" = "xyes"; then
 138   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_FTS4"
 139   AC_MSG_RESULT([enabled])
 140 else
 141   AC_MSG_RESULT([disabled])
 142 fi
 143 #-----------------------------------------------------------------------
 144
 145 #-----------------------------------------------------------------------
 146 #   --enable-fts3
 147 #
 148 AC_ARG_ENABLE(fts3, [AS_HELP_STRING(
 149   [--enable-fts3], [include fts3 support [default=no]])],
 150   [], [])
 151 AC_MSG_CHECKING([FTS3 extension])
 152 if test x"$enable_fts3" = "xyes" -a x"$enable_fts4" = "xno"; then
 153   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_FTS3"
 154   AC_MSG_RESULT([enabled])
 155 else
 156   AC_MSG_RESULT([disabled])
 157 fi
 158 #-----------------------------------------------------------------------
 159
 160 #-----------------------------------------------------------------------
 161 #   --enable-fts5
 162 #
 163 AC_ARG_ENABLE(fts5, [AS_HELP_STRING(
 164   [--enable-fts5], [include fts5 support [default=yes]])],
 165   [], [enable_fts5=yes])
 166 AC_MSG_CHECKING([FTS5 extension])
 167 if test x"$enable_fts5" = "xyes"; then
 168   AC_MSG_RESULT([enabled])
 169   AC_SEARCH_LIBS(log, m)
 170   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_FTS5"
 171 else
 172   AC_MSG_RESULT([disabled])
 173 fi
 174 #-----------------------------------------------------------------------
 175
 176 #-----------------------------------------------------------------------
 177 #   --enable-json1
 178 #
 179 AC_ARG_ENABLE(json1, [AS_HELP_STRING(
 180   [--enable-json1], [include json1 support [default=yes]])],
 181   [],[enable_json1=yes])
 182 AC_MSG_CHECKING([JSON functions])
 183 if test x"$enable_json1" = "xyes"; then
 184   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_JSON1"
 185   AC_MSG_RESULT([enabled])
 186 else
 187   AC_MSG_RESULT([disabled])
 188 fi
 189 #-----------------------------------------------------------------------
 190
 191 #-----------------------------------------------------------------------
 192 #   --enable-rtree
 193 #
 194 AC_ARG_ENABLE(rtree, [AS_HELP_STRING(
 195   [--enable-rtree], [include rtree support [default=yes]])],
 196   [], [enable_rtree=yes])
 197 AC_MSG_CHECKING([RTREE extension])
 198 if test x"$enable_rtree" = "xyes"; then
 199   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_RTREE -DSQLITE_ENABLE_GEOPOLY"
 200   AC_MSG_RESULT([enabled])
 201 else
 202   AC_MSG_RESULT([disabled])
 203 fi
 204 #-----------------------------------------------------------------------
 205
 206 #-----------------------------------------------------------------------
 207 #   --enable-session
 208 #
 209 AC_ARG_ENABLE(session, [AS_HELP_STRING(
 210   [--enable-session], [enable the session extension [default=no]])],
 211   [], [])
 212 AC_MSG_CHECKING([Session extension])
 213 if test x"$enable_session" = "xyes"; then
 214   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_ENABLE_SESSION -DSQLITE_ENABLE_PREUPDATE_HOOK"
 215   AC_MSG_RESULT([enabled])
 216 else
 217   AC_MSG_RESULT([disabled])
 218 fi
 219 #-----------------------------------------------------------------------
 220
 221 #-----------------------------------------------------------------------
 222 #   --enable-debug
 223 #
 224 AC_ARG_ENABLE(debug, [AS_HELP_STRING(
 225   [--enable-debug], [build with debugging features enabled [default=no]])],
 226   [], [])
 227 AC_MSG_CHECKING([Build type])
 228 if test x"$enable_debug" = "xyes"; then
 229   BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_DEBUG -DSQLITE_ENABLE_SELECTTRACE -DSQLITE_ENABLE_WHERETRACE"
 230   CFLAGS="-g -O0"
 231   AC_MSG_RESULT([debug])
 232 else
 233   AC_MSG_RESULT([release])
 234 fi
 235 #-----------------------------------------------------------------------
 236
 237 #-----------------------------------------------------------------------
 238 #   --enable-static-shell
 239 #
 240 AC_ARG_ENABLE(static-shell, [AS_HELP_STRING(
 241   [--enable-static-shell],
 242   [statically link libsqlite3 into shell tool [default=yes]])],
 243   [], [enable_static_shell=yes])
 244 if test x"$enable_static_shell" = "xyes"; then
 245   EXTRA_SHELL_OBJ=sqlite3-sqlite3.$OBJEXT
 246 else
 247   EXTRA_SHELL_OBJ=libsqlite3.la
 248 fi
 249 AC_SUBST(EXTRA_SHELL_OBJ)
 250 #-----------------------------------------------------------------------
 251
 252 AC_CHECK_FUNCS(posix_fallocate)
 253 AC_CHECK_HEADERS(zlib.h,[
 254   AC_SEARCH_LIBS(deflate,z,[BUILD_CFLAGS="$BUILD_CFLAGS -DSQLITE_HAVE_ZLIB"])
 255 ])
 256
 257 AC_SEARCH_LIBS(system,,,[SHELL_CFLAGS="-DSQLITE_NOHAVE_SYSTEM"])
 258 AC_SUBST(SHELL_CFLAGS)
 259
 260 #-----------------------------------------------------------------------
 261 # UPDATE: Maybe it's better if users just set CFLAGS before invoking
 262 # configure. This option doesn't really add much...
 263 #
 264 #   --enable-tempstore
 265 #
 266 # AC_ARG_ENABLE(tempstore, [AS_HELP_STRING(
 267 #   [--enable-tempstore],
 268 #   [in-memory temporary tables (never, no, yes, always) [default=no]])],
 269 #   [], [enable_tempstore=no])
 270 # AC_MSG_CHECKING([for whether or not to store temp tables in-memory])
 271 # case "$enable_tempstore" in
 272 #   never )  TEMP_STORE=0 ;;
 273 #   no )     TEMP_STORE=1 ;;
 274 #   always ) TEMP_STORE=3 ;;
 275 #   yes )    TEMP_STORE=3 ;;
 276 #   * )
 277 #     TEMP_STORE=1
 278 #     enable_tempstore=yes
 279 #   ;;
 280 # esac
 281 # AC_MSG_RESULT($enable_tempstore)
 282 # AC_SUBST(TEMP_STORE)
 283 #-----------------------------------------------------------------------
 284
 285 AC_OUTPUT