contrib/unbound/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[8])
  14 m4_define([VERSION_MICRO],[1])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=8
  21 LIBUNBOUND_REVISION=1
  22 LIBUNBOUND_AGE=0
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75 # 1.6.4 had 7:3:5
  76 # 1.6.5 had 7:4:5
  77 # 1.6.6 had 7:5:5
  78 # 1.6.7 had 7:6:5
  79 # 1.6.8 had 7:7:5
  80 # 1.7.0 had 7:8:5
  81 # 1.7.1 had 7:9:5
  82 # 1.7.2 had 7:10:5
  83 # 1.7.3 had 7:11:5
  84 # 1.8.0 had 8:0:0 # changes the event callback function signature
  85 # 1.8.1 had 8:1:0
  86
  87 #   Current  -- the number of the binary API that we're implementing
  88 #   Revision -- which iteration of the implementation of the binary
  89 #               API are we supplying?
  90 #   Age      -- How many previous binary API versions do we also
  91 #               support?
  92 #
  93 # If we release a new version that does not change the binary API,
  94 # increment Revision.
  95 #
  96 # If we release a new version that changes the binary API, but does
  97 # not break programs compiled against the old binary API, increment
  98 # Current and Age.  Set Revision to 0, since this is the first
  99 # implementation of the new API.
 100 #
 101 # Otherwise, we're changing the binary API and breaking backward
 102 # compatibility with old binaries.  Increment Current.  Set Age to 0,
 103 # since we're backward compatible with no previous APIs.  Set Revision
 104 # to 0 too.
 105 AC_SUBST(LIBUNBOUND_CURRENT)
 106 AC_SUBST(LIBUNBOUND_REVISION)
 107 AC_SUBST(LIBUNBOUND_AGE)
 108
 109 CFLAGS="$CFLAGS"
 110 AC_AIX
 111 if test "$ac_cv_header_minix_config_h" = "yes"; then
 112         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 113 fi
 114
 115 dnl
 116 dnl By default set prefix to /usr/local
 117 dnl
 118 case "$prefix" in
 119         NONE)
 120                 prefix="/usr/local"
 121         ;;
 122 esac
 123 case "$exec_prefix" in
 124         NONE)
 125                 exec_prefix="$prefix"
 126         ;;
 127 esac
 128
 129 # are we on MinGW?
 130 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 131 else
 132         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 133         else on_mingw="no"; fi
 134 fi
 135
 136 #
 137 # Determine configuration file
 138 # the eval is to evaluate shell expansion twice
 139 UNBOUND_SBIN_DIR=`eval echo "${sbindir}"`
 140 AC_SUBST(UNBOUND_SBIN_DIR)
 141 UNBOUND_SYSCONF_DIR=`eval echo "${sysconfdir}"`
 142 AC_SUBST(UNBOUND_SYSCONF_DIR)
 143 UNBOUND_LOCALSTATE_DIR=`eval echo "${localstatedir}"`
 144 AC_SUBST(UNBOUND_LOCALSTATE_DIR)
 145 if test $on_mingw = "no"; then
 146   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 147 else
 148   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 149 fi
 150 AC_ARG_WITH([conf_file],
 151         AC_HELP_STRING([--with-conf-file=path],
 152         [Pathname to the Unbound configuration file]),
 153         [ub_conf_file="$withval"])
 154 AC_SUBST(ub_conf_file)
 155 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 156 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 157 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 158 AC_SUBST(ub_conf_dir)
 159
 160 # Determine run, chroot directory and pidfile locations
 161 AC_ARG_WITH(run-dir,
 162     AC_HELP_STRING([--with-run-dir=path],
 163     [set default directory to chdir to (by default dir part of cfg file)]),
 164     UNBOUND_RUN_DIR="$withval",
 165 if test $on_mingw = no; then
 166     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 167 else
 168     UNBOUND_RUN_DIR=""
 169 fi
 170 )
 171 AC_SUBST(UNBOUND_RUN_DIR)
 172 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 173 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 174
 175 AC_ARG_WITH(chroot-dir,
 176     AC_HELP_STRING([--with-chroot-dir=path],
 177     [set default directory to chroot to (by default same as run-dir)]),
 178     UNBOUND_CHROOT_DIR="$withval",
 179 if test $on_mingw = no; then
 180     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 181 else
 182     UNBOUND_CHROOT_DIR=""
 183 fi
 184 )
 185 AC_SUBST(UNBOUND_CHROOT_DIR)
 186 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 187 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 188
 189 AC_ARG_WITH(share-dir,
 190     AC_HELP_STRING([--with-share-dir=path],
 191     [set default directory with shared data (by default same as share/unbound)]),
 192     UNBOUND_SHARE_DIR="$withval",
 193     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 194 AC_SUBST(UNBOUND_SHARE_DIR)
 195 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 196
 197 AC_ARG_WITH(pidfile,
 198     AC_HELP_STRING([--with-pidfile=filename],
 199     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 200     UNBOUND_PIDFILE="$withval",
 201 if test $on_mingw = no; then
 202     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 203 else
 204     UNBOUND_PIDFILE=""
 205 fi
 206 )
 207 AC_SUBST(UNBOUND_PIDFILE)
 208 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 209 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 210
 211 AC_ARG_WITH(rootkey-file,
 212     AC_HELP_STRING([--with-rootkey-file=filename],
 213     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 214     UNBOUND_ROOTKEY_FILE="$withval",
 215 if test $on_mingw = no; then
 216     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 217 else
 218     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 219 fi
 220 )
 221 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 222 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 223 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 224
 225 AC_ARG_WITH(rootcert-file,
 226     AC_HELP_STRING([--with-rootcert-file=filename],
 227     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 228     UNBOUND_ROOTCERT_FILE="$withval",
 229 if test $on_mingw = no; then
 230     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 231 else
 232     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 233 fi
 234 )
 235 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 236 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 237 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 238
 239 AC_ARG_WITH(username,
 240     AC_HELP_STRING([--with-username=user],
 241     [set default user that unbound changes to (default user is unbound)]),
 242     UNBOUND_USERNAME="$withval",
 243     UNBOUND_USERNAME="unbound")
 244 AC_SUBST(UNBOUND_USERNAME)
 245 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 246
 247 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 248 ACX_RSRC_VERSION(wnvs)
 249 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 250
 251 # Checks for typedefs, structures, and compiler characteristics.
 252 AC_C_CONST
 253 AC_LANG_C
 254 # allow user to override the -g -O2 flags.
 255 default_cflags=no
 256 if test "x$CFLAGS" = "x" ; then
 257 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 258 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 259 default_cflags=yes
 260 fi
 261 AC_PROG_CC
 262 ACX_DEPFLAG
 263 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 264
 265 # debug mode flags warnings
 266 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 267 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 268 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 269 else debug_enabled="$enable_checking"; fi
 270 AC_SUBST(debug_enabled)
 271 case "$debug_enabled" in
 272         yes)
 273                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 274                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 275                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 276                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 277                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 278                 ;;
 279         no|*)
 280                 # nothing to do.
 281                 ;;
 282 esac
 283 if test "$default_cflags" = "yes"; then
 284         # only when CFLAGS was "" at the start, if the users wants to
 285         # override we shouldn't add default cflags, because they wouldn't
 286         # be able to turn off these options and set the CFLAGS wanted.
 287         ACX_CHECK_FLTO
 288         ACX_CHECK_PIE
 289         ACX_CHECK_RELRO_NOW
 290 fi
 291
 292 AC_C_INLINE
 293 ACX_CHECK_FORMAT_ATTRIBUTE
 294 ACX_CHECK_UNUSED_ATTRIBUTE
 295
 296 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 297 [AC_REQUIRE([AC_PROG_CC])
 298 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 299 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 300 [ac_cv_c_weak_attribute=no
 301 AC_TRY_COMPILE(
 302 [ #include <stdio.h>
 303 __attribute__((weak)) void f(int x) { printf("%d", x); }
 304 ], [
 305    f(1);
 306 ],
 307 [ac_cv_c_weak_attribute="yes"],
 308 [ac_cv_c_weak_attribute="no"])
 309 ])
 310
 311 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 312 if test $ac_cv_c_weak_attribute = yes; then
 313   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 314   AC_DEFINE(ATTR_WEAK, [__attribute__((weak))], [apply the weak attribute to a symbol])
 315 fi
 316 ])dnl End of CHECK_WEAK_ATTRIBUTE
 317
 318 CHECK_WEAK_ATTRIBUTE
 319
 320 AC_DEFUN([CHECK_NORETURN_ATTRIBUTE],
 321 [AC_REQUIRE([AC_PROG_CC])
 322 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "noreturn" attribute)
 323 AC_CACHE_VAL(ac_cv_c_noreturn_attribute,
 324 [ac_cv_c_noreturn_attribute=no
 325 AC_TRY_COMPILE(
 326 [ #include <stdio.h>
 327 __attribute__((noreturn)) void f(int x) { printf("%d", x); }
 328 ], [
 329    f(1);
 330 ],
 331 [ac_cv_c_noreturn_attribute="yes"],
 332 [ac_cv_c_noreturn_attribute="no"])
 333 ])
 334
 335 AC_MSG_RESULT($ac_cv_c_noreturn_attribute)
 336 if test $ac_cv_c_noreturn_attribute = yes; then
 337   AC_DEFINE(HAVE_ATTR_NORETURN, 1, [Whether the C compiler accepts the "noreturn" attribute])
 338   AC_DEFINE(ATTR_NORETURN, [__attribute__((__noreturn__))], [apply the noreturn attribute to a function that exits the program])
 339 fi
 340 ])dnl End of CHECK_NORETURN_ATTRIBUTE
 341
 342 CHECK_NORETURN_ATTRIBUTE
 343
 344 if test "$srcdir" != "."; then
 345         CPPFLAGS="$CPPFLAGS -I$srcdir"
 346 fi
 347
 348 AC_DEFUN([ACX_YYLEX_DESTROY], [
 349         AC_MSG_CHECKING([for yylex_destroy])
 350         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 351                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 352                 AC_MSG_RESULT(yes)
 353         else AC_MSG_RESULT(no);
 354                 LEX=":"
 355         fi
 356 ])
 357
 358 AC_DEFUN([ACX_YYLEX_OPTION], [
 359         AC_MSG_CHECKING([for lex %option])
 360         if cat <<EOF | $LEX -t 2>&1 | grep yy_delete_buffer >/dev/null 2>&1; then
 361 %option nounput
 362 %%
 363 EOF
 364                 AC_MSG_RESULT(yes)
 365         else AC_MSG_RESULT(no);
 366                 LEX=":"
 367         fi
 368 ])
 369
 370 AC_PROG_LEX
 371 if test "$LEX" != "" -a "$LEX" != ":"; then
 372 ACX_YYLEX_DESTROY
 373 fi
 374 if test "$LEX" != "" -a "$LEX" != ":"; then
 375 ACX_YYLEX_OPTION
 376 fi
 377 AC_PROG_YACC
 378 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 379 AC_CHECK_TOOL(STRIP, strip)
 380 ACX_LIBTOOL_C_ONLY
 381
 382 # Checks for header files.
 383 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/endian.h libkern/OSByteOrder.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 384
 385 # check for types.
 386 # Using own tests for int64* because autoconf builtin only give 32bit.
 387 AC_CHECK_TYPE(int8_t, signed char)
 388 AC_CHECK_TYPE(int16_t, short)
 389 AC_CHECK_TYPE(int32_t, int)
 390 AC_CHECK_TYPE(int64_t, long long)
 391 AC_CHECK_TYPE(uint8_t, unsigned char)
 392 AC_CHECK_TYPE(uint16_t, unsigned short)
 393 AC_CHECK_TYPE(uint32_t, unsigned int)
 394 AC_CHECK_TYPE(uint64_t, unsigned long long)
 395 AC_TYPE_SIZE_T
 396 AC_CHECK_TYPE(ssize_t, int)
 397 AC_TYPE_UID_T
 398 AC_TYPE_PID_T
 399 AC_TYPE_OFF_T
 400 ACX_TYPE_U_CHAR
 401 ACX_TYPE_RLIM_T
 402 ACX_TYPE_SOCKLEN_T
 403 ACX_TYPE_IN_ADDR_T
 404 ACX_TYPE_IN_PORT_T
 405 ACX_CHECK_MEMCMP_SIGNED
 406
 407 AC_CHECK_SIZEOF(time_t,,[
 408 AC_INCLUDES_DEFAULT
 409 #ifdef TIME_WITH_SYS_TIME
 410 # include <sys/time.h>
 411 # include <time.h>
 412 #else
 413 # ifdef HAVE_SYS_TIME_H
 414 #  include <sys/time.h>
 415 # else
 416 #  include <time.h>
 417 # endif
 418 #endif
 419 ])
 420
 421 # add option to disable the evil rpath
 422 ACX_ARG_RPATH
 423 AC_SUBST(RUNTIME_PATH)
 424
 425 # check to see if libraries are needed for these functions.
 426 AC_SEARCH_LIBS([inet_pton], [nsl])
 427 AC_SEARCH_LIBS([socket], [socket])
 428
 429 # check wether strptime also works
 430 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 431 [AC_REQUIRE([AC_PROG_CC])
 432 AC_MSG_CHECKING(whether strptime works)
 433 if test c${cross_compiling} = cno; then
 434 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 435 #define _XOPEN_SOURCE 600
 436 #include <time.h>
 437 int main(void) { struct tm tm; char *res;
 438 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 439 if (!res) return 2;
 440 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 441 if (!res) return 1; return 0; }
 442 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 443 else
 444 eval "ac_cv_c_strptime_works=maybe"
 445 fi
 446 AC_MSG_RESULT($ac_cv_c_strptime_works)
 447 if test $ac_cv_c_strptime_works = no; then
 448 AC_LIBOBJ(strptime)
 449 else
 450 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 451 fi
 452 ])dnl
 453
 454 # check some functions of the OS before linking libs (while still runnable).
 455 AC_FUNC_CHOWN
 456 AC_FUNC_FORK
 457 AC_TYPE_SIGNAL
 458 AC_FUNC_FSEEKO
 459 ACX_SYS_LARGEFILE
 460 ACX_CHECK_NONBLOCKING_BROKEN
 461 ACX_MKDIR_ONE_ARG
 462 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 463
 464 # check if we can use SO_REUSEPORT
 465 if echo "$host" | grep -i -e linux -e dragonfly >/dev/null; then
 466         AC_DEFINE(REUSEPORT_DEFAULT, 1, [if REUSEPORT is enabled by default])
 467 else
 468         AC_DEFINE(REUSEPORT_DEFAULT, 0, [if REUSEPORT is enabled by default])
 469 fi
 470
 471 # set memory allocation checking if requested
 472 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 473         [ enable to memory allocation statistics, for debug purposes ]),
 474         , )
 475 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 476         [ enable for lightweight alloc assertions, for debug purposes ]),
 477         , )
 478 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 479         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 480         , )
 481 if test x_$enable_alloc_nonregional = x_yes; then
 482         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 483 fi
 484 if test x_$enable_alloc_checks = x_yes; then
 485         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 486 else
 487         if test x_$enable_alloc_lite = x_yes; then
 488                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 489         else
 490                 ACX_FUNC_MALLOC([unbound])
 491         fi
 492 fi
 493
 494 # check windows threads (we use them, not pthreads, on windows).
 495 if test "$on_mingw" = "yes"; then
 496 # check windows threads
 497         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 498         AC_MSG_CHECKING([for CreateThread])
 499         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 500 #ifdef HAVE_WINDOWS_H
 501 #include <windows.h>
 502 #endif
 503 ], [
 504         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 505 ])],
 506         AC_MSG_RESULT(yes)
 507         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 508 ,
 509         AC_MSG_RESULT(no)
 510 )
 511
 512 else
 513 # not on mingw, check thread libraries.
 514
 515 # check for thread library.
 516 # check this first, so that the pthread lib does not get linked in via
 517 # libssl or libpython, and thus distorts the tests, and we end up using
 518 # the non-threadsafe C libraries.
 519 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 520  [use pthreads library, or --without-pthreads to disable threading support.]),
 521  [ ],[ withval="yes" ])
 522 ub_have_pthreads=no
 523 if test x_$withval != x_no; then
 524         AX_PTHREAD([
 525                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 526                 if test -n "$PTHREAD_LIBS"; then
 527                   LIBS="$PTHREAD_LIBS $LIBS"
 528                 fi
 529                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 530                 CC="$PTHREAD_CC"
 531                 ub_have_pthreads=yes
 532                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 533
 534                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 535                 AC_MSG_CHECKING([if -pthread unused during linking])
 536                 # catch clang warning 'argument unused during compilation'
 537                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 538 [[
 539 int main(void) {return 0;}
 540 ]])])
 541                 pthread_unused="yes"
 542                 # first compile
 543                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 544                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 545                 if test $? = 0; then
 546                         # then link
 547                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 548                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 549                         if test $? -ne 0; then
 550                                 AC_MSG_RESULT(yes)
 551                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 552                                 PTHREAD_CFLAGS_ONLY="-pthread"
 553                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 554                         else
 555                                 AC_MSG_RESULT(no)
 556                         fi
 557                 else
 558                         AC_MSG_RESULT(no)
 559                 fi # endif cc successful
 560                 rm -f conftest conftest.c conftest.o
 561                 fi # endif -pthread in CFLAGS
 562
 563                 ])
 564 fi
 565
 566 # check solaris thread library
 567 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 568         [use solaris native thread library.]), [ ],[ withval="no" ])
 569 ub_have_sol_threads=no
 570 if test x_$withval != x_no; then
 571         if test x_$ub_have_pthreads != x_no; then
 572             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 573         else
 574         AC_SEARCH_LIBS(thr_create, [thread],
 575         [
 576                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 577
 578                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 579                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 580                 ub_have_sol_threads=yes
 581         ] , [
 582                 AC_ERROR([no solaris threads found.])
 583         ])
 584         fi
 585 fi
 586
 587 fi # end of non-mingw check of thread libraries
 588
 589 # Check for PyUnbound
 590 AC_ARG_WITH(pyunbound,
 591    AC_HELP_STRING([--with-pyunbound],
 592    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 593    [], [ withval="no" ])
 594
 595 ub_test_python=no
 596 ub_with_pyunbound=no
 597 if test x_$withval != x_no; then
 598    ub_with_pyunbound=yes
 599    ub_test_python=yes
 600 fi
 601
 602 # Check for Python module
 603 AC_ARG_WITH(pythonmodule,
 604    AC_HELP_STRING([--with-pythonmodule],
 605    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 606    [], [ withval="no" ])
 607
 608 ub_with_pythonmod=no
 609 if test x_$withval != x_no; then
 610    ub_with_pythonmod=yes
 611    ub_test_python=yes
 612 fi
 613
 614 # Check for Python & SWIG only on PyUnbound or PyModule
 615 if test x_$ub_test_python != x_no; then
 616
 617    # Check for Python
 618    ub_have_python=no
 619    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 620    AC_PYTHON_DEVEL
 621    if test ! -z "$PYTHON_VERSION"; then
 622         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 623                 AC_ERROR([Python version >= 2.4.0 is required])
 624         fi
 625
 626       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 627       AC_SUBST(PY_MAJOR_VERSION)
 628       # Have Python
 629       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 630       if test -n "$LIBS"; then
 631         LIBS="$PYTHON_LDFLAGS $LIBS"
 632       else
 633         LIBS="$PYTHON_LDFLAGS"
 634       fi
 635       if test -n "$CPPFLAGS"; then
 636         CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 637       else
 638         CPPFLAGS="$PYTHON_CPPFLAGS"
 639       fi
 640       ub_have_python=yes
 641       PKG_PROG_PKG_CONFIG
 642       PKG_CHECK_EXISTS(["python${PY_MAJOR_VERSION}"],
 643                        [PC_PY_DEPENDENCY="python${PY_MAJOR_VERSION}"],
 644                        [PC_PY_DEPENDENCY="python"])
 645       AC_SUBST(PC_PY_DEPENDENCY)
 646
 647       # Check for SWIG
 648       ub_have_swig=no
 649       AC_ARG_ENABLE(swig-version-check, AC_HELP_STRING([--disable-swig-version-check], [Disable swig version check to build python modules with older swig even though that is unreliable]))
 650       if test "$enable_swig_version_check" = "yes"; then
 651         AC_PROG_SWIG(2.0.1)
 652       else
 653         AC_PROG_SWIG
 654       fi
 655       AC_MSG_CHECKING(SWIG)
 656       if test ! -x "$SWIG"; then
 657          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 658       else
 659          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 660          AC_SUBST(swig, "$SWIG")
 661          AC_MSG_RESULT(present)
 662
 663          # If have Python & SWIG
 664          # Declare PythonMod
 665          if test x_$ub_with_pythonmod != x_no; then
 666             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 667             WITH_PYTHONMODULE=yes
 668             AC_SUBST(WITH_PYTHONMODULE)
 669             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 670             AC_SUBST(PYTHONMOD_OBJ)
 671             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 672             AC_SUBST(PYTHONMOD_HEADER)
 673             PYTHONMOD_INSTALL=pythonmod-install
 674             AC_SUBST(PYTHONMOD_INSTALL)
 675             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 676             AC_SUBST(PYTHONMOD_UNINSTALL)
 677          fi
 678
 679          # Declare PyUnbound
 680          if test x_$ub_with_pyunbound != x_no; then
 681             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 682             WITH_PYUNBOUND=yes
 683             AC_SUBST(WITH_PYUNBOUND)
 684             PYUNBOUND_OBJ="libunbound_wrap.lo"
 685             AC_SUBST(PYUNBOUND_OBJ)
 686             PYUNBOUND_TARGET="_unbound.la"
 687             AC_SUBST(PYUNBOUND_TARGET)
 688             PYUNBOUND_INSTALL=pyunbound-install
 689             AC_SUBST(PYUNBOUND_INSTALL)
 690             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 691             AC_SUBST(PYUNBOUND_UNINSTALL)
 692          fi
 693       fi
 694    else
 695       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 696       ub_with_pyunbound=no
 697       ub_with_pythonmod=no
 698    fi
 699 fi
 700
 701 if test "`uname`" = "NetBSD"; then
 702         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 703         AC_SUBST(NETBSD_LINTFLAGS)
 704 fi
 705 CONFIG_DATE=`date +%Y%m%d`
 706 AC_SUBST(CONFIG_DATE)
 707
 708 # Checks for libraries.
 709
 710 # libnss
 711 USE_NSS="no"
 712 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 713         [use libnss instead of openssl, installed at path.]),
 714         [
 715         USE_NSS="yes"
 716         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 717         if test "$withval" != "" -a "$withval" != "yes"; then
 718                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 719                 LDFLAGS="$LDFLAGS -L$withval/lib"
 720                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 721                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 722         else
 723                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 724                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 725         fi
 726         LIBS="$LIBS -lnss3 -lnspr4"
 727         SSLLIB=""
 728         ]
 729 )
 730
 731 # libnettle
 732 USE_NETTLE="no"
 733 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 734         [use libnettle as crypto library, installed at path.]),
 735         [
 736         USE_NETTLE="yes"
 737         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 738         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 739         if test "$withval" != "" -a "$withval" != "yes"; then
 740                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 741                 LDFLAGS="$LDFLAGS -L$withval/lib"
 742                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 743         else
 744                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 745         fi
 746         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 747         SSLLIB=""
 748         ]
 749 )
 750
 751 # openssl
 752 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 753 ACX_WITH_SSL
 754 ACX_LIB_SSL
 755 SSLLIB="-lssl"
 756
 757 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 758 BAKLIBS="$LIBS"
 759 LIBS="-lssl $LIBS"
 760 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 761 AC_TRY_LINK_FUNC([HMAC_Update], [
 762         AC_MSG_RESULT([no])
 763         LIBS="$BAKLIBS"
 764 ], [
 765         AC_MSG_RESULT([yes])
 766         LIBS="$BAKLIBS"
 767         LIBS="$LIBS -lcrypt32"
 768 ])
 769
 770 AC_MSG_CHECKING([for LibreSSL])
 771 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 772         AC_MSG_RESULT([yes])
 773         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 774         # libressl provides these compat functions, but they may also be
 775         # declared by the OS in libc.  See if they have been declared.
 776         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform,reallocarray])
 777 else
 778         AC_MSG_RESULT([no])
 779 fi
 780 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h],,, [AC_INCLUDES_DEFAULT])
 781 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1 EVP_DigestVerify])
 782
 783 # these check_funcs need -lssl
 784 BAKLIBS="$LIBS"
 785 LIBS="-lssl $LIBS"
 786 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level SSL_set1_host SSL_get0_peername])
 787 LIBS="$BAKLIBS"
 788
 789 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 790 AC_INCLUDES_DEFAULT
 791 #ifdef HAVE_OPENSSL_ERR_H
 792 #include <openssl/err.h>
 793 #endif
 794
 795 #ifdef HAVE_OPENSSL_RAND_H
 796 #include <openssl/rand.h>
 797 #endif
 798
 799 #ifdef HAVE_OPENSSL_CONF_H
 800 #include <openssl/conf.h>
 801 #endif
 802
 803 #ifdef HAVE_OPENSSL_ENGINE_H
 804 #include <openssl/engine.h>
 805 #endif
 806 #include <openssl/ssl.h>
 807 #include <openssl/evp.h>
 808 ])
 809 fi
 810 AC_SUBST(SSLLIB)
 811
 812
 813 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 814 case "$enable_sha1" in
 815         no)
 816         ;;
 817         yes|*)
 818         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 819         ;;
 820 esac
 821
 822
 823 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 824 case "$enable_sha2" in
 825         no)
 826         ;;
 827         yes|*)
 828         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 829         ;;
 830 esac
 831
 832 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 833 case "$enable_subnet" in
 834         yes)
 835         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 836         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 837         AC_SUBST(SUBNET_OBJ)
 838         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 839         AC_SUBST(SUBNET_HEADER)
 840         ;;
 841         no|*)
 842         ;;
 843 esac
 844
 845 # check wether gost also works
 846 AC_DEFUN([AC_CHECK_GOST_WORKS],
 847 [AC_REQUIRE([AC_PROG_CC])
 848 AC_MSG_CHECKING([if GOST works])
 849 if test c${cross_compiling} = cno; then
 850 BAKCFLAGS="$CFLAGS"
 851 if test -n "$ssldir"; then
 852         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 853 fi
 854 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 855 #include <string.h>
 856 #include <openssl/ssl.h>
 857 #include <openssl/evp.h>
 858 #include <openssl/engine.h>
 859 #include <openssl/conf.h>
 860 /* routine to load gost (from sldns) */
 861 int load_gost_id(void)
 862 {
 863         static int gost_id = 0;
 864         const EVP_PKEY_ASN1_METHOD* meth;
 865         ENGINE* e;
 866
 867         if(gost_id) return gost_id;
 868
 869         /* see if configuration loaded gost implementation from other engine*/
 870         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 871         if(meth) {
 872                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 873                 return gost_id;
 874         }
 875
 876         /* see if engine can be loaded already */
 877         e = ENGINE_by_id("gost");
 878         if(!e) {
 879                 /* load it ourself, in case statically linked */
 880                 ENGINE_load_builtin_engines();
 881                 ENGINE_load_dynamic();
 882                 e = ENGINE_by_id("gost");
 883         }
 884         if(!e) {
 885                 /* no gost engine in openssl */
 886                 return 0;
 887         }
 888         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 889                 ENGINE_finish(e);
 890                 ENGINE_free(e);
 891                 return 0;
 892         }
 893
 894         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 895         if(!meth) {
 896                 /* algo not found */
 897                 ENGINE_finish(e);
 898                 ENGINE_free(e);
 899                 return 0;
 900         }
 901         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 902         return gost_id;
 903 }
 904 int main(void) {
 905         EVP_MD_CTX* ctx;
 906         const EVP_MD* md;
 907         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 908         const char* str = "Hello world";
 909         const unsigned char check[] = {
 910                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 911                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 912                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 913                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 914         };
 915         OPENSSL_config(NULL);
 916         (void)load_gost_id();
 917         md = EVP_get_digestbyname("md_gost94");
 918         if(!md) return 1;
 919         memset(digest, 0, sizeof(digest));
 920         ctx = EVP_MD_CTX_create();
 921         if(!ctx) return 2;
 922         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 923         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 924         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 925         /* uncomment to see the hash calculated.
 926                 {int i;
 927                 for(i=0; i<32; i++)
 928                         printf(" %2.2x", (int)digest[i]);
 929                 printf("\n");}
 930         */
 931         if(memcmp(digest, check, sizeof(check)) != 0)
 932                 return 6;
 933         return 0;
 934 }
 935 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 936 CFLAGS="$BAKCFLAGS"
 937 else
 938 eval "ac_cv_c_gost_works=maybe"
 939 fi
 940 AC_MSG_RESULT($ac_cv_c_gost_works)
 941 ])dnl
 942
 943 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 944 use_gost="no"
 945 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 946 case "$enable_gost" in
 947         no)
 948         ;;
 949         *)
 950         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 951         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 952         AC_CHECK_GOST_WORKS
 953         if test "$ac_cv_c_gost_works" != no; then
 954                 use_gost="yes"
 955                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 956         fi
 957         ;;
 958 esac
 959 fi dnl !USE_NSS && !USE_NETTLE
 960
 961 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 962 use_ecdsa="no"
 963 case "$enable_ecdsa" in
 964     no)
 965       ;;
 966     *)
 967       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 968               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 969               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 970               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 971 #include <openssl/evp.h>
 972               ])
 973               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 974               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 975               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
 976                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 977                   AC_MSG_RESULT([no])
 978                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 979                 else
 980                   AC_MSG_RESULT([yes])
 981                 fi
 982               else
 983                 # not OpenSSL, thus likely LibreSSL, which supports it
 984                 AC_MSG_RESULT([yes])
 985               fi
 986       fi
 987       # we now know we have ECDSA and the required curves.
 988       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 989       use_ecdsa="yes"
 990       ;;
 991 esac
 992
 993 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
 994 use_dsa="no"
 995 case "$enable_dsa" in
 996     no)
 997       ;;
 998     *)
 999       # detect if DSA is supported, and turn it off if not.
1000       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1001       AC_CHECK_FUNC(DSA_SIG_new, [
1002       AC_CHECK_TYPE(DSA_SIG*, [
1003       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1004       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1005                fi ], [
1006 AC_INCLUDES_DEFAULT
1007 #ifdef HAVE_OPENSSL_ERR_H
1008 #include <openssl/err.h>
1009 #endif
1010
1011 #ifdef HAVE_OPENSSL_RAND_H
1012 #include <openssl/rand.h>
1013 #endif
1014
1015 #ifdef HAVE_OPENSSL_CONF_H
1016 #include <openssl/conf.h>
1017 #endif
1018
1019 #ifdef HAVE_OPENSSL_ENGINE_H
1020 #include <openssl/engine.h>
1021 #endif
1022       ])
1023       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
1024                fi ])
1025       else
1026       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
1027       fi
1028       ;;
1029 esac
1030
1031 AC_ARG_ENABLE(ed25519, AC_HELP_STRING([--disable-ed25519], [Disable ED25519 support]))
1032 use_ed25519="no"
1033 case "$enable_ed25519" in
1034     no)
1035       ;;
1036     *)
1037       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1038               AC_CHECK_DECLS([NID_ED25519], [
1039                 use_ed25519="yes"
1040               ], [ if test "x$enable_ed25519" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED25519 and you used --enable-ed25519.])
1041                 fi ], [AC_INCLUDES_DEFAULT
1042 #include <openssl/evp.h>
1043               ])
1044       fi
1045       if test $USE_NETTLE = "yes"; then
1046                 AC_CHECK_HEADERS([nettle/eddsa.h], use_ed25519="yes",, [AC_INCLUDES_DEFAULT])
1047       fi
1048       if test $use_ed25519 = "yes"; then
1049                 AC_DEFINE_UNQUOTED([USE_ED25519], [1], [Define this to enable ED25519 support.])
1050       fi
1051       ;;
1052 esac
1053
1054 AC_ARG_ENABLE(ed448, AC_HELP_STRING([--disable-ed448], [Disable ED448 support]))
1055 use_ed448="no"
1056 case "$enable_ed448" in
1057     no)
1058       ;;
1059     *)
1060       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1061               AC_CHECK_DECLS([NID_ED448], [
1062                 use_ed448="yes"
1063               ], [ if test "x$enable_ed448" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED448 and you used --enable-ed448.])
1064                 fi ], [AC_INCLUDES_DEFAULT
1065 #include <openssl/evp.h>
1066               ])
1067       fi
1068       if test $use_ed448 = "yes"; then
1069                 AC_DEFINE_UNQUOTED([USE_ED448], [1], [Define this to enable ED448 support.])
1070       fi
1071       ;;
1072 esac
1073
1074 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
1075 case "$enable_event_api" in
1076     yes)
1077       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
1078       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
1079       ;;
1080     *)
1081       ;;
1082 esac
1083
1084 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
1085 case "$enable_tfo_client" in
1086         yes)
1087                 case `uname` in
1088                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1089                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1090                                              [AC_INCLUDES_DEFAULT
1091 #include <netinet/tcp.h>
1092 ])
1093                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1094                           ;;
1095                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1096                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1097                                               [AC_INCLUDES_DEFAULT
1098 #include <sys/socket.h>
1099 ])
1100                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1101                           ;;
1102                 esac
1103         ;;
1104         no|*)
1105                 ;;
1106 esac
1107
1108 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
1109 case "$enable_tfo_server" in
1110         yes)
1111               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
1112 #include <netinet/tcp.h>
1113               ])
1114                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
1115                 ;;
1116         no|*)
1117                 ;;
1118 esac
1119
1120 # check for libevent
1121 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
1122     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
1123     [ ],[ withval="no" ])
1124 if test x_$withval = x_yes -o x_$withval != x_no; then
1125         AC_MSG_CHECKING(for libevent)
1126         if test x_$withval = x_ -o x_$withval = x_yes; then
1127             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1128         fi
1129         for dir in $withval; do
1130             thedir="$dir"
1131             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
1132                 found_libevent="yes"
1133                 dnl assume /usr is in default path.
1134                 if test "$thedir" != "/usr"; then
1135                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
1136                 fi
1137                 break;
1138             fi
1139         done
1140         if test x_$found_libevent != x_yes; then
1141                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
1142                         # libevent source directory
1143                         AC_MSG_RESULT(found in $thedir)
1144                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
1145                         BAK_LDFLAGS_SET="1"
1146                         BAK_LDFLAGS="$LDFLAGS"
1147                         # remove evdns from linking
1148                         mkdir build >/dev/null 2>&1
1149                         mkdir build/libevent >/dev/null 2>&1
1150                         mkdir build/libevent/.libs >/dev/null 2>&1
1151                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1152                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
1153                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1154                         cp $ev_files_o build/libevent
1155                         cp $ev_files_lo build/libevent
1156                         cp $ev_files_libso build/libevent/.libs
1157                         LATE_LDFLAGS="build/libevent/*.lo -lm"
1158                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
1159                 else
1160                         AC_MSG_ERROR([Cannot find the libevent library in $withval
1161 You can restart ./configure --with-libevent=no to use a builtin alternative.
1162 Please note that this alternative is not as capable as libevent when using
1163 large outgoing port ranges.  ])
1164                 fi
1165         else
1166             AC_MSG_RESULT(found in $thedir)
1167             dnl if event2 exists and no event lib in dir itself, use subdir
1168             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1169                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1170                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1171             else
1172                     dnl assume /usr is in default path, do not add "".
1173                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1174                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1175                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1176                     fi
1177             fi
1178         fi
1179         # check for library used by libevent after 1.3c
1180         AC_SEARCH_LIBS([clock_gettime], [rt])
1181
1182         # is the event.h header libev or libevent?
1183         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1184         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1185                 AC_SEARCH_LIBS(event_set, [ev])
1186         ],[
1187                 AC_SEARCH_LIBS(event_set, [event])
1188         ],[AC_INCLUDES_DEFAULT
1189 #include <event.h>
1190         ])
1191         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1192         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1193         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1194         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1195         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1196         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1197         PC_LIBEVENT_DEPENDENCY="libevent"
1198         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1199         if test -n "$BAK_LDFLAGS_SET"; then
1200                 LDFLAGS="$BAK_LDFLAGS"
1201         fi
1202 else
1203         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1204 fi
1205
1206 # check for libexpat
1207 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1208     [specify explicit path for libexpat.]),
1209     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1210 AC_MSG_CHECKING(for libexpat)
1211 found_libexpat="no"
1212 for dir in $withval ; do
1213             if test -f "$dir/include/expat.h"; then
1214                 found_libexpat="yes"
1215                 dnl assume /usr is in default path.
1216                 if test "$dir" != "/usr"; then
1217                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1218                     LDFLAGS="$LDFLAGS -L$dir/lib"
1219                 fi
1220                 AC_MSG_RESULT(found in $dir)
1221                 break;
1222             fi
1223 done
1224 if test x_$found_libexpat != x_yes; then
1225         AC_ERROR([Could not find libexpat, expat.h])
1226 fi
1227 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1228 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1229 #include <expat.h>
1230 ])
1231
1232 # hiredis (redis C client for cachedb)
1233 AC_ARG_WITH(libhiredis, AC_HELP_STRING([--with-libhiredis=path],
1234     [specify explicit path for libhiredis.]),
1235     [ ],[ withval="no" ])
1236 found_libhiredis="no"
1237 if test x_$withval = x_yes -o x_$withval != x_no; then
1238    AC_MSG_CHECKING(for libhiredis)
1239    if test x_$withval = x_ -o x_$withval = x_yes; then
1240             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1241    fi
1242    for dir in $withval ; do
1243             if test -f "$dir/include/hiredis/hiredis.h"; then
1244                 found_libhiredis="yes"
1245                 dnl assume /usr is in default path.
1246                 if test "$dir" != "/usr"; then
1247                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1248                     LDFLAGS="$LDFLAGS -L$dir/lib"
1249                 fi
1250                 AC_MSG_RESULT(found in $dir)
1251                 AC_DEFINE([USE_REDIS], [1], [Define this to use hiredis client.])
1252                 LIBS="$LIBS -lhiredis"
1253                 break;
1254             fi
1255     done
1256     if test x_$found_libhiredis != x_yes; then
1257         AC_ERROR([Could not find libhiredis, hiredis.h])
1258     fi
1259     AC_CHECK_HEADERS([hiredis/hiredis.h],,, [AC_INCLUDES_DEFAULT])
1260     AC_CHECK_DECLS([redisConnect], [], [], [AC_INCLUDES_DEFAULT
1261     #include <hiredis/hiredis.h>
1262     ])
1263 fi
1264
1265 # set static linking if requested
1266 AC_SUBST(staticexe)
1267 staticexe=""
1268 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1269         [ enable to compile executables statically against (event) libs, for debug purposes ]),
1270         , )
1271 if test x_$enable_static_exe = x_yes; then
1272         staticexe="-static"
1273         if test "$on_mingw" = yes; then
1274                 staticexe="-all-static"
1275                 # for static compile, include gdi32 and zlib here.
1276                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1277                         :
1278                 else
1279                         LIBS="$LIBS -lgdi32"
1280                 fi
1281                 LIBS="$LIBS -lz"
1282         fi
1283 fi
1284
1285 # Include systemd.m4 - begin
1286 sinclude(systemd.m4)
1287 # Include systemd.m4 - end
1288
1289 # set lock checking if requested
1290 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1291         [ enable to check lock and unlock calls, for debug purposes ]),
1292         , )
1293 if test x_$enable_lock_checks = x_yes; then
1294         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1295         CHECKLOCK_OBJ="checklocks.lo"
1296         AC_SUBST(CHECKLOCK_OBJ)
1297 fi
1298
1299 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1300 if test "$USE_WINSOCK" = 1; then
1301         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1302         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1303 #include <windows.h>
1304         ])
1305         AC_CHECK_TOOL(WINDRES, windres)
1306         LIBS="$LIBS -liphlpapi -lcrypt32"
1307         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1308         AC_SUBST(WINAPPS)
1309         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1310         AC_SUBST(WIN_DAEMON_SRC)
1311         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1312         AC_SUBST(WIN_DAEMON_OBJ)
1313         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1314         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1315         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1316         AC_SUBST(WIN_HOST_OBJ_LINK)
1317         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1318         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1319         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1320         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1321         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1322         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1323 fi
1324 if test $ac_cv_func_getaddrinfo = no; then
1325         AC_LIBOBJ([fake-rfc2553])
1326 fi
1327 # check after getaddrinfo for its libraries
1328 ACX_FUNC_IOCTLSOCKET
1329
1330 # see if daemon(3) exists, and if it is deprecated.
1331 AC_CHECK_FUNCS([daemon])
1332 if test $ac_cv_func_daemon = yes; then
1333         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1334 #include <stdlib.h>
1335 ])
1336 fi
1337
1338 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1339 AC_INCLUDES_DEFAULT
1340 #ifdef HAVE_SYS_UN_H
1341 #include <sys/un.h>
1342 #endif
1343 ])
1344 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1345 AC_INCLUDES_DEFAULT
1346 #if HAVE_SYS_PARAM_H
1347 #include <sys/param.h>
1348 #endif
1349
1350 #ifdef HAVE_SYS_SOCKET_H
1351 #include <sys/socket.h>
1352 #endif
1353
1354 #ifdef HAVE_SYS_UIO_H
1355 #include <sys/uio.h>
1356 #endif
1357
1358 #ifdef HAVE_NETINET_IN_H
1359 #include <netinet/in.h>
1360 #endif
1361
1362 #ifdef HAVE_NETINET_TCP_H
1363 #include <netinet/tcp.h>
1364 #endif
1365
1366 #ifdef HAVE_ARPA_INET_H
1367 #include <arpa/inet.h>
1368 #endif
1369
1370 #ifdef HAVE_WINSOCK2_H
1371 #include <winsock2.h>
1372 #endif
1373
1374 #ifdef HAVE_WS2TCPIP_H
1375 #include <ws2tcpip.h>
1376 #endif
1377 ])
1378 AC_SEARCH_LIBS([setusercontext], [util])
1379 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget accept4])
1380 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1381 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1382
1383 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1384 if echo $target_os | grep darwin8 > /dev/null; then
1385         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1386 fi
1387 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1388 AC_INCLUDES_DEFAULT
1389 #ifdef HAVE_NETINET_IN_H
1390 #include <netinet/in.h>
1391 #endif
1392
1393 #ifdef HAVE_NETINET_TCP_H
1394 #include <netinet/tcp.h>
1395 #endif
1396
1397 #ifdef HAVE_ARPA_INET_H
1398 #include <arpa/inet.h>
1399 #endif
1400
1401 #ifdef HAVE_WINSOCK2_H
1402 #include <winsock2.h>
1403 #endif
1404
1405 #ifdef HAVE_WS2TCPIP_H
1406 #include <ws2tcpip.h>
1407 #endif
1408 ])
1409 AC_REPLACE_FUNCS(inet_aton)
1410 AC_REPLACE_FUNCS(inet_pton)
1411 AC_REPLACE_FUNCS(inet_ntop)
1412 AC_REPLACE_FUNCS(snprintf)
1413 # test if snprintf return the proper length
1414 if test "x$ac_cv_func_snprintf" = xyes; then
1415     if test c${cross_compiling} = cno; then
1416         AC_MSG_CHECKING([for correct snprintf return value])
1417         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1418 [[
1419 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1420 ]])], [AC_MSG_RESULT(yes)], [
1421                 AC_MSG_RESULT(no)
1422                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1423                 AC_LIBOBJ(snprintf)
1424           ])
1425     fi
1426 fi
1427 AC_REPLACE_FUNCS(strlcat)
1428 AC_REPLACE_FUNCS(strlcpy)
1429 AC_REPLACE_FUNCS(memmove)
1430 AC_REPLACE_FUNCS(gmtime_r)
1431 AC_REPLACE_FUNCS(isblank)
1432 AC_REPLACE_FUNCS(explicit_bzero)
1433 dnl without CTIME, ARC4-functions and without reallocarray.
1434 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1435 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1436 AC_REPLACE_FUNCS(reallocarray)
1437 if test "$USE_NSS" = "no"; then
1438         AC_REPLACE_FUNCS(arc4random)
1439         AC_REPLACE_FUNCS(arc4random_uniform)
1440         if test "$ac_cv_func_arc4random" = "no"; then
1441                 AC_LIBOBJ(arc4_lock)
1442                 AC_CHECK_FUNCS([getentropy],,[
1443                     if test "$USE_WINSOCK" = 1; then
1444                         AC_LIBOBJ(getentropy_win)
1445                     else
1446                         case "$host" in
1447                         Darwin|*darwin*)
1448                                 AC_LIBOBJ(getentropy_osx)
1449                         ;;
1450                         *solaris*|*sunos*|SunOS)
1451                                 AC_LIBOBJ(getentropy_solaris)
1452                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1453                                         AC_CHECK_FUNCS([SHA512_Update],,[
1454                                                 AC_LIBOBJ(sha512)
1455                                         ])
1456                                 ], [AC_INCLUDES_DEFAULT])
1457                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1458                                         # this lib needed for sha2 on solaris
1459                                         LIBS="$LIBS -lmd"
1460                                 fi
1461                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1462                         ;;
1463                         *linux*|Linux|*)
1464                                 AC_LIBOBJ(getentropy_linux)
1465                                 AC_CHECK_FUNCS([SHA512_Update],,[
1466                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1467                                         AC_LIBOBJ(sha512)
1468                                 ])
1469                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1470                                 AC_CHECK_FUNCS([getauxval])
1471                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1472                         ;;
1473                         esac
1474                     fi
1475                 ])
1476         fi
1477 fi
1478 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1479 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1480 AC_REPLACE_FUNCS(ctime_r)
1481 AC_REPLACE_FUNCS(strsep)
1482
1483 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1484 case "$enable_allsymbols" in
1485         yes)
1486         COMMON_OBJ_ALL_SYMBOLS=""
1487         UBSYMS=""
1488         EXTRALINK="-L. -L.libs -lunbound"
1489         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1490         ;;
1491         no|*)
1492         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1493         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1494         EXTRALINK=""
1495         ;;
1496 esac
1497 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1498 AC_SUBST(EXTRALINK)
1499 AC_SUBST(UBSYMS)
1500 if test x_$enable_lock_checks = x_yes; then
1501         UBSYMS="-export-symbols clubsyms.def"
1502         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1503         echo lock_protect >> clubsyms.def
1504         echo lock_unprotect >> clubsyms.def
1505         echo lock_get_mem >> clubsyms.def
1506         echo checklock_start >> clubsyms.def
1507         echo checklock_stop >> clubsyms.def
1508         echo checklock_lock >> clubsyms.def
1509         echo checklock_unlock >> clubsyms.def
1510         echo checklock_init >> clubsyms.def
1511         echo checklock_thrcreate >> clubsyms.def
1512         echo checklock_thrjoin >> clubsyms.def
1513 fi
1514
1515 # check for dnstap if requested
1516 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1517     [
1518         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1519         AC_SUBST([ENABLE_DNSTAP], [1])
1520
1521         AC_SUBST([opt_dnstap_socket_path])
1522         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1523         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1524             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1525
1526         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1527         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1528     ],
1529     [
1530         AC_SUBST([ENABLE_DNSTAP], [0])
1531     ]
1532 )
1533
1534 # check for dnscrypt if requested
1535 dnsc_DNSCRYPT([
1536         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1537         AC_SUBST([ENABLE_DNSCRYPT], [1])
1538
1539         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1540         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1541     ],
1542     [
1543         AC_SUBST([ENABLE_DNSCRYPT], [0])
1544     ]
1545 )
1546
1547 # check for cachedb if requested
1548 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1549 # turn on cachedb when hiredis support is enabled.
1550 if test "$found_libhiredis" = "yes"; then enable_cachedb="yes"; fi
1551 case "$enable_cachedb" in
1552     yes)
1553         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1554         ;;
1555     no|*)
1556         # nothing
1557         ;;
1558 esac
1559
1560 # check for ipsecmod if requested
1561 AC_ARG_ENABLE(ipsecmod, AC_HELP_STRING([--enable-ipsecmod], [Enable ipsecmod module that facilitates opportunistic IPsec]))
1562 case "$enable_ipsecmod" in
1563         yes)
1564                 AC_DEFINE([USE_IPSECMOD], [1], [Define to 1 to use ipsecmod support.])
1565                 IPSECMOD_OBJ="ipsecmod.lo ipsecmod-whitelist.lo"
1566                 AC_SUBST(IPSECMOD_OBJ)
1567                 IPSECMOD_HEADER='$(srcdir)/ipsecmod/ipsecmod.h $(srcdir)/ipsecmod/ipsecmod-whitelist.h'
1568                 AC_SUBST(IPSECMOD_HEADER)
1569                 ;;
1570         no|*)
1571                 # nothing
1572                 ;;
1573 esac
1574
1575 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1576 # on openBSD, the implicit rule make $< work.
1577 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1578 # gmake works.
1579 cat >conftest.make <<EOF
1580 all:    conftest.lo
1581
1582 conftest.lo foo.lo bla.lo:
1583         if test -f "\$<"; then touch \$@; fi
1584
1585 .SUFFIXES: .lo
1586 .c.lo:
1587         if test -f "\$<"; then touch \$@; fi
1588
1589 conftest.lo:        conftest.dir/conftest.c
1590 EOF
1591 mkdir conftest.dir
1592 touch conftest.dir/conftest.c
1593 rm -f conftest.lo conftest.c
1594 ${MAKE:-make} -f conftest.make >/dev/null
1595 rm -f conftest.make conftest.c conftest.dir/conftest.c
1596 rm -rf conftest.dir
1597 if test ! -f conftest.lo; then
1598         AC_MSG_RESULT(no)
1599         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1600         SOURCEFILE='`cat .source`'
1601 else
1602         AC_MSG_RESULT(yes)
1603         SOURCEDETERMINE=':'
1604         SOURCEFILE='$<'
1605 fi
1606 rm -f conftest.lo
1607 AC_SUBST(SOURCEDETERMINE)
1608 AC_SUBST(SOURCEFILE)
1609
1610 # see if we want to build the library or everything
1611 ALLTARGET="alltargets"
1612 INSTALLTARGET="install-all"
1613 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1614         [do not build daemon and tool programs]),
1615         [
1616         if test "$withval" = "yes"; then
1617                 ALLTARGET="lib"
1618                 INSTALLTARGET="install-lib"
1619         fi
1620 ])
1621 if test $ALLTARGET = "alltargets"; then
1622         if test $USE_NSS = "yes"; then
1623                 AC_ERROR([--with-nss can only be used in combination with --with-libunbound-only.])
1624         fi
1625         if test $USE_NETTLE = "yes"; then
1626                 AC_ERROR([--with-nettle can only be used in combination with --with-libunbound-only.])
1627         fi
1628 fi
1629
1630 AC_SUBST(ALLTARGET)
1631 AC_SUBST(INSTALLTARGET)
1632
1633 ACX_STRIP_EXT_FLAGS
1634 if test -n "$LATE_LDFLAGS"; then
1635   LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1636 fi
1637 # remove start spaces
1638 LDFLAGS=`echo "$LDFLAGS"|sed -e 's/^ *//'`
1639 LIBS=`echo "$LIBS"|sed -e 's/^ *//'`
1640
1641 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1642
1643 AH_BOTTOM(
1644 dnl this must be first AH_CONFIG, to define the flags before any includes.
1645 AHX_CONFIG_EXT_FLAGS
1646
1647 dnl includes
1648 [
1649 #ifndef UNBOUND_DEBUG
1650 #  define NDEBUG
1651 #endif
1652
1653 /** Use small-ldns codebase */
1654 #define USE_SLDNS 1
1655 #ifdef HAVE_SSL
1656 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1657 #endif
1658
1659 #include <stdio.h>
1660 #include <string.h>
1661 #include <unistd.h>
1662 #include <assert.h>
1663
1664 #if STDC_HEADERS
1665 #include <stdlib.h>
1666 #include <stddef.h>
1667 #endif
1668
1669 #ifdef HAVE_STDARG_H
1670 #include <stdarg.h>
1671 #endif
1672
1673 #ifdef HAVE_STDINT_H
1674 #include <stdint.h>
1675 #endif
1676
1677 #include <errno.h>
1678
1679 #if HAVE_SYS_PARAM_H
1680 #include <sys/param.h>
1681 #endif
1682
1683 #ifdef HAVE_SYS_SOCKET_H
1684 #include <sys/socket.h>
1685 #endif
1686
1687 #ifdef HAVE_SYS_UIO_H
1688 #include <sys/uio.h>
1689 #endif
1690
1691 #ifdef HAVE_NETINET_IN_H
1692 #include <netinet/in.h>
1693 #endif
1694
1695 #ifdef HAVE_NETINET_TCP_H
1696 #include <netinet/tcp.h>
1697 #endif
1698
1699 #ifdef HAVE_ARPA_INET_H
1700 #include <arpa/inet.h>
1701 #endif
1702
1703 #ifdef HAVE_WINSOCK2_H
1704 #include <winsock2.h>
1705 #endif
1706
1707 #ifdef HAVE_WS2TCPIP_H
1708 #include <ws2tcpip.h>
1709 #endif
1710
1711 #ifndef USE_WINSOCK
1712 #define ARG_LL "%ll"
1713 #else
1714 #define ARG_LL "%I64"
1715 #endif
1716
1717 #ifndef AF_LOCAL
1718 #define AF_LOCAL AF_UNIX
1719 #endif
1720 ]
1721
1722 AHX_CONFIG_FORMAT_ATTRIBUTE
1723 AHX_CONFIG_UNUSED_ATTRIBUTE
1724 AHX_CONFIG_FSEEKO
1725 AHX_CONFIG_MAXHOSTNAMELEN
1726 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1727 #define snprintf snprintf_unbound
1728 #define vsnprintf vsnprintf_unbound
1729 #include <stdarg.h>
1730 int snprintf (char *str, size_t count, const char *fmt, ...);
1731 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1732 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1733 AHX_CONFIG_INET_PTON(unbound)
1734 AHX_CONFIG_INET_NTOP(unbound)
1735 AHX_CONFIG_INET_ATON(unbound)
1736 AHX_CONFIG_MEMMOVE(unbound)
1737 AHX_CONFIG_STRLCAT(unbound)
1738 AHX_CONFIG_STRLCPY(unbound)
1739 AHX_CONFIG_GMTIME_R(unbound)
1740 AHX_CONFIG_REALLOCARRAY(unbound)
1741 AHX_CONFIG_W32_SLEEP
1742 AHX_CONFIG_W32_USLEEP
1743 AHX_CONFIG_W32_RANDOM
1744 AHX_CONFIG_W32_SRANDOM
1745 AHX_CONFIG_W32_FD_SET_T
1746 AHX_CONFIG_IPV6_MIN_MTU
1747 AHX_MEMCMP_BROKEN(unbound)
1748
1749 [
1750 #ifndef HAVE_CTIME_R
1751 #define ctime_r unbound_ctime_r
1752 char *ctime_r(const time_t *timep, char *buf);
1753 #endif
1754
1755 #ifndef HAVE_STRSEP
1756 #define strsep unbound_strsep
1757 char *strsep(char **stringp, const char *delim);
1758 #endif
1759
1760 #ifndef HAVE_ISBLANK
1761 #define isblank unbound_isblank
1762 int isblank(int c);
1763 #endif
1764
1765 #ifndef HAVE_EXPLICIT_BZERO
1766 #define explicit_bzero unbound_explicit_bzero
1767 void explicit_bzero(void* buf, size_t len);
1768 #endif
1769
1770 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
1771 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
1772 #endif
1773
1774 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
1775 int inet_pton(int af, const char* src, void* dst);
1776 #endif
1777
1778 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1779 #define strptime unbound_strptime
1780 struct tm;
1781 char *strptime(const char *s, const char *format, struct tm *tm);
1782 #endif
1783
1784 #ifdef HAVE_LIBRESSL
1785 #  if !HAVE_DECL_STRLCPY
1786 size_t strlcpy(char *dst, const char *src, size_t siz);
1787 #  endif
1788 #  if !HAVE_DECL_STRLCAT
1789 size_t strlcat(char *dst, const char *src, size_t siz);
1790 #  endif
1791 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
1792 uint32_t arc4random(void);
1793 #  endif
1794 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
1795 uint32_t arc4random_uniform(uint32_t upper_bound);
1796 #  endif
1797 #  if !HAVE_DECL_REALLOCARRAY
1798 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1799 #  endif
1800 #endif /* HAVE_LIBRESSL */
1801 #ifndef HAVE_ARC4RANDOM
1802 int getentropy(void* buf, size_t len);
1803 uint32_t arc4random(void);
1804 void arc4random_buf(void* buf, size_t n);
1805 void _ARC4_LOCK(void);
1806 void _ARC4_UNLOCK(void);
1807 void _ARC4_LOCK_DESTROY(void);
1808 #endif
1809 #ifndef HAVE_ARC4RANDOM_UNIFORM
1810 uint32_t arc4random_uniform(uint32_t upper_bound);
1811 #endif
1812 #ifdef COMPAT_SHA512
1813 #ifndef SHA512_DIGEST_LENGTH
1814 #define SHA512_BLOCK_LENGTH             128
1815 #define SHA512_DIGEST_LENGTH            64
1816 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
1817 typedef struct _SHA512_CTX {
1818         uint64_t        state[8];
1819         uint64_t        bitcount[2];
1820         uint8_t buffer[SHA512_BLOCK_LENGTH];
1821 } SHA512_CTX;
1822 #endif /* SHA512_DIGEST_LENGTH */
1823 void SHA512_Init(SHA512_CTX*);
1824 void SHA512_Update(SHA512_CTX*, void*, size_t);
1825 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
1826 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
1827 #endif /* COMPAT_SHA512 */
1828
1829
1830
1831 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1832    /* using version of libevent that is not threadsafe. */
1833 #  define LIBEVENT_SIGNAL_PROBLEM 1
1834 #endif
1835
1836 #ifndef CHECKED_INET6
1837 #  define CHECKED_INET6
1838 #  ifdef AF_INET6
1839 #    define INET6
1840 #  else
1841 #    define AF_INET6        28
1842 #  endif
1843 #endif /* CHECKED_INET6 */
1844
1845 #ifndef HAVE_GETADDRINFO
1846 struct sockaddr_storage;
1847 #include "compat/fake-rfc2553.h"
1848 #endif
1849
1850 #ifdef UNBOUND_ALLOC_STATS
1851 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1852 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1853 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1854 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1855 void *unbound_stat_malloc(size_t size);
1856 void *unbound_stat_calloc(size_t nmemb, size_t size);
1857 void unbound_stat_free(void *ptr);
1858 void *unbound_stat_realloc(void *ptr, size_t size);
1859 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1860         const char* func);
1861 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1862         int line, const char* func);
1863 void unbound_stat_free_log(void *ptr, const char* file, int line,
1864         const char* func);
1865 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1866         int line, const char* func);
1867 #elif defined(UNBOUND_ALLOC_LITE)
1868 #  include "util/alloc.h"
1869 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1870
1871 /** default port for DNS traffic. */
1872 #define UNBOUND_DNS_PORT 53
1873 /** default port for DNS over TLS traffic. */
1874 #define UNBOUND_DNS_OVER_TLS_PORT 853
1875 /** default port for unbound control traffic, registered port with IANA,
1876     ub-dns-control  8953/tcp    unbound dns nameserver control */
1877 #define UNBOUND_CONTROL_PORT 8953
1878 /** the version of unbound-control that this software implements */
1879 #define UNBOUND_CONTROL_VERSION 1
1880
1881 ])
1882
1883 dnl if we build from source tree, the man pages need @date@ and @version@
1884 dnl if this is a distro tarball, that was already done by makedist.sh
1885 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
1886 AC_SUBST(date, [`date +'%b %e, %Y'`])
1887
1888 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service])
1889 AC_CONFIG_HEADER([config.h])
1890 AC_OUTPUT