contrib/tzdata/leapseconds.awk

   1 # Generate zic format 'leapseconds' from NIST/IERS format 'leap-seconds.list'.
   2
   3 # This file is in the public domain.
   4
   5 # This program uses awk arithmetic.  POSIX requires awk to support
   6 # exact integer arithmetic only through 10**10, which means for NTP
   7 # timestamps this program works only to the year 2216, which is the
   8 # year 1900 plus 10**10 seconds.  However, in practice
   9 # POSIX-conforming awk implementations invariably use IEEE-754 double
  10 # and so support exact integers through 2**53.  By the year 2216,
  11 # POSIX will almost surely require at least 2**53 for awk, so for NTP
  12 # timestamps this program should be good until the year 285,428,681
  13 # (the year 1900 plus 2**53 seconds).  By then leap seconds will be
  14 # long obsolete, as the Earth will likely slow down so much that
  15 # there will be more than 25 hours per day and so some other scheme
  16 # will be needed.
  17
  18 BEGIN {
  19   print "# Allowance for leap seconds added to each time zone file."
  20   print ""
  21   print "# This file is in the public domain."
  22   print ""
  23   print "# This file is generated automatically from the data in the public-domain"
  24   print "# NIST/IERS format leap-seconds.list file, which can be copied from"
  25   print "# <https://hpiers.obspm.fr/iers/bul/bulc/ntp/leap-seconds.list>"
  26   print "# or, in a variant with different comments, from"
  27   print "# <ftp://ftp.boulder.nist.gov/pub/time/leap-seconds.list>."
  28   print "# For more about leap-seconds.list, please see"
  29   print "# The NTP Timescale and Leap Seconds"
  30   print "# <https://www.eecis.udel.edu/~mills/leap.html>."
  31   print ""
  32   print "# The rules for leap seconds are specified in Annex 1 (Time scales) of:"
  33   print "# Standard-frequency and time-signal emissions."
  34   print "# International Telecommunication Union - Radiocommunication Sector"
  35   print "# (ITU-R) Recommendation TF.460-6 (02/2002)"
  36   print "# <https://www.itu.int/rec/R-REC-TF.460-6-200202-I/>."
  37   print "# The International Earth Rotation and Reference Systems Service (IERS)"
  38   print "# periodically uses leap seconds to keep UTC to within 0.9 s of UT1"
  39   print "# (a proxy for Earth's angle in space as measured by astronomers)"
  40   print "# and publishes leap second data in a copyrighted file"
  41   print "# <https://hpiers.obspm.fr/iers/bul/bulc/Leap_Second.dat>."
  42   print "# See: Levine J. Coordinated Universal Time and the leap second."
  43   print "# URSI Radio Sci Bull. 2016;89(4):30-6. doi:10.23919/URSIRSB.2016.7909995"
  44   print "# <https://ieeexplore.ieee.org/document/7909995>."
  45   print ""
  46   print "# There were no leap seconds before 1972, as no official mechanism"
  47   print "# accounted for the discrepancy between atomic time (TAI) and the earth's"
  48   print "# rotation.  The first (\"1 Jan 1972\") data line in leap-seconds.list"
  49   print "# does not denote a leap second; it denotes the start of the current definition"
  50   print "# of UTC."
  51   print ""
  52   print "# All leap-seconds are Stationary (S) at the given UTC time."
  53   print "# The correction (+ or -) is made at the given time, so in the unlikely"
  54   print "# event of a negative leap second, a line would look like this:"
  55   print "# Leap YEAR    MON     DAY     23:59:59        -       S"
  56   print "# Typical lines look like this:"
  57   print "# Leap YEAR    MON     DAY     23:59:60        +       S"
  58
  59   monthabbr[ 1] = "Jan"
  60   monthabbr[ 2] = "Feb"
  61   monthabbr[ 3] = "Mar"
  62   monthabbr[ 4] = "Apr"
  63   monthabbr[ 5] = "May"
  64   monthabbr[ 6] = "Jun"
  65   monthabbr[ 7] = "Jul"
  66   monthabbr[ 8] = "Aug"
  67   monthabbr[ 9] = "Sep"
  68   monthabbr[10] = "Oct"
  69   monthabbr[11] = "Nov"
  70   monthabbr[12] = "Dec"
  71
  72   sstamp_init()
  73 }
  74
  75 # In case the input has CRLF form a la NIST.
  76 { sub(/\r$/, "") }
  77
  78 /^#[ \t]*[Uu]pdated through/ || /^#[ \t]*[Ff]ile expires on/ {
  79     last_lines = last_lines $0 "\n"
  80 }
  81
  82 /^#[$][ \t]/ { updated = $2 }
  83 /^#[@][ \t]/ { expires = $2 }
  84
  85 /^[ \t]*#/ { next }
  86
  87 {
  88     NTP_timestamp = $1
  89     TAI_minus_UTC = $2
  90     if (old_TAI_minus_UTC) {
  91         if (old_TAI_minus_UTC < TAI_minus_UTC) {
  92             sign = "23:59:60\t+"
  93         } else {
  94             sign = "23:59:59\t-"
  95         }
  96         sstamp_to_ymdhMs(NTP_timestamp - 1, ss_NTP)
  97         printf "Leap\t%d\t%s\t%d\t%s\tS\n", \
  98           ss_year, monthabbr[ss_month], ss_mday, sign
  99     }
 100     old_TAI_minus_UTC = TAI_minus_UTC
 101 }
 102
 103 END {
 104     print ""
 105
 106     if (expires) {
 107       sstamp_to_ymdhMs(expires, ss_NTP)
 108
 109       print "# UTC timestamp when this leap second list expires."
 110       print "# Any additional leap seconds will come after this."
 111       if (! EXPIRES_LINE) {
 112         print "# This Expires line is commented out for now,"
 113         print "# so that pre-2020a zic implementations do not reject this file."
 114       }
 115       printf "%sExpires %.4d\t%s\t%.2d\t%.2d:%.2d:%.2d\n", \
 116         EXPIRES_LINE ? "" : "#", \
 117         ss_year, monthabbr[ss_month], ss_mday, ss_hour, ss_min, ss_sec
 118     } else {
 119       print "# (No Expires line, since the expires time is unknown.)"
 120     }
 121
 122     # The difference between the NTP and POSIX epochs is 70 years
 123     # (including 17 leap days), each 24 hours of 60 minutes of 60
 124     # seconds each.
 125     epoch_minus_NTP = ((1970 - 1900) * 365 + 17) * 24 * 60 * 60
 126
 127     print ""
 128     print "# POSIX timestamps for the data in this file:"
 129     if (updated) {
 130       sstamp_to_ymdhMs(updated, ss_NTP)
 131       printf "#updated %d (%.4d-%.2d-%.2d %.2d:%.2d:%.2d UTC)\n", \
 132         updated - epoch_minus_NTP, \
 133         ss_year, ss_month, ss_mday, ss_hour, ss_min, ss_sec
 134     } else {
 135       print "#(updated time unknown)"
 136     }
 137     if (expires) {
 138       sstamp_to_ymdhMs(expires, ss_NTP)
 139       printf "#expires %d (%.4d-%.2d-%.2d %.2d:%.2d:%.2d UTC)\n", \
 140         expires - epoch_minus_NTP, \
 141         ss_year, ss_month, ss_mday, ss_hour, ss_min, ss_sec
 142     } else {
 143       print "#(expires time unknown)"
 144     }
 145     printf "\n%s", last_lines
 146 }
 147
 148 # sstamp_to_ymdhMs - convert seconds timestamp to date and time
 149 #
 150 # Call as:
 151 #
 152 #    sstamp_to_ymdhMs(sstamp, epoch_days)
 153 #
 154 # where:
 155 #
 156 #    sstamp - is the seconds timestamp.
 157 #    epoch_days - is the timestamp epoch in Gregorian days since 1600-03-01.
 158 #       ss_NTP is appropriate for an NTP sstamp.
 159 #
 160 # Both arguments should be nonnegative integers.
 161 # On return, the following variables are set based on sstamp:
 162 #
 163 #    ss_year    - Gregorian calendar year
 164 #    ss_month   - month of the year (1-January to 12-December)
 165 #    ss_mday    - day of the month (1-31)
 166 #    ss_hour    - hour (0-23)
 167 #    ss_min     - minute (0-59)
 168 #    ss_sec     - second (0-59)
 169 #    ss_wday    - day of week (0-Sunday to 6-Saturday)
 170 #
 171 # The function sstamp_init should be called prior to using sstamp_to_ymdhMs.
 172
 173 function sstamp_init()
 174 {
 175   # Days in month N, where March is month 0 and January month 10.
 176   ss_mon_days[ 0] = 31
 177   ss_mon_days[ 1] = 30
 178   ss_mon_days[ 2] = 31
 179   ss_mon_days[ 3] = 30
 180   ss_mon_days[ 4] = 31
 181   ss_mon_days[ 5] = 31
 182   ss_mon_days[ 6] = 30
 183   ss_mon_days[ 7] = 31
 184   ss_mon_days[ 8] = 30
 185   ss_mon_days[ 9] = 31
 186   ss_mon_days[10] = 31
 187
 188   # Counts of days in a Gregorian year, quad-year, century, and quad-century.
 189   ss_year_days = 365
 190   ss_quadyear_days = ss_year_days * 4 + 1
 191   ss_century_days = ss_quadyear_days * 25 - 1
 192   ss_quadcentury_days = ss_century_days * 4 + 1
 193
 194   # Standard day epochs, suitable for epoch_days.
 195   # ss_MJD = 94493
 196   # ss_POSIX = 135080
 197   ss_NTP = 109513
 198 }
 199
 200 function sstamp_to_ymdhMs(sstamp, epoch_days, \
 201                           quadcentury, century, quadyear, year, month, day)
 202 {
 203   ss_hour = int(sstamp / 3600) % 24
 204   ss_min = int(sstamp / 60) % 60
 205   ss_sec = sstamp % 60
 206
 207   # Start with a count of days since 1600-03-01 Gregorian.
 208   day = epoch_days + int(sstamp / (24 * 60 * 60))
 209
 210   # Compute a year-month-day date with days of the month numbered
 211   # 0-30, months (March-February) numbered 0-11, and years that start
 212   # start March 1 and end after the last day of February.  A quad-year
 213   # starts on March 1 of a year evenly divisible by 4 and ends after
 214   # the last day of February 4 years later.  A century starts on and
 215   # ends before March 1 in years evenly divisible by 100.
 216   # A quad-century starts on and ends before March 1 in years divisible
 217   # by 400.  While the number of days in a quad-century is a constant,
 218   # the number of days in each other time period can vary by 1.
 219   # Any variation is in the last day of the time period (there might
 220   # or might not be a February 29) where it is easy to deal with.
 221
 222   quadcentury = int(day / ss_quadcentury_days)
 223   day -= quadcentury * ss_quadcentury_days
 224   ss_wday = (day + 3) % 7
 225   century = int(day / ss_century_days)
 226   century -= century == 4
 227   day -= century * ss_century_days
 228   quadyear = int(day / ss_quadyear_days)
 229   day -= quadyear * ss_quadyear_days
 230   year = int(day / ss_year_days)
 231   year -= year == 4
 232   day -= year * ss_year_days
 233   for (month = 0; month < 11; month++) {
 234     if (day < ss_mon_days[month])
 235       break
 236     day -= ss_mon_days[month]
 237   }
 238
 239   # Convert the date to a conventional day of month (1-31),
 240   # month (1-12, January-December) and Gregorian year.
 241   ss_mday = day + 1
 242   if (month <= 9) {
 243     ss_month = month + 3
 244   } else {
 245     ss_month = month - 9
 246     year++
 247   }
 248   ss_year = 1600 + quadcentury * 400 + century * 100 + quadyear * 4 + year
 249 }