contrib/subversion/configure.ac

   1 dnl     Licensed to the Apache Software Foundation (ASF) under one
   2 dnl     or more contributor license agreements.  See the NOTICE file
   3 dnl     distributed with this work for additional information
   4 dnl     regarding copyright ownership.  The ASF licenses this file
   5 dnl     to you under the Apache License, Version 2.0 (the
   6 dnl     "License"); you may not use this file except in compliance
   7 dnl     with the License.  You may obtain a copy of the License at
   8 dnl
   9 dnl       http://www.apache.org/licenses/LICENSE-2.0
  10 dnl
  11 dnl     Unless required by applicable law or agreed to in writing,
  12 dnl     software distributed under the License is distributed on an
  13 dnl     "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
  14 dnl     KIND, either express or implied.  See the License for the
  15 dnl     specific language governing permissions and limitations
  16 dnl     under the License.
  17
  18 dnl configure.ac: Autoconfiscation for Subversion
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_PREREQ(2.59)
  22
  23 dnl Get the version of Subversion, using m4's esyscmd() command to do this
  24 dnl at m4-time, since AC_INIT() requires it then.
  25 AC_INIT([subversion],
  26      [esyscmd(python build/getversion.py SVN subversion/include/svn_version.h)],
  27      [http://subversion.apache.org/])
  28
  29 AC_CONFIG_SRCDIR(subversion/include/svn_types.h)
  30 AC_CONFIG_AUX_DIR([build])
  31
  32 AC_MSG_NOTICE([Configuring Subversion ]AC_PACKAGE_VERSION)
  33
  34 AC_SUBST([abs_srcdir], ["`cd $srcdir && pwd`"])
  35 AC_SUBST([abs_builddir], ["`pwd`"])
  36 if test "$abs_srcdir" = "$abs_builddir"; then
  37   canonicalized_srcdir=""
  38 else
  39   canonicalized_srcdir="$srcdir/"
  40 fi
  41 AC_SUBST([canonicalized_srcdir])
  42
  43 SWIG_LDFLAGS="$LDFLAGS"
  44 AC_SUBST([SWIG_LDFLAGS])
  45
  46 # Generate config.nice early (before the arguments are munged)
  47 SVN_CONFIG_NICE(config.nice)
  48
  49 # ==== Check for programs ====================================================
  50
  51 # Look for a C compiler (before anything can set CFLAGS)
  52 CMAINTAINERFLAGS="$CUSERFLAGS"
  53 CUSERFLAGS="$CFLAGS"
  54 AC_PROG_CC
  55 SVN_CC_MODE_SETUP
  56
  57 # Look for a C++ compiler (before anything can set CXXFLAGS)
  58 CXXMAINTAINERFLAGS="$CXXUSERFLAGS"
  59 CXXUSERFLAGS="$CXXFLAGS"
  60 AC_PROG_CXX
  61 SVN_CXX_MODE_SETUP
  62
  63 # Look for a C pre-processor
  64 AC_PROG_CPP
  65
  66 # Look for a good sed
  67 # AC_PROG_SED was introduced in Autoconf 2.59b
  68 m4_ifdef([AC_PROG_SED], [AC_PROG_SED], [SED="${SED:-sed}"])
  69
  70 # Grab target_cpu, so we can use it in the Solaris pkginfo file
  71 AC_CANONICAL_TARGET
  72
  73 # Look for an extended grep
  74 AC_PROG_EGREP
  75
  76 AC_PROG_LN_S
  77
  78 AC_PROG_INSTALL
  79 # If $INSTALL is relative path to our fallback install-sh, then convert
  80 # to an absolute path, as in some cases (e.g. Solaris VPATH build), libtool
  81 # may try to use it from a changed working directory.
  82 if test "$INSTALL" = "build/install-sh -c"; then
  83   INSTALL="$abs_srcdir/$INSTALL"
  84 fi
  85
  86 if test -z "$MKDIR"; then
  87   MKDIR="$INSTALL -d"
  88 fi
  89 AC_SUBST([MKDIR])
  90
  91 # ==== Libraries, for which we may have source to build ======================
  92
  93 dnl verify apr version and set apr flags
  94 dnl These regular expressions should not contain "\(" and "\)".
  95 dnl The specific reason we require APR 0.9.7 is:
  96 dnl   It contains fixes to its file writing routines
  97 dnl   now generating errors instead of silently ignoring
  98 dnl   them.  Only .7 and later can guarantee repository
  99 dnl   integrity with FSFS.
 100
 101 APR_VER_REGEXES=["0\.9\.[7-9] 0\.9\.1[0-9] 1\. 2\."]
 102
 103 SVN_LIB_APR($APR_VER_REGEXES)
 104
 105 if test `expr $apr_version : 2` -ne 0; then
 106   dnl Bump the library so-version to 2 if using APR-2
 107   dnl (Debian uses so-version 1 for APR-1-with-largefile)
 108   svn_lib_ver=2
 109   dnl APR-2 provides APRUTIL
 110   apu_config=$apr_config
 111   AC_SUBST(SVN_APRUTIL_INCLUDES)
 112   AC_SUBST(SVN_APRUTIL_CONFIG, ["$apu_config"])
 113   AC_SUBST(SVN_APRUTIL_LIBS)
 114 else
 115   svn_lib_ver=0
 116   APU_VER_REGEXES=["0\.9\.[7-9] 0\.9\.1[0-9] 1\."]
 117   SVN_LIB_APRUTIL($APU_VER_REGEXES)
 118 fi
 119 SVN_LT_SOVERSION="-version-info $svn_lib_ver"
 120 AC_SUBST(SVN_LT_SOVERSION)
 121 AC_DEFINE_UNQUOTED(SVN_SOVERSION, $svn_lib_ver,
 122                    [Subversion library major verson])
 123
 124 dnl Search for pkg-config
 125 AC_PATH_PROG(PKG_CONFIG, pkg-config)
 126
 127 dnl Search for serf
 128 SVN_LIB_SERF(1,2,1)
 129
 130 if test "$svn_lib_serf" = "yes"; then
 131   AC_DEFINE([SVN_HAVE_SERF], 1,
 132             [Defined if support for Serf is enabled])
 133 fi
 134
 135 dnl Search for apr_memcache (only affects fs_fs)
 136 SVN_LIB_APR_MEMCACHE
 137
 138 if test "$svn_lib_apr_memcache" = "yes"; then
 139   AC_DEFINE(SVN_HAVE_MEMCACHE, 1,
 140             [Defined if apr_memcache (standalone or in apr-util) is present])
 141 fi
 142
 143
 144 dnl Find Apache with a recent-enough magic module number
 145 SVN_FIND_APACHE(20020903)
 146
 147 dnl Search for SQLite.  If you change SQLITE_URL from a .zip to
 148 dnl something else also update build/ac-macros/sqlite.m4 to reflect
 149 dnl the correct command to unpack the downloaded file.
 150 SQLITE_MINIMUM_VER="3.7.12"
 151 SQLITE_RECOMMENDED_VER="3.7.15.1"
 152 SQLITE_URL="http://www.sqlite.org/sqlite-amalgamation-$(printf %d%02d%02d%02d $(echo ${SQLITE_RECOMMENDED_VER} | sed -e 's/\./ /g')).zip"
 153
 154 SVN_LIB_SQLITE(${SQLITE_MINIMUM_VER}, ${SQLITE_RECOMMENDED_VER},
 155                ${SQLITE_URL})
 156
 157 AC_ARG_ENABLE(sqlite-compatibility-version,
 158   AS_HELP_STRING([--enable-sqlite-compatibility-version=X.Y.Z],
 159                  [Allow binary to run against SQLite as old as ARG]),
 160   [sqlite_compat_ver=$enableval],[sqlite_compat_ver=no])
 161
 162 if test -n "$sqlite_compat_ver" && test "$sqlite_compat_ver" != no; then
 163   SVN_SQLITE_VERNUM_PARSE([$sqlite_compat_ver],
 164                           [sqlite_compat_ver_num])
 165   CFLAGS="-DSVN_SQLITE_MIN_VERSION='\"$sqlite_compat_ver\"' $CFLAGS"
 166   CFLAGS="-DSVN_SQLITE_MIN_VERSION_NUMBER=$sqlite_compat_ver_num $CFLAGS"
 167 fi
 168
 169 SVN_CHECK_FOR_ATOMIC_BUILTINS
 170
 171 if test "$svn_cv_atomic_builtins" = "yes"; then
 172     AC_DEFINE(SVN_HAS_ATOMIC_BUILTINS, 1, [Define if compiler provides atomic builtins])
 173 fi
 174
 175 dnl Set up a number of directories ---------------------
 176
 177 dnl Create SVN_BINDIR for proper substitution
 178 if test "${bindir}" = '${exec_prefix}/bin'; then
 179         if test "${exec_prefix}" = "NONE"; then
 180                 if test "${prefix}" = "NONE"; then
 181                         SVN_BINDIR="${ac_default_prefix}/bin"
 182                 else
 183                         SVN_BINDIR="${prefix}/bin"
 184                 fi
 185         else
 186                 SVN_BINDIR="${exec_prefix}/bin"
 187         fi
 188 else
 189         SVN_BINDIR="${bindir}"
 190 fi
 191
 192 dnl fully evaluate this value. when we substitute it into our tool scripts,
 193 dnl they will not have things such as ${bindir} available
 194 SVN_BINDIR="`eval echo ${SVN_BINDIR}`"
 195 AC_SUBST(SVN_BINDIR)
 196
 197 dnl provide ${bindir} in svn_private_config.h for use in compiled code
 198 AC_DEFINE_UNQUOTED(SVN_BINDIR, "${SVN_BINDIR}",
 199         [Defined to be the path to the installed binaries])
 200
 201 dnl This purposely does *not* allow for multiple parallel installs.
 202 dnl However, it is compatible with most gettext usages.
 203 localedir='${datadir}/locale'
 204 AC_SUBST(localedir)
 205
 206 dnl For SVN_LOCALE_DIR, we have to expand it to something.  See SVN_BINDIR.
 207 if test "${datadir}" = '${prefix}/share' && test "${prefix}" = "NONE"; then
 208   exp_localedir='${ac_default_prefix}/share/locale'
 209 else
 210   exp_localedir=$localedir
 211 fi
 212 SVN_EXPAND_VAR(svn_localedir, "${exp_localedir}")
 213 AC_DEFINE_UNQUOTED(SVN_LOCALE_DIR, "${svn_localedir}",
 214                    [Defined to be the path to the installed locale dirs])
 215
 216 dnl Check for libtool -- we'll definitely need it for all our shared libs!
 217 AC_MSG_NOTICE([configuring libtool now])
 218 ifdef([LT_INIT], [LT_INIT], [AC_PROG_LIBTOOL])
 219 AC_ARG_ENABLE(experimental-libtool,
 220   AS_HELP_STRING([--enable-experimental-libtool],[Use APR's libtool]),
 221   [experimental_libtool=$enableval],[experimental_libtool=no])
 222
 223 if test "$experimental_libtool" = "yes"; then
 224   echo "using APR's libtool"
 225   sh_libtool="`$apr_config --apr-libtool`"
 226   LIBTOOL="$sh_libtool"
 227   SVN_LIBTOOL="$sh_libtool"
 228 else
 229   sh_libtool="$abs_builddir/libtool"
 230   SVN_LIBTOOL="\$(SHELL) $sh_libtool"
 231 fi
 232 AC_SUBST(SVN_LIBTOOL)
 233
 234 dnl Determine the libtool version
 235 changequote(, )dnl
 236 lt_pversion=`$LIBTOOL --version 2>/dev/null|$SED -e 's/([^)]*)//g;s/^[^0-9]*//;s/[- ].*//g;q'`
 237 lt_version=`echo $lt_pversion|$SED -e 's/\([a-z]*\)$/.\1/'`
 238 lt_major_version=`echo $lt_version | cut -d'.' -f 1`
 239 changequote([, ])dnl
 240
 241 dnl set the default parameters
 242 svn_enable_static=yes
 243 svn_enable_shared=yes
 244
 245 dnl check for --enable-static option
 246 AC_ARG_ENABLE(static,
 247   AS_HELP_STRING([--enable-static],
 248                  [Build static libraries]),
 249   [svn_enable_static="$enableval"], [svn_enable_static="yes"])
 250
 251 dnl check for --enable-shared option
 252 AC_ARG_ENABLE(shared,
 253   AS_HELP_STRING([--enable-shared],
 254                  [Build shared libraries]),
 255   [svn_enable_shared="$enableval"], [svn_enable_shared="yes"])
 256
 257 if test "$svn_enable_static" = "yes" && test "$svn_enable_shared" = "yes" ; then
 258   AC_MSG_NOTICE([building both shared and static libraries])
 259 elif test "$svn_enable_static" = "yes" ; then
 260   AC_MSG_NOTICE([building static libraries only])
 261   LT_CFLAGS="-static $LT_CFLAGS"
 262   LT_LDFLAGS="-static $LT_LDFLAGS"
 263 elif test "$svn_enable_shared" = "yes" ; then
 264   AC_MSG_NOTICE([building shared libraries only])
 265   if test "$lt_major_version" = "1" ; then
 266     LT_CFLAGS="-prefer-pic $LT_CFLAGS"
 267   elif test "$lt_major_version" = "2" ; then
 268     LT_CFLAGS="-shared $LT_CFLAGS"
 269   fi
 270   LT_LDFLAGS="-shared $LT_LDFLAGS"
 271 else
 272   AC_MSG_ERROR([cannot disable both shared and static libraries])
 273 fi
 274
 275 dnl Check for --enable-all-static option
 276 AC_ARG_ENABLE(all-static,
 277   AS_HELP_STRING([--enable-all-static],
 278                  [Build completely static (standalone) binaries.]),
 279   [
 280     if test "$enableval" = "yes" ; then
 281       LT_LDFLAGS="-all-static $LT_LDFLAGS"
 282     elif test "$enableval" != "no" ; then
 283       AC_MSG_ERROR([--enable-all-static doesn't accept argument])
 284     fi
 285 ])
 286
 287 AC_SUBST(LT_CFLAGS)
 288 AC_SUBST(LT_LDFLAGS)
 289
 290 AC_ARG_ENABLE(local-library-preloading,
 291   AS_HELP_STRING([--enable-local-library-preloading],
 292                  [Enable preloading of locally built libraries in locally
 293                   built executables.  This may be necessary for testing
 294                   prior to installation on some platforms.  It does not
 295                   work on some platforms (Darwin, OpenBSD, ...).]),
 296   [
 297   if test "$enableval" != "no"; then
 298     if test "$svn_enable_shared" = "yes"; then
 299       TRANSFORM_LIBTOOL_SCRIPTS="transform-libtool-scripts"
 300     else
 301       AC_MSG_ERROR([--enable-local-library-preloading conflicts with --disable-shared])
 302     fi
 303   else
 304     TRANSFORM_LIBTOOL_SCRIPTS=""
 305   fi
 306   ], [
 307   TRANSFORM_LIBTOOL_SCRIPTS=""
 308 ])
 309 AC_SUBST(TRANSFORM_LIBTOOL_SCRIPTS)
 310
 311 dnl Check if -no-undefined is needed for the platform.
 312 dnl It should always work but with libtool 1.4.3 on OS X it breaks the build.
 313 dnl So we only turn it on for platforms where we know we really need it.
 314 AC_MSG_CHECKING([whether libtool needs -no-undefined])
 315 case $host in
 316   *-*-cygwin*)
 317     AC_MSG_RESULT([yes])
 318     LT_NO_UNDEFINED="-no-undefined"
 319     ;;
 320   *)
 321     AC_MSG_RESULT([no])
 322     LT_NO_UNDEFINED=""
 323     ;;
 324 esac
 325 AC_SUBST(LT_NO_UNDEFINED)
 326
 327 AC_MSG_CHECKING([whether to avoid circular linkage at all costs])
 328 case $host in
 329   *-*-cygwin*)
 330     AC_MSG_RESULT([yes])
 331     AC_DEFINE([SVN_AVOID_CIRCULAR_LINKAGE_AT_ALL_COSTS_HACK], 1,
 332               [Define if circular linkage is not possible on this platform.])
 333     ;;
 334   *)
 335     AC_MSG_RESULT([no])
 336     ;;
 337 esac
 338
 339 dnl Check for trang.
 340 trang=yes
 341 AC_ARG_WITH(trang,
 342 AS_HELP_STRING([--with-trang=PATH],
 343                [Specify the command to run the trang schema converter]),
 344 [
 345     trang="$withval"
 346 ])
 347 if test "$trang" = "yes"; then
 348     AC_PATH_PROG(TRANG, trang, none)
 349 else
 350     TRANG="$trang"
 351     AC_SUBST(TRANG)
 352 fi
 353
 354 dnl Check for doxygen
 355 doxygen=yes
 356 AC_ARG_WITH(doxygen,
 357 AC_HELP_STRING([--with-doxygen=PATH],
 358                [Specify the command to run doxygen]),
 359 [
 360     doxygen="$withval"
 361 ])
 362 if test "$doxygen" = "yes"; then
 363     AC_PATH_PROG(DOXYGEN, doxygen, none)
 364 else
 365     DOXYGEN="$doxygen"
 366     AC_SUBST(DOXYGEN)
 367 fi
 368
 369
 370 dnl Check for libraries --------------------
 371
 372 dnl Expat -------------------
 373
 374 AC_ARG_WITH(expat,
 375   AS_HELP_STRING([--with-expat=INCLUDES:LIB_SEARCH_DIRS:LIBS],
 376                  [Specify location of Expat]),
 377                  [svn_lib_expat="$withval"],
 378                  [svn_lib_expat="::expat"])
 379
 380 # APR-util accepts "builtin" as an argument to this option so if the user
 381 # passed "builtin" pretend the user didn't specify the --with-expat option
 382 # at all. Expat will (hopefully) be found in apr-util.
 383 test "_$svn_lib_expat" = "_builtin" && svn_lib_expat="::expat"
 384
 385 AC_MSG_CHECKING([for Expat])
 386 if test -n "`echo "$svn_lib_expat" | $EGREP ":.*:"`"; then
 387   SVN_XML_INCLUDES=""
 388   for i in [`echo "$svn_lib_expat" | $SED -e "s/\([^:]*\):.*/\1/"`]; do
 389     SVN_XML_INCLUDES="$SVN_XML_INCLUDES -I$i"
 390   done
 391   SVN_XML_INCLUDES="${SVN_XML_INCLUDES## }"
 392   for l in [`echo "$svn_lib_expat" | $SED -e "s/.*:\([^:]*\):.*/\1/"`]; do
 393     LDFLAGS="$LDFLAGS -L$l"
 394   done
 395   for l in [`echo "$svn_lib_expat" | $SED -e "s/.*:\([^:]*\)/\1/"`]; do
 396     SVN_XML_LIBS="$SVN_XML_LIBS -l$l"
 397   done
 398   SVN_XML_LIBS="${SVN_XML_LIBS## }"
 399   old_CPPFLAGS="$CPPFLAGS"
 400   old_LIBS="$LIBS"
 401   CPPFLAGS="$CPPFLAGS $SVN_XML_INCLUDES"
 402   LIBS="$LIBS $SVN_XML_LIBS"
 403   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 404 #include <expat.h>
 405 int main()
 406 {XML_ParserCreate(NULL);}]])], svn_lib_expat="yes", svn_lib_expat="no")
 407   LIBS="$old_LIBS"
 408   if test "$svn_lib_expat" = "yes"; then
 409     AC_MSG_RESULT([yes])
 410   else
 411     SVN_XML_INCLUDES=""
 412     SVN_XML_LIBS=""
 413     CPPFLAGS="$CPPFLAGS $SVN_APRUTIL_INCLUDES"
 414     if test "$enable_all_static" != "yes"; then
 415       SVN_APRUTIL_LIBS="$SVN_APRUTIL_LIBS `$apu_config --libs`"
 416     fi
 417     AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 418 #include <expat.h>
 419 int main()
 420 {XML_ParserCreate(NULL);}]])], svn_lib_expat="yes", svn_lib_expat="no")
 421     if test "$svn_lib_expat" = "yes"; then
 422       AC_MSG_RESULT([yes])
 423       AC_MSG_WARN([Expat found amongst libraries used by APR-Util, but Subversion libraries might be needlessly linked against additional unused libraries. It can be avoided by specifying exact location of Expat in argument of --with-expat option.])
 424     else
 425       AC_MSG_RESULT([no])
 426       AC_MSG_ERROR([Expat not found])
 427     fi
 428   fi
 429   CPPFLAGS="$old_CPPFLAGS"
 430 else
 431   AC_MSG_RESULT([no])
 432   if test "$svn_lib_expat" = "yes"; then
 433     AC_MSG_ERROR([--with-expat option requires argument])
 434   elif test "$svn_lib_expat" = "no"; then
 435     AC_MSG_ERROR([Expat is required])
 436   else
 437     AC_MSG_ERROR([Invalid syntax of argument of --with-expat option])
 438   fi
 439 fi
 440 AC_SUBST(SVN_XML_INCLUDES)
 441 AC_SUBST(SVN_XML_LIBS)
 442
 443 dnl Berkeley DB -------------------
 444
 445 # Berkeley DB on SCO OpenServer needs -lsocket
 446 AC_CHECK_LIB(socket, socket)
 447
 448 # Build the BDB filesystem library only if we have an appropriate
 449 # version of Berkeley DB.
 450 case "$host" in
 451 powerpc-apple-darwin*)
 452     # Berkeley DB 4.0 does not work on OS X.
 453     SVN_FS_WANT_DB_MAJOR=4
 454     SVN_FS_WANT_DB_MINOR=1
 455     SVN_FS_WANT_DB_PATCH=25
 456     ;;
 457 *)
 458     SVN_FS_WANT_DB_MAJOR=4
 459     SVN_FS_WANT_DB_MINOR=0
 460     SVN_FS_WANT_DB_PATCH=14
 461     ;;
 462 esac
 463 # Look for libdb4.so first:
 464 SVN_LIB_BERKELEY_DB($SVN_FS_WANT_DB_MAJOR, $SVN_FS_WANT_DB_MINOR,
 465                     $SVN_FS_WANT_DB_PATCH, [db4 db])
 466
 467 AC_DEFINE_UNQUOTED(SVN_FS_WANT_DB_MAJOR, $SVN_FS_WANT_DB_MAJOR,
 468                    [The desired major version for the Berkeley DB])
 469 AC_DEFINE_UNQUOTED(SVN_FS_WANT_DB_MINOR, $SVN_FS_WANT_DB_MINOR,
 470                    [The desired minor version for the Berkeley DB])
 471 AC_DEFINE_UNQUOTED(SVN_FS_WANT_DB_PATCH, $SVN_FS_WANT_DB_PATCH,
 472                    [The desired patch version for the Berkeley DB])
 473
 474 AC_SUBST(SVN_DB_INCLUDES)
 475 AC_SUBST(SVN_DB_LIBS)
 476
 477 SVN_LIB_SASL
 478
 479 if test "$svn_lib_sasl" = "yes"; then
 480   AC_DEFINE(SVN_HAVE_SASL, 1,
 481             [Defined if Cyrus SASL v2 is present on the system])
 482 fi
 483
 484 dnl Mac OS specific features -------------------
 485
 486 SVN_LIB_MACHO_ITERATE
 487 SVN_LIB_MACOS_PLIST
 488 SVN_LIB_MACOS_KEYCHAIN
 489
 490 dnl APR_HAS_DSO -------------------
 491
 492 AC_MSG_CHECKING([whether APR has support for DSOs])
 493 old_CPPFLAGS="$CPPFLAGS"
 494 CPPFLAGS="$CPPFLAGS $SVN_APR_INCLUDES"
 495 AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 496 #include <apr.h>
 497 #if !APR_HAS_DSO
 498 #error
 499 #endif]])],
 500   APR_HAS_DSO="yes"
 501   AC_MSG_RESULT([yes]),
 502   APR_HAS_DSO="no"
 503   AC_MSG_RESULT([no]))
 504 CPPFLAGS="$old_CPPFLAGS"
 505
 506
 507 dnl D-Bus (required for support for KWallet) -------------------
 508
 509 if test -n "$PKG_CONFIG"; then
 510   AC_MSG_CHECKING([for D-Bus .pc file])
 511   if $PKG_CONFIG --exists dbus-1; then
 512     AC_MSG_RESULT([yes])
 513     old_CPPFLAGS="$CPPFLAGS"
 514     old_LIBS="$LIBS"
 515     DBUS_CPPFLAGS="`$PKG_CONFIG --cflags dbus-1`"
 516     AC_MSG_CHECKING([D-Bus version])
 517     DBUS_VERSION="`$PKG_CONFIG --modversion dbus-1`"
 518     AC_MSG_RESULT([$DBUS_VERSION])
 519     # D-Bus 0.* requires DBUS_API_SUBJECT_TO_CHANGE
 520     if test -n ["`echo "$DBUS_VERSION" | $EGREP '^0\.[[:digit:]]+'`"]; then
 521       DBUS_CPPFLAGS="$DBUS_CPPFLAGS -DDBUS_API_SUBJECT_TO_CHANGE"
 522     fi
 523     DBUS_LIBS="`$PKG_CONFIG --libs dbus-1`"
 524     CPPFLAGS="$CPPFLAGS $DBUS_CPPFLAGS"
 525     LIBS="$LIBS $DBUS_LIBS"
 526     AC_MSG_CHECKING([for D-Bus])
 527     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 528 #include <dbus/dbus.h>
 529 int main()
 530 {dbus_bus_get(DBUS_BUS_SESSION, NULL);}]])], HAVE_DBUS="yes", HAVE_DBUS="no")
 531     if test "$HAVE_DBUS" = "yes"; then
 532       AC_MSG_RESULT([yes])
 533     else
 534       AC_MSG_RESULT([no])
 535     fi
 536     CPPFLAGS="$old_CPPFLAGS"
 537     LIBS="$old_LIBS"
 538   else
 539     AC_MSG_RESULT([no])
 540   fi
 541 fi
 542
 543 dnl GPG Agent -------------------
 544
 545 AC_ARG_WITH(gpg_agent,
 546 AS_HELP_STRING([--without-gpg-agent],
 547                [Disable support for GPG-Agent]),
 548                [], [with_gpg_agent=yes])
 549 AC_MSG_CHECKING([whether to support GPG-Agent])
 550 if test "$with_gpg_agent" = "yes"; then
 551   AC_MSG_RESULT([yes])
 552   AC_DEFINE([SVN_HAVE_GPG_AGENT], [1],
 553             [Is GPG Agent support enabled?])
 554 else
 555   AC_MSG_RESULT([no])
 556 fi
 557
 558 AC_SUBST(SVN_HAVE_GPG_AGENT)
 559
 560 dnl GNOME Keyring -------------------
 561
 562 AC_ARG_WITH(gnome_keyring,
 563   AS_HELP_STRING([--with-gnome-keyring],
 564                  [Enable use of GNOME Keyring for auth credentials (enabled by default if found)]),
 565                  [with_gnome_keyring="$withval"],
 566                  [with_gnome_keyring=auto])
 567
 568 found_gnome_keyring=no
 569 AC_MSG_CHECKING([whether to look for GNOME Keyring])
 570 if test "$with_gnome_keyring" != "no"; then
 571   AC_MSG_RESULT([yes])
 572   if test "$svn_enable_shared" = "yes"; then
 573     if test "$APR_HAS_DSO" = "yes"; then
 574       if test -n "$PKG_CONFIG"; then
 575         AC_MSG_CHECKING([for GLib and GNOME Keyring .pc files])
 576         if $PKG_CONFIG --exists glib-2.0 gnome-keyring-1; then
 577           AC_MSG_RESULT([yes])
 578           old_CPPFLAGS="$CPPFLAGS"
 579           SVN_GNOME_KEYRING_INCLUDES="`$PKG_CONFIG --cflags glib-2.0 gnome-keyring-1`"
 580           CPPFLAGS="$CPPFLAGS $SVN_GNOME_KEYRING_INCLUDES"
 581           AC_CHECK_HEADER(gnome-keyring.h, found_gnome_keyring=yes, found_gnome_keyring=no)
 582           AC_MSG_CHECKING([for GNOME Keyring])
 583           if test "$found_gnome_keyring" = "yes"; then
 584             AC_MSG_RESULT([yes])
 585             AC_DEFINE([SVN_HAVE_GNOME_KEYRING], [1],
 586                       [Is GNOME Keyring support enabled?])
 587             CPPFLAGS="$old_CPPFLAGS"
 588             SVN_GNOME_KEYRING_LIBS="`$PKG_CONFIG --libs glib-2.0 gnome-keyring-1`"
 589           else
 590             AC_MSG_RESULT([no])
 591             if test "$with_gnome_keyring" = "yes"; then
 592               AC_MSG_ERROR([cannot find GNOME Keyring])
 593             fi
 594           fi
 595         else
 596           AC_MSG_RESULT([no])
 597           if test "$with_gnome_keyring" = "yes"; then
 598             AC_MSG_ERROR([cannot find GLib and GNOME Keyring .pc files.])
 599           else
 600             with_gnome_keyring=no
 601           fi
 602         fi
 603       else
 604         if test "$with_gnome_keyring" = "yes"; then
 605           AC_MSG_ERROR([cannot find pkg-config. GNOME Keyring requires this.])
 606         else
 607           with_gnome_keyring=no
 608         fi
 609       fi
 610     else
 611       if test "$with_gnome_keyring" = "yes"; then
 612         AC_MSG_ERROR([APR does not have support for DSOs. GNOME Keyring requires this.])
 613       else
 614         with_gnome_keyring=no
 615       fi
 616     fi
 617   else
 618     if test "$with_gnome_keyring" = "yes"; then
 619       AC_MSG_ERROR([--with-gnome-keyring conflicts with --disable-shared])
 620     else
 621       with_gnome_keyring=no
 622     fi
 623   fi
 624 else
 625   AC_MSG_RESULT([no])
 626 fi
 627 AC_SUBST(SVN_GNOME_KEYRING_INCLUDES)
 628 AC_SUBST(SVN_GNOME_KEYRING_LIBS)
 629
 630
 631 dnl Ev2 experimental features ----------------------
 632 dnl Note: The Ev2 implementations will be built unconditionally, but by
 633 dnl providing this flag, users can choose to use the currently-shimmed Ev2
 634 dnl editor implementations for various operations.  This will probably
 635 dnl negatively impact performance, but is useful for testing.
 636 AC_ARG_ENABLE(ev2-impl,
 637   AS_HELP_STRING([--enable-ev2-impl],
 638                  [Use Ev2 implementations, where available [EXPERIMENTAL]]),
 639   [enable_ev2_impl=$enableval],[enable_ev2_impl=no])
 640 if test "$enable_ev2_impl" = "yes"; then
 641   AC_DEFINE(ENABLE_EV2_IMPL, 1,
 642             [Define to 1 if Ev2 implementations should be used.])
 643 fi
 644
 645
 646 dnl I18n -------------------
 647
 648 AC_ARG_ENABLE(nls,
 649   AS_HELP_STRING([--disable-nls],[Disable gettext functionality]),
 650   [enable_nls=$enableval],[enable_nls=yes])
 651
 652 USE_NLS="no"
 653 if test "$enable_nls" = "yes"; then
 654   dnl First, check to see if there is a working msgfmt.
 655   AC_PATH_PROG(MSGFMT, msgfmt, none)
 656   AC_PATH_PROG(MSGMERGE, msgmerge, none)
 657   AC_PATH_PROG(XGETTEXT, xgettext, none)
 658   if test "$MSGFMT" != "none"; then
 659     AC_SEARCH_LIBS(bindtextdomain, [intl], [],
 660                    [
 661                     enable_nls="no"
 662                    ])
 663     if test "$enable_nls" = "no"; then
 664       # Destroy the cached result so we can test again
 665       unset ac_cv_search_bindtextdomain
 666       # On some systems, libintl needs libiconv to link properly,
 667       # so try again with -liconv.
 668       AC_SEARCH_LIBS(bindtextdomain, [intl],
 669                      [
 670                       enable_nls="yes"
 671                       # This is here so that -liconv ends up in LIBS
 672                       # if it worked with -liconv.
 673                       AC_CHECK_LIB(iconv, libiconv_open)
 674                      ],
 675                      [
 676                       AC_MSG_WARN([bindtextdomain() not found.  Disabling NLS.])
 677                       enable_nls="no"
 678                      ], -liconv)
 679     fi
 680     if test "$enable_nls" = "yes"; then
 681       AC_DEFINE(ENABLE_NLS, 1,
 682                 [Define to 1 if translation of program messages to the user's
 683                  native language is requested.])
 684       USE_NLS="yes"
 685     fi
 686   fi
 687 fi
 688
 689 AH_BOTTOM([
 690 /* Indicate to translators that string X should be translated.  Do not look
 691    up the translation at run time; just expand to X.  This macro is suitable
 692    for use where a constant string is required at compile time. */
 693 #define N_(x) x
 694 /* Indicate to translators that we have decided the string X should not be
 695    translated.  Expand to X. */
 696 #define U_(x) x
 697 #ifdef ENABLE_NLS
 698 #include <locale.h>
 699 #include <libintl.h>
 700 /* Indicate to translators that string X should be translated.  At run time,
 701    look up and return the translation of X. */
 702 #define _(x) dgettext(PACKAGE_NAME, x)
 703 /* Indicate to translators that strings X1 and X2 are singular and plural
 704    forms of the same message, and should be translated.  At run time, return
 705    an appropriate translation depending on the number N. */
 706 #define Q_(x1, x2, n) dngettext(PACKAGE_NAME, x1, x2, n)
 707 #else
 708 #define _(x) (x)
 709 #define Q_(x1, x2, n) (((n) == 1) ? x1 : x2)
 710 #define gettext(x) (x)
 711 #define dgettext(domain, x) (x)
 712 #endif
 713 ])
 714
 715 dnl Used to simulate makefile conditionals.
 716 GETTEXT_CODESET=\#
 717 NO_GETTEXT_CODESET=\#
 718 if test $USE_NLS = "yes"; then
 719    AC_CHECK_FUNCS(bind_textdomain_codeset,
 720                   [ GETTEXT_CODESET="" ],
 721                   [ NO_GETTEXT_CODESET="" ])
 722 fi
 723 AC_SUBST(GETTEXT_CODESET)
 724 AC_SUBST(NO_GETTEXT_CODESET)
 725
 726 # Check if we are using GNU gettext.
 727 GNU_GETTEXT=no
 728 MSGFMTFLAGS=''
 729 if test $USE_NLS = "yes"; then
 730    AC_MSG_CHECKING(if we are using GNU gettext)
 731    if $MSGFMT --version 2>&1 | $EGREP GNU > /dev/null; then
 732       GNU_GETTEXT=yes
 733       MSGFMTFLAGS='-c'
 734    fi
 735    AC_MSG_RESULT($GNU_GETTEXT)
 736 fi
 737 AC_SUBST(MSGFMTFLAGS)
 738
 739 dnl libmagic -------------------
 740
 741 libmagic_found=no
 742
 743 AC_ARG_WITH(libmagic,AS_HELP_STRING([--with-libmagic=PREFIX],
 744                                 [libmagic filetype detection library]),
 745 [
 746   if test "$withval" = "yes" ; then
 747     AC_CHECK_HEADER(magic.h, [
 748       AC_CHECK_LIB(magic, magic_open, [libmagic_found="builtin"])
 749     ])
 750     libmagic_prefix="the default locations"
 751   elif test "$withval" != "no"; then
 752     libmagic_prefix=$withval
 753     save_cppflags="$CPPFLAGS"
 754     CPPFLAGS="$CPPFLAGS -I$libmagic_prefix/include"
 755     AC_CHECK_HEADERS(magic.h,[
 756       save_ldflags="$LDFLAGS"
 757       LDFLAGS="-L$libmagic_prefix/lib"
 758       AC_CHECK_LIB(magic, magic_open, [libmagic_found="yes"])
 759       LDFLAGS="$save_ldflags"
 760     ])
 761     CPPFLAGS="$save_cppflags"
 762   fi
 763   if test "$withval" != "no" && test "$libmagic_found" = "no"; then
 764     AC_MSG_ERROR([[--with-libmagic requested, but libmagic not found at $libmagic_prefix]])
 765   fi
 766 ],
 767 [
 768   AC_CHECK_HEADER(magic.h, [
 769     AC_CHECK_LIB(magic, magic_open, [libmagic_found="builtin"])
 770   ])
 771 ])
 772
 773 if test "$libmagic_found" != "no"; then
 774   AC_DEFINE([SVN_HAVE_LIBMAGIC], [1], [Defined if libmagic support is enabled])
 775   SVN_MAGIC_LIBS="-lmagic"
 776 fi
 777
 778 if test "$libmagic_found" = "yes"; then
 779   SVN_MAGIC_INCLUDES="-I$libmagic_prefix/include"
 780   LDFLAGS="$LDFLAGS `SVN_REMOVE_STANDARD_LIB_DIRS(-L$libmagic_prefix/lib)`"
 781 fi
 782
 783 AC_SUBST(SVN_MAGIC_INCLUDES)
 784 AC_SUBST(SVN_MAGIC_LIBS)
 785
 786 dnl KWallet -------------------
 787 SVN_LIB_KWALLET
 788
 789 if test "$svn_lib_kwallet" = "yes"; then
 790   AC_DEFINE([SVN_HAVE_KWALLET], 1,
 791             [Defined if KWallet support is enabled])
 792 fi
 793
 794 dnl plaintext passwords -------------------
 795 AC_ARG_ENABLE(plaintext-password-storage,
 796 AS_HELP_STRING([--disable-plaintext-password-storage],
 797                [Disable on-disk caching of plaintext passwords and passphrases.
 798                 (Leaving this functionality enabled will not force Subversion
 799                 to store passwords in plaintext, but does permit users to
 800                 explicitly allow that behavior via runtime configuration.)]),
 801 [
 802    if test "$enableval" = "no"; then
 803       AC_MSG_NOTICE([Disabling plaintext password/passphrase storage])
 804       AC_DEFINE(SVN_DISABLE_PLAINTEXT_PASSWORD_STORAGE, 1,
 805                 [Defined if plaintext password/passphrase storage is disabled])
 806    fi
 807 ])
 808
 809 dnl Build and install rules -------------------
 810
 811 INSTALL_STATIC_RULES="install-bin install-docs"
 812 INSTALL_RULES="install-fsmod-lib install-ramod-lib install-lib install-include install-static"
 813 INSTALL_RULES="$INSTALL_RULES $INSTALL_APACHE_RULE"
 814 BUILD_RULES="fsmod-lib ramod-lib lib bin test sub-test $BUILD_APACHE_RULE tools"
 815
 816 if test "$svn_lib_berkeley_db" = "yes"; then
 817   BUILD_RULES="$BUILD_RULES bdb-lib bdb-test"
 818   INSTALL_RULES="`echo $INSTALL_RULES | $SED 's/install-fsmod-lib/install-fsmod-lib install-bdb-lib/'`"
 819   INSTALL_STATIC_RULES="$INSTALL_STATIC_RULES install-bdb-lib"
 820   BDB_TEST_DEPS="\$(BDB_TEST_DEPS)"
 821   BDB_TEST_PROGRAMS="\$(BDB_TEST_PROGRAMS)"
 822 fi
 823
 824 if test "$svn_lib_serf" = "yes"; then
 825   BUILD_RULES="$BUILD_RULES serf-lib"
 826   INSTALL_RULES="`echo $INSTALL_RULES | $SED 's/install-ramod-lib/install-ramod-lib install-serf-lib/'`"
 827   INSTALL_STATIC_RULES="$INSTALL_STATIC_RULES install-serf-lib"
 828 fi
 829
 830 if test "$svn_lib_kwallet" = "yes"; then
 831   BUILD_RULES="$BUILD_RULES kwallet-lib"
 832   INSTALL_RULES="`echo $INSTALL_RULES | $SED 's/install-lib/install-lib install-kwallet-lib/'`"
 833   INSTALL_STATIC_RULES="$INSTALL_STATIC_RULES install-kwallet-lib"
 834 fi
 835
 836 if test "$found_gnome_keyring" = "yes"; then
 837   BUILD_RULES="$BUILD_RULES gnome-keyring-lib"
 838   INSTALL_RULES="`echo $INSTALL_RULES | $SED 's/install-lib/install-lib install-gnome-keyring-lib/'`"
 839   INSTALL_STATIC_RULES="$INSTALL_STATIC_RULES install-gnome-keyring-lib"
 840 fi
 841
 842 if test "$USE_NLS" = "yes"; then
 843   BUILD_RULES="$BUILD_RULES locale"
 844   INSTALL_RULES="$INSTALL_RULES install-locale"
 845 fi
 846
 847 AC_SUBST(BUILD_RULES)
 848 AC_SUBST(INSTALL_STATIC_RULES)
 849 AC_SUBST(INSTALL_RULES)
 850 AC_SUBST(BDB_TEST_DEPS)
 851 AC_SUBST(BDB_TEST_PROGRAMS)
 852
 853 dnl Check for header files ----------------
 854
 855 dnl Standard C headers
 856 AC_HEADER_STDC
 857
 858 dnl Check for typedefs, structures, and compiler characteristics ----------
 859
 860 dnl if compiler doesn't understand `const', then define it empty
 861 AC_C_CONST
 862
 863 dnl if non-existent, define size_t to be `unsigned'
 864 AC_TYPE_SIZE_T
 865
 866
 867 dnl Check for library functions ----------
 868
 869 AC_FUNC_MEMCMP
 870
 871 dnl svn_error's default warning handler uses vfprintf()
 872 AC_FUNC_VPRINTF
 873
 874 dnl check for functions needed in special file handling
 875 AC_CHECK_FUNCS(symlink readlink)
 876
 877 dnl check for uname
 878 AC_CHECK_HEADERS(sys/utsname.h, [AC_CHECK_FUNCS(uname)], [])
 879
 880 dnl check for termios
 881 AC_CHECK_HEADER(termios.h,[
 882   AC_CHECK_FUNCS(tcgetattr tcsetattr,[
 883     AC_DEFINE(HAVE_TERMIOS_H,1,[Defined if we have a usable termios library.])
 884   ])
 885 ])
 886
 887 dnl Process some configuration options ----------
 888
 889 AC_ARG_WITH(openssl,
 890 AS_HELP_STRING([--with-openssl],
 891                [This option does NOT affect the Subversion build process in any
 892                 way. It tells an integrated Serf HTTP client library build
 893                 process where to locate the OpenSSL library when (and only when)
 894                 building Serf as an integrated part of the Subversion build
 895                 process. When linking to a previously installed version of Serf
 896                 instead, you do not need to use this option.]),
 897 [])
 898
 899 AC_ARG_ENABLE(debug,
 900 AS_HELP_STRING([--enable-debug],
 901                [Turn on debugging]),
 902 [
 903     if test "$enableval" = "yes" ; then
 904       enable_debugging="yes"
 905     else
 906       enable_debugging="no"
 907     fi
 908 ],
 909 [
 910     # Neither --enable-debug nor --disable-debug was passed.
 911     enable_debugging="maybe"
 912 ])
 913
 914 AC_ARG_ENABLE(optimize,
 915 AS_HELP_STRING([--enable-optimize],
 916                [Turn on optimizations]),
 917 [
 918     if test "$enableval" = "yes" ; then
 919       enable_optimization="yes"
 920     else
 921       enable_optimization="no"
 922     fi
 923 ],
 924 [
 925     # Neither --enable-optimize nor --disable-optimize was passed.
 926     enable_optimization="maybe"
 927 ])
 928
 929 dnl Use -Wl,--no-undefined during linking of some libraries
 930 AC_ARG_ENABLE(disallowing-of-undefined-references,
 931   [AS_HELP_STRING([--enable-disallowing-of-undefined-references],
 932                   [Use -Wl,--no-undefined flag during linking of some libraries to disallow undefined references])])
 933 if test "$enable_disallowing_of_undefined_references" != "yes" && test "`uname`" != "Linux"; then
 934   enable_disallowing_of_undefined_references="no"
 935 fi
 936 if test "$enable_disallowing_of_undefined_references" != "no"; then
 937   AC_MSG_CHECKING([for -Wl,--no-undefined])
 938   old_LDFLAGS="$LDFLAGS"
 939   LDFLAGS="$LDFLAGS -Wl,--no-undefined"
 940   AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(){;}]])], [svn_wl_no_undefined="yes"], [svn_wl_no_undefined="no"])
 941   LDFLAGS="$old_LDFLAGS"
 942   if test "$svn_wl_no_undefined" = "yes"; then
 943     AC_MSG_RESULT([yes])
 944     for library_dir in "$abs_srcdir/subversion/libsvn_"*; do
 945       eval "`basename $library_dir`_LDFLAGS=-Wl,--no-undefined"
 946     done
 947   else
 948     AC_MSG_RESULT([no])
 949     if test "$enable_disallowing_of_undefined_references" = "yes"; then
 950       AC_MSG_ERROR([--enable-disallowing-of-undefined-references explicitly requested, but -Wl,--no-undefined not supported])
 951     fi
 952   fi
 953 fi
 954 AC_SUBST([libsvn_auth_gnome_keyring_LDFLAGS])
 955 AC_SUBST([libsvn_auth_kwallet_LDFLAGS])
 956 AC_SUBST([libsvn_client_LDFLAGS])
 957 AC_SUBST([libsvn_delta_LDFLAGS])
 958 AC_SUBST([libsvn_diff_LDFLAGS])
 959 AC_SUBST([libsvn_fs_LDFLAGS])
 960 AC_SUBST([libsvn_fs_base_LDFLAGS])
 961 AC_SUBST([libsvn_fs_fs_LDFLAGS])
 962 AC_SUBST([libsvn_fs_util_LDFLAGS])
 963 AC_SUBST([libsvn_ra_LDFLAGS])
 964 AC_SUBST([libsvn_ra_local_LDFLAGS])
 965 AC_SUBST([libsvn_ra_serf_LDFLAGS])
 966 AC_SUBST([libsvn_ra_svn_LDFLAGS])
 967 AC_SUBST([libsvn_repos_LDFLAGS])
 968 AC_SUBST([libsvn_subr_LDFLAGS])
 969 AC_SUBST([libsvn_wc_LDFLAGS])
 970
 971
 972 AC_ARG_ENABLE(maintainer-mode,
 973 AS_HELP_STRING([--enable-maintainer-mode],
 974                [Turn on debugging and very strict compile-time warnings]),
 975 [
 976     if test "$enableval" = "yes" ; then
 977       if test "$enable_debugging" = "no" ; then
 978         AC_MSG_ERROR([Can't have --disable-debug and --enable-maintainer-mode])
 979       fi
 980       enable_debugging=yes
 981
 982       dnl Enable some extra warnings. Put these before the user's flags
 983       dnl so the user can specify flags that override these.
 984       if test "$GCC" = "yes"; then
 985         AC_MSG_NOTICE([maintainer-mode: adding GCC warning flags])
 986
 987         dnl some additional flags that can be handy for an occasional review,
 988         dnl but throw too many warnings in svn code, of too little importance,
 989         dnl to keep these enabled. Remove the "dnl" to do a run with these
 990         dnl switches enabled.
 991         dnl ./configure CUSERFLAGS="-Wswitch-enum -Wswitch-default"
 992
 993         dnl Add each of the following flags only if the C compiler accepts it.
 994         CFLAGS_KEEP="$CFLAGS"
 995         CFLAGS=""
 996
 997         SVN_CFLAGS_ADD_IFELSE([-Werror=implicit-function-declaration])
 998         SVN_CFLAGS_ADD_IFELSE([-Werror=declaration-after-statement])
 999         SVN_CFLAGS_ADD_IFELSE([-Wextra-tokens])
1000         SVN_CFLAGS_ADD_IFELSE([-Wnewline-eof])
1001         SVN_CFLAGS_ADD_IFELSE([-Wshorten-64-to-32])
1002         SVN_CFLAGS_ADD_IFELSE([-Wold-style-definition])
1003         SVN_CFLAGS_ADD_IFELSE([-Wno-system-headers])
1004         SVN_CFLAGS_ADD_IFELSE([-Wno-format-nonliteral])
1005
1006         CMAINTAINERFLAGS="$CFLAGS $CMAINTAINERFLAGS"
1007         CFLAGS="$CFLAGS_KEEP"
1008
1009         dnl Add flags that all versions of GCC (should) support
1010         CMAINTAINERFLAGS="-Wall -Wpointer-arith -Wwrite-strings -Wshadow -Wformat=2 -Wunused -Waggregate-return -Wstrict-prototypes -Wmissing-prototypes -Wmissing-declarations -Wno-multichar -Wredundant-decls -Wnested-externs -Winline -Wno-long-long $CMAINTAINERFLAGS"
1011       fi
1012       if test "$GXX" = "yes"; then
1013         AC_MSG_NOTICE([maintainer-mode: adding G++ warning flags])
1014
1015         dnl Add each of the following flags only if the C++ compiler accepts it.
1016         CXXFLAGS_KEEP="$CXXFLAGS"
1017         CXXFLAGS=""
1018
1019         SVN_CXXFLAGS_ADD_IFELSE([-Wextra-tokens])
1020         SVN_CXXFLAGS_ADD_IFELSE([-Wnewline-eof])
1021         SVN_CXXFLAGS_ADD_IFELSE([-Wshorten-64-to-32])
1022         SVN_CXXFLAGS_ADD_IFELSE([-Wno-system-headers])
1023
1024         CXXMAINTAINERFLAGS="$CXXFLAGS $CXXMAINTAINERFLAGS"
1025         CXXFLAGS="$CXXFLAGS_KEEP"
1026
1027         dnl Add flags that all versions of G++ (should) support
1028         CXXMAINTAINERFLAGS="-Wall -Wpointer-arith -Wwrite-strings -Wshadow -Wunused -Wunreachable-code $CXXMAINTAINERFLAGS"
1029       fi
1030     fi
1031 ])
1032
1033 if test "$enable_debugging" = "yes" ; then
1034   dnl At the moment, we don't want optimization, because we're
1035   dnl debugging. Unless optiization was explicitly enabled.
1036   if test "$enable_optimization" != "yes"; then
1037     AC_MSG_NOTICE([Disabling optimizations for debugging])
1038     CFLAGS=["`echo $CFLAGS' ' | $SED -e 's/-O[^ ]* //g'`"]
1039     CXXFLAGS=["`echo $CXXFLAGS' ' | $SED -e 's/-O[^ ]* //g'`"]
1040   fi
1041   dnl Add debugging flags, unless they were set by the user
1042   if test -z ["`echo $CUSERFLAGS' ' | $EGREP -- '-g[0-9]? '`"]; then
1043     AC_MSG_NOTICE([Enabling debugging for C])
1044     CFLAGS=["`echo $CFLAGS' ' | $SED -e 's/-g[0-9] //g' -e 's/-g //g'`"]
1045     SVN_CFLAGS_ADD_IFELSE([-fno-inline])
1046     SVN_CFLAGS_ADD_IFELSE([-fno-omit-frame-pointer])
1047     SVN_CFLAGS_ADD_IFELSE([-g3],[],[
1048       SVN_CFLAGS_ADD_IFELSE([-g2],[],[
1049         SVN_CFLAGS_ADD_IFELSE([-g])])])
1050   fi
1051   if test -z ["`echo $CXXUSERFLAGS' ' | $EGREP -- '-g[0-9]? '`"]; then
1052     AC_MSG_NOTICE([Enabling debugging for C++])
1053     CXXFLAGS=["`echo $CXXFLAGS' ' | $SED -e 's/-g[0-9] //g' -e 's/-g //g'`"]
1054     SVN_CXXFLAGS_ADD_IFELSE([-fno-inline])
1055     SVN_CXXFLAGS_ADD_IFELSE([-fno-omit-frame-pointer])
1056     SVN_CXXFLAGS_ADD_IFELSE([-g3],[],[
1057       SVN_CXXFLAGS_ADD_IFELSE([-g2],[],[
1058         SVN_CXXFLAGS_ADD_IFELSE([-g])])])
1059   fi
1060   dnl SVN_DEBUG enables specific features for developer builds
1061   dnl AP_DEBUG enables specific (Apache) features for developer builds
1062   CFLAGS="$CFLAGS -DSVN_DEBUG -DAP_DEBUG"
1063   CXXFLAGS="$CXXFLAGS -DSVN_DEBUG -DAP_DEBUG"
1064 elif test "$enable_debugging" = "no" ; then
1065   AC_MSG_NOTICE([Disabling debugging])
1066   CFLAGS=["`echo $CFLAGS' ' | $SED -e 's/-g[0-9] //g' -e 's/-g //g'`"]
1067   CXXFLAGS=["`echo $CXXFLAGS' ' | $SED -e 's/-g[0-9] //g' -e 's/-g //g'`"]
1068   dnl Compile with NDEBUG to get rid of assertions
1069   CFLAGS="$CFLAGS -DNDEBUG"
1070   CXXFLAGS="$CXXFLAGS -DNDEBUG"
1071 # elif test "$enable_debugging" = "maybe" ; then
1072 #   # do nothing
1073 fi
1074
1075 if test "$enable_optimization" = "yes"; then
1076   dnl Add optimization flags, unless they were set by the user
1077   if test -z ["`echo $CUSERFLAGS' ' | $EGREP -- '-O[^ ]* '`"]; then
1078     CFLAGS=["`echo $CFLAGS' ' | $SED -e 's/-O[^ ]* //g'`"]
1079     if test "$enable_debugging" = "yes"; then
1080       AC_MSG_NOTICE([Enabling optimizations for C (with debugging enabled)])
1081       SVN_CFLAGS_ADD_IFELSE([-O1],[],[
1082         SVN_CFLAGS_ADD_IFELSE([-O])])
1083     else
1084       AC_MSG_NOTICE([Enabling optimizations for C])
1085       SVN_CFLAGS_ADD_IFELSE([-O3],[],[
1086         SVN_CFLAGS_ADD_IFELSE([-O2],[],[
1087           SVN_CFLAGS_ADD_IFELSE([-O1],[],[
1088             SVN_CFLAGS_ADD_IFELSE([-O])])])])
1089       SVN_CFLAGS_ADD_IFELSE([-Wno-clobbered])
1090       SVN_CFLAGS_ADD_IFELSE([-flto])
1091       SVN_CFLAGS_ADD_IFELSE([-fwhole-program])
1092     fi
1093   fi
1094   if test -z ["`echo $CXXUSERFLAGS' ' | $EGREP -- '-O[^ ]* '`"]; then
1095     CXXFLAGS=["`echo $CXXFLAGS' ' | $SED -e 's/-O[^ ]* //g'`"]
1096     if test "$enable_debugging" = "yes"; then
1097       AC_MSG_NOTICE([Enabling optimizations for C++ (with debugging enabled)])
1098       SVN_CXXFLAGS_ADD_IFELSE([-O1],[],[
1099         SVN_CXXFLAGS_ADD_IFELSE([-O])])
1100     else
1101       AC_MSG_NOTICE([Enabling optimizations for C++])
1102       SVN_CXXFLAGS_ADD_IFELSE([-O3],[],[
1103         SVN_CXXFLAGS_ADD_IFELSE([-O2],[],[
1104           SVN_CXXFLAGS_ADD_IFELSE([-O1],[],[
1105             SVN_CXXFLAGS_ADD_IFELSE([-O])])])])
1106       SVN_CXXFLAGS_ADD_IFELSE([-Wno-clobbered])
1107       SVN_CXXFLAGS_ADD_IFELSE([-flto])
1108       SVN_CXXFLAGS_ADD_IFELSE([-fwhole-program])
1109     fi
1110   fi
1111 elif test "$enable_optimization" = "no"; then
1112   dnl Remove all optimization flags
1113   AC_MSG_NOTICE([Disabling optimizations])
1114   CFLAGS=["`echo $CFLAGS' ' | $SED -e 's/-O[^ ]* //g'`"]
1115   CXXFLAGS=["`echo $CXXFLAGS' ' | $SED -e 's/-O[^ ]* //g'`"]
1116 # elif test "$enable_optimization" = "maybe" ; then
1117 #   # do nothing
1118 fi
1119
1120
1121 AC_ARG_ENABLE(full-version-match,
1122 AS_HELP_STRING([--disable-full-version-match],
1123                [Disable the full version match rules when checking
1124                 Subversion library compatibility.]),
1125 [
1126     if test "$enableval" = "no" ; then
1127       AC_MSG_NOTICE([Disabling svn full version matching])
1128       AC_DEFINE(SVN_DISABLE_FULL_VERSION_MATCH, 1,
1129                 [Defined if the full version matching rules are disabled])
1130     fi
1131 ])
1132
1133 AC_ARG_WITH(editor,
1134 AS_HELP_STRING([--with-editor=PATH],
1135                [Specify a default editor for the subversion client.]),
1136 [
1137
1138     if test "$withval" = "yes" ; then
1139       AC_MSG_ERROR([--with-editor requires an argument.])
1140     else
1141       SVN_CLIENT_EDITOR=$withval
1142       AC_DEFINE_UNQUOTED(SVN_CLIENT_EDITOR, "$SVN_CLIENT_EDITOR",
1143                          [The path of a default editor for the client.])
1144
1145     fi
1146
1147 ])
1148
1149 SVN_LIB_Z
1150
1151 MOD_ACTIVATION=""
1152 AC_ARG_ENABLE(mod-activation,
1153 AS_HELP_STRING([--enable-mod-activation],
1154                [Enable mod_dav_svn in httpd.conf]),
1155 [
1156     if test "$enableval" = "yes" ; then
1157       MOD_ACTIVATION="-a"
1158       AC_MSG_NOTICE([Enabling apache module activation])
1159     else
1160       AC_MSG_NOTICE([Disabling apache module activation])
1161     fi
1162 ])
1163 AC_SUBST(MOD_ACTIVATION)
1164
1165
1166
1167 AC_ARG_ENABLE(gcov,
1168 AC_HELP_STRING([--enable-gcov],
1169                [Turn on gcov coverage testing (GCC only).]),
1170 [
1171     if test "$enableval" = "yes" ; then
1172       dnl Probably other compilers support something similar;
1173       dnl feel free to extend this to include them.
1174       if test "$GCC" = "yes"; then
1175         if test "$svn_enable_shared" = "yes" ; then
1176           AC_MSG_ERROR([Can't have --enable-gcov without --disable-shared (we
1177                         recommend also using --enable-all-static).])
1178         fi
1179         if test ! "$enable_all_static" = "yes" ; then
1180           AC_MSG_WARN(We recommend --enable-all-static with --enable-gcov.)
1181         fi
1182         AC_MSG_NOTICE([Enabling gcov coverage testing.])
1183         CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
1184         CXXFLAGS="$CXXFLAGS -fprofile-arcs -ftest-coverage"
1185       else
1186         AC_MSG_ERROR([We only support --enable-gcov with GCC right now.])
1187       fi
1188     fi
1189 ])
1190
1191 AC_ARG_ENABLE(gprof,
1192 AS_HELP_STRING([--enable-gprof],
1193                [Produce gprof profiling data in 'gmon.out' (GCC only).]),
1194 [
1195     if test "$enableval" = "yes" ; then
1196       dnl Probably other compilers support -pg or something similar;
1197       dnl feel free to extend this to include them.
1198       if test "$GCC" = "yes"; then
1199         if test "$svn_enable_shared" = "yes" ; then
1200           AC_MSG_ERROR([Can't have --enable-gprof without --disable-shared (we
1201                         recommend also using --enable-all-static).])
1202         fi
1203         if test ! "$enable_all_static" = "yes" ; then
1204           AC_MSG_WARN(We recommend --enable-all-static with --enable-gprof.)
1205         fi
1206         AC_MSG_NOTICE([Enabling gprof profiling data (to gmon.out).])
1207         CFLAGS="$CFLAGS -pg"
1208         CXXFLAGS="$CXXFLAGS -pg"
1209         LT_LDFLAGS="$LT_LDFLAGS -pg"
1210       else
1211         AC_MSG_ERROR([We only support --enable-gprof with GCC right now.])
1212       fi
1213     fi
1214 ])
1215
1216
1217 # Scripting and Bindings languages
1218
1219 # Python: Used for testsuite, and bindings
1220
1221
1222 PYTHON="`$abs_srcdir/build/find_python.sh`"
1223 if test -z "$PYTHON"; then
1224   AC_MSG_WARN([Python 2.5 or later is required to run the testsuite])
1225   AC_MSG_WARN([or to use the Subversion Python bindings])
1226   AC_MSG_WARN([])
1227   AC_MSG_WARN([If you have a suitable Python installed, but not on the])
1228   AC_MSG_WARN([PATH, set the environment variable PYTHON to the full path])
1229   AC_MSG_WARN([to the Python executable, and re-run configure])
1230 fi
1231 AC_PATH_PROGS(PYTHON, "$PYTHON", none)
1232
1233 # The minimum version for the JVM runtime for our Java bytecode.
1234 JAVA_OLDEST_WORKING_VER='1.5'
1235 # SVN_CHECK_JDK sets $JAVA_CLASSPATH
1236 SVN_CHECK_JDK($JAVA_OLDEST_WORKING_VER)
1237
1238 AC_PATH_PROG(PERL, perl, none)
1239
1240 if test -n "$RUBY"; then
1241   AC_PATH_PROG(RUBY, "$RUBY", none)
1242 else
1243   AC_PATH_PROGS(RUBY, ruby ruby1.8 ruby18 ruby1.9 ruby1 ruby1.9.3 ruby193, none)
1244 fi
1245 if test "$RUBY" != "none"; then
1246   AC_MSG_CHECKING([rb_hash_foreach])
1247   if "$RUBY" -r mkmf -e 'exit(have_func("rb_hash_foreach") ? 0 : 1)' >/dev/null; then
1248     AC_MSG_RESULT([yes])
1249     if test -n "$RDOC"; then
1250       AC_PATH_PROG(RDOC, "$RDOC", none)
1251     else
1252       AC_PATH_PROGS(RDOC, rdoc rdoc1.8 rdoc18 rdoc1.9 rdoc19 rdoc1.9.3 rdoc193, none)
1253     fi
1254     AC_CACHE_CHECK([for Ruby major version], [svn_cv_ruby_major],[
1255     svn_cv_ruby_major="`$RUBY -rrbconfig -e 'print RbConfig::CONFIG.fetch(%q(MAJOR))'`"
1256     ])
1257     RUBY_MAJOR="$svn_cv_ruby_major"
1258
1259     AC_CACHE_CHECK([for Ruby minor version], [svn_cv_ruby_minor],[
1260     svn_cv_ruby_minor="`$RUBY -rrbconfig -e 'print RbConfig::CONFIG.fetch(%q(MINOR))'`"
1261     ])
1262     RUBY_MINOR="$svn_cv_ruby_minor"
1263
1264     AC_CACHE_CHECK([for Ruby teeny version], [svn_cv_ruby_teeny],[
1265     svn_cv_ruby_teeny="`$RUBY -rrbconfig -e 'major, minor, teeny = RUBY_VERSION.split("."); print teeny;'`"
1266     ])
1267     RUBY_TEENY="$svn_cv_ruby_teeny"
1268
1269     AC_SUBST(RUBY_MAJOR)
1270     AC_SUBST(RUBY_MINOR)
1271     AC_SUBST(RUBY_TEENY)
1272     if test \( "$RUBY_MAJOR" -eq "1" -a "$RUBY_MINOR" -gt "8" -a "$RUBY_TEENY" -lt "3" \); then
1273       # Disallow Ruby between 1.8.7 and 1.9.3
1274       RUBY="none"
1275       AC_MSG_WARN([The detected Ruby is between 1.9 and 1.9.3])
1276       AC_MSG_WARN([Only 1.8.x and 1.9.3 releases are supported at this time])
1277     elif test \(  "$RUBY_MAJOR" -eq "1" -a "$RUBY_MINOR" -eq "9" -a "$RUBY_TEENY" -eq "3" \); then
1278       #Warn about 1.9.3 support
1279       AC_MSG_WARN([WARNING: The detected Ruby is 1.9.3])
1280       AC_MSG_WARN([WARNING: Only 1.8.x releases are fully supported, 1.9.3 support is new])
1281     fi
1282   else
1283     AC_MSG_RESULT([no])
1284     RUBY="none"
1285     AC_MSG_WARN([The detected Ruby is too old for Subversion to use])
1286     AC_MSG_WARN([A Ruby which has rb_hash_foreach is required to use the])
1287     AC_MSG_WARN([Subversion Ruby bindings])
1288     AC_MSG_WARN([Upgrade to the official 1.8.2 release, or later])
1289   fi
1290 fi
1291
1292 SVN_CHECK_SWIG
1293
1294 SVN_CHECK_CTYPESGEN
1295
1296 dnl decide whether we want to link against the RA/FS libraries
1297 AC_ARG_ENABLE(runtime-module-search,
1298 AS_HELP_STRING([--enable-runtime-module-search],
1299                [Turn on dynamic loading of RA/FS libraries including
1300                 third-party FS libraries]),
1301 [
1302     if test "$enableval" = "yes"; then
1303       use_dso=yes
1304       if test "$svn_enable_shared" = "no"; then
1305         AC_MSG_ERROR([--enable-runtime-module-search conflicts with --disable-shared])
1306       fi
1307       AC_DEFINE(SVN_USE_DSO, 1,
1308                 [Defined if svn should try to load DSOs])
1309     fi
1310 ])
1311
1312 if test "$svn_enable_shared" = "no" || test "$use_dso" != "yes"; then
1313   AC_DEFINE(SVN_LIBSVN_CLIENT_LINKS_RA_LOCAL, 1,
1314       [Defined if libsvn_client should link against libsvn_ra_local])
1315   svn_ra_lib_deps="\$(RA_LOCAL_DEPS)"
1316   svn_ra_lib_install_deps="install-ramod-lib"
1317   svn_ra_lib_link="\$(RA_LOCAL_LINK)"
1318
1319   AC_DEFINE(SVN_LIBSVN_CLIENT_LINKS_RA_SVN, 1,
1320       [Defined if libsvn_client should link against libsvn_ra_svn])
1321   svn_ra_lib_deps="$svn_ra_lib_deps \$(RA_SVN_DEPS)"
1322   svn_ra_lib_link="$svn_ra_lib_link \$(RA_SVN_LINK)"
1323
1324   if test "$svn_lib_serf" = "yes"; then
1325     AC_DEFINE(SVN_LIBSVN_CLIENT_LINKS_RA_SERF, 1,
1326           [Defined if libsvn_client should link against libsvn_ra_serf])
1327     svn_ra_lib_deps="$svn_ra_lib_deps \$(RA_SERF_DEPS)"
1328     svn_ra_lib_install_deps="$svn_ra_lib_install_deps install-serf-lib"
1329     svn_ra_lib_link="$svn_ra_lib_link \$(RA_SERF_LINK)"
1330   fi
1331
1332   SVN_RA_LIB_DEPS=$svn_ra_lib_deps
1333   SVN_RA_LIB_INSTALL_DEPS=$svn_ra_lib_install_deps
1334   SVN_RA_LIB_LINK=$svn_ra_lib_link
1335
1336   AC_DEFINE(SVN_LIBSVN_FS_LINKS_FS_FS, 1,
1337       [Defined if libsvn_fs should link against libsvn_fs_fs])
1338   svn_fs_lib_deps="\$(FS_FS_DEPS)"
1339   svn_fs_lib_install_deps="install-fsmod-lib"
1340   svn_fs_lib_link="\$(FS_FS_LINK)"
1341
1342   if test "$svn_lib_berkeley_db" = "yes"; then
1343   AC_DEFINE(SVN_LIBSVN_FS_LINKS_FS_BASE, 1,
1344       [Defined if libsvn_fs should link against libsvn_fs_base])
1345     svn_fs_lib_deps="$svn_fs_lib_deps \$(FS_BASE_DEPS)"
1346     svn_fs_lib_install_deps="$svn_fs_lib_install_deps install-bdb-lib"
1347     svn_fs_lib_link="$svn_fs_lib_link \$(FS_BASE_LINK)"
1348   fi
1349
1350   SVN_FS_LIB_DEPS=$svn_fs_lib_deps
1351   SVN_FS_LIB_INSTALL_DEPS=$svn_fs_lib_install_deps
1352   SVN_FS_LIB_LINK=$svn_fs_lib_link
1353 fi
1354
1355 AC_SUBST(SVN_RA_LIB_DEPS)
1356 AC_SUBST(SVN_RA_LIB_INSTALL_DEPS)
1357 AC_SUBST(SVN_RA_LIB_LINK)
1358 AC_SUBST(SVN_FS_LIB_DEPS)
1359 AC_SUBST(SVN_FS_LIB_INSTALL_DEPS)
1360 AC_SUBST(SVN_FS_LIB_LINK)
1361
1362 # ==== JavaHL ================================================================
1363
1364 dnl Possibly compile JavaHL
1365 do_javahl_build=no
1366 AC_ARG_ENABLE(javahl,
1367   AS_HELP_STRING([--enable-javahl],
1368              [Enable compilation of Java high-level bindings (requires C++)]),
1369   [ if test "$enableval" = "yes" ; then
1370         do_javahl_build="yes"
1371     fi
1372   ])
1373
1374 JAVAHL_OBJDIR=""
1375 INSTALL_EXTRA_JAVAHL_LIB=""
1376 FIX_JAVAHL_LIB=""
1377 JAVAHL_TESTS_TARGET=""
1378 JAVAHL_COMPAT_TESTS_TARGET=""
1379 LT_CXX_LIBADD=""
1380 if test "$do_javahl_build" = "yes"; then
1381   dnl Check for suitable JDK
1382   if test "$JDK_SUITABLE" = "no"; then
1383     AC_MSG_ERROR([Cannot compile JavaHL without a suitable JDK.
1384                   Please specify a suitable JDK using the --with-jdk option.])
1385   fi
1386
1387   dnl The temporary directory where libtool compiles libsvnjavahl.
1388   JAVAHL_OBJDIR='$(libsvnjavahl_PATH)/.libs'
1389
1390   os_arch=`uname`
1391   if test "$os_arch" = "Darwin"; then
1392     dnl On Darwin, JNI libs must be installed as .jnilib
1393     INSTALL_EXTRA_JAVAHL_LIB='ln -sf $(libdir)/libsvnjavahl-1.dylib $(libdir)/libsvnjavahl-1.jnilib'
1394     FIX_JAVAHL_LIB="ln -sf libsvnjavahl-1.dylib $JAVAHL_OBJDIR/libsvnjavahl-1.jnilib"
1395   fi
1396   # This segment (and the rest of r10800) is very likely unnecessary
1397   # with libtool 1.5, which automatically adds libstdc++ as a
1398   # dependency to the C++ libraries it builds.  So at some future time
1399   # when autogen.sh requires libtool 1.5 or higher, we can get rid of
1400   # it.
1401   AC_MSG_CHECKING([for additional flags to link C++ libraries])
1402   if test "x$ac_compiler_gnu" = "xyes"; then
1403     LT_CXX_LIBADD="-lstdc++"
1404     AC_MSG_RESULT([$LT_CXX_LIBADD])
1405   else
1406     AC_MSG_RESULT([none needed])
1407   fi
1408 fi
1409 AC_SUBST(INSTALL_EXTRA_JAVAHL_LIB)
1410 AC_SUBST(JAVAHL_OBJDIR)
1411 AC_SUBST(FIX_JAVAHL_LIB)
1412 AC_SUBST(LT_CXX_LIBADD)
1413
1414 AC_ARG_WITH(junit,
1415 AS_HELP_STRING([--with-junit=PATH],
1416                [Specify a path to the junit JAR file.]),
1417 [
1418     if test "$withval" != "no"; then
1419       if test -n "$JAVA_CLASSPATH"; then
1420         JAVA_CLASSPATH="$withval:$JAVA_CLASSPATH"
1421       else
1422         JAVA_CLASSPATH="$withval"
1423       fi
1424       JAVAHL_TESTS_TARGET="javahl-tests"
1425       JAVAHL_COMPAT_TESTS_TARGET="javahl-compat-tests"
1426     fi
1427 ])
1428 AC_SUBST(JAVA_CLASSPATH)
1429 AC_SUBST(JAVAHL_TESTS_TARGET)
1430 AC_SUBST(JAVAHL_COMPAT_TESTS_TARGET)
1431
1432 # ==== Miscellaneous bits ====================================================
1433
1434 # Strip '-no-cpp-precomp' from CPPFLAGS for the clang compiler
1435 ### I think we get this flag from APR, so the fix probably belongs there
1436 if test "$CC" = "clang"; then
1437   SVN_STRIP_FLAG(CPPFLAGS, [-no-cpp-precomp ])
1438 fi
1439
1440 dnl Since this is used only on Unix-y systems, define the path separator as '/'
1441 AC_DEFINE_UNQUOTED(SVN_PATH_LOCAL_SEPARATOR, '/',
1442         [Defined to be the path separator used on your local filesystem])
1443
1444 AC_DEFINE_UNQUOTED(SVN_NULL_DEVICE_NAME, "/dev/null",
1445         [Defined to be the null device for the system])
1446
1447 DEFAULT_FS_TYPE="fsfs"
1448 AC_DEFINE_UNQUOTED(DEFAULT_FS_TYPE, "$DEFAULT_FS_TYPE",
1449                    [The fs type to use by default])
1450
1451 DEFAULT_HTTP_LIBRARY="serf"
1452 AC_DEFINE_UNQUOTED(DEFAULT_HTTP_LIBRARY, "$DEFAULT_HTTP_LIBRARY",
1453                    [The http library to use by default])
1454
1455 # BSD/OS (BSDi) needs to use a different include syntax in Makefile
1456 INCLUDE_OUTPUTS="include \$(top_srcdir)/build-outputs.mk"
1457 case "$host" in
1458   *bsdi*)
1459     # Check whether they've installed GNU make
1460     if ! make --version > /dev/null 2>&1; then
1461       # BSDi make
1462       INCLUDE_OUTPUTS=".include \"\$(top_srcdir)/build-outputs.mk\""
1463     fi
1464     ;;
1465 esac
1466 AC_SUBST(INCLUDE_OUTPUTS)
1467
1468 # ==== Detection complete - output and run config.status =====================
1469
1470 AC_CONFIG_HEADERS(subversion/svn_private_config.h.tmp:subversion/svn_private_config.h.in)
1471 AC_CONFIG_COMMANDS([svn_private_config.h.tmp],
1472                    [svn_cf=subversion/svn_private_config.h;
1473                     $SED -e "s/@SVN_DB_HEADER@/$SVN_DB_HEADER/" $svn_cf.tmp > $svn_cf.tmp.new
1474                     cmp -s $svn_cf.tmp.new $svn_cf || mv -f $svn_cf.tmp.new $svn_cf
1475                     rm -f $svn_cf.tmp.new $svn_cf.tmp],
1476                    [SED="$SED"
1477                     SVN_DB_HEADER="$SVN_DB_HEADER"])
1478 AC_CONFIG_FILES([Makefile])
1479
1480 SVN_CONFIG_SCRIPT(tools/backup/hot-backup.py)
1481 SVN_CONFIG_SCRIPT(tools/hook-scripts/commit-access-control.pl)
1482 SVN_CONFIG_SCRIPT(subversion/bindings/swig/perl/native/Makefile.PL)
1483 if test -e packages/solaris/pkginfo.in; then
1484   SVN_CONFIG_SCRIPT(packages/solaris/pkginfo)
1485 fi
1486 AC_SUBST(SVN_CONFIG_SCRIPT_FILES)
1487
1488 # Ensure that SWIG is checked after reconfiguration.
1489 rm -f .swig_checked
1490
1491 dnl Provide ${host} for use in compiled code (for svn --version)
1492 AC_DEFINE_UNQUOTED([SVN_BUILD_HOST], "${host}",
1493                    [Defined to the config.guess name of the build system])
1494
1495 dnl Provide ${target} for use in compiled code (for user-agent string)
1496 AC_DEFINE_UNQUOTED([SVN_BUILD_TARGET], "${target}",
1497                    [Defined to the config.guess name of the build target])
1498
1499 AC_OUTPUT
1500
1501 # ==== Print final messages to user ==========================================
1502
1503 dnl Configure is long - users tend to miss warnings printed during it.
1504 dnl Hence, print a warnings about what we did and didn't configure at the
1505 dnl end, where people will actually see them.
1506
1507 if test "$svn_lib_berkeley_db" = "no" && test "$with_berkeley_db" != "no"; then
1508   db_version="$SVN_FS_WANT_DB_MAJOR.$SVN_FS_WANT_DB_MINOR.$SVN_FS_WANT_DB_PATCH"
1509   AC_MSG_WARN([we have configured without BDB filesystem support
1510
1511
1512 You don't seem to have Berkeley DB version $db_version or newer
1513 installed and linked to APR-UTIL.  We have created a Makefile which will build
1514 Subversion without support for the Berkeley DB back-end.  You can find the
1515 latest version of Berkeley DB here:
1516
1517   http://www.oracle.com/technetwork/products/berkeleydb/downloads/index.html
1518
1519 or explicitly specify --without-berkeley-db to silence this warning.
1520 ])
1521 fi