contrib/tcsh/complete.tcsh

   1 #
   2 # $Id: complete.tcsh,v 1.43 2004/02/22 15:57:15 christos Exp $
   3 # example file using the new completion code
   4 #
   5 # Debian GNU/Linux
   6 # /usr/share/doc/tcsh/examples/complete.gz
   7 #
   8 # This file may be read from user's ~/.cshrc or ~/.tcsh file by
   9 # decompressing it into the home directory as ~/.complete and
  10 # then adding the line "source ~/.complete" and maybe defining
  11 # some of the shell variables described below.
  12 #
  13 # Added two Debian-specific completions: dpkg and dpkg-deb (who
  14 # wrote them?). Changed completions of several commands. The ones
  15 # are evaluated if the `traditional_complete' shell variable is
  16 # defined.
  17 #
  18 # Debian enhancements by Vadim Vygonets <vadik@cs.huji.ac.il>.
  19 # Bugfixes and apt completions by Miklos Quartus <miklos.quartus@nokia.com>.
  20 # Cleanup by Martin A. Godisch <martin@godisch.de>.
  21
  22 onintr -
  23 if (! $?prompt) goto end
  24
  25 if ($?tcsh) then
  26     if ($tcsh != 1) then
  27         set rev=$tcsh:r
  28         set rel=$rev:e
  29         set pat=$tcsh:e
  30         set rev=$rev:r
  31     endif
  32     if ($rev > 5 && $rel > 1) then
  33         set _complete=1
  34     endif
  35     unset rev rel pat
  36 endif
  37
  38 if ($?_complete) then
  39     set noglob
  40     if ( ! $?hosts ) set hosts
  41     foreach f ($HOME/.hosts /usr/local/etc/csh.hosts $HOME/.rhosts /etc/hosts.equiv)
  42         if ( -r $f ) then
  43             set hosts = ($hosts `grep -v "+" $f | grep -E -v "^#" | tr -s " " " " | cut -f 1`)
  44         endif
  45     end
  46     if ( -r $HOME/.netrc ) then
  47         set f=`awk '/machine/ { print $2 }' < $HOME/.netrc` >& /dev/null
  48         set hosts=($hosts $f)
  49     endif
  50     if ( -r $HOME/.ssh/known_hosts ) then
  51         set f=`cat $HOME/.ssh/known_hosts | cut -f 1 -d \ ` >& /dev/null
  52         set hosts=($hosts $f)
  53     endif
  54     unset f
  55     if ( ! $?hosts ) then
  56         set hosts=(hyperion.ee.cornell.edu phaeton.ee.cornell.edu \
  57                    guillemin.ee.cornell.edu vangogh.cs.berkeley.edu \
  58                    ftp.uu.net prep.ai.mit.edu export.lcs.mit.edu \
  59                    labrea.stanford.edu sumex-aim.stanford.edu \
  60                    tut.cis.ohio-state.edu)
  61     endif
  62
  63     complete ywho       n/*/\$hosts/    # argument from list in $hosts
  64     complete rsh        p/1/\$hosts/ c/-/"(l n)"/   n/-l/u/ N/-l/c/ n/-/c/ p/2/c/ p/*/f/
  65     complete ssh        p/1/\$hosts/ c/-/"(l n)"/   n/-l/u/ N/-l/c/ n/-/c/ p/2/c/ p/*/f/
  66     complete xrsh       p/1/\$hosts/ c/-/"(l 8 e)"/ n/-l/u/ N/-l/c/ n/-/c/ p/2/c/ p/*/f/
  67     complete rlogin     p/1/\$hosts/ c/-/"(l 8 e)"/ n/-l/u/
  68     complete telnet     p/1/\$hosts/ p/2/x:'<port>'/ n/*/n/
  69
  70     complete cd         p/1/d/          # Directories only
  71     complete chdir      p/1/d/
  72     complete pushd      p/1/d/
  73     complete popd       p/1/d/
  74     complete pu         p/1/d/
  75     complete po         p/1/d/
  76     complete complete   p/1/X/          # Completions only
  77     complete uncomplete n/*/X/
  78     complete exec       p/1/c/          # Commands only
  79     complete trace      p/1/c/
  80     complete strace     p/1/c/
  81     complete which      n/*/c/
  82     complete where      n/*/c/
  83     complete skill      p/1/c/
  84     complete dde        p/1/c/
  85     complete adb        c/-I/d/ n/-/c/ N/-/"(core)"/ p/1/c/ p/2/"(core)"/
  86     complete sdb        p/1/c/
  87     complete dbx        c/-I/d/ n/-/c/ N/-/"(core)"/ p/1/c/ p/2/"(core)"/
  88     complete xdb        p/1/c/
  89     complete gdb        n/-d/d/ n/*/c/
  90     complete ups        p/1/c/
  91     complete set        'c/*=/f/' 'p/1/s/=' 'n/=/f/'
  92     complete unset      n/*/s/
  93     complete alias      p/1/a/          # only aliases are valid
  94     complete unalias    n/*/a/
  95     complete xdvi       n/*/f:*.dvi/    # Only files that match *.dvi
  96     complete dvips      n/*/f:*.dvi/
  97 if ($?traditional_complete) then
  98     complete tex        n/*/f:*.tex/    # Only files that match *.tex
  99 else
 100     complete tex        n/*/f:*.{tex,texi}/     # Files that match *.tex and *.texi
 101 endif
 102     complete latex      n/*/f:*.{tex,ltx}/
 103     complete su         c/--/"(login fast preserve-environment command shell \
 104                         help version)"/ c/-/"(f l m p c s -)"/ \
 105                         n/{-c,--command}/c/ \
 106                         n@{-s,--shell}@'`cat /etc/shells`'@ n/*/u/
 107     complete cc         c/-[IL]/d/ \
 108               c@-l@'`\ls -1 /usr/lib/lib*.a | sed s%^.\*/lib%%\;s%\\.a\$%%`'@ \
 109                         c/-/"(o l c g L I D U)"/ n/*/f:*.[coasi]/
 110     complete acc        c/-[IL]/d/ \
 111        c@-l@'`\ls -1 /usr/lang/SC1.0/lib*.a | sed s%^.\*/lib%%\;s%\\.a\$%%`'@ \
 112                         c/-/"(o l c g L I D U)"/ n/*/f:*.[coasi]/
 113     complete gcc        c/-[IL]/d/ \
 114                         c/-f/"(caller-saves cse-follow-jumps delayed-branch \
 115                                elide-constructors expensive-optimizations \
 116                                float-store force-addr force-mem inline \
 117                                inline-functions keep-inline-functions \
 118                                memoize-lookups no-default-inline \
 119                                no-defer-pop no-function-cse omit-frame-pointer \
 120                                rerun-cse-after-loop schedule-insns \
 121                                schedule-insns2 strength-reduce \
 122                                thread-jumps unroll-all-loops \
 123                                unroll-loops syntax-only all-virtual \
 124                                cond-mismatch dollars-in-identifiers \
 125                                enum-int-equiv no-asm no-builtin \
 126                                no-strict-prototype signed-bitfields \
 127                                signed-char this-is-variable unsigned-bitfields \
 128                                unsigned-char writable-strings call-saved-reg \
 129                                call-used-reg fixed-reg no-common \
 130                                no-gnu-binutils nonnull-objects \
 131                                pcc-struct-return pic PIC shared-data \
 132                                short-enums short-double volatile)"/ \
 133                         c/-W/"(all aggregate-return cast-align cast-qual \
 134                                comment conversion enum-clash error format \
 135                                id-clash-len implicit missing-prototypes \
 136                                no-parentheses pointer-arith return-type shadow \
 137                                strict-prototypes switch uninitialized unused \
 138                                write-strings)"/ \
 139                         c/-m/"(68000 68020 68881 bitfield fpa nobitfield rtd \
 140                                short c68000 c68020 soft-float g gnu unix fpu \
 141                                no-epilogue)"/ \
 142                         c/-d/"(D M N)"/ \
 143                         c/-/"(f W vspec v vpath ansi traditional \
 144                               traditional-cpp trigraphs pedantic x o l c g L \
 145                               I D U O O2 C E H B b V M MD MM i dynamic \
 146                               nodtdlib static nostdinc undef)"/ \
 147                         c/-l/f:*.a/ \
 148                         n/*/f:*.{c,C,cc,o,a,s,i}/
 149     complete g++        n/*/f:*.{C,cc,o,s,i}/
 150     complete CC         n/*/f:*.{C,cc,cpp,o,s,i}/
 151     complete rm         c/--/"(directory force interactive verbose \
 152                         recursive help version)"/ c/-/"(d f i v r R -)"/ \
 153                         n/*/f:^*.{c,cc,C,h,in}/ # Protect precious files
 154     complete vi         n/*/f:^*.[oa]/
 155     complete bindkey    N/-a/b/ N/-c/c/ n/-[ascr]/'x:<key-sequence>'/ \
 156                         n/-[svedlr]/n/ c/-[vedl]/n/ c/-/"(a s k c v e d l r)"/\
 157                         n/-k/"(left right up down)"/ p/2-/b/ \
 158                         p/1/'x:<key-sequence or option>'/
 159
 160     complete find       n/-fstype/"(nfs 4.2)"/ n/-name/f/ \
 161                         n/-type/"(c b d f p l s)"/ n/-user/u/ n/-group/g/ \
 162                         n/-exec/c/ n/-ok/c/ n/-cpio/f/ n/-ncpio/f/ n/-newer/f/ \
 163                         c/-/"(fstype name perm prune type user nouser \
 164                              group nogroup size inum atime mtime ctime exec \
 165                              ok print ls cpio ncpio newer xdev depth \
 166                              daystart follow maxdepth mindepth noleaf version \
 167                              anewer cnewer amin cmin mmin true false uid gid \
 168                              ilname iname ipath iregex links lname empty path \
 169                              regex used xtype fprint fprint0 fprintf \
 170                              print0 printf not a and o or)"/ \
 171                              n/*/d/
 172
 173     complete -%*        c/%/j/                  # fill in the jobs builtin
 174     complete {fg,bg,stop}       c/%/j/ p/1/"(%)"//
 175
 176     complete limit      c/-/"(h)"/ n/*/l/
 177     complete unlimit    c/-/"(h)"/ n/*/l/
 178
 179     complete -co*       p/0/"(compress)"/       # make compress completion
 180                                                 # not ambiguous
 181 if ($?traditional_complete) then
 182     complete zcat       n/*/f:*.Z/
 183 else
 184     # "zcat" may be linked to "compress" or "gzip"
 185     if (-X zcat) then
 186         zcat --version >& /dev/null
 187         if ($status != 0) then
 188             complete zcat       n/*/f:*.Z/
 189         else
 190             complete zcat       c/--/"(force help license quiet version)"/ \
 191                                 c/-/"(f h L q V -)"/ n/*/f:*.{gz,Z,z,zip}/
 192         endif
 193     endif
 194 endif
 195
 196     complete finger     c/*@/\$hosts/ n/*/u/@
 197     complete ping       p/1/\$hosts/
 198     complete traceroute p/1/\$hosts/
 199
 200     complete {talk,ntalk,phone} p/1/'`users | tr " " "\012" | uniq`'/ \
 201                 n/*/\`who\ \|\ grep\ \$:1\ \|\ awk\ \'\{\ print\ \$2\ \}\'\`/
 202
 203     complete ftp        c/-/"(d i g n v)"/ n/-/\$hosts/ p/1/\$hosts/ n/*/n/
 204
 205     # this one is simple...
 206     #complete rcp c/*:/f/ C@[./\$~]*@f@ n/*/\$hosts/:
 207     # From Michael Schroeder <mlschroe@immd4.informatik.uni-erlangen.de>
 208     # This one will rsh to the file to fetch the list of files!
 209     complete rcp 'c%*@*:%`set q=$:-0;set q="$q:s/@/ /";set q="$q:s/:/ /";set q=($q " ");rsh $q[2] -l $q[1] ls -dp $q[3]\*`%' 'c%*:%`set q=$:-0;set q="$q:s/:/ /";set q=($q " ");rsh $q[1] ls -dp $q[2]\*`%' 'c%*@%$hosts%:' 'C@[./$~]*@f@'  'n/*/$hosts/:'
 210
 211     complete dd c/--/"(help version)"/ c/[io]f=/f/ \
 212                 c/conv=*,/"(ascii ebcdic ibm block unblock \
 213                             lcase notrunc ucase swab noerror sync)"/,\
 214                 c/conv=/"(ascii ebcdic ibm block unblock \
 215                           lcase notrunc ucase swab noerror sync)"/,\
 216                 c/*=/x:'<number>'/ \
 217                 n/*/"(if of conv ibs obs bs cbs files skip file seek count)"/=
 218
 219     complete nslookup   p/1/x:'<host>'/ p/2/\$hosts/
 220
 221     complete ar c/[dmpqrtx]/"(c l o u v a b i)"/ p/1/"(d m p q r t x)"// \
 222                 p/2/f:*.a/ p/*/f:*.o/
 223
 224     # these should be merged with the MH completion hacks below - jgotts
 225     complete {refile,sprev,snext,scan,pick,rmm,inc,folder,show} \
 226                 c@+@F:$HOME/Mail/@
 227
 228     # these and interrupt handling from Jaap Vermeulen <jaap@sequent.com>
 229     complete {rexec,rxexec,rxterm,rmterm} \
 230                         'p/1/$hosts/' 'c/-/(l L E)/' 'n/-l/u/' 'n/-L/f/' \
 231                         'n/-E/e/' 'n/*/c/'
 232     complete kill       'c/-/S/' 'c/%/j/' \
 233                         'n/*/`ps -u $LOGNAME | awk '"'"'{print $1}'"'"'`/'
 234
 235     # these from Marc Horowitz <marc@cam.ov.com>
 236     complete attach 'n/-mountpoint/d/' 'n/-m/d/' 'n/-type/(afs nfs rvd ufs)/' \
 237                     'n/-t/(afs nfs rvd ufs)/' 'n/-user/u/' 'n/-U/u/' \
 238                     'c/-/(verbose quiet force printpath lookup debug map \
 239                           nomap remap zephyr nozephyr readonly write \
 240                           mountpoint noexplicit explicit type mountoptions \
 241                           nosetuid setuid override skipfsck lock user host)/' \
 242                     'n/-e/f/' 'n/*/()/'
 243     complete hesinfo    'p/1/u/' \
 244                         'p/2/(passwd group uid grplist pcap pobox cluster \
 245                               filsys sloc service)/'
 246
 247     # these from E. Jay Berkenbilt <ejb@ERA.COM>
 248     # = isn't always followed by a filename or a path anymore - jgotts
 249 if ($?traditional_complete) then
 250     complete ./configure 'c/--*=/f/' 'c/--{cache-file,prefix,exec-prefix,\
 251                                 bindir,sbindir,libexecdir,datadir,\
 252                                 sysconfdir,sharedstatedir,localstatedir,\
 253                                 libdir,includedir,oldincludedir,infodir,\
 254                                 mandir,srcdir}/(=)//' \
 255                          'c/--/(cache-file verbose prefix exec-prefix bindir \
 256                                 sbindir libexecdir datadir sysconfdir \
 257                                 sharedstatedir localstatedir libdir \
 258                                 includedir oldincludedir infodir mandir \
 259                                 srcdir)//'
 260 else
 261         complete ./configure \
 262                         'c@--{prefix,exec-prefix,bindir,sbindir,libexecdir,datadir,sysconfdir,sharedstatedir,localstatedir,infodir,mandir,srcdir,x-includes,x-libraries}=*@x:<directory e.g. /usr/local>'@ \
 263                         'c/--cachefile=*/x:<filename>/' \
 264                         'c/--{enable,disable,with}-*/x:<feature>//' \
 265                         'c/--*=/x:<directory>//' \
 266                         'c/--/(prefix= exec-prefix= bindir= \
 267                         sbindir= libexecdir= datadir= sysconfdir= \
 268                         sharedstatedir= localstatedir= infodir= \
 269                         mandir= srcdir= x-includes= x-libraries= cachefile= \
 270                         enable- disable- with- \
 271                         help no-create quiet silent version verbose )//'
 272 endif
 273     complete gs 'c/-sDEVICE=/(x11 cdjmono cdj550 epson eps9high epsonc \
 274                               dfaxhigh dfaxlow laserjet ljet4 sparc pbm \
 275                               pbmraw pgm pgmraw ppm ppmraw bit)/' \
 276                 'c/-sOutputFile=/f/' 'c/-s/(DEVICE OutputFile)/=' \
 277                 'c/-d/(NODISPLAY NOPLATFONTS NOPAUSE)/' 'n/*/f/'
 278     complete perl       'n/-S/c/'
 279     complete printenv   'n/*/e/'
 280     complete sccs       p/1/"(admin cdc check clean comb deledit delget \
 281                         delta diffs edit enter fix get help info \
 282                         print prs prt rmdel sccsdiff tell unedit \
 283                         unget val what)"/
 284     complete setenv     'p/1/e/' 'c/*:/f/'
 285
 286     # these and method of setting hosts from Kimmo Suominen <kim@tac.nyc.ny.us>
 287     if ( -f $HOME/.mh_profile && -x "`which folders`" ) then
 288
 289     if ( ! $?FOLDERS ) setenv FOLDERS "`folders -fast -recurse`"
 290     if ( ! $?MHA )     setenv MHA     "`ali | sed -e '/^ /d' -e 's/:.*//'`"
 291
 292     set folders = ( $FOLDERS )
 293     set mha = ( $MHA )
 294
 295     complete ali \
 296         'c/-/(alias nolist list nonormalize normalize nouser user help)/' \
 297         'n,-alias,f,'
 298
 299     complete anno \
 300         'c/-/(component noinplace inplace nodate date text help)/' \
 301         'c,+,$folders,'  \
 302         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 303
 304     complete burst \
 305         'c/-/(noinplace inplace noquiet quiet noverbose verbose help)/' \
 306         'c,+,$folders,'  \
 307         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 308
 309     complete comp \
 310         'c/-/(draftfolder draftmessage nodraftfolder editor noedit file form nouse use whatnowproc nowhatnowproc help)/' \
 311         'c,+,$folders,'  \
 312         'n,-whatnowproc,c,'  \
 313         'n,-file,f,'\
 314         'n,-form,f,'\
 315         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 316
 317     complete dist \
 318         'c/-/(noannotate annotate draftfolder draftmessage nodraftfolder editor noedit form noinplace inplace whatnowproc nowhatnowproc help)/' \
 319         'c,+,$folders,'  \
 320         'n,-whatnowproc,c,'  \
 321         'n,-form,f,'\
 322         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 323
 324     complete folder \
 325         'c/-/(all nofast fast noheader header nopack pack noverbose verbose norecurse recurse nototal total noprint print nolist list push pop help)/' \
 326         'c,+,$folders,'  \
 327         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 328
 329     complete folders \
 330         'c/-/(all nofast fast noheader header nopack pack noverbose verbose norecurse recurse nototal total noprint print nolist list push pop help)/' \
 331         'c,+,$folders,'  \
 332         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 333
 334     complete forw \
 335         'c/-/(noannotate annotate draftfolder draftmessage nodraftfolder editor noedit filter form noformat format noinplace inplace digest issue volume whatnowproc nowhatnowproc help)/' \
 336         'c,+,$folders,'  \
 337         'n,-whatnowproc,c,'  \
 338         'n,-filter,f,'\
 339         'n,-form,f,'\
 340         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 341
 342     complete inc \
 343         'c/-/(audit file noaudit nochangecur changecur file form format nosilent silent notruncate truncate width help)/' \
 344         'c,+,$folders,'  \
 345         'n,-audit,f,'\
 346         'n,-form,f,'
 347
 348     complete mark \
 349         'c/-/(add delete list sequence nopublic public nozero zero help)/' \
 350         'c,+,$folders,'  \
 351         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 352
 353     complete mhmail \
 354         'c/-/(body cc from subject help)/' \
 355         'n,-cc,$mha,'  \
 356         'n,-from,$mha,'  \
 357         'n/*/$mha/'
 358
 359     complete mhpath \
 360         'c/-/(help)/' \
 361         'c,+,$folders,'  \
 362         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 363
 364     complete msgchk \
 365         'c/-/(nodate date nonotify notify help)/'
 366
 367     complete msh \
 368         'c/-/(prompt noscan scan notopcur topcur help)/'
 369
 370     complete next \
 371         'c/-/(draft form moreproc nomoreproc length width showproc noshowproc header noheader help)/' \
 372         'c,+,$folders,'  \
 373         'n,-moreproc,c,'  \
 374         'n,-showproc,c,'  \
 375         'n,-form,f,'
 376
 377     complete packf \
 378         'c/-/(file help)/' \
 379         'c,+,$folders,'  \
 380         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 381
 382     complete pick \
 383         'c/-/(and or not lbrace rbrace cc date from search subject to othercomponent after before datefield sequence nopublic public nozero zero nolist list help)/' \
 384         'c,+,$folders,'  \
 385         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 386
 387     complete prev \
 388         'c/-/(draft form moreproc nomoreproc length width showproc noshowproc header noheader help)/' \
 389         'c,+,$folders,'  \
 390         'n,-moreproc,c,'  \
 391         'n,-showproc,c,'  \
 392         'n,-form,f,'
 393
 394     complete prompter \
 395         'c/-/(erase kill noprepend prepend norapid rapid nodoteof doteof help)/'
 396
 397     complete refile \
 398         'c/-/(draft nolink link nopreserve preserve src file help)/' \
 399         'c,+,$folders,'  \
 400         'n,-file,f,'\
 401         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 402
 403     complete rmf \
 404         'c/-/(nointeractive interactive help)/' \
 405         'c,+,$folders,'
 406
 407     complete rmm \
 408         'c/-/(help)/' \
 409         'c,+,$folders,'  \
 410         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 411
 412     complete scan \
 413         'c/-/(noclear clear form format noheader header width noreverse reverse file help)/' \
 414         'c,+,$folders,'  \
 415         'n,-form,f,'\
 416         'n,-file,f,'\
 417         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 418
 419     complete send \
 420         'c/-/(alias draft draftfolder draftmessage nodraftfolder filter nofilter noformat format noforward forward nomsgid msgid nopush push noverbose verbose nowatch watch width help)/' \
 421         'n,-alias,f,'\
 422         'n,-filter,f,'
 423
 424     complete show \
 425         'c/-/(draft form moreproc nomoreproc length width showproc noshowproc header noheader help)/' \
 426         'c,+,$folders,'  \
 427         'n,-moreproc,c,'  \
 428         'n,-showproc,c,'  \
 429         'n,-form,f,'\
 430         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 431
 432     complete sortm \
 433         'c/-/(datefield textfield notextfield limit nolimit noverbose verbose help)/' \
 434         'c,+,$folders,'  \
 435         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 436
 437     complete vmh \
 438         'c/-/(prompt vmhproc novmhproc help)/' \
 439         'n,-vmhproc,c,'
 440
 441     complete whatnow \
 442         'c/-/(draftfolder draftmessage nodraftfolder editor noedit prompt help)/'
 443
 444     complete whom \
 445         'c/-/(alias nocheck check draft draftfolder draftmessage nodraftfolder help)/' \
 446         'n,-alias,f,'
 447
 448     complete plum \
 449         'c/-/()/' \
 450         'c,+,$folders,'  \
 451         'n,*,`(mark | sed "s/:.*//";echo next cur prev first last)|tr " " "\12" | sort -u`,'
 452
 453     complete mail \
 454         'c/-/()/' \
 455         'n/*/$mha/'
 456
 457     endif
 458
 459     #from Dan Nicolaescu <dann@ics.uci.edu>
 460     if ( $?MODULESHOME ) then
 461         alias Compl_module 'find ${MODULEPATH:as/:/ /} -name .version -o -name .modulea\* -prune -o -print  | sed `echo "-e s@${MODULEPATH:as%:%/\*@@g -e s@%}/\*@@g"`'
 462         complete module 'p%1%(add load unload switch display avail use unuse update purge list clear help initadd initrm initswitch initlist initclear)%' \
 463         'n%{unl*,sw*,inits*}%`echo "$LOADEDMODULES:as/:/ /"`%' \
 464         'n%{lo*,di*,he*,inita*,initr*}%`eval Compl_module`%' \
 465         'N%{sw*,initsw*}%`eval Compl_module`%' 'C%-%(-append)%' 'n%{use,unu*,av*}%d%' 'n%-append%d%' \
 466         'C%[^-]*%`eval Compl_module`%'
 467     endif
 468
 469     # from George Cox
 470     complete acroread   'p/*/f:*.{pdf,PDF}/'
 471     complete apachectl  'c/*/(start stop restart fullstatus status graceful \
 472                         configtest help)/'
 473     complete appletviewer       'p/*/f:*.class/'
 474     complete bison      'c/--/(debug defines file-prefix= fixed-output-files \
 475                         help name-prefix= no-lines no-parser output= \
 476                         token-table verbose version yacc)/' \
 477                         'c/-/(b d h k l n o p t v y V)/' 'n/-b/f/' 'n/-o/f/' \
 478                         'n/-p/f/'
 479     complete bunzip2    'p/*/f:*.bz2/'
 480     complete bzip2      'n/-9/f:^*.bz2/' 'n/-d/f:*.bz2/'
 481     complete c++        'p/*/f:*.{c++,cxx,c,cc,C,cpp}/'
 482     complete co         'p@1@`\ls -1a RCS | sed -e "s/\(.*\),v/\1/"`@'
 483     complete crontab    'n/-u/u/'
 484     complete camcontrol 'p/1/(cmd debug defects devlist eject inquiry \
 485                         modepage negotiate periphlist rescan reset start \
 486                         stop tags tur)/'
 487     complete ctlinnd    'p/1/(addhist allow begin cancel changegroup \
 488                         checkfile drop feedinfo flush flushlogs go hangup \
 489                         logmode mode name newgroup param pause readers refile \
 490                         reject reload renumber reserve rmgroup send shutdown \
 491                         kill throttle trace xabort xexec)/'
 492     complete cvs        'c/--/(help help-commands help-synonyms)/' \
 493                         'p/1/(add admin annotate checkout commit diff \
 494                         edit editors export history import init log login \
 495                         logout rdiff release remove rtag status tag unedit \
 496                         update watch watchers)/' 'n/-a/(edit unedit commit \
 497                         all none)/' 'n/watch/(on off add remove)/'
 498     complete cxx        'p/*/f:*.{c++,cxx,c,cc,C,cpp}/'
 499     complete detex      'p/*/f:*.tex/'
 500     complete edquota    'n/*/u/'
 501     complete exec       'p/1/c/'
 502     complete ghostview  'p/*/f:*.ps/'
 503     complete gv         'p/*/f:*.ps/'
 504     complete ifconfig   'p@1@`ifconfig -l`@' 'n/*/(range phase link netmask \
 505                         mtu vlandev vlan metric mediaopt down delete \
 506                         broadcast arp debug)/'
 507     complete imake      'c/-I/d/'
 508     complete ipfw       'p/1/(flush add delete list show zero)/' \
 509                         'n/add/(allow permit accept pass deny drop reject \
 510                         reset count skipto num divert port tee port)/'
 511     complete javac      'p/*/f:*.java/'
 512     complete ldif2ldbm  'n/-i/f:*.ldif/'
 513     complete libtool    'c/--mode=/(compile execute finish install link \
 514                         uninstall)/' 'c/--/(config debug dry-run features \
 515                         finish help quiet silent version mode=)/'
 516     complete libtoolize 'c/--/(automake copy debug dry-run force help ltdl \
 517                         ltdl-tar version)/'
 518     complete links      'c/-/(assume-codepage async-dns download-dir \
 519                         format-cache-size ftp-proxy help http-proxy \
 520                         max-connections max-connections-to-host \
 521                         memory-cache-size receive-timeout retries \
 522                         unrestartable-receive-timeout version)/'
 523     complete natd       c/-/'(alias_address config deny_incoming dynamic \
 524                         inport interface log log_denied log_facility \
 525                         outport outport port pptpalias proxy_only \
 526                         proxy_rule redirect_address redirect_port \
 527                         reverse same_ports unregistered_only use_sockets \
 528                         verbose)'/ 'n@-interface@`ifconfig -l`@'
 529     complete netstat    'n@-I@`ifconfig -l`@'
 530     complete objdump    'c/--/(adjust-vma= all-headers architecture= \
 531                         archive-headers debugging demangle disassemble \
 532                         disassemble-all disassemble-zeroes dynamic-reloc \
 533                         dynamic-syms endian= file-headers full-contents \
 534                         headers help info line-numbers no-show-raw-insn \
 535                         prefix-addresses private-headers reloc section-headers \
 536                         section=source stabs start-address= stop-address= \
 537                         syms target= version wide)/' \
 538                         'c/-/(a h i f C d D p r R t T x s S l w)/'
 539     complete xmodmap    'c/-/(display help grammar verbose quiet n e pm pk \
 540                         pke pp)/'
 541     complete lynx       'c/-/(accept_all_cookies anonymous assume_charset= \
 542                         assume_local_charset= assume_unrec_charset= auth= base \
 543                         book buried_news cache= case cfg= child cookie_file= \
 544                         cookies core crawl debug_partial display= dump editor= \
 545                         emacskeys enable_scrollback error_file= force_html \
 546                         force_secure forms_options from ftp get_data head help \
 547                         hiddenlinks= historical homepage= image_links index= \
 548                         ismap link= localhost mime_header minimal \
 549                         newschunksize= newsmaxchunk= nobrowse nocc nocolor \
 550                         nofilereferer nolist nolog nopause noprint noredir \
 551                         noreferer nostatus number_links partial partial_thres \
 552                         pauth= popup post_data preparsed print pseudo_inlines \
 553                         raw realm reload restrictions= resubmit_posts rlogin \
 554                         selective show_cursor soft_dquotes source stack_dump \
 555                         startfile_ok tagsoup telnet term= tlog trace traversal \
 556                         underscore useragent= validate verbose version vikeys \
 557                         width=)/' 'c/(http|ftp)/$URLS/'
 558     complete gmake      'c/{--directory=,--include-dir=}/d/' \
 559                         'c/{--assume-new,--assume-old,--makefile,--new-file,--what-if,--file}/f/' \
 560                         'c/--/(assume-new= assume-old= debug directory= \
 561                         dry-run environment-overrides file= help \
 562                         ignore-errors include-dir= jobs[=N] just-print \
 563                         keep-going load-average[=N] makefile= max-load[=N] \
 564                         new-file= no-builtin-rules no-keep-going \
 565                         no-print-directory old-file= print-data-base \
 566                         print-directory question quiet recon silent stop \
 567                         touch version warn-undefined-variables what-if=)/' \
 568                         'n@*@`cat -s GNUMakefile Makefile makefile |& sed -n -e "/No such file/d" -e "s/^\([A-Za-z0-9-]*\):.*/\1/p"`@' \
 569                         'n/=/f/' 'n/-f/f/'
 570     complete mixer      p/1/'(vol bass treble synth pcm speaker mic cd mix \
 571                         pcm2 rec igain ogain line1 line2 line3)'/ \
 572                         p@2@'`mixer $:-1 | awk \{\ print\ \$7\ \}`'@
 573
 574     complete mpg123     'c/--/(2to1 4to1 8bit aggressive au audiodevice \
 575                         auth buffer cdr check doublespeed equalizer frames \
 576                         gain halfspeed headphones left lineout list mix mono \
 577                         proxy quiet random rate reopen resync right scale \
 578                         shuffle single0 single1 skip speaker stdout stereo \
 579                         test verbose wav)/'
 580     complete mysqladmin 'n/*/(create drop extended-status flush-hosts \
 581                         flush-logs flush-status flush-tables flush-privileges \
 582                         kill password ping processlist reload refresh \
 583                         shutdown status variables version)/'
 584     complete mutt       c@-f=@F:${HOME}/Mail/@ \
 585                         n/-a/f/ \
 586                         n/-F/f/ n/-H/f/ \
 587                         n/-s/x:'<subject line>'/ \
 588                         n/-e/x:'<command>'/ \
 589                         n@-b@'`cat ${HOME}/.muttrc-alias | awk '"'"'{print $2 }'"'"\`@ \
 590                         n@-c@'`cat ${HOME}/.muttrc-alias | awk '"'"'{print $2 }'"'"\`@ \
 591                         n@*@'`cat ${HOME}/.muttrc-alias | awk '"'"'{print $2 }'"'"\`@
 592     complete ndc        'n/*/(status dumpdb reload stats trace notrace \
 593                         querylog start stop restart )/'
 594         if ($?traditional_complete) then
 595     complete nm         'c/--/(debug-syms defined-only demangle dynamic \
 596                         extern-only format= help line-numbers no-demangle \
 597                         no-sort numeric-sort portability print-armap \
 598                         print-file-name reverse-sort size-sort undefined-only \
 599                         version)/' 'p/*/f:^*.{h,C,c,cc}/'
 600         else
 601         complete nm     'c/--radix=/x:<radix: _o_ctal _d_ecimal he_x_adecimal>/' \
 602                 'c/--target=/x:<bfdname>/' \
 603                 'c/--format=/(bsd sysv posix)/n/' \
 604                 'c/--/(debugsyms extern-only demangle dynamic print-armap \
 605                         print-file-name numeric-sort no-sort reverse-sort \
 606                         size-sort undefined-only portability target= radix= \
 607                         format= defined-only\ line-numbers no-demangle version \
 608                         help)//' \
 609                 'n/*/f:^*.{h,c,cc,s,S}/'
 610         endif
 611     complete nmap       'n@-e@`ifconfig -l`@' 'p/*/$hostnames/'
 612     complete perldoc    'n@*@`\ls -1 /usr/libdata/perl/5.*/pod | sed s%\\.pod.\*\$%%`@'
 613     complete postfix    'n/*/(start stop reload abort flush check)/'
 614     complete postmap    'n/1/(hash: regexp:)' 'c/hash:/f/' 'c/regexp:/f/'
 615     complete rcsdiff    'p@1@`\ls -1a RCS | sed -e "s/\(.*\),v/\1/"`@'
 616     complete X          'c/-/(I a ac allowMouseOpenFail allowNonLocalModInDev \
 617                         allowNonLocalXvidtune ar1 ar2 audit auth bestRefresh \
 618                         bgamma bpp broadcast bs c cc class co core deferglyphs \
 619                         disableModInDev disableVidMode displayID dpi dpms f fc \
 620                         flipPixels fn fp gamma ggamma help indirect kb keeptty \
 621                         ld lf logo ls nolisten string noloadxkb nolock nopn \
 622                         once p pn port probeonly query quiet r rgamma s \
 623                         showconfig sp su t terminate to tst v verbose version \
 624                         weight wm x xkbdb xkbmap)/'
 625     complete users      'c/--/(help version)/' 'p/1/x:"<accounting_file>"/'
 626     complete vidcontrol 'p/1/(132x25 132x30 132x43 132x50 132x60 40x25 80x25 \
 627                         80x30 80x43 80x50 80x60 EGA_80x25 EGA_80x43 \
 628                         VESA_132x25 VESA_132x30 VESA_132x43 VESA_132x50 \
 629                         VESA_132x60 VESA_800x600 VGA_320x200 VGA_40x25 \
 630                         VGA_80x25 VGA_80x30 VGA_80x50 VGA_80x60)/'
 631     complete vim        'n/*/f:^*.[oa]/'
 632     complete where      'n/*/c/'
 633     complete which      'n/*/c/'
 634     complete wmsetbg    'c/-/(display D S a b c d e m p s t u w)/' \
 635                         'c/--/(back-color center colors dither help match \
 636                         maxscale parse scale smooth tile update-domain \
 637                         update-wmaker version workspace)/'
 638     complete xdb        'p/1/c/'
 639     complete xdvi       'c/-/(allowshell debug display expert gamma hushchars \
 640                         hushchecksums hushspecials install interpreter keep \
 641                         margins nogrey noinstall nomakepk noscan paper safer \
 642                         shrinkbuttonn thorough topmargin underlink version)/' \
 643                         'n/-paper/(a4 a4r a5 a5r)/' 'p/*/f:*.dvi/'
 644     complete xlock      'c/-/(allowaccess allowroot debug description \
 645                         echokeys enablesaver grabmouse grabserver hide inroot \
 646                         install inwindow mono mousemotion nolock remote \
 647                         resetsaver sound timeelapsed use3d usefirst verbose \
 648                         wireframe background batchcount bg bitmap both3d \
 649                         count cycles delay delta3d display dpmsoff \
 650                         dpmsstandby dpmssuspend endCmd erasedelay erasemode \
 651                         erasetime fg font foreground geometry help \
 652                         icongeometry info invalid left3d lockdelay logoutCmd \
 653                         mailCmd mailIcon message messagefile messagefont \
 654                         messagesfile mode name ncolors nice nomailIcon none3d \
 655                         parent password planfont program resources right3d \
 656                         saturation size startCmd timeout username validate \
 657                         version visual)/' 'n/-mode/(ant atlantis ball bat \
 658                         blot bouboule bounce braid bubble bubble3d bug cage \
 659                         cartoon clock coral crystal daisy dclock decay deco \
 660                         demon dilemma discrete drift eyes fadeplot flag flame \
 661                         flow forest galaxy gears goop grav helix hop hyper \
 662                         ico ifs image invert julia kaleid kumppa lament laser \
 663                         life life1d life3d lightning lisa lissie loop lyapunov \
 664                         mandelbrot marquee matrix maze moebius morph3d \
 665                         mountain munch nose pacman penrose petal pipes puzzle \
 666                         pyro qix roll rotor rubik shape sierpinski slip sphere \
 667                         spiral spline sproingies stairs star starfish strange \
 668                         superquadrics swarm swirl tetris thornbird triangle \
 669                         tube turtle vines voters wator wire world worm xjack \
 670                         blank bomb random)/'
 671     complete xfig       'c/-/(display)/' 'p/*/f:*.fig/'
 672     complete wget       c/--/"(accept= append-output= background cache= \
 673                         continue convert-links cut-dirs= debug \
 674                         delete-after directory-prefix= domains= \
 675                         dont-remove-listing dot-style= exclude-directories= \
 676                         exclude-domains= execute= follow-ftp \
 677                         force-directories force-html glob= header= help \
 678                         http-passwd= http-user= ignore-length \
 679                         include-directories= input-file= level= mirror \
 680                         no-clobber no-directories no-host-directories \
 681                         no-host-lookup no-parent non-verbose \
 682                         output-document= output-file= passive-ftp \
 683                         proxy-passwd= proxy-user= proxy= quiet quota= \
 684                         recursive reject= relative retr-symlinks save-headers \
 685                         server-response span-hosts spider timeout= \
 686                         timestamping tries= user-agent= verbose version wait=)"/
 687
 688     # these from Tom Warzeka <tom@waz.cc>
 689
 690     # this one works but is slow and doesn't descend into subdirectories
 691     # complete  cd      C@[./\$~]*@d@ \
 692     #                   p@1@'`\ls -1F . $cdpath | grep /\$ | sort -u`'@ n@*@n@
 693
 694     if ( -r /etc/shells ) then
 695         complete setenv p@1@e@ n@DISPLAY@\$hosts@: n@SHELL@'`cat /etc/shells`'@
 696     else
 697         complete setenv p@1@e@ n@DISPLAY@\$hosts@:
 698     endif
 699     complete unsetenv   n/*/e/
 700
 701     set _maildir = /var/mail
 702     if (-r $HOME/.mailrc) then
 703         complete mail   c/-/"(e i f n s u v)"/ c/*@/\$hosts/ \
 704                         c@+@F:$HOME/Mail@ C@[./\$~]@f@ n/-s/x:'<subject>'/ \
 705                         n@-u@T:$_maildir@ n/-f/f/ \
 706                         n@*@'`sed -n s/alias//p $HOME/.mailrc | tr -s " " "     " | cut -f 2`'@
 707     else
 708         complete mail   c/-/"(e i f n s u v)"/ c/*@/\$hosts/ \
 709                         c@+@F:$HOME/Mail@ C@[./\$~]@f@ n/-s/x:'<subject>'/ \
 710                         n@-u@T:$_maildir@ n/-f/f/ n/*/u/
 711     endif
 712     unset _maildir
 713
 714     if (! $?MANPATH) then
 715         if (-r /usr/share/man) then
 716             setenv MANPATH /usr/share/man:
 717         else
 718             setenv MANPATH /usr/man:
 719         endif
 720     endif
 721
 722         if ($?traditional_complete) then
 723     # use of $MANPATH from Dan Nicolaescu <dann@ics.uci.edu>
 724     # use of 'find' adapted from Lubomir Host <host8@kepler.fmph.uniba.sk>
 725     complete man \
 726             'n@1@`set q = "$MANPATH:as%:%/man1 %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.1.\*\$%%`@'\
 727             'n@2@`set q = "$MANPATH:as%:%/man2 %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.2.\*\$%%`@'\
 728             'n@3@`set q = "$MANPATH:as%:%/man3 %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.3.\*\$%%`@'\
 729             'n@4@`set q = "$MANPATH:as%:%/man4 %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.4.\*\$%%`@'\
 730             'n@5@`set q = "$MANPATH:as%:%/man5 %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.5.\*\$%%`@'\
 731             'n@6@`set q = "$MANPATH:as%:%/man6 %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.6.\*\$%%`@'\
 732             'n@7@`set q = "$MANPATH:as%:%/man7 %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.7.\*\$%%`@'\
 733             'n@8@`set q = "$MANPATH:as%:%/man8 %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.8.\*\$%%`@'\
 734             'n@9@`set q = "$MANPATH:as%:%/man9 %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.9.\*\$%%`@'\
 735             'n@0@`set q = "$MANPATH:as%:%/man0 %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.0.\*\$%%`@'\
 736             'n@n@`set q = "$MANPATH:as%:%/mann %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.n.\*\$%%`@'\
 737             'n@o@`set q = "$MANPATH:as%:%/mano %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.o.\*\$%%`@'\
 738             'n@l@`set q = "$MANPATH:as%:%/manl %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.l.\*\$%%`@'\
 739             'n@p@`set q = "$MANPATH:as%:%/manp %" ; \ls -1 $q |& sed -e s%^.\*:.\*\$%% -e s%\\.p.\*\$%%`@'\
 740             c@-@"(- f k M P s S t)"@ n@-f@c@ n@-k@x:'<keyword>'@ n@-[MP]@d@   \
 741             'N@-[MP]@`\ls -1 $:-1/man? |& sed -n s%\\..\\+\$%%p`@'            \
 742             'n@-[sS]@`\ls -1 $MANPATH:as%:% % |& sed -n s%^man%%p | sort -u`@'\
 743             'n@*@`find $MANPATH:as%:% % \( -type f -o -type l \) -printf "%f " |& sed -e "s%find: .*: No such file or directory%%" -e "s%\([^\.]\+\)\.\([^ ]*\) %\1 %g"`@'
 744             #n@*@c@ # old way -- commands only
 745         else
 746     complete man            n@1@'`\ls -1 /usr/man/man1 | sed s%\\.1.\*\$%%`'@ \
 747                             n@2@'`\ls -1 /usr/man/man2 | sed s%\\.2.\*\$%%`'@ \
 748                             n@3@'`\ls -1 /usr/man/man3 | sed s%\\.3.\*\$%%`'@ \
 749                             n@4@'`\ls -1 /usr/man/man4 | sed s%\\.4.\*\$%%`'@ \
 750                             n@5@'`\ls -1 /usr/man/man5 | sed s%\\.5.\*\$%%`'@ \
 751                             n@6@'`\ls -1 /usr/man/man6 | sed s%\\.6.\*\$%%`'@ \
 752                             n@7@'`\ls -1 /usr/man/man7 | sed s%\\.7.\*\$%%`'@ \
 753                             n@8@'`\ls -1 /usr/man/man8 | sed s%\\.8.\*\$%%`'@ \
 754     n@9@'`[ -r /usr/man/man9 ] && \ls -1 /usr/man/man9 | sed s%\\.9.\*\$%%`'@ \
 755     n@0@'`[ -r /usr/man/man0 ] && \ls -1 /usr/man/man0 | sed s%\\.0.\*\$%%`'@ \
 756   n@new@'`[ -r /usr/man/mann ] && \ls -1 /usr/man/mann | sed s%\\.n.\*\$%%`'@ \
 757   n@old@'`[ -r /usr/man/mano ] && \ls -1 /usr/man/mano | sed s%\\.o.\*\$%%`'@ \
 758 n@local@'`[ -r /usr/man/manl ] && \ls -1 /usr/man/manl | sed s%\\.l.\*\$%%`'@ \
 759 n@public@'`[ -r /usr/man/manp ]&& \ls -1 /usr/man/manp | sed s%\\.p.\*\$%%`'@ \
 760                 c/-/"(- f k P s t)"/ n/-f/c/ n/-k/x:'<keyword>'/ n/-P/d/ \
 761                 N@-P@'`\ls -1 $:-1/man? | sed s%\\..\*\$%%`'@ n/*/c/
 762         endif
 763
 764     complete ps         c/-t/x:'<tty>'/ c/-/"(a c C e g k l S t u v w x)"/ \
 765                         n/-k/x:'<kernel>'/ N/-k/x:'<core_file>'/ n/*/x:'<PID>'/
 766     complete compress   c/-/"(c f v b)"/ n/-b/x:'<max_bits>'/ n/*/f:^*.Z/
 767     complete uncompress c/-/"(c f v)"/                        n/*/f:*.Z/
 768
 769     complete uuencode   p/1/f/ p/2/x:'<decode_pathname>'/ n/*/n/
 770     complete uudecode   c/-/"(f)"/ n/-f/f:*.{uu,UU}/ p/1/f:*.{uu,UU}/ n/*/n/
 771
 772     complete xhost      c/[+-]/\$hosts/ n/*/\$hosts/
 773     complete xpdf       c/-/"(z g remote raise quit cmap rgb papercolor       \
 774                               eucjp t1lib freetype ps paperw paperh level1    \
 775                               upw fullscreen cmd q v h help)"/                \
 776                         n/-z/x:'<zoom (-5 .. +5) or "page" or "width">'/      \
 777                         n/-g/x:'<geometry>'/ n/-remote/x:'<name>'/            \
 778                         n/-rgb/x:'<number>'/ n/-papercolor/x:'<color>'/       \
 779                         n/-{t1lib,freetype}/x:'<font_type>'/                  \
 780                         n/-ps/x:'<PS_file>'/ n/-paperw/x:'<width>'/           \
 781                         n/-paperh/x:'<height>'/ n/-upw/x:'<password>'/        \
 782                         n/-/f:*.{pdf,PDF}/                                    \
 783                         N/-{z,g,remote,rgb,papercolor,t1lib,freetype,ps,paperw,paperh,upw}/f:*.{pdf,PDF}/ \
 784                         N/-/x:'<page>'/ p/1/f:*.{pdf,PDF}/ p/2/x:'<page>'/
 785
 786     complete tcsh       c/-D*=/'x:<value>'/ c/-D/'x:<name>'/ \
 787                         c/-/"(b c d D e f F i l m n q s t v V x X -version)"/ \
 788                         n/-c/c/ n/{-l,--version}/n/ n/*/'f:*.{,t}csh'/
 789
 790     complete rpm        c/--/"(query verify nodeps nofiles nomd5 noscripts    \
 791                         nogpg nopgp install upgrade freshen erase allmatches  \
 792                         notriggers repackage test rebuild recompile initdb    \
 793                         rebuilddb addsign resign querytags showrc setperms    \
 794                         setugids all file group package querybynumber qf      \
 795                         triggeredby whatprovides whatrequires changelog       \
 796                         configfiles docfiles dump filesbypkg info last list   \
 797                         provides queryformat requires scripts state triggers  \
 798                         triggerscripts allfiles badreloc excludepath checksig \
 799                         excludedocs force hash ignoresize ignorearch ignoreos \
 800                         includedocs justdb noorder oldpackage percent prefix  \
 801                         relocate replace-files replacepkgs buildroot clean    \
 802                         nobuild rmsource rmspec short-circuit sign target     \
 803                         help version quiet rcfile pipe dbpath root specfile)"/\
 804                         c/-/"(q V K i U F e ba bb bp bc bi bl bs ta tb tp tc  \
 805                         ti tl ts a f g p c d l R s h ? v vv -)"/              \
 806                 n/{-f,--file}/f/ n/{-g,--group}/g/ n/--pipe/c/ n/--dbpath/d/  \
 807                 n/--querybynumber/x:'<number>'/ n/--triggeredby/x:'<package>'/\
 808                 n/--what{provides,requires}/x:'<capability>'/ n/--root/d/     \
 809                 n/--{qf,queryformat}/x:'<format>'/ n/--buildroot/d/           \
 810                 n/--excludepath/x:'<oldpath>'/  n/--prefix/x:'<newpath>'/     \
 811                 n/--relocate/x:'<oldpath=newpath>'/ n/--target/x:'<platform>'/\
 812                 n/--rcfile/x:'<filelist>'/ n/--specfile/x:'<specfile>'/       \
 813                 n/{-[iUFep],--{install,upgrade,freshen,erase,package}}/f:*.rpm/
 814
 815     # these conform to the latest GNU versions available at press time ...
 816     # updates by John Gotts <jgotts@engin.umich.edu>
 817     if (-X emacs) then
 818       # TW note:  if your version of GNU Emacs supports the "--version" option,
 819       #           uncomment this line and comment the next to automatically
 820       #           detect the version, else set "_emacs_ver" to your version.
 821       #set _emacs_ver=`emacs --version | sed -e 's%GNU Emacs %%' -e q | cut -d . -f1-2`
 822       set _emacs_ver=21.3
 823       set _emacs_dir=`which emacs | sed s%/bin/emacs%%`
 824       complete emacs    c/--/"(batch terminal display no-windows no-init-file \
 825                                user debug-init unibyte multibyte version help \
 826                                no-site-file funcall load eval insert kill)"/ \
 827                         c/-/"(t d nw q u f l -)"/ c/+/x:'<line_number>'/ \
 828                         n/{-t,--terminal}/x:'<terminal>'/ n/{-d,--display}/x:'<display>'/ \
 829                         n/{-u,--user}/u/ n/{-f,--funcall}/x:'<lisp_function>'/ \
 830                         n@{-l,--load}@F:$_emacs_dir/share/emacs/$_emacs_ver/lisp@ \
 831                         n/--eval/x:'<expression>'/ n/--insert/f/ n/*/f:^*[\#~]/
 832       unset _emacs_ver _emacs_dir
 833     endif
 834
 835     complete gzcat      c/--/"(force help license quiet version)"/ \
 836                         c/-/"(f h L q V -)"/ n/*/f:*.{gz,Z,z,zip}/
 837     complete gzip       c/--/"(stdout to-stdout decompress uncompress \
 838                         force help list license no-name quiet recurse \
 839                         suffix test verbose version fast best)"/ \
 840                         c/-/"(c d f h l L n q r S t v V 1 2 3 4 5 6 7 8 9 -)"/\
 841                         n/{-S,--suffix}/x:'<file_name_suffix>'/ \
 842                         n/{-d,--{de,un}compress}/f:*.{gz,Z,z,zip,taz,tgz}/ \
 843                         N/{-d,--{de,un}compress}/f:*.{gz,Z,z,zip,taz,tgz}/ \
 844                         n/*/f:^*.{gz,Z,z,zip,taz,tgz}/
 845     complete {gunzip,ungzip} c/--/"(stdout to-stdout force help list license \
 846                         no-name quiet recurse suffix test verbose version)"/ \
 847                         c/-/"(c f h l L n q r S t v V -)"/ \
 848                         n/{-S,--suffix}/x:'<file_name_suffix>'/ \
 849                         n/*/f:*.{gz,Z,z,zip,taz,tgz}/
 850     complete zgrep      c/-*A/x:'<#_lines_after>'/ c/-*B/x:'<#_lines_before>'/\
 851                         c/-/"(A b B c C e f h i l n s v V w x)"/ \
 852                         p/1/x:'<limited_regular_expression>'/ N/-*e/f/ \
 853                         n/-*e/x:'<limited_regular_expression>'/ n/-*f/f/ n/*/f/
 854     complete zegrep     c/-*A/x:'<#_lines_after>'/ c/-*B/x:'<#_lines_before>'/\
 855                         c/-/"(A b B c C e f h i l n s v V w x)"/ \
 856                         p/1/x:'<full_regular_expression>'/ N/-*e/f/ \
 857                         n/-*e/x:'<full_regular_expression>'/ n/-*f/f/ n/*/f/
 858     complete zfgrep     c/-*A/x:'<#_lines_after>'/ c/-*B/x:'<#_lines_before>'/\
 859                         c/-/"(A b B c C e f h i l n s v V w x)"/ \
 860                         p/1/x:'<fixed_string>'/ N/-*e/f/ \
 861                         n/-*e/x:'<fixed_string>'/ n/-*f/f/ n/*/f/
 862     complete znew       c/-/"(f t v 9 P K)"/ n/*/f:*.Z/
 863     complete zmore      n/*/f:*.{gz,Z,z,zip}/
 864     complete zfile      n/*/f:*.{gz,Z,z,zip,taz,tgz}/
 865     complete ztouch     n/*/f:*.{gz,Z,z,zip,taz,tgz}/
 866     complete zforce     n/*/f:^*.{gz,tgz}/
 867
 868     complete dcop 'p/1/`$:0`/ /' \
 869         'p/2/`$:0 $:1 | awk \{print\ \$1\}`/ /' \
 870         'p/3/`$:0 $:1 $:2 | sed "s%.* \(.*\)(.*%\1%"`/ /'
 871
 872
 873     complete grep       c/-*A/x:'<#_lines_after>'/ c/-*B/x:'<#_lines_before>'/\
 874                         c/--/"(extended-regexp fixed-regexp basic-regexp \
 875                         regexp file ignore-case word-regexp line-regexp \
 876                         no-messages revert-match version help byte-offset \
 877                         line-number with-filename no-filename quiet silent \
 878                         text directories recursive files-without-match \
 879                         files-with-matches count before-context after-context \
 880                         context binary unix-byte-offsets)"/ \
 881                         c/-/"(A a B b C c d E e F f G H h i L l n q r s U u V \
 882                                 v w x)"/ \
 883                         p/1/x:'<limited_regular_expression>'/ N/-*e/f/ \
 884                         n/-*e/x:'<limited_regular_expression>'/ n/-*f/f/ n/*/f/
 885     complete egrep      c/-*A/x:'<#_lines_after>'/ c/-*B/x:'<#_lines_before>'/\
 886                         c/--/"(extended-regexp fixed-regexp basic-regexp \
 887                         regexp file ignore-case word-regexp line-regexp \
 888                         no-messages revert-match version help byte-offset \
 889                         line-number with-filename no-filename quiet silent \
 890                         text directories recursive files-without-match \
 891                         files-with-matches count before-context after-context \
 892                         context binary unix-byte-offsets)"/ \
 893                         c/-/"(A a B b C c d E e F f G H h i L l n q r s U u V \
 894                                 v w x)"/ \
 895                         p/1/x:'<full_regular_expression>'/ N/-*e/f/ \
 896                         n/-*e/x:'<full_regular_expression>'/ n/-*f/f/ n/*/f/
 897     complete fgrep      c/-*A/x:'<#_lines_after>'/ c/-*B/x:'<#_lines_before>'/\
 898                         c/--/"(extended-regexp fixed-regexp basic-regexp \
 899                         regexp file ignore-case word-regexp line-regexp \
 900                         no-messages revert-match version help byte-offset \
 901                         line-number with-filename no-filename quiet silent \
 902                         text directories recursive files-without-match \
 903                         files-with-matches count before-context after-context \
 904                         context binary unix-byte-offsets)"/ \
 905                         c/-/"(A a B b C c d E e F f G H h i L l n q r s U u V \
 906                                 v w x)"/ \
 907                         p/1/x:'<fixed_string>'/ N/-*e/f/ \
 908                         n/-*e/x:'<fixed_string>'/ n/-*f/f/ n/*/f/
 909
 910     complete sed        c/--/"(quiet silent version help expression file)"/   \
 911                         c/-/"(n V e f -)"/ n/{-e,--expression}/x:'<script>'/  \
 912                         n/{-f,--file}/f:*.sed/ N/-{e,f,-{file,expression}}/f/ \
 913                         n/-/x:'<script>'/ N/-/f/ p/1/x:'<script>'/ p/2/f/
 914
 915     complete users      c/--/"(help version)"/ p/1/x:'<accounting_file>'/
 916     complete who        c/--/"(heading idle count mesg message writable help \
 917                         version)"/ c/-/"(H i m q s T w u -)"/ \
 918                         p/1/x:'<accounting_file>'/ n/am/"(i)"/ n/are/"(you)"/
 919
 920     complete chown      c/--/"(changes dereference no-dereference silent \
 921                         quiet reference recursive verbose help version)"/ \
 922                         c/-/"(c f h R v -)"/ C@[./\$~]@f@ c/*[.:]/g/ \
 923                         n/-/u/: p/1/u/: n/*/f/
 924     complete chgrp      c/--/"(changes no-dereference silent quiet reference \
 925                         recursive verbose help version)"/ \
 926                         c/-/"(c f h R v -)"/ n/-/g/ p/1/g/ n/*/f/
 927     complete chmod      c/--/"(changes silent quiet verbose reference \
 928                         recursive help version)"/ c/-/"(c f R v)"/
 929     complete df         c/--/"(all block-size human-readable si inodes \
 930                         kilobytes local megabytes no-sync portability sync \
 931                         type print-type exclude-type help version)"/ \
 932                         c/-/"(a H h i k l m P T t v x)"/
 933     complete du         c/--/"(all block-size bytes total dereference-args \
 934                         human-readable si kilobytes count-links dereference \
 935                         megabytes separate-dirs summarize one-file-system \
 936                         exclude-from exclude max-depth help version"/ \
 937                         c/-/"(a b c D H h k L l m S s X x)"/
 938
 939     complete cat        c/--/"(number-nonblank number squeeze-blank show-all \
 940                         show-nonprinting show-ends show-tabs help version)"/ \
 941                         c/-/"(A b E e n s T t u v -)"/ n/*/f/
 942     complete mv         c/--/"(backup force interactive update verbose suffix \
 943                         version-control help version)"/ \
 944                         c/-/"(b f i S u V v -)"/ \
 945                         n/{-S,--suffix}/x:'<suffix>'/ \
 946                         n/{-V,--version-control}/"(t numbered nil existing \
 947                         never simple)"/ n/-/f/ N/-/d/ p/1/f/ p/2/d/ n/*/f/
 948     complete cp         c/--/"(archive backup no-dereference force \
 949                         interactive link preserve parents sparse recursive \
 950                         symbolic-link suffix update verbose version-control \
 951                         one-file-system help version)"/ \
 952                         c/-/"(a b d f i l P p R r S s u V v x -)"/ \
 953                         n/-*r/d/ n/{-S,--suffix}/x:'<suffix>'/ \
 954                         n/{-V,--version-control}/"(t numbered nil existing \
 955                         never simple)"/ n/-/f/ N/-/d/ p/1/f/ p/2/d/ n/*/f/
 956     complete ln         c/--/"(backup directory force no-dereference \
 957                         interactive symbolic suffix verbose version-control \
 958                         help version)"/ \
 959                         c/-/"(b d F f i n S s V v -)"/ \
 960                         n/{-S,--suffix}/x:'<suffix>'/ \
 961                         n/{-V,--version-control}/"(t numbered nil existing \
 962                         never simple)"/ n/-/f/ N/-/x:'<link_name>'/ \
 963                         p/1/f/ p/2/x:'<link_name>'/
 964     complete touch      c/--/"(date reference time help version)"/ \
 965                         c/-/"(a c d f m r t -)"/ \
 966                         n/{-d,--date}/x:'<date_string>'/ \
 967                         c/--time/"(access atime mtime modify use)"/ \
 968                         n/{-r,--file}/f/ n/-t/x:'<time_stamp>'/ n/*/f/
 969     complete mkdir      c/--/"(mode parents verbose help version)"/ \
 970                         c/-/"(p m -)"/ \
 971                         n/{-m,--mode}/x:'<mode>'/ n/*/d/
 972     complete rmdir      c/--/"(ignore-fail-on-non-empty parents verbose help \
 973                         version)"/ c/-/"(p -)"/ n/*/d/
 974     complete env        'c/*=/f/' 'p/1/e/=/' 'p/2/c/'
 975
 976     complete tar        c/-[Acru]*/"(b B C f F g G h i l L M N o P \
 977                         R S T v V w W X z Z)"/ \
 978                         c/-[dtx]*/"( B C f F g G i k K m M O p P \
 979                         R s S T v w x X z Z)"/ \
 980                         p/1/"(A c d r t u x -A -c -d -r -t -u -x \
 981                         --catenate --concatenate --create --diff --compare \
 982                         --delete --append --list --update --extract --get \
 983                         --help --version)"/ \
 984                         c/--/"(catenate concatenate create diff compare \
 985                         delete append list update extract get atime-preserve \
 986                         block-size read-full-blocks directory checkpoint file \
 987                         force-local info-script new-volume-script incremental \
 988                         listed-incremental dereference ignore-zeros \
 989                         ignore-failed-read keep-old-files starting-file \
 990                         one-file-system tape-length modification-time \
 991                         multi-volume after-date newer old-archive portability \
 992                         to-stdout same-permissions preserve-permissions \
 993                         absolute-paths preserve record-number remove-files \
 994                         same-order preserve-order same-owner sparse \
 995                         files-from null totals verbose label version \
 996                         interactive confirmation verify exclude exclude-from \
 997                         compress uncompress gzip ungzip use-compress-program \
 998                         block-compress help version)"/ \
 999                         c/-/"(b B C f F g G h i k K l L m M N o O p P R s S \
1000                         T v V w W X z Z 0 1 2 3 4 5 6 7 -)"/ \
1001                         C@/dev@f@ \
1002                         n/-c*f/x:'<new_tar_file, device_file, or "-">'/ \
1003                         n/{-[Adrtux]z*f,--file}/f:*.{tar.gz,tgz}/ \
1004                         n/{-[Adrtux]Z*f,--file}/f:*.{tar.Z,taz}/ \
1005                         n/{-[Adrtux]*f,--file}/f:*.tar/ \
1006                         N/{-xz*f,--file}/'`tar -tzf $:-1`'/ \
1007                         N/{-xZ*f,--file}/'`tar -tZf $:-1`'/ \
1008                         N/{-x*f,--file}/'`tar -tf $:-1`'/ \
1009                         n/--use-compress-program/c/ \
1010                         n/{-b,--block-size}/x:'<block_size>'/ \
1011                         n/{-V,--label}/x:'<volume_label>'/ \
1012                         n/{-N,--{after-date,newer}}/x:'<date>'/ \
1013                         n/{-L,--tape-length}/x:'<tape_length_in_kB>'/ \
1014                         n/{-C,--directory}/d/ \
1015                         N/{-C,--directory}/'`\ls $:-1`'/ \
1016                         n/-[0-7]/"(l m h)"/
1017
1018     # SVR4 filesystems
1019     complete  mount     c/-/"(a F m o O p r v V)"/ n/-p/n/ n/-v/n/ \
1020                         n/-o/x:'<FSType_options>'/ \
1021                         n@-F@'`\ls -1 /usr/lib/fs`'@ \
1022                         n@*@'`grep -v "^#" /etc/vfstab | tr -s " " "     " | cut -f 3`'@
1023     complete umount     c/-/"(a o V)"/ n/-o/x:'<FSType_options>'/ \
1024                         n/*/'`mount | cut -d " " -f 1`'/
1025     complete  mountall  c/-/"(F l r)"/ n@-F@'`\ls -1 /usr/lib/fs`'@
1026     complete umountall  c/-/"(F h k l r s)"/ n@-F@'`\ls -1 /usr/lib/fs`'@ \
1027                         n/-h/'`df -k | cut -s -d ":" -f 1 | sort -u`'/
1028     # BSD 4.3 filesystems
1029     #complete  mount    c/-/"(a r t v)"/ n/-t/"(4.2 nfs)"/ \
1030     #                   n@*@'`grep -v "^#" /etc/fstab | tr -s " " "     " | cut -f 2`'@
1031     #complete umount    c/-/"(a h t v)"/ n/-t/"(4.2 nfs)"/ \
1032     #                   n/-h/'`df | cut -s -d ":" -f 1 | sort -u`'/ \
1033     #                   n/*/'`mount | cut -d " " -f 3`'/
1034     # BSD 4.2 filesystems
1035     #complete  mount    c/-/"(a r t v)"/ n/-t/"(ufs nfs)"/ \
1036     #                   n@*@'`cut -d ":" -f 2 /etc/fstab`'@
1037     #complete umount    c/-/"(a h t v)"/ n/-t/"(ufs nfs)"/ \
1038     #                   n/-h/'`df | cut -s -d ":" -f 1 | sort -u`'/ \
1039     #                   n/*/'`mount | cut -d " " -f 3`'/
1040
1041     # these deal with NIS (formerly YP); if it's not running you don't need 'em
1042     if (-X domainname) then
1043       set _domain = "`domainname`"
1044       set _ypdir  = /var/yp     # directory where NIS (YP) maps are kept
1045       if ("$_domain" != "" && "$_domain" != "noname") then
1046         complete domainname p@1@D:$_ypdir@" " n@*@n@
1047         complete ypcat      c@-@"(d k t x)"@ n@-x@n@ n@-d@D:$_ypdir@" " \
1048                             N@-d@\`\\ls\ -1\ $_ypdir/\$:-1\ \|\ sed\ -n\ s%\\\\.pag\\\$%%p\`@ \
1049                             n@*@\`\\ls\ -1\ $_ypdir/$_domain\ \|\ sed\ -n\ s%\\\\.pag\\\$%%p\`@
1050         complete ypmatch    c@-@"(d k t x)"@ n@-x@n@ n@-d@D:$_ypdir@" " \
1051                             N@-d@x:'<key ...>'@ n@-@x:'<key ...>'@ p@1@x:'<key ...>'@ \
1052                             n@*@\`\\ls\ -1\ $_ypdir/$_domain\ \|\ sed\ -n\ s%\\\\.pag\\\$%%p\`@
1053         complete ypwhich    c@-@"(d m t x V1 V2)"@ n@-x@n@ n@-d@D:$_ypdir@" " \
1054                             n@-m@\`\\ls\ -1\ $_ypdir/$_domain\ \|\ sed\ -n\ s%\\\\.pag\\\$%%p\`@ \
1055                             N@-m@n@ n@*@\$hosts@
1056       endif
1057       unset _domain _ypdir
1058     endif
1059
1060     complete make \
1061         'n/-f/f/' \
1062         'c/*=/f/' \
1063         'n@*@`cat -s GNUmakefile Makefile makefile |& sed -n -e "/No such file/d" -e "/^[^     #].*:/s/:.*//p"`@'
1064
1065     if ( -f /etc/printcap ) then
1066         set printers=(`sed -n -e "/^[^     #].*:/s/:.*//p" /etc/printcap`)
1067
1068         complete lpr    'c/-P/$printers/'
1069         complete lpq    'c/-P/$printers/'
1070         complete lprm   'c/-P/$printers/'
1071         complete lpquota        'p/1/(-Qprlogger)/' 'c/-P/$printers/'
1072         complete dvips  'c/-P/$printers/' 'n/-o/f:*.{ps,PS}/' 'n/*/f:*.dvi/'
1073         complete dvilj  'p/*/f:*.dvi/'
1074     endif
1075
1076     # From Alphonse Bendt
1077     complete ant \
1078          'n/-f/f:*.xml/' \
1079               'n@*@`cat build.xml | sed -n -e "s/[ \t]*<target[\t\n]*name=.\([a-zA-Z0-9_:]*\).*/\1/p"`@'
1080
1081     if ($?P4CLIENT && -X perl) then
1082         # This is from Greg Allen.
1083         set p4cmds=(add branch branches commands change changes client clients \
1084             counter counters delete depot depots describe diff diff2 \
1085             edit filelog files fix fixes fstat group groups have help \
1086             info integrate integrated job jobs jobspec label labels \
1087             labelsync lock obliterate opened passwd print protect rename \
1088             reopen resolve resolved revert review reviews set submit \
1089             sync triggers unlock user users verify where)
1090         complete p4 'p/1/$p4cmds/' 'n/help/$p4cmds/' \
1091             'n%{-l,label}%`p4 labels | sed "s/Label \([^ ]*\) .*/\1/"`%' \
1092             'n%-t%`p4 $:1s | sed "s/[^ ]* \([^ ]*\) .*/\1/"`%' \
1093             'c%*@%`p4 labels | sed "s/Label \([^ ]*\) .*/\1/"`%' \
1094             'c@//*/*@`p4 files $:-0... |& perl -nle "m%\Q$:-0\E([^#][^/# ] \
1095             *)%;print "\$"1 if \\\!/no such/&&\!"\$"h{"\$"1}++"`@@' \
1096             'c@//@`p4 depots | sed "s/Depot \([^ ]*\) .*/\1/"`@/@'
1097     endif
1098
1099
1100         if (! $?traditional_complete) then
1101     uncomplete vi
1102     uncomplete vim
1103     complete {vi,vim,gvim,nvi,elvis}    n/*/f:^*.{o,a,so,sa,aux,dvi,log,fig,bbl,blg,bst,idx,ilg,ind,toc}/
1104     complete {ispell,spell,spellword}   'n@-d@`ls /usr/lib/ispell/*.aff | sed -e "s/\.aff//" `@' 'n/*/f:^*.{o,a,so,sa,aux,dvi,log,fig,bbl,blg,bst,idx,ilg,ind,toc}/'
1105     complete elm        'n/-[Ai]/f/' 'c@=@F:$HOME/Mail/@' 'n/-s/x:\<subject\>/'
1106     complete ncftp      'n@*@`sed -e '1,2d' $HOME/.ncftp/bookmarks | cut -f 1,2 -d "," | tr "," "\012" | sort | uniq ` '@
1107     complete bibtex     'n@*@`ls *.aux | sed -e "s/\.aux//"`'@
1108     complete dvi2tty    n/*/f:*.dvi/    # Only files that match *.dvi
1109         uncomplete gv
1110         uncomplete ghostview
1111     complete {gv,ghostview}     'n/*/f:*.{ps,eps,epsi}/'
1112     complete enscript \
1113                 'c/--/(columns= pages= header= no-header truncate-lines \
1114                         line-numbers setpagedevice= escapes font= \
1115                         header-font= fancy-header no-job-header \
1116                         highlight-bars indent= filter= borders page-prefeed \
1117                         no-page-prefeed lineprinter lines-per-page= mail \
1118                         media= copies= newline= output= missing-characters \
1119                         printer= quiet silent landscape portrait \
1120                         baselineskip= statusdict= title= tabsize= underlay= \
1121                         verbose version encoding pass-through download-font= \
1122                         filter-stdin= help highlight-bar-gray= list-media \
1123                         list-options non-printable-format= page-label-format= \
1124                         printer-options= ul-angle= ul-font= ul-gray= \
1125                         ul-position= ul-style= \
1126                      )/'
1127         endif
1128
1129 complete dpkg   'c/--{admindir,instdir,root}=/d/' \
1130                 'c/--debug=/n/' \
1131                 'c/--{admindir,debug,instdir,root}/(=)//' \
1132                 'c/--/(admindir= debug= instdir= root= \
1133                         assert-support-predepends assert-working-epoch \
1134                         audit auto-deconfigure clear-avail \
1135                         compare-versions configure contents control \
1136                         extract force-bad-path field \
1137                         force-configure-any force-conflicts \
1138                         force-depends force-depends-version force-help \
1139                         force-hold force-non-root \
1140                         force-overwrite-diverted \
1141                         force-remove-essential force-remove-reinstreq \
1142                         forget-old-unavail fsys-tarfile get-selections \
1143                         help ignore-depends info install largemem \
1144                         license list listfiles merge-avail no-act \
1145                         pending predep-package print-architecture \
1146                         print-gnu-build-architecture \
1147                         print-installation-architecture print-avail \
1148                         purge record-avail recursive refuse-downgrade \
1149                         remove search set-selections selected-only \
1150                         skip-same-version smallmem status unpack \
1151                         update-avail version vextract \
1152                       )//' \
1153                 'n/{-l}/`dpkg -l|awk \{print\ \$2\}`/' \
1154                 'n/*/f:*.deb'/
1155 complete dpkg-deb 'c/--{build}=/d/' \
1156                            'c/--/(build contents info field control extract \
1157                                  vextract fsys-tarfile help version \
1158                                  license)//' \
1159                            'n/*/f:*.deb/'
1160 complete apt-get 'c/--/(build config-file diff-only download-only \
1161                    fix-broken fix-missing force-yes help ignore-hold no-download \
1162                    no-upgrade option print-uris purge reinstall quiet simulate \
1163                    show-upgraded target-release tar-only version yes )/' \
1164                 'c/-/(b c= d f h m o= q qq s t x y )/' \
1165                 'n/{source,build-dep}/x:<pkgname>/' \
1166                 'n/{remove}/`dpkg -l|grep ^ii|awk \{print\ \$2\}`/' \
1167                 'n/{install}/`apt-cache pkgnames | sort`/' \
1168                 'C/*/(update upgrade dselect-upgrade source \
1169                    build-dep check clean autoclean install remove)/'
1170 complete apt-cache \
1171                 'c/--/(all-versions config-file generate full help important \
1172                 names-only option pkg-cache quiet recurse src-cache version )/' \
1173                 'c/-/(c= h i o= p= q s= v)/' \
1174                 'n/{search}/x:<regex>/' \
1175                 'n/{pkgnames,policy,show,showpkg,depends,dotty}/`apt-cache pkgnames | sort`/' \
1176                 'C/*/(add gencaches showpkg stats dump dumpavail unmet show \
1177                 search depends pkgnames dotty policy )/'
1178
1179     unset noglob
1180     unset _complete
1181     unset traditional_complete
1182 endif
1183
1184 end:
1185         onintr