contrib/tcpdump/CMakeLists.txt

   1 if(WIN32)
   2     #
   3     # We need 3.12 or later, so that we can set policy CMP0074; see
   4     # below.
   5     cmake_minimum_required(VERSION 3.12)
   6 else(WIN32)
   7     #
   8     # For now, require only 2.8.6, just in case somebody is
   9     # configuring with CMake on a "long-term support" version
  10     # of some OS and that version supplies an older version of
  11     # CMake.
  12     #
  13     # If this is ever updated to CMake 3.1 or later, remove the
  14     # stuff in cmake/Modules/FindPCAP.cmake that appends subdirectories
  15     # of directories from CMAKE_PREFIX_PATH to the PKG_CONFIG_PATH
  16     # environment variable when running pkg-config, to make sure
  17     # it finds any .pc file from there.
  18     #
  19     cmake_minimum_required(VERSION 2.8.12)
  20 endif(WIN32)
  21
  22 #
  23 # We want find_path() and find_library() to honor {packagename}_ROOT,
  24 # as that appears to be the standard way to say "hey, look here for
  25 # this package" from the command line.
  26 #
  27 if(POLICY CMP0074)
  28     cmake_policy(SET CMP0074 NEW)
  29 endif()
  30
  31 #
  32 # OK, this is a pain.
  33 #
  34 # When building on NetBSD, with a libpcap installed from pkgsrc,
  35 # a -Wl,-rpath,/usr/pkg/lib option is added to the options when
  36 # linking tcpdump.  This puts /usr/pkg/lib into the run-time path.
  37 #
  38 # However, by default, CMake adds a rule to the install CMake script
  39 # a CMake command (using an undocumented subcommand of file()) that
  40 # strips /usr/pkg/lib *out* of the run-time path; the message in the
  41 # output for the "install" target is
  42 #
  43 #    -- Set runtime path of "{target-directory}/tcpdump" to ""
  44 #
  45 # I am not certain what the rationale is for doing this, but a
  46 # *consequence* of this is that, when you run the installed tcpdump,
  47 # it fails to find libpcap.so:
  48 #
  49 #    $ {target-directory}/tcpdump -h
  50 #    {target-directory}/tcpdump: Shared object "libpcap.so.0" not found
  51 #
  52 # It also appears to be the case that, on Ubuntu 22.04, FreeBSD 12,
  53 # DragonFly BSD 5.8, OpenBSD 6.6, and Solaris 11.4,
  54 #
  55 # On Ubuntu and Solaris, even if you have a libpcap in /usr/local, you
  56 # have to provide not only -I/usr/local/include and -L/usr/local/lib,
  57 # you also must provide -Wl,-rpath,/usr/local/lib in order to have
  58 # the run-time linker look in /usr/local/lib for libpcap.  If it's not
  59 # specified, then, if the shared library major version number of the
  60 # libpcap in /usr/lib is the same as the shared major version number
  61 # of the libpcap in /usr/local/lib, the run-time linker will find the
  62 # libpcap in /usr/lib; if the versions are different, the run-time
  63 # linker will fail to find the libpcap in /usr/lib, so the program will
  64 # fail to run.
  65 #
  66 # We suppress this by setting CMAKE_INSTALL_RPATH_USE_LINK_PATH to TRUE;
  67 # as the documentation for that variable says:
  68 #
  69 #    Add paths to linker search and installed rpath.
  70 #
  71 #    CMAKE_INSTALL_RPATH_USE_LINK_PATH is a boolean that if set to True
  72 #    will append to the runtime search path (rpath) of installed
  73 #    binaries any directories outside the project that are in the linker
  74 #    search path or contain linked library files. The directories are
  75 #    appended after the value of the INSTALL_RPATH target property.
  76 #
  77 # If, for whatever reason, directories in which we search for external
  78 # libraries, other than the standard system library directories, are
  79 # added to the executable's rpath in the build process, we most
  80 # defintely want them in the installed image's rpath if they are
  81 # necessary in order to find the libraries at run time.
  82 #
  83 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  84
  85 set(CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/Modules)
  86
  87 #
  88 # OK, this is a royal pain.
  89 #
  90 # CMake will try to determine the sizes of some data types, including
  91 # void *, early in the process of configuration; apparently, it's done
  92 # as part of processing the project() command.
  93 #
  94 # At least as of CMake 2.8.6, it does so by checking the size of
  95 # "void *" in C, setting CMAKE_C_SIZEOF_DATA_PTR based on that,
  96 # setting CMAKE_SIZEOF_VOID_P to that, and then checking the size
  97 # of "void *" in C++, setting CMAKE_CXX_SIZEOF_DATA_PTR based on
  98 # that, and then setting CMAKE_SIZEOF_VOID_P to *that*.
  99 #
 100 # The compile tests include whatever C flags may have been provided
 101 # to CMake in the CFLAGS and CXXFLAGS environment variables.
 102 #
 103 # If you set an architecture flag such as -m32 or -m64 in CFLAGS
 104 # but *not* in CXXFLAGS, the size for C++ will win, and hilarity
 105 # will ensue.
 106 #
 107 # Or if, at least on Solaris, you have a newer version of GCC
 108 # installed, but *not* a newer version of G++, and you have Oracle
 109 # Studio installed, it will find GCC, which will default to building
 110 # 64-bit, and Oracle Studio's C++ compiler, which will default to
 111 # building 32-bit, the size for C++ will win, and, again, hilarity
 112 # will ensue.
 113 #
 114 # So we *explicitly* state that only C is used; there is currently no
 115 # C++ code in tcpdump.
 116 #
 117 project(tcpdump C)
 118
 119 #
 120 # For checking if a compiler flag works and adding it if it does.
 121 #
 122 include(CheckCCompilerFlag)
 123 macro(check_and_add_compiler_option _option)
 124     message(STATUS "Checking C compiler flag ${_option}")
 125     string(REPLACE "=" "-" _temp_option_variable ${_option})
 126     string(REGEX REPLACE "^-" "" _option_variable ${_temp_option_variable})
 127     check_c_compiler_flag("${_option}" ${_option_variable})
 128     if(${${_option_variable}})
 129         set(C_ADDITIONAL_FLAGS "${C_ADDITIONAL_FLAGS} ${_option}")
 130     endif()
 131 endmacro()
 132
 133 #
 134 # If we're building with Visual Studio, we require Visual Studio 2015,
 135 # in order to get sufficient C99 compatibility.  Check for that.
 136 #
 137 # If not, try the appropriate flag for the compiler to enable C99
 138 # features.
 139 #
 140 set(C_ADDITIONAL_FLAGS "")
 141 if(MSVC)
 142     if(MSVC_VERSION LESS 1900)
 143         message(FATAL_ERROR "Visual Studio 2015 or later is required")
 144     endif()
 145
 146     #
 147     # Treat source files as being in UTF-8 with MSVC if it's not using
 148     # the Clang front end.
 149     # We assume that UTF-8 source is OK with other compilers and with
 150     # MSVC if it's using the Clang front end.
 151     #
 152     if(NOT ${CMAKE_C_COMPILER} MATCHES "clang*")
 153         set(C_ADDITIONAL_FLAGS "${C_ADDITIONAL_FLAGS} /utf-8")
 154     endif(NOT ${CMAKE_C_COMPILER} MATCHES "clang*")
 155 else(MSVC)
 156     #
 157     # Try to enable as many C99 features as we can.
 158     # At minimum, we want C++/C99-style // comments.
 159     #
 160     # Newer versions of compilers might default to supporting C99, but
 161     # older versions may require a special flag.
 162     #
 163     # Prior to CMake 3.1, setting CMAKE_C_STANDARD will not have any effect,
 164     # so, unless and until we require CMake 3.1 or later, we have to do it
 165     # ourselves on pre-3.1 CMake, so we just do it ourselves on all versions
 166     # of CMake.
 167     #
 168     # Note: with CMake 3.1 through 3.5, the only compilers for which CMake
 169     # handles CMAKE_C_STANDARD are GCC and Clang.  3.6 adds support only
 170     # for Intel C; 3.9 adds support for PGI C, Sun C, and IBM XL C, and
 171     # 3.10 adds support for Cray C and IAR C, but no version of CMake has
 172     # support for HP C.  Therefore, even if we use CMAKE_C_STANDARD with
 173     # compilers for which CMake supports it, we may still have to do it
 174     # ourselves on other compilers.
 175     #
 176     # See the CMake documentation for the CMAKE_<LANG>_COMPILER_ID variables
 177     # for a list of compiler IDs.
 178     #
 179     # XXX - this just tests whether the option works and adds it if it does.
 180     # We don't test whether it's necessary in order to get the C99 features
 181     # that we use; if we ever have a user who tries to compile with a compiler
 182     # that can't be made to support those features, we can add a test to make
 183     # sure we actually *have* C99 support.
 184     #
 185     if(CMAKE_C_COMPILER_ID MATCHES "GNU" OR
 186        CMAKE_C_COMPILER_ID MATCHES "Clang")
 187         check_and_add_compiler_option("-std=gnu99")
 188     elseif(CMAKE_C_COMPILER_ID MATCHES "XL")
 189         #
 190         # We want support for extensions picked up for GNU C compatibility,
 191         # so we use -qlanglvl=extc99.
 192         #
 193         check_and_add_compiler_option("-qlanglvl=extc99")
 194     elseif(CMAKE_C_COMPILER_ID MATCHES "HP")
 195         check_and_add_compiler_option("-AC99")
 196     elseif(CMAKE_C_COMPILER_ID MATCHES "Sun")
 197         check_and_add_compiler_option("-xc99")
 198     elseif(CMAKE_C_COMPILER_ID MATCHES "Intel")
 199         check_and_add_compiler_option("-c99")
 200     endif()
 201 endif(MSVC)
 202
 203 set(LIBRARY_NAME netdissect)
 204
 205 ###################################################################
 206 #   Parameters
 207 ###################################################################
 208
 209 option(WITH_SMI "Build with libsmi, if available" ON)
 210 option(WITH_CRYPTO "Build with OpenSSL/libressl libcrypto, if available" ON)
 211 option(WITH_CAPSICUM "Build with Capsicum security functions, if available" ON)
 212 option(WITH_CAP_NG "Use libcap-ng, if available" ON)
 213 option(ENABLE_SMB "Build with the SMB dissector" OFF)
 214
 215 #
 216 # String parameters.  Neither of them are set, initially; only if the
 217 # user explicitly configures them are they set.
 218 #
 219 # WITH_CHROOT is STRING, not PATH, as the directory need not exist
 220 # when CMake is run.
 221 #
 222 set(WITH_CHROOT CACHE STRING
 223     "Directory to which to chroot when dropping privileges")
 224 set(WITH_USER CACHE STRING
 225     "User to whom to set the UID when dropping privileges")
 226
 227 #
 228 # By default, build universal with the appropriate set of architectures
 229 # for the OS on which we're doing the build.
 230 #
 231 if(APPLE AND "${CMAKE_OSX_ARCHITECTURES}" STREQUAL "")
 232     #
 233     # Get the major version of Darwin.
 234     #
 235     string(REGEX MATCH "^([0-9]+)" SYSTEM_VERSION_MAJOR "${CMAKE_SYSTEM_VERSION}")
 236
 237     if(SYSTEM_VERSION_MAJOR EQUAL 9)
 238         #
 239         # Leopard.  Build for x86 and 32-bit PowerPC, with
 240         # x86 first.  (That's what Apple does.)
 241         #
 242         set(CMAKE_OSX_ARCHITECTURES "i386;ppc")
 243     elseif(SYSTEM_VERSION_MAJOR EQUAL 10)
 244         #
 245         # Snow Leopard.  Build for x86-64 and x86, with
 246         # x86-64 first.  (That's what Apple does.)
 247         #
 248         set(CMAKE_OSX_ARCHITECTURES "x86_64;i386")
 249     endif()
 250 endif()
 251
 252 ###################################################################
 253 #   Versioning
 254 ###################################################################
 255
 256 # Get, parse, format and set tcpdump's version string from
 257 # [tcpdump_root]/VERSION for later use.
 258
 259 # Get MAJOR, MINOR, PATCH & SUFFIX
 260 file(STRINGS ${tcpdump_SOURCE_DIR}/VERSION
 261     PACKAGE_VERSION
 262     LIMIT_COUNT 1 # Read only the first line
 263 )
 264
 265 ######################################
 266 # Project settings
 267 ######################################
 268
 269 add_definitions(-DHAVE_CONFIG_H)
 270
 271 include_directories(
 272     ${CMAKE_CURRENT_BINARY_DIR}
 273     ${tcpdump_SOURCE_DIR}
 274 )
 275
 276 if(MSVC)
 277     add_definitions(-D__STDC__)
 278     add_definitions(-D_CRT_SECURE_NO_WARNINGS)
 279 endif(MSVC)
 280
 281 if(MSVC)
 282     if (USE_STATIC_RT)
 283         MESSAGE(STATUS "Use STATIC runtime")
 284         set(NAME_RT MT)
 285         set (CMAKE_CXX_FLAGS_MINSIZEREL     "${CMAKE_CXX_FLAGS_MINSIZEREL} /MT")
 286         set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /MT")
 287         set (CMAKE_CXX_FLAGS_RELEASE        "${CMAKE_CXX_FLAGS_RELEASE} /MT")
 288         set (CMAKE_CXX_FLAGS_DEBUG          "${CMAKE_CXX_FLAGS_DEBUG} /MTd")
 289
 290         set (CMAKE_C_FLAGS_MINSIZEREL       "${CMAKE_C_FLAGS_MINSIZEREL} /MT")
 291         set (CMAKE_C_FLAGS_RELWITHDEBINFO   "${CMAKE_C_FLAGS_RELWITHDEBINFO} /MT")
 292         set (CMAKE_C_FLAGS_RELEASE          "${CMAKE_C_FLAGS_RELEASE} /MT")
 293         set (CMAKE_C_FLAGS_DEBUG            "${CMAKE_C_FLAGS_DEBUG} /MTd")
 294     else (USE_STATIC_RT)
 295         MESSAGE(STATUS "Use DYNAMIC runtime")
 296         set(NAME_RT MD)
 297         set (CMAKE_CXX_FLAGS_MINSIZEREL     "${CMAKE_CXX_FLAGS_MINSIZEREL} /MD")
 298         set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /MD")
 299         set (CMAKE_CXX_FLAGS_RELEASE        "${CMAKE_CXX_FLAGS_RELEASE} /MD")
 300         set (CMAKE_CXX_FLAGS_DEBUG          "${CMAKE_CXX_FLAGS_DEBUG} /MDd")
 301
 302         set (CMAKE_C_FLAGS_MINSIZEREL       "${CMAKE_C_FLAGS_MINSIZEREL} /MD")
 303         set (CMAKE_C_FLAGS_RELWITHDEBINFO   "${CMAKE_C_FLAGS_RELWITHDEBINFO} /MD")
 304         set (CMAKE_C_FLAGS_RELEASE          "${CMAKE_C_FLAGS_RELEASE} /MD")
 305         set (CMAKE_C_FLAGS_DEBUG            "${CMAKE_C_FLAGS_DEBUG} /MDd")
 306    endif (USE_STATIC_RT)
 307 endif(MSVC)
 308
 309 ###################################################################
 310 #   Detect available platform features
 311 ###################################################################
 312
 313 include(CMakePushCheckState)
 314 include(CheckIncludeFile)
 315 include(CheckIncludeFiles)
 316 include(CheckFunctionExists)
 317 include(CheckLibraryExists)
 318 include(CheckSymbolExists)
 319 include(CheckStructHasMember)
 320 include(CheckVariableExists)
 321 include(CheckTypeSize)
 322
 323 #
 324 # Header files.
 325 #
 326 check_include_file(fcntl.h HAVE_FCNTL_H)
 327 check_include_file(rpc/rpc.h HAVE_RPC_RPC_H)
 328 check_include_file(net/if.h HAVE_NET_IF_H)
 329 if(HAVE_RPC_RPC_H)
 330     check_include_files("rpc/rpc.h;rpc/rpcent.h" HAVE_RPC_RPCENT_H)
 331 endif(HAVE_RPC_RPC_H)
 332
 333 #
 334 # Functions.
 335 #
 336 check_function_exists(strlcat HAVE_STRLCAT)
 337 check_function_exists(strlcpy HAVE_STRLCPY)
 338 check_function_exists(strdup HAVE_STRDUP)
 339 check_function_exists(strsep HAVE_STRSEP)
 340
 341 #
 342 # Find library needed for gethostbyaddr.
 343 # NOTE: if you hand check_library_exists as its last argument a variable
 344 # that's been set, it skips the test, so we need different variables.
 345 #
 346 set(TCPDUMP_LINK_LIBRARIES "")
 347 if(WIN32)
 348     #
 349     # We need winsock2.h and ws2tcpip.h.
 350     #
 351     cmake_push_check_state()
 352     set(CMAKE_REQUIRED_LIBRARIES ws2_32)
 353     check_symbol_exists(gethostbyaddr "winsock2.h;ws2tcpip.h" LIBWS2_32_HAS_GETHOSTBYADDR)
 354     cmake_pop_check_state()
 355     if(LIBWS2_32_HAS_GETHOSTBYADDR)
 356         set(TCPDUMP_LINK_LIBRARIES ws2_32 ${TCPDUMP_LINK_LIBRARIES})
 357     else(LIBWS2_32_HAS_GETHOSTBYADDR)
 358         message(FATAL_ERROR "gethostbyaddr is required, but wasn't found")
 359     endif(LIBWS2_32_HAS_GETHOSTBYADDR)
 360 else(WIN32)
 361     check_function_exists(gethostbyaddr STDLIBS_HAVE_GETHOSTBYADDR)
 362     if(NOT STDLIBS_HAVE_GETHOSTBYADDR)
 363         check_library_exists(socket gethostbyaddr "" LIBSOCKET_HAS_GETHOSTBYADDR)
 364         if(LIBSOCKET_HAS_GETHOSTBYADDR)
 365             set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} socket)
 366         else(LIBSOCKET_HAS_GETHOSTBYADDR)
 367             check_library_exists(nsl gethostbyaddr "" LIBNSL_HAS_GETHOSTBYADDR)
 368             if(LIBNSL_HAS_GETHOSTBYADDR)
 369                 set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} nsl)
 370             else(LIBNSL_HAS_GETHOSTBYADDR)
 371                 message(FATAL_ERROR "gethostbyaddr is required, but wasn't found")
 372             endif(LIBNSL_HAS_GETHOSTBYADDR)
 373         endif(LIBSOCKET_HAS_GETHOSTBYADDR)
 374     endif(NOT STDLIBS_HAVE_GETHOSTBYADDR)
 375 endif(WIN32)
 376
 377 #
 378 # This may require additional libraries.
 379 #
 380 cmake_push_check_state()
 381 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES})
 382 check_function_exists(getservent STDLIBS_HAVE_GETSERVENT)
 383 if(STDLIBS_HAVE_GETSERVENT)
 384     set(HAVE_GETSERVENT TRUE)
 385 else(STDLIBS_HAVE_GETSERVENT)
 386     #
 387     # Some platforms may need -lsocket for getservent.
 388     #
 389     set(CMAKE_REQUIRED_LIBRARIES socket ${TCPDUMP_LINK_LIBRARIES})
 390     check_function_exists(getservent LIBSOCKET_HAS_GETSERVENT)
 391     if(LIBSOCKET_HAS_GETSERVENT)
 392         set(HAVE_GETSERVENT TRUE)
 393         set(TCPDUMP_LINK_LIBRARIES socket ${TCPDUMP_LINK_LIBRARIES})
 394     endif(LIBSOCKET_HAS_GETSERVENT)
 395 endif(STDLIBS_HAVE_GETSERVENT)
 396 cmake_pop_check_state()
 397
 398 #
 399 # Make sure we have vsnprintf() and snprintf(); we require them.
 400 # We use check_symbol_exists(), as they aren't necessarily external
 401 # functions - in Visual Studio, for example, they're inline functions
 402 # calling a common external function.
 403 #
 404 check_symbol_exists(vsnprintf "stdio.h" HAVE_VSNPRINTF)
 405 if(NOT HAVE_VSNPRINTF)
 406     message(FATAL_ERROR "vsnprintf() is required but wasn't found")
 407 endif(NOT HAVE_VSNPRINTF)
 408 check_symbol_exists(snprintf "stdio.h" HAVE_SNPRINTF)
 409 if(NOT HAVE_SNPRINTF)
 410     message(FATAL_ERROR "snprintf() is required but wasn't found")
 411 endif()
 412
 413 check_function_exists(getopt_long HAVE_GETOPT_LONG)
 414 check_function_exists(setlinebuf HAVE_SETLINEBUF)
 415 #
 416 # For Windows,  don't need to waste time checking for fork() or vfork().
 417 #
 418 if(NOT WIN32)
 419     check_function_exists(fork HAVE_FORK)
 420     check_function_exists(vfork HAVE_VFORK)
 421 endif(NOT WIN32)
 422
 423 #
 424 # Some platforms may need -lnsl for getrpcbynumber.
 425 #
 426 cmake_push_check_state()
 427 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES})
 428 check_function_exists(getrpcbynumber STDLIBS_HAVE_GETRPCBYNUMBER)
 429 if(STDLIBS_HAVE_GETRPCBYNUMBER)
 430     set(HAVE_GETRPCBYNUMBER TRUE)
 431 else(STDLIBS_HAVE_GETRPCBYNUMBER)
 432     set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} nsl)
 433     check_function_exists(getrpcbynumber LIBNSL_HAS_GETRPCBYNUMBER)
 434     if(LIBNSL_HAS_GETRPCBYNUMBER)
 435         set(HAVE_GETRPCBYNUMBER TRUE)
 436         set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} nsl)
 437     endif(LIBNSL_HAS_GETRPCBYNUMBER)
 438 endif(STDLIBS_HAVE_GETRPCBYNUMBER)
 439 cmake_pop_check_state()
 440
 441 #
 442 # This requires the libraries we require, as ether_ntohost might be
 443 # in one of those libraries.  That means we have to do this after
 444 # we check for those libraries.
 445 #
 446 # You are in a twisty little maze of UN*Xes, all different.
 447 # Some might not have ether_ntohost().
 448 # Some might have it and declare it in <net/ethernet.h>.
 449 # Some might have it and declare it in <netinet/ether.h>
 450 # Some might have it and declare it in <sys/ethernet.h>.
 451 # Some might have it and declare it in <arpa/inet.h>.
 452 # Some might have it and declare it in <netinet/if_ether.h>.
 453 # Some might have it and not declare it in any header file.
 454 #
 455 # Before you is a C compiler.
 456 #
 457 cmake_push_check_state()
 458 set(CMAKE_REQUIRED_LIBRARIES ${TCPDUMP_LINK_LIBRARIES})
 459 check_function_exists(ether_ntohost HAVE_ETHER_NTOHOST)
 460 if(HAVE_ETHER_NTOHOST)
 461     #
 462     # OK, we have ether_ntohost().  We don't check whether it's buggy,
 463     # as we assume any system that has CMake is likely to be new enough
 464     # that, if it has ether_ntohost(), whatever bug is checked for in
 465     # autotools is fixed; we just decide to use it.
 466     #
 467     set(USE_ETHER_NTOHOST TRUE)
 468
 469     #
 470     # Is it declared in <net/ethernet.h>?
 471     #
 472     # This test fails if we don't have <net/ethernet.h> or if we do
 473     # but it doesn't declare ether_ntohost().
 474     #
 475     check_symbol_exists(ether_ntohost net/ethernet.h NET_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 476     if(NET_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 477         #
 478         # Yes - we have it declared.
 479         #
 480         set(HAVE_DECL_ETHER_NTOHOST TRUE)
 481     endif()
 482     #
 483     # Did that succeed?
 484     #
 485     if(NOT HAVE_DECL_ETHER_NTOHOST)
 486         #
 487         # No - how about <netinet/ether.h>, as on Linux?
 488         #
 489         # This test fails if we don't have <netinet/ether.h>
 490         # or if we do but it doesn't declare ether_ntohost().
 491         #
 492         check_symbol_exists(ether_ntohost netinet/ether.h NETINET_ETHER_H_DECLARES_ETHER_NTOHOST)
 493         if(NETINET_ETHER_H_DECLARES_ETHER_NTOHOST)
 494             #
 495             # Yes - we have it declared.
 496             #
 497             set(HAVE_DECL_ETHER_NTOHOST TRUE)
 498         endif()
 499     endif()
 500     #
 501     # Did that succeed?
 502     #
 503     if(NOT HAVE_DECL_ETHER_NTOHOST)
 504         #
 505         # No - how about <sys/ethernet.h>, as on Solaris 10 and later?
 506         #
 507         # This test fails if we don't have <sys/ethernet.h>
 508         # or if we do but it doesn't declare ether_ntohost().
 509         #
 510         check_symbol_exists(ether_ntohost sys/ethernet.h SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 511         if(SYS_ETHERNET_H_DECLARES_ETHER_NTOHOST)
 512             #
 513             # Yes - we have it declared.
 514             #
 515             set(HAVE_DECL_ETHER_NTOHOST TRUE)
 516         endif()
 517     endif()
 518     #
 519     # Did that succeed?
 520     #
 521     if(NOT HAVE_DECL_ETHER_NTOHOST)
 522         #
 523         # No, how about <arpa/inet.h>, as on AIX?
 524         #
 525         # This test fails if we don't have <arpa/inet.h>
 526         # or if we do but it doesn't declare ether_ntohost().
 527         #
 528         check_symbol_exists(ether_ntohost arpa/inet.h ARPA_INET_H_DECLARES_ETHER_NTOHOST)
 529         if(ARPA_INET_H_DECLARES_ETHER_NTOHOST)
 530             #
 531             # Yes - we have it declared.
 532             #
 533             set(HAVE_DECL_ETHER_NTOHOST TRUE)
 534         endif()
 535     endif()
 536     #
 537     # Did that succeed?
 538     #
 539     if(NOT HAVE_DECL_ETHER_NTOHOST)
 540         #
 541         # No, how about <netinet/if_ether.h>?
 542         # On some platforms, it requires <net/if.h> and
 543         # <netinet/in.h>, and we always include it with
 544         # both of them, so test it with both of them.
 545         #
 546         # This test fails if we don't have <netinet/if_ether.h>
 547         # and the headers we include before it, or if we do but
 548         # <netinet/if_ether.h> doesn't declare ether_ntohost().
 549         #
 550         check_symbol_exists(ether_ntohost "sys/types.h;sys/socket.h;net/if.h;netinet/in.h;netinet/if_ether.h" NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST)
 551         if(NETINET_IF_ETHER_H_DECLARES_ETHER_NTOHOST)
 552             #
 553             # Yes - we have it declared.
 554             #
 555             set(HAVE_DECL_ETHER_NTOHOST TRUE)
 556         endif()
 557     endif()
 558     #
 559     # After all that, is ether_ntohost() declared?
 560     #
 561     if(NOT HAVE_DECL_ETHER_NTOHOST)
 562         #
 563         # No, we'll have to declare it ourselves.
 564         # Do we have "struct ether_addr" if we include<netinet/if_ether.h>?
 565         #
 566         check_struct_has_member("struct ether_addr" octet "sys/types.h;sys/socket.h;net/if.h;netinet/in.h;netinet/if_ether.h" HAVE_STRUCT_ETHER_ADDR)
 567     endif()
 568 endif()
 569 cmake_pop_check_state()
 570
 571 #
 572 # Data types.
 573 #
 574 # XXX - there's no check_struct() macro that's like check_struct_has_member()
 575 # except that it only checks for the existence of the structure type,
 576 # so we use check_struct_has_member() and look for ss_family.
 577 #
 578
 579 #
 580 # Check for IPv6 support.
 581 # We just check for AF_INET6 and struct in6_addr.
 582 #
 583 cmake_push_check_state()
 584 if(WIN32)
 585     set(CMAKE_EXTRA_INCLUDE_FILES sys/types.h ws2tcpip.h)
 586     check_symbol_exists(AF_INET6 "sys/types.h;ws2tcpip.h" HAVE_AF_INET6)
 587 else(WIN32)
 588     set(CMAKE_EXTRA_INCLUDE_FILES sys/types.h sys/socket.h netinet/in.h)
 589     check_symbol_exists(AF_INET6 "sys/types.h;sys/socket.h;netinet/in.h" HAVE_AF_INET6)
 590 endif(WIN32)
 591 check_type_size("struct in6_addr" HAVE_STRUCT_IN6_ADDR)
 592 cmake_pop_check_state()
 593 if(HAVE_AF_INET6 AND HAVE_STRUCT_IN6_ADDR)
 594     set(HAVE_OS_IPV6_SUPPORT TRUE)
 595 endif(HAVE_AF_INET6 AND HAVE_STRUCT_IN6_ADDR)
 596
 597 ######################################
 598 # External dependencies
 599 ######################################
 600
 601 #
 602 # libpcap/WinPcap/Npcap.
 603 # First, find it.
 604 #
 605 find_package(PCAP REQUIRED)
 606 include_directories(${PCAP_INCLUDE_DIRS})
 607
 608 cmake_push_check_state()
 609
 610 #
 611 # Now check headers.
 612 #
 613 set(CMAKE_REQUIRED_INCLUDES ${PCAP_INCLUDE_DIRS})
 614
 615 #
 616 # Check whether we have pcap/pcap-inttypes.h.
 617 # If we do, we use that to get the C99 types defined.
 618 #
 619 check_include_file(pcap/pcap-inttypes.h HAVE_PCAP_PCAP_INTTYPES_H)
 620
 621 #
 622 # Check for various functions in libpcap/WinPcap/Npcap.
 623 #
 624 cmake_push_check_state()
 625 set(CMAKE_REQUIRED_LIBRARIES ${PCAP_LIBRARIES})
 626
 627 #
 628 # Check for "pcap_list_datalinks()" and use a substitute version if
 629 # it's not present.  If it is present, check for "pcap_free_datalinks()";
 630 # if it's not present, we don't replace it for now.  (We could do so
 631 # on UN*X, but not on Windows, where hilarity ensues if a program
 632 # built with one version of the MSVC support library tries to free
 633 # something allocated by a library built with another version of
 634 # the MSVC support library.)
 635 #
 636 check_function_exists(pcap_list_datalinks HAVE_PCAP_LIST_DATALINKS)
 637 if(HAVE_PCAP_LIST_DATALINKS)
 638     check_function_exists(pcap_free_datalinks HAVE_PCAP_FREE_DATALINKS)
 639 endif(HAVE_PCAP_LIST_DATALINKS)
 640
 641 #
 642 # Check for "pcap_datalink_name_to_val()", and use a substitute
 643 # version if it's not present.  If it is present, check for
 644 # "pcap_datalink_val_to_description()", and if we don't have it,
 645 # use a substitute version.
 646 #
 647 check_function_exists(pcap_datalink_name_to_val HAVE_PCAP_DATALINK_NAME_TO_VAL)
 648 if(HAVE_PCAP_DATALINK_NAME_TO_VAL)
 649     check_function_exists(pcap_datalink_val_to_description HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION)
 650 endif(HAVE_PCAP_DATALINK_NAME_TO_VAL)
 651
 652 #
 653 # Check for "pcap_set_datalink()"; you can't substitute for it if
 654 # it's absent (it has hooks into libpcap), so just define the
 655 # HAVE_ value if it's there.
 656 #
 657 check_function_exists(pcap_set_datalink HAVE_PCAP_SET_DATALINK)
 658
 659 #
 660 # Check for "pcap_breakloop()"; you can't substitute for it if
 661 # it's absent (it has hooks into the live capture routines),
 662 # so just define the HAVE_ value if it's there.
 663 #
 664 check_function_exists(pcap_breakloop HAVE_PCAP_BREAKLOOP)
 665
 666 #
 667 # Check for "pcap_dump_ftell()"; we use a substitute version
 668 # if it's not present.
 669 #
 670 check_function_exists(pcap_dump_ftell HAVE_PCAP_DUMP_FTELL)
 671
 672 #
 673 # Do we have the new open API?  Check for pcap_create() and for
 674 # pcap_statustostr(), and assume that, if we have both of them,
 675 # we also have pcap_activate() and the other new routines
 676 # introduced in libpcap 1.0.0.  (We check for pcap_statustostr()
 677 # as well, because WinPcap 4.1.3 screwed up and exported pcap_create()
 678 # but not other routines such as pcap_statustostr(), even though it
 679 # defined them and even though you really want pcap_statustostr() to
 680 # get strings corresponding to some of the status returns from the
 681 # new routines.)
 682 #
 683 check_function_exists(pcap_statustostr HAVE_PCAP_STATUSTOSTR)
 684 #
 685 # If we don't have pcap_statustostr(), don't check for pcap_create(),
 686 # so we pretend we don't have it.
 687 #
 688 if(HAVE_PCAP_STATUSTOSTR)
 689     check_function_exists(pcap_create HAVE_PCAP_CREATE)
 690 endif(HAVE_PCAP_STATUSTOSTR)
 691 if(HAVE_PCAP_CREATE)
 692     #
 693     # OK, do we have pcap_set_tstamp_type?  If so, assume we have
 694     # pcap_list_tstamp_types and pcap_free_tstamp_types as well.
 695     #
 696     check_function_exists(pcap_set_tstamp_type HAVE_PCAP_SET_TSTAMP_TYPE)
 697
 698     #
 699     # And do we have pcap_set_tstamp_precision?  If so, we assume
 700     # we also have pcap_open_offline_with_tstamp_precision.
 701     #
 702     check_function_exists(pcap_set_tstamp_precision HAVE_PCAP_SET_TSTAMP_PRECISION)
 703 endif(HAVE_PCAP_CREATE)
 704
 705 #
 706 # Check for a miscellaneous collection of functions which we use
 707 # if we have them.
 708 #
 709 check_function_exists(pcap_findalldevs HAVE_PCAP_FINDALLDEVS)
 710 if(HAVE_PCAP_FINDALLDEVS)
 711     #
 712     # Check for libpcap having pcap_findalldevs() but the pcap.h header
 713     # not having pcap_if_t; some versions of Mac OS X shipped with pcap.h
 714     # from 0.6 and libpcap 0.8, so that libpcap had pcap_findalldevs but
 715     # pcap.h didn't have pcap_if_t.
 716     #
 717     cmake_push_check_state()
 718     set(CMAKE_REQUIRED_INCLUDES ${PCAP_INCLUDE_DIRS})
 719     set(CMAKE_EXTRA_INCLUDE_FILES pcap.h)
 720     check_type_size(pcap_if_t PCAP_IF_T)
 721     cmake_pop_check_state()
 722 endif(HAVE_PCAP_FINDALLDEVS)
 723 check_function_exists(pcap_dump_flush HAVE_PCAP_DUMP_FLUSH)
 724 check_function_exists(pcap_lib_version HAVE_PCAP_LIB_VERSION)
 725 if(NOT HAVE_PCAP_LIB_VERSION)
 726     # Check for the pcap_version string variable and set HAVE_PCAP_VERSION
 727 endif(NOT HAVE_PCAP_LIB_VERSION)
 728 check_function_exists(pcap_setdirection HAVE_PCAP_SETDIRECTION)
 729 check_function_exists(pcap_set_immediate_mode HAVE_PCAP_SET_IMMEDIATE_MODE)
 730 check_function_exists(pcap_dump_ftell64 HAVE_PCAP_DUMP_FTELL64)
 731 check_function_exists(pcap_open HAVE_PCAP_OPEN)
 732 check_function_exists(pcap_findalldevs_ex HAVE_PCAP_FINDALLDEVS_EX)
 733
 734 #
 735 # On Windows, check for pcap_wsockinit(); if we don't have it, check for
 736 # wsockinit().
 737 #
 738 if(WIN32)
 739     check_function_exists(pcap_wsockinit HAVE_PCAP_WSOCKINIT)
 740     if(NOT HAVE_PCAP_WSOCKINIT)
 741         check_function_exists(wsockinit HAVE_WSOCKINIT)
 742     endif(NOT HAVE_PCAP_WSOCKINIT)
 743 endif(WIN32)
 744
 745 #
 746 # Check for special debugging functions
 747 #
 748 check_function_exists(pcap_set_parser_debug HAVE_PCAP_SET_PARSER_DEBUG)
 749 if(NOT HAVE_PCAP_SET_PARSER_DEBUG)
 750     # Check whether libpcap defines pcap_debug or yydebug
 751     check_variable_exists(pcap_debug HAVE_PCAP_DEBUG)
 752     if(NOT HAVE_PCAP_DEBUG)
 753         check_variable_exists(yydebug HAVE_YYDEBUG)
 754     endif(NOT HAVE_PCAP_DEBUG)
 755 endif(NOT HAVE_PCAP_SET_PARSER_DEBUG)
 756
 757 check_function_exists(pcap_set_optimizer_debug HAVE_PCAP_SET_OPTIMIZER_DEBUG)
 758 check_function_exists(bpf_dump HAVE_BPF_DUMP)
 759
 760 cmake_pop_check_state()
 761
 762 #
 763 # We have libpcap.
 764 #
 765 include_directories(SYSTEM ${PCAP_INCLUDE_DIRS})
 766 set(TCPDUMP_LINK_LIBRARIES ${PCAP_LIBRARIES} ${TCPDUMP_LINK_LIBRARIES})
 767
 768 #
 769 # Optional libraries.
 770 #
 771
 772 #
 773 # libsmi.
 774 #
 775 if(WITH_SMI)
 776     find_package(SMI)
 777     if(SMI_FOUND)
 778         include_directories(SYSTEM ${SMI_INCLUDE_DIRS})
 779         set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} ${SMI_LIBRARIES})
 780         set(USE_LIBSMI ON)
 781     endif(SMI_FOUND)
 782 endif(WITH_SMI)
 783
 784 #
 785 # OpenSSL/libressl libcrypto.
 786 #
 787 if(WITH_CRYPTO)
 788     find_package(CRYPTO)
 789     if(CRYPTO_FOUND)
 790         #
 791         # Check for some headers and functions.
 792         #
 793         check_include_file(openssl/evp.h HAVE_OPENSSL_EVP_H)
 794
 795         #
 796         # 1) do we have EVP_CIPHER_CTX_new?
 797         # If so, we use it to allocate an EVP_CIPHER_CTX, as
 798         # EVP_CIPHER_CTX may be opaque; otherwise, we allocate
 799         # it ourselves.
 800         #
 801         cmake_push_check_state()
 802         set(CMAKE_REQUIRED_LIBRARIES "${CRYPTO_LIBRARIES}")
 803
 804         check_function_exists(EVP_CIPHER_CTX_new HAVE_EVP_CIPHER_CTX_NEW)
 805
 806         #
 807         # 2) do we have EVP_DecryptInit_ex()?
 808         # If so, we use it, because we need to be able to make two
 809         # "initialize the cipher" calls, one with the cipher and key,
 810         # and one with the IV, and, as of OpenSSL 1.1, You Can't Do That
 811         # with EVP_DecryptInit(), because a call to EVP_DecryptInit() will
 812         # unconditionally clear the context, and if you don't supply a
 813         # cipher, it'll clear the cipher, rendering the context unusable
 814         # and causing a crash.
 815         #
 816         check_function_exists(EVP_DecryptInit_ex HAVE_EVP_DECRYPTINIT_EX)
 817
 818         cmake_pop_check_state()
 819
 820         #
 821         # We have libcrypto.
 822         #
 823         include_directories(SYSTEM ${CRYPTO_INCLUDE_DIRS})
 824         set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} ${CRYPTO_LIBRARIES})
 825         set(HAVE_LIBCRYPTO ON)
 826     endif(CRYPTO_FOUND)
 827 endif(WITH_CRYPTO)
 828
 829 #
 830 # Capsicum sandboxing.
 831 # Some of this is in the system library, some of it is in other libraries.
 832 #
 833 if(WITH_CAPSICUM)
 834     check_include_files("sys/capsicum.h" HAVE_SYS_CAPSICUM_H)
 835     if(HAVE_SYS_CAPSICUM_H)
 836         check_function_exists(cap_enter HAVE_CAP_ENTER)
 837         check_function_exists(cap_rights_limit HAVE_CAP_RIGHTS_LIMIT)
 838         check_function_exists(cap_ioctls_limit HAVE_CAP_IOCTLS_LIMIT)
 839         check_function_exists(openat HAVE_OPENAT)
 840         if(HAVE_CAP_ENTER AND HAVE_CAP_RIGHTS_LIMIT AND
 841            HAVE_CAP_IOCTLS_LIMIT AND HAVE_OPENAT)
 842             #
 843             # OK, we have the functions we need to support Capsicum.
 844             #
 845             set(HAVE_CAPSICUM TRUE)
 846
 847             #
 848             # OK, can we use Casper?
 849             #
 850             check_library_exists(casper cap_init "" HAVE_CAP_INIT)
 851             if(HAVE_CAP_INIT)
 852                 cmake_push_check_state()
 853                 set(CMAKE_REQUIRED_LIBRARIES casper)
 854                 check_library_exists(cap_dns cap_gethostbyaddr "" HAVE_CAP_GETHOSTBYADDR)
 855                 cmake_pop_check_state()
 856                 if(HAVE_CAP_GETHOSTBYADDR)
 857                     set(HAVE_CASPER TRUE)
 858                     set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} casper cap_dns)
 859                 endif(HAVE_CAP_GETHOSTBYADDR)
 860             endif(HAVE_CAP_INIT)
 861         endif(HAVE_CAP_ENTER AND HAVE_CAP_RIGHTS_LIMIT AND
 862               HAVE_CAP_IOCTLS_LIMIT AND HAVE_OPENAT)
 863     endif(HAVE_SYS_CAPSICUM_H)
 864 endif(WITH_CAPSICUM)
 865
 866 #
 867 # libcap-ng.
 868 #
 869 if(WITH_CAP_NG)
 870     check_include_file(cap-ng.h HAVE_CAP_NG_H)
 871     check_library_exists(cap-ng capng_change_id "" HAVE_LIBCAP_NG)
 872     if(HAVE_LIBCAP_NG)
 873         set(TCPDUMP_LINK_LIBRARIES ${TCPDUMP_LINK_LIBRARIES} cap-ng)
 874     endif(HAVE_LIBCAP_NG)
 875 endif(WITH_CAP_NG)
 876
 877 ###################################################################
 878 #   Warning options
 879 ###################################################################
 880
 881 #
 882 # Check and add warning options if we have a .devel file.
 883 #
 884 if(EXISTS ${CMAKE_SOURCE_DIR}/.devel OR EXISTS ${CMAKE_BINARY_DIR}/.devel)
 885     #
 886     # Warning options.
 887     #
 888     if(MSVC AND NOT ${CMAKE_C_COMPILER} MATCHES "clang*")
 889         #
 890         # MSVC, with Microsoft's front end and code generator.
 891         # "MSVC" is also set for Microsoft's compiler with a Clang
 892         # front end and their code generator ("Clang/C2"), so we
 893         # check for clang.exe and treat that differently.
 894         #
 895         check_and_add_compiler_option(-Wall)
 896         #
 897         # Disable some pointless warnings that /Wall turns on.
 898         #
 899         # Unfortunately, MSVC does not appear to have an equivalent
 900         # to "__attribute__((unused))" to mark a particular function
 901         # parameter as being known to be unused, so that the compiler
 902         # won't warn about it (for example, the function might have
 903         # that parameter because a pointer to it is being used, and
 904         # the signature of that function includes that parameter).
 905         # C++ lets you give a parameter a type but no name, but C
 906         # doesn't have that.
 907         #
 908         check_and_add_compiler_option(-wd4100)
 909         #
 910         # In theory, we care whether somebody uses f() rather than
 911         # f(void) to declare a function with no arguments, but, in
 912         # practice, there are places in the Windows header files
 913         # that appear to do that, so we squelch that warning.
 914         #
 915         check_and_add_compiler_option(-wd4255)
 916         #
 917         # Windows FD_SET() generates this, so we suppress it.
 918         #
 919         check_and_add_compiler_option(-wd4548)
 920         #
 921         # Perhaps testing something #defined to be 0 with #ifdef is an
 922         # error, and it should be tested with #if, but perhaps it's
 923         # not, and Microsoft does that in its headers, so we squelch
 924         # that warning.
 925         #
 926         check_and_add_compiler_option(-wd4574)
 927         #
 928         # The Windows headers also test not-defined values in #if, so
 929         # we don't want warnings about that, either.
 930         #
 931         check_and_add_compiler_option(-wd4668)
 932         #
 933         # We do *not* care whether some function is, or isn't, going to be
 934         # expanded inline.
 935         #
 936         check_and_add_compiler_option(-wd4710)
 937         check_and_add_compiler_option(-wd4711)
 938         #
 939         # We do *not* care whether we're adding padding bytes after
 940         # structure members.
 941         #
 942         check_and_add_compiler_option(-wd4820)
 943         #
 944         # We do *not* care about every single place the compiler would
 945         # have inserted Spectre mitigation if only we had told it to
 946         # do so with /Qspectre.  I guess the theory is that it's seeing
 947         # bounds checks that would prevent out-of-bounds loads and that
 948         # those out-of-bounds loads could be done speculatively and that
 949         # the Spectre attack could detect the value of the out-of-bounds
 950         # data *if* it's within our address space, but unless I'm
 951         # missing something I don't see that as being any form of
 952         # security hole.
 953         #
 954         # XXX - add /Qspectre if that is really worth doing.
 955         #
 956         check_and_add_compiler_option(-wd5045)
 957         #
 958         # We do *not* care whether a structure had padding added at
 959         # the end because of __declspec(align) - *we* don't use
 960         # __declspec(align), because the only structures whose layout
 961         # we precisely specify are those that get overlayed on packet
 962         # data, and in those every element is an array of octets so
 963         # that we have full control over the size and aligmnet, and,
 964         # apparently, jmp_buf has such a declaration on x86, meaning
 965         # that everything that includes netdissect.h, i.e. almost every
 966         # file in tcpdump, gets a warning.
 967         #
 968         check_and_add_compiler_option(-wd4324)
 969     else()
 970         #
 971         # Other compilers, including MSVC with a Clang front end and
 972         # Microsoft's code generator.  We currently treat them as if
 973         # they might support GCC-style -W options.
 974         #
 975         check_and_add_compiler_option(-W)
 976         check_and_add_compiler_option(-Wall)
 977         check_and_add_compiler_option(-Wassign-enum)
 978         check_and_add_compiler_option(-Wcast-qual)
 979         check_and_add_compiler_option(-Wmissing-prototypes)
 980         check_and_add_compiler_option(-Wmissing-variable-declarations)
 981         check_and_add_compiler_option(-Wold-style-definition)
 982         check_and_add_compiler_option(-Wpedantic)
 983         check_and_add_compiler_option(-Wpointer-arith)
 984         check_and_add_compiler_option(-Wpointer-sign)
 985         check_and_add_compiler_option(-Wshadow)
 986         check_and_add_compiler_option(-Wsign-compare)
 987         check_and_add_compiler_option(-Wstrict-prototypes)
 988         check_and_add_compiler_option(-Wunreachable-code-return)
 989         check_and_add_compiler_option(-Wused-but-marked-unused)
 990         check_and_add_compiler_option(-Wwrite-strings)
 991     endif()
 992 endif()
 993
 994 #
 995 # Extra compiler options for the build matrix scripts to request -Werror or
 996 # its equivalent if required.  The CMake variable name cannot be CFLAGS
 997 # because that is already used for a different purpose in CMake.  Example
 998 # usage: cmake -DEXTRA_CFLAGS='-Wall -Wextra -Werror' ...
 999 #
1000 if(NOT "${EXTRA_CFLAGS}" STREQUAL "")
1001     foreach(_extra_cflag ${EXTRA_CFLAGS})
1002         check_and_add_compiler_option("${_extra_cflag}")
1003     endforeach(_extra_cflag)
1004     message(STATUS "Added extra compile options (${EXTRA_CFLAGS})")
1005 endif()
1006
1007 ######################################
1008 # Input files
1009 ######################################
1010
1011 if(ENABLE_SMB)
1012     #
1013     # We allow the SMB dissector to be omitted.
1014     #
1015     set(LOCALSRC ${LOCALSRC}
1016         print-smb.c
1017         smbutil.c)
1018 endif(ENABLE_SMB)
1019
1020 set(NETDISSECT_SOURCE_LIST_C
1021     addrtoname.c
1022     addrtostr.c
1023     af.c
1024     ascii_strcasecmp.c
1025     checksum.c
1026     cpack.c
1027     gmpls.c
1028     in_cksum.c
1029     ipproto.c
1030     l2vpn.c
1031     machdep.c
1032     netdissect.c
1033     netdissect-alloc.c
1034     nlpid.c
1035     oui.c
1036     ntp.c
1037     parsenfsfh.c
1038     print.c
1039     print-802_11.c
1040     print-802_15_4.c
1041     print-ah.c
1042     print-ahcp.c
1043     print-aodv.c
1044     print-aoe.c
1045     print-ap1394.c
1046     print-arcnet.c
1047     print-arista.c
1048     print-arp.c
1049     print-ascii.c
1050     print-atalk.c
1051     print-atm.c
1052     print-babel.c
1053     print-bcm-li.c
1054     print-beep.c
1055     print-bfd.c
1056     print-bgp.c
1057     print-bootp.c
1058     print-brcmtag.c
1059     print-bt.c
1060     print-calm-fast.c
1061     print-carp.c
1062     print-cdp.c
1063     print-cfm.c
1064     print-chdlc.c
1065     print-cip.c
1066     print-cnfp.c
1067     print-dccp.c
1068     print-decnet.c
1069     print-dhcp6.c
1070     print-domain.c
1071     print-dsa.c
1072     print-dtp.c
1073     print-dvmrp.c
1074     print-eap.c
1075     print-egp.c
1076     print-eigrp.c
1077     print-enc.c
1078     print-esp.c
1079     print-ether.c
1080     print-fddi.c
1081     print-forces.c
1082     print-fr.c
1083     print-frag6.c
1084     print-ftp.c
1085     print-geneve.c
1086     print-geonet.c
1087     print-gre.c
1088     print-hncp.c
1089     print-hsrp.c
1090     print-http.c
1091     print-icmp.c
1092     print-icmp6.c
1093     print-igmp.c
1094     print-igrp.c
1095     print-ip-demux.c
1096     print-ip.c
1097     print-ip6.c
1098     print-ip6opts.c
1099     print-ipcomp.c
1100     print-ipfc.c
1101     print-ipnet.c
1102     print-ipoib.c
1103     print-ipx.c
1104     print-isakmp.c
1105     print-isoclns.c
1106     print-juniper.c
1107     print-krb.c
1108     print-l2tp.c
1109     print-lane.c
1110     print-ldp.c
1111     print-lisp.c
1112     print-llc.c
1113     print-lldp.c
1114     print-lmp.c
1115     print-loopback.c
1116     print-lspping.c
1117     print-lwapp.c
1118     print-lwres.c
1119     print-m3ua.c
1120     print-macsec.c
1121     print-mobile.c
1122     print-mobility.c
1123     print-mpcp.c
1124     print-mpls.c
1125     print-mptcp.c
1126     print-msdp.c
1127     print-msnlb.c
1128     print-nflog.c
1129     print-nfs.c
1130     print-nsh.c
1131     print-ntp.c
1132     print-null.c
1133     print-olsr.c
1134     print-openflow-1.0.c
1135     print-openflow-1.3.c
1136     print-openflow.c
1137     print-ospf.c
1138     print-ospf6.c
1139     print-otv.c
1140     print-pflog.c
1141     print-pgm.c
1142     print-pim.c
1143     print-pktap.c
1144     print-ppi.c
1145     print-ppp.c
1146     print-pppoe.c
1147     print-pptp.c
1148     print-ptp.c
1149     print-radius.c
1150     print-raw.c
1151     print-realtek.c
1152     print-resp.c
1153     print-rip.c
1154     print-ripng.c
1155     print-rpki-rtr.c
1156     print-rsvp.c
1157     print-rt6.c
1158     print-rtsp.c
1159     print-rx.c
1160     print-sctp.c
1161     print-sflow.c
1162     print-sip.c
1163     print-sl.c
1164     print-sll.c
1165     print-slow.c
1166     print-smtp.c
1167     print-snmp.c
1168     print-someip.c
1169     print-ssh.c
1170     print-stp.c
1171     print-sunatm.c
1172     print-sunrpc.c
1173     print-symantec.c
1174     print-syslog.c
1175     print-tcp.c
1176     print-telnet.c
1177     print-tftp.c
1178     print-timed.c
1179     print-tipc.c
1180     print-token.c
1181     print-udld.c
1182     print-udp.c
1183     print-unsupported.c
1184     print-usb.c
1185     print-vjc.c
1186     print-vqp.c
1187     print-vrrp.c
1188     print-vsock.c
1189     print-vtp.c
1190     print-vxlan-gpe.c
1191     print-vxlan.c
1192     print-wb.c
1193     print-whois.c
1194     print-zep.c
1195     print-zephyr.c
1196     print-zeromq.c
1197     ${LOCALSRC}
1198     signature.c
1199     strtoaddr.c
1200     util-print.c
1201 )
1202
1203 #
1204 # Replace missing functions
1205 #
1206 foreach(FUNC strlcat strlcpy strdup strsep getservent getopt_long)
1207     string(TOUPPER ${FUNC} FUNC_UPPERCASE)
1208     set(HAVE_FUNC_UPPERCASE HAVE_${FUNC_UPPERCASE})
1209     if(NOT ${HAVE_FUNC_UPPERCASE})
1210         set(NETDISSECT_SOURCE_LIST_C ${NETDISSECT_SOURCE_LIST_C} missing/${FUNC}.c)
1211     endif()
1212 endforeach()
1213
1214 add_library(netdissect STATIC
1215     ${NETDISSECT_SOURCE_LIST_C}
1216 )
1217 if(NOT C_ADDITIONAL_FLAGS STREQUAL "")
1218     set_target_properties(netdissect PROPERTIES COMPILE_FLAGS ${C_ADDITIONAL_FLAGS})
1219 endif()
1220
1221 set(TCPDUMP_SOURCE_LIST_C fptype.c tcpdump.c)
1222
1223 if(NOT HAVE_BPF_DUMP)
1224     set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} bpf_dump.c)
1225 endif(NOT HAVE_BPF_DUMP)
1226 if(NOT HAVE_PCAP_DUMP_FTELL)
1227     set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} missing/pcap_dump_ftell.c)
1228 endif(NOT HAVE_PCAP_DUMP_FTELL)
1229
1230 if(NOT HAVE_PCAP_LIST_DATALINKS)
1231     set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} missing/datalinks.c)
1232 endif(NOT HAVE_PCAP_LIST_DATALINKS)
1233
1234 if((NOT HAVE_PCAP_DATALINK_NAME_TO_VAL) OR (NOT HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION))
1235     set(TCPDUMP_SOURCE_LIST_C ${TCPDUMP_SOURCE_LIST_C} missing/dlnames.c)
1236 endif((NOT HAVE_PCAP_DATALINK_NAME_TO_VAL) OR (NOT HAVE_PCAP_DATALINK_VAL_TO_DESCRIPTION))
1237
1238 set(PROJECT_SOURCE_LIST_C ${NETDISSECT_SOURCE_LIST_C} ${TCPDUMP_SOURCE_LIST_C})
1239
1240 file(GLOB PROJECT_SOURCE_LIST_H
1241     *.h
1242 )
1243
1244 #
1245 # Assume, by default, no support for shared libraries and V7/BSD
1246 # convention for man pages (devices in section 4, file formats in
1247 # section 5, miscellaneous info in section 7, administrative commands
1248 # and daemons in section 8).  Individual cases can override this.
1249 # Individual cases can override this.
1250 #
1251 set(MAN_FILE_FORMATS 5)
1252 set(MAN_MISC_INFO 7)
1253 if(CMAKE_SYSTEM_NAME STREQUAL "AIX")
1254     # Workaround to enable certain features
1255     set(_SUN TRUE)
1256 elseif(CMAKE_SYSTEM_NAME STREQUAL "HP-UX")
1257     #
1258     # Use System V conventions for man pages.
1259     #
1260     set(MAN_FILE_FORMATS 4)
1261     set(MAN_MISC_INFO 5)
1262 elseif(CMAKE_SYSTEM_NAME STREQUAL "IRIX" OR CMAKE_SYSTEM_NAME STREQUAL "IRIX64")
1263     #
1264     # Use IRIX conventions for man pages; they're the same as the
1265     # System V conventions, except that they use section 8 for
1266     # administrative commands and daemons.
1267     #
1268     set(MAN_FILE_FORMATS 4)
1269     set(MAN_MISC_INFO 5)
1270 elseif(CMAKE_SYSTEM_NAME STREQUAL "OSF1")
1271     #
1272     # DEC OSF/1, a/k/a Digital UNIX, a/k/a Tru64 UNIX.
1273     # Use Tru64 UNIX conventions for man pages; they're the same as the
1274     # System V conventions except that they use section 8 for
1275     # administrative commands and daemons.
1276     #
1277     set(MAN_FILE_FORMATS 4)
1278     set(MAN_MISC_INFO 5)
1279 elseif(CMAKE_SYSTEM_NAME STREQUAL "SunOS" AND CMAKE_SYSTEM_VERSION MATCHES "5[.][0-9.]*")
1280     #
1281     # SunOS 5.x.
1282     #
1283     if(CMAKE_SYSTEM_VERSION STREQUAL "5.12")
1284     else()
1285         #
1286         # Use System V conventions for man pages.
1287         #
1288         set(MAN_FILE_FORMATS 4)
1289         set(MAN_MISC_INFO 5)
1290     endif()
1291 endif()
1292
1293 source_group("Source Files" FILES ${PROJECT_SOURCE_LIST_C})
1294 source_group("Header Files" FILES ${PROJECT_SOURCE_LIST_H})
1295
1296 ######################################
1297 # Register targets
1298 ######################################
1299
1300 add_executable(tcpdump ${TCPDUMP_SOURCE_LIST_C})
1301 if(NOT C_ADDITIONAL_FLAGS STREQUAL "")
1302     set_target_properties(tcpdump PROPERTIES COMPILE_FLAGS ${C_ADDITIONAL_FLAGS})
1303 endif()
1304 target_link_libraries(tcpdump netdissect ${TCPDUMP_LINK_LIBRARIES})
1305
1306 ######################################
1307 # Write out the config.h file
1308 ######################################
1309
1310 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmakeconfig.h.in ${CMAKE_CURRENT_BINARY_DIR}/config.h)
1311
1312 ######################################
1313 # Install tcpdump and man pages
1314 ######################################
1315
1316 #
1317 # "Define GNU standard installation directories", which actually
1318 # are also defined, to some degree, by autotools, and at least
1319 # some of which are general UN*X conventions.
1320 #
1321 include(GNUInstallDirs)
1322
1323 set(MAN1_EXPAND tcpdump.1.in)
1324
1325 if(WIN32)
1326     # XXX TODO where to install on Windows?
1327 else(WIN32)
1328     install(TARGETS tcpdump DESTINATION bin)
1329 endif(WIN32)
1330
1331 # On UN*X, and on Windows when not using MSVC, process man pages and
1332 # arrange that they be installed.
1333 if(NOT MSVC)
1334     #
1335     # Man pages.
1336     #
1337     # For each section of the manual for which we have man pages
1338     # that require macro expansion, do the expansion.
1339     #
1340     set(MAN1 "")
1341     foreach(TEMPLATE_MANPAGE ${MAN1_EXPAND})
1342         string(REPLACE ".in" "" MANPAGE ${TEMPLATE_MANPAGE})
1343         configure_file(${CMAKE_SOURCE_DIR}/${TEMPLATE_MANPAGE} ${CMAKE_CURRENT_BINARY_DIR}/${MANPAGE} @ONLY)
1344         set(MAN1 ${MAN1} ${CMAKE_CURRENT_BINARY_DIR}/${MANPAGE})
1345     endforeach(TEMPLATE_MANPAGE)
1346     install(FILES ${MAN1} DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)
1347 endif(NOT MSVC)
1348
1349 # uninstall target
1350 configure_file(
1351     "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
1352     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
1353     IMMEDIATE @ONLY)
1354
1355 add_custom_target(uninstall
1356     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
1357
1358 #
1359 # Tcpdump tests
1360 # We try to find the Perl interpreter and, if we do, we have the check
1361 # rule run tests/TESTrun with it, because just trying to run the TESTrun
1362 # script as a command won't work on Windows.
1363 #
1364 find_program(PERL perl)
1365 if(PERL)
1366     message(STATUS "Found perl at ${PERL}")
1367     add_custom_target(check
1368         COMMAND ${PERL} ${CMAKE_SOURCE_DIR}/tests/TESTrun)
1369 else()
1370     message(STATUS "Didn't find perl")
1371 endif()