contrib/tzdata/leapseconds.awk

   1 # Generate zic format 'leapseconds' from NIST format 'leap-seconds.list'.
   2
   3 # This file is in the public domain.
   4
   5 # This program uses awk arithmetic.  POSIX requires awk to support
   6 # exact integer arithmetic only through 10**10, which means for NTP
   7 # timestamps this program works only to the year 2216, which is the
   8 # year 1900 plus 10**10 seconds.  However, in practice
   9 # POSIX-conforming awk implementations invariably use IEEE-754 double
  10 # and so support exact integers through 2**53.  By the year 2216,
  11 # POSIX will almost surely require at least 2**53 for awk, so for NTP
  12 # timestamps this program should be good until the year 285,428,681
  13 # (the year 1900 plus 2**53 seconds).  By then leap seconds will be
  14 # long obsolete, as the Earth will likely slow down so much that
  15 # there will be more than 25 hours per day and so some other scheme
  16 # will be needed.
  17
  18 BEGIN {
  19   print "# Allowance for leap seconds added to each time zone file."
  20   print ""
  21   print "# This file is in the public domain."
  22   print ""
  23   print "# This file is generated automatically from the data in the public-domain"
  24   print "# NIST format leap-seconds.list file, which can be copied from"
  25   print "# <ftp://ftp.nist.gov/pub/time/leap-seconds.list>"
  26   print "# or <ftp://ftp.boulder.nist.gov/pub/time/leap-seconds.list>."
  27   print "# The NIST file is used instead of its IERS upstream counterpart"
  28   print "# <https://hpiers.obspm.fr/iers/bul/bulc/ntp/leap-seconds.list>"
  29   print "# because under US law the NIST file is public domain"
  30   print "# whereas the IERS file's copyright and license status is unclear."
  31   print "# For more about leap-seconds.list, please see"
  32   print "# The NTP Timescale and Leap Seconds"
  33   print "# <https://www.eecis.udel.edu/~mills/leap.html>."
  34   print ""
  35   print "# The rules for leap seconds are specified in Annex 1 (Time scales) of:"
  36   print "# Standard-frequency and time-signal emissions."
  37   print "# International Telecommunication Union - Radiocommunication Sector"
  38   print "# (ITU-R) Recommendation TF.460-6 (02/2002)"
  39   print "# <https://www.itu.int/rec/R-REC-TF.460-6-200202-I/>."
  40   print "# The International Earth Rotation and Reference Systems Service (IERS)"
  41   print "# periodically uses leap seconds to keep UTC to within 0.9 s of UT1"
  42   print "# (a proxy for Earth's angle in space as measured by astronomers)"
  43   print "# and publishes leap second data in a copyrighted file"
  44   print "# <https://hpiers.obspm.fr/iers/bul/bulc/Leap_Second.dat>."
  45   print "# See: Levine J. Coordinated Universal Time and the leap second."
  46   print "# URSI Radio Sci Bull. 2016;89(4):30-6. doi:10.23919/URSIRSB.2016.7909995"
  47   print "# <https://ieeexplore.ieee.org/document/7909995>."
  48   print ""
  49   print "# There were no leap seconds before 1972, as no official mechanism"
  50   print "# accounted for the discrepancy between atomic time (TAI) and the earth's"
  51   print "# rotation.  The first (\"1 Jan 1972\") data line in leap-seconds.list"
  52   print "# does not denote a leap second; it denotes the start of the current definition"
  53   print "# of UTC."
  54   print ""
  55   print "# All leap-seconds are Stationary (S) at the given UTC time."
  56   print "# The correction (+ or -) is made at the given time, so in the unlikely"
  57   print "# event of a negative leap second, a line would look like this:"
  58   print "# Leap YEAR    MON     DAY     23:59:59        -       S"
  59   print "# Typical lines look like this:"
  60   print "# Leap YEAR    MON     DAY     23:59:60        +       S"
  61
  62   monthabbr[ 1] = "Jan"
  63   monthabbr[ 2] = "Feb"
  64   monthabbr[ 3] = "Mar"
  65   monthabbr[ 4] = "Apr"
  66   monthabbr[ 5] = "May"
  67   monthabbr[ 6] = "Jun"
  68   monthabbr[ 7] = "Jul"
  69   monthabbr[ 8] = "Aug"
  70   monthabbr[ 9] = "Sep"
  71   monthabbr[10] = "Oct"
  72   monthabbr[11] = "Nov"
  73   monthabbr[12] = "Dec"
  74
  75   sstamp_init()
  76 }
  77
  78 # In case the input has CRLF form a la NIST.
  79 { sub(/\r$/, "") }
  80
  81 /^#[ \t]*[Uu]pdated through/ || /^#[ \t]*[Ff]ile expires on/ {
  82     last_lines = last_lines $0 "\n"
  83 }
  84
  85 /^#[$][ \t]/ { updated = $2 }
  86 /^#[@][ \t]/ { expires = $2 }
  87
  88 /^[ \t]*#/ { next }
  89
  90 {
  91     NTP_timestamp = $1
  92     TAI_minus_UTC = $2
  93     if (old_TAI_minus_UTC) {
  94         if (old_TAI_minus_UTC < TAI_minus_UTC) {
  95             sign = "23:59:60\t+"
  96         } else {
  97             sign = "23:59:59\t-"
  98         }
  99         sstamp_to_ymdhMs(NTP_timestamp - 1, ss_NTP)
 100         printf "Leap\t%d\t%s\t%d\t%s\tS\n", \
 101           ss_year, monthabbr[ss_month], ss_mday, sign
 102     }
 103     old_TAI_minus_UTC = TAI_minus_UTC
 104 }
 105
 106 END {
 107     print ""
 108
 109     if (expires) {
 110       sstamp_to_ymdhMs(expires, ss_NTP)
 111
 112       print "# UTC timestamp when this leap second list expires."
 113       print "# Any additional leap seconds will come after this."
 114       if (! EXPIRES_LINE) {
 115         print "# This Expires line is commented out for now,"
 116         print "# so that pre-2020a zic implementations do not reject this file."
 117       }
 118       printf "%sExpires %.4d\t%s\t%.2d\t%.2d:%.2d:%.2d\n", \
 119         EXPIRES_LINE ? "" : "#", \
 120         ss_year, monthabbr[ss_month], ss_mday, ss_hour, ss_min, ss_sec
 121     } else {
 122       print "# (No Expires line, since the expires time is unknown.)"
 123     }
 124
 125     # The difference between the NTP and POSIX epochs is 70 years
 126     # (including 17 leap days), each 24 hours of 60 minutes of 60
 127     # seconds each.
 128     epoch_minus_NTP = ((1970 - 1900) * 365 + 17) * 24 * 60 * 60
 129
 130     print ""
 131     print "# POSIX timestamps for the data in this file:"
 132     if (updated) {
 133       sstamp_to_ymdhMs(updated, ss_NTP)
 134       printf "#updated %d (%.4d-%.2d-%.2d %.2d:%.2d:%.2d UTC)\n", \
 135         updated - epoch_minus_NTP, \
 136         ss_year, ss_month, ss_mday, ss_hour, ss_min, ss_sec
 137     } else {
 138       print "#(updated time unknown)"
 139     }
 140     if (expires) {
 141       sstamp_to_ymdhMs(expires, ss_NTP)
 142       printf "#expires %d (%.4d-%.2d-%.2d %.2d:%.2d:%.2d UTC)\n", \
 143         expires - epoch_minus_NTP, \
 144         ss_year, ss_month, ss_mday, ss_hour, ss_min, ss_sec
 145     } else {
 146       print "#(expires time unknown)"
 147     }
 148     printf "\n%s", last_lines
 149 }
 150
 151 # sstamp_to_ymdhMs - convert seconds timestamp to date and time
 152 #
 153 # Call as:
 154 #
 155 #    sstamp_to_ymdhMs(sstamp, epoch_days)
 156 #
 157 # where:
 158 #
 159 #    sstamp - is the seconds timestamp.
 160 #    epoch_days - is the timestamp epoch in Gregorian days since 1600-03-01.
 161 #       ss_NTP is appropriate for an NTP sstamp.
 162 #
 163 # Both arguments should be nonnegative integers.
 164 # On return, the following variables are set based on sstamp:
 165 #
 166 #    ss_year    - Gregorian calendar year
 167 #    ss_month   - month of the year (1-January to 12-December)
 168 #    ss_mday    - day of the month (1-31)
 169 #    ss_hour    - hour (0-23)
 170 #    ss_min     - minute (0-59)
 171 #    ss_sec     - second (0-59)
 172 #    ss_wday    - day of week (0-Sunday to 6-Saturday)
 173 #
 174 # The function sstamp_init should be called prior to using sstamp_to_ymdhMs.
 175
 176 function sstamp_init()
 177 {
 178   # Days in month N, where March is month 0 and January month 10.
 179   ss_mon_days[ 0] = 31
 180   ss_mon_days[ 1] = 30
 181   ss_mon_days[ 2] = 31
 182   ss_mon_days[ 3] = 30
 183   ss_mon_days[ 4] = 31
 184   ss_mon_days[ 5] = 31
 185   ss_mon_days[ 6] = 30
 186   ss_mon_days[ 7] = 31
 187   ss_mon_days[ 8] = 30
 188   ss_mon_days[ 9] = 31
 189   ss_mon_days[10] = 31
 190
 191   # Counts of days in a Gregorian year, quad-year, century, and quad-century.
 192   ss_year_days = 365
 193   ss_quadyear_days = ss_year_days * 4 + 1
 194   ss_century_days = ss_quadyear_days * 25 - 1
 195   ss_quadcentury_days = ss_century_days * 4 + 1
 196
 197   # Standard day epochs, suitable for epoch_days.
 198   # ss_MJD = 94493
 199   # ss_POSIX = 135080
 200   ss_NTP = 109513
 201 }
 202
 203 function sstamp_to_ymdhMs(sstamp, epoch_days, \
 204                           quadcentury, century, quadyear, year, month, day)
 205 {
 206   ss_hour = int(sstamp / 3600) % 24
 207   ss_min = int(sstamp / 60) % 60
 208   ss_sec = sstamp % 60
 209
 210   # Start with a count of days since 1600-03-01 Gregorian.
 211   day = epoch_days + int(sstamp / (24 * 60 * 60))
 212
 213   # Compute a year-month-day date with days of the month numbered
 214   # 0-30, months (March-February) numbered 0-11, and years that start
 215   # start March 1 and end after the last day of February.  A quad-year
 216   # starts on March 1 of a year evenly divisible by 4 and ends after
 217   # the last day of February 4 years later.  A century starts on and
 218   # ends before March 1 in years evenly divisible by 100.
 219   # A quad-century starts on and ends before March 1 in years divisible
 220   # by 400.  While the number of days in a quad-century is a constant,
 221   # the number of days in each other time period can vary by 1.
 222   # Any variation is in the last day of the time period (there might
 223   # or might not be a February 29) where it is easy to deal with.
 224
 225   quadcentury = int(day / ss_quadcentury_days)
 226   day -= quadcentury * ss_quadcentury_days
 227   ss_wday = (day + 3) % 7
 228   century = int(day / ss_century_days)
 229   century -= century == 4
 230   day -= century * ss_century_days
 231   quadyear = int(day / ss_quadyear_days)
 232   day -= quadyear * ss_quadyear_days
 233   year = int(day / ss_year_days)
 234   year -= year == 4
 235   day -= year * ss_year_days
 236   for (month = 0; month < 11; month++) {
 237     if (day < ss_mon_days[month])
 238       break
 239     day -= ss_mon_days[month]
 240   }
 241
 242   # Convert the date to a conventional day of month (1-31),
 243   # month (1-12, January-December) and Gregorian year.
 244   ss_mday = day + 1
 245   if (month <= 9) {
 246     ss_month = month + 3
 247   } else {
 248     ss_month = month - 9
 249     year++
 250   }
 251   ss_year = 1600 + quadcentury * 400 + century * 100 + quadyear * 4 + year
 252 }