contrib/unbound/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[7])
  14 m4_define([VERSION_MICRO],[1])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=7
  21 LIBUNBOUND_REVISION=9
  22 LIBUNBOUND_AGE=5
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75 # 1.6.4 had 7:3:5
  76 # 1.6.5 had 7:4:5
  77 # 1.6.6 had 7:5:5
  78 # 1.6.7 had 7:6:5
  79 # 1.6.8 had 7:7:5
  80 # 1.7.0 had 7:8:5
  81 # 1.7.1 had 7:9:5
  82
  83 #   Current  -- the number of the binary API that we're implementing
  84 #   Revision -- which iteration of the implementation of the binary
  85 #               API are we supplying?
  86 #   Age      -- How many previous binary API versions do we also
  87 #               support?
  88 #
  89 # If we release a new version that does not change the binary API,
  90 # increment Revision.
  91 #
  92 # If we release a new version that changes the binary API, but does
  93 # not break programs compiled against the old binary API, increment
  94 # Current and Age.  Set Revision to 0, since this is the first
  95 # implementation of the new API.
  96 #
  97 # Otherwise, we're changing the binary API and breaking backward
  98 # compatibility with old binaries.  Increment Current.  Set Age to 0,
  99 # since we're backward compatible with no previous APIs.  Set Revision
 100 # to 0 too.
 101 AC_SUBST(LIBUNBOUND_CURRENT)
 102 AC_SUBST(LIBUNBOUND_REVISION)
 103 AC_SUBST(LIBUNBOUND_AGE)
 104
 105 CFLAGS="$CFLAGS"
 106 AC_AIX
 107 if test "$ac_cv_header_minix_config_h" = "yes"; then
 108         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 109 fi
 110
 111 dnl
 112 dnl By default set prefix to /usr/local
 113 dnl
 114 case "$prefix" in
 115         NONE)
 116                 prefix="/usr/local"
 117         ;;
 118 esac
 119 case "$exec_prefix" in
 120         NONE)
 121                 exec_prefix="$prefix"
 122         ;;
 123 esac
 124
 125 # are we on MinGW?
 126 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 127 else
 128         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 129         else on_mingw="no"; fi
 130 fi
 131
 132 #
 133 # Determine configuration file
 134 # the eval is to evaluate shell expansion twice
 135 UNBOUND_SBIN_DIR=`eval echo "${sbindir}"`
 136 AC_SUBST(UNBOUND_SBIN_DIR)
 137 UNBOUND_SYSCONF_DIR=`eval echo "${sysconfdir}"`
 138 AC_SUBST(UNBOUND_SYSCONF_DIR)
 139 UNBOUND_LOCALSTATE_DIR=`eval echo "${localstatedir}"`
 140 AC_SUBST(UNBOUND_LOCALSTATE_DIR)
 141 if test $on_mingw = "no"; then
 142   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 143 else
 144   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 145 fi
 146 AC_ARG_WITH([conf_file],
 147         AC_HELP_STRING([--with-conf-file=path],
 148         [Pathname to the Unbound configuration file]),
 149         [ub_conf_file="$withval"])
 150 AC_SUBST(ub_conf_file)
 151 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 152 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 153 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 154 AC_SUBST(ub_conf_dir)
 155
 156 # Determine run, chroot directory and pidfile locations
 157 AC_ARG_WITH(run-dir,
 158     AC_HELP_STRING([--with-run-dir=path],
 159     [set default directory to chdir to (by default dir part of cfg file)]),
 160     UNBOUND_RUN_DIR="$withval",
 161 if test $on_mingw = no; then
 162     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 163 else
 164     UNBOUND_RUN_DIR=""
 165 fi
 166 )
 167 AC_SUBST(UNBOUND_RUN_DIR)
 168 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 169 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 170
 171 AC_ARG_WITH(chroot-dir,
 172     AC_HELP_STRING([--with-chroot-dir=path],
 173     [set default directory to chroot to (by default same as run-dir)]),
 174     UNBOUND_CHROOT_DIR="$withval",
 175 if test $on_mingw = no; then
 176     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 177 else
 178     UNBOUND_CHROOT_DIR=""
 179 fi
 180 )
 181 AC_SUBST(UNBOUND_CHROOT_DIR)
 182 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 183 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 184
 185 AC_ARG_WITH(share-dir,
 186     AC_HELP_STRING([--with-share-dir=path],
 187     [set default directory with shared data (by default same as share/unbound)]),
 188     UNBOUND_SHARE_DIR="$withval",
 189     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 190 AC_SUBST(UNBOUND_SHARE_DIR)
 191 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 192
 193 AC_ARG_WITH(pidfile,
 194     AC_HELP_STRING([--with-pidfile=filename],
 195     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 196     UNBOUND_PIDFILE="$withval",
 197 if test $on_mingw = no; then
 198     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 199 else
 200     UNBOUND_PIDFILE=""
 201 fi
 202 )
 203 AC_SUBST(UNBOUND_PIDFILE)
 204 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 205 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 206
 207 AC_ARG_WITH(rootkey-file,
 208     AC_HELP_STRING([--with-rootkey-file=filename],
 209     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 210     UNBOUND_ROOTKEY_FILE="$withval",
 211 if test $on_mingw = no; then
 212     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 213 else
 214     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 215 fi
 216 )
 217 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 218 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 219 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 220
 221 AC_ARG_WITH(rootcert-file,
 222     AC_HELP_STRING([--with-rootcert-file=filename],
 223     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 224     UNBOUND_ROOTCERT_FILE="$withval",
 225 if test $on_mingw = no; then
 226     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 227 else
 228     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 229 fi
 230 )
 231 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 232 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 233 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 234
 235 AC_ARG_WITH(username,
 236     AC_HELP_STRING([--with-username=user],
 237     [set default user that unbound changes to (default user is unbound)]),
 238     UNBOUND_USERNAME="$withval",
 239     UNBOUND_USERNAME="unbound")
 240 AC_SUBST(UNBOUND_USERNAME)
 241 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 242
 243 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 244 ACX_RSRC_VERSION(wnvs)
 245 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 246
 247 # Checks for typedefs, structures, and compiler characteristics.
 248 AC_C_CONST
 249 AC_LANG_C
 250 # allow user to override the -g -O2 flags.
 251 default_cflags=no
 252 if test "x$CFLAGS" = "x" ; then
 253 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 254 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 255 default_cflags=yes
 256 fi
 257 AC_PROG_CC
 258 ACX_DEPFLAG
 259 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 260
 261 # debug mode flags warnings
 262 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 263 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 264 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 265 else debug_enabled="$enable_checking"; fi
 266 AC_SUBST(debug_enabled)
 267 case "$debug_enabled" in
 268         yes)
 269                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 270                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 271                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 272                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 273                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 274                 ;;
 275         no|*)
 276                 # nothing to do.
 277                 ;;
 278 esac
 279 if test "$default_cflags" = "yes"; then
 280         # only when CFLAGS was "" at the start, if the users wants to
 281         # override we shouldn't add default cflags, because they wouldn't
 282         # be able to turn off these options and set the CFLAGS wanted.
 283         ACX_CHECK_FLTO
 284         ACX_CHECK_PIE
 285         ACX_CHECK_RELRO_NOW
 286 fi
 287
 288 AC_C_INLINE
 289 ACX_CHECK_FORMAT_ATTRIBUTE
 290 ACX_CHECK_UNUSED_ATTRIBUTE
 291
 292 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 293 [AC_REQUIRE([AC_PROG_CC])
 294 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 295 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 296 [ac_cv_c_weak_attribute=no
 297 AC_TRY_COMPILE(
 298 [ #include <stdio.h>
 299 __attribute__((weak)) void f(int x) { printf("%d", x); }
 300 ], [
 301    f(1);
 302 ],
 303 [ac_cv_c_weak_attribute="yes"],
 304 [ac_cv_c_weak_attribute="no"])
 305 ])
 306
 307 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 308 if test $ac_cv_c_weak_attribute = yes; then
 309   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 310 fi
 311 ])dnl End of CHECK_WEAK_ATTRIBUTE
 312
 313 CHECK_WEAK_ATTRIBUTE
 314
 315 if test "$srcdir" != "."; then
 316         CPPFLAGS="$CPPFLAGS -I$srcdir"
 317 fi
 318
 319 AC_DEFUN([ACX_YYLEX_DESTROY], [
 320         AC_MSG_CHECKING([for yylex_destroy])
 321         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 322                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 323                 AC_MSG_RESULT(yes)
 324         else AC_MSG_RESULT(no); fi
 325 ])
 326
 327 AC_PROG_LEX
 328 ACX_YYLEX_DESTROY
 329 AC_PROG_YACC
 330 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 331 AC_CHECK_TOOL(STRIP, strip)
 332 ACX_LIBTOOL_C_ONLY
 333
 334 # Checks for header files.
 335 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/endian.h libkern/OSByteOrder.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 336
 337 # check for types.
 338 # Using own tests for int64* because autoconf builtin only give 32bit.
 339 AC_CHECK_TYPE(int8_t, signed char)
 340 AC_CHECK_TYPE(int16_t, short)
 341 AC_CHECK_TYPE(int32_t, int)
 342 AC_CHECK_TYPE(int64_t, long long)
 343 AC_CHECK_TYPE(uint8_t, unsigned char)
 344 AC_CHECK_TYPE(uint16_t, unsigned short)
 345 AC_CHECK_TYPE(uint32_t, unsigned int)
 346 AC_CHECK_TYPE(uint64_t, unsigned long long)
 347 AC_TYPE_SIZE_T
 348 AC_CHECK_TYPE(ssize_t, int)
 349 AC_TYPE_UID_T
 350 AC_TYPE_PID_T
 351 AC_TYPE_OFF_T
 352 ACX_TYPE_U_CHAR
 353 ACX_TYPE_RLIM_T
 354 ACX_TYPE_SOCKLEN_T
 355 ACX_TYPE_IN_ADDR_T
 356 ACX_TYPE_IN_PORT_T
 357 ACX_CHECK_MEMCMP_SIGNED
 358
 359 AC_CHECK_SIZEOF(time_t,,[
 360 AC_INCLUDES_DEFAULT
 361 #ifdef TIME_WITH_SYS_TIME
 362 # include <sys/time.h>
 363 # include <time.h>
 364 #else
 365 # ifdef HAVE_SYS_TIME_H
 366 #  include <sys/time.h>
 367 # else
 368 #  include <time.h>
 369 # endif
 370 #endif
 371 ])
 372
 373 # add option to disable the evil rpath
 374 ACX_ARG_RPATH
 375 AC_SUBST(RUNTIME_PATH)
 376
 377 # check to see if libraries are needed for these functions.
 378 AC_SEARCH_LIBS([inet_pton], [nsl])
 379 AC_SEARCH_LIBS([socket], [socket])
 380
 381 # check wether strptime also works
 382 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 383 [AC_REQUIRE([AC_PROG_CC])
 384 AC_MSG_CHECKING(whether strptime works)
 385 if test c${cross_compiling} = cno; then
 386 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 387 #define _XOPEN_SOURCE 600
 388 #include <time.h>
 389 int main(void) { struct tm tm; char *res;
 390 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 391 if (!res) return 2;
 392 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 393 if (!res) return 1; return 0; }
 394 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 395 else
 396 eval "ac_cv_c_strptime_works=maybe"
 397 fi
 398 AC_MSG_RESULT($ac_cv_c_strptime_works)
 399 if test $ac_cv_c_strptime_works = no; then
 400 AC_LIBOBJ(strptime)
 401 else
 402 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 403 fi
 404 ])dnl
 405
 406 # check some functions of the OS before linking libs (while still runnable).
 407 AC_FUNC_CHOWN
 408 AC_FUNC_FORK
 409 AC_TYPE_SIGNAL
 410 AC_FUNC_FSEEKO
 411 ACX_SYS_LARGEFILE
 412 ACX_CHECK_NONBLOCKING_BROKEN
 413 ACX_MKDIR_ONE_ARG
 414 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 415
 416 # set memory allocation checking if requested
 417 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 418         [ enable to memory allocation statistics, for debug purposes ]),
 419         , )
 420 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 421         [ enable for lightweight alloc assertions, for debug purposes ]),
 422         , )
 423 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 424         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 425         , )
 426 if test x_$enable_alloc_nonregional = x_yes; then
 427         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 428 fi
 429 if test x_$enable_alloc_checks = x_yes; then
 430         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 431 else
 432         if test x_$enable_alloc_lite = x_yes; then
 433                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 434         else
 435                 ACX_FUNC_MALLOC([unbound])
 436         fi
 437 fi
 438
 439 # check windows threads (we use them, not pthreads, on windows).
 440 if test "$on_mingw" = "yes"; then
 441 # check windows threads
 442         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 443         AC_MSG_CHECKING([for CreateThread])
 444         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 445 #ifdef HAVE_WINDOWS_H
 446 #include <windows.h>
 447 #endif
 448 ], [
 449         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 450 ])],
 451         AC_MSG_RESULT(yes)
 452         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 453 ,
 454         AC_MSG_RESULT(no)
 455 )
 456
 457 else
 458 # not on mingw, check thread libraries.
 459
 460 # check for thread library.
 461 # check this first, so that the pthread lib does not get linked in via
 462 # libssl or libpython, and thus distorts the tests, and we end up using
 463 # the non-threadsafe C libraries.
 464 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 465  [use pthreads library, or --without-pthreads to disable threading support.]),
 466  [ ],[ withval="yes" ])
 467 ub_have_pthreads=no
 468 if test x_$withval != x_no; then
 469         AX_PTHREAD([
 470                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 471                 if test -n "$PTHREAD_LIBS"; then
 472                   LIBS="$PTHREAD_LIBS $LIBS"
 473                 fi
 474                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 475                 CC="$PTHREAD_CC"
 476                 ub_have_pthreads=yes
 477                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 478
 479                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 480                 AC_MSG_CHECKING([if -pthread unused during linking])
 481                 # catch clang warning 'argument unused during compilation'
 482                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 483 [[
 484 int main(void) {return 0;}
 485 ]])])
 486                 pthread_unused="yes"
 487                 # first compile
 488                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 489                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 490                 if test $? = 0; then
 491                         # then link
 492                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 493                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 494                         if test $? -ne 0; then
 495                                 AC_MSG_RESULT(yes)
 496                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 497                                 PTHREAD_CFLAGS_ONLY="-pthread"
 498                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 499                         else
 500                                 AC_MSG_RESULT(no)
 501                         fi
 502                 else
 503                         AC_MSG_RESULT(no)
 504                 fi # endif cc successful
 505                 rm -f conftest conftest.c conftest.o
 506                 fi # endif -pthread in CFLAGS
 507
 508                 ])
 509 fi
 510
 511 # check solaris thread library
 512 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 513         [use solaris native thread library.]), [ ],[ withval="no" ])
 514 ub_have_sol_threads=no
 515 if test x_$withval != x_no; then
 516         if test x_$ub_have_pthreads != x_no; then
 517             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 518         else
 519         AC_SEARCH_LIBS(thr_create, [thread],
 520         [
 521                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 522
 523                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 524                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 525                 ub_have_sol_threads=yes
 526         ] , [
 527                 AC_ERROR([no solaris threads found.])
 528         ])
 529         fi
 530 fi
 531
 532 fi # end of non-mingw check of thread libraries
 533
 534 # Check for PyUnbound
 535 AC_ARG_WITH(pyunbound,
 536    AC_HELP_STRING([--with-pyunbound],
 537    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 538    [], [ withval="no" ])
 539
 540 ub_test_python=no
 541 ub_with_pyunbound=no
 542 if test x_$withval != x_no; then
 543    ub_with_pyunbound=yes
 544    ub_test_python=yes
 545 fi
 546
 547 # Check for Python module
 548 AC_ARG_WITH(pythonmodule,
 549    AC_HELP_STRING([--with-pythonmodule],
 550    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 551    [], [ withval="no" ])
 552
 553 ub_with_pythonmod=no
 554 if test x_$withval != x_no; then
 555    ub_with_pythonmod=yes
 556    ub_test_python=yes
 557 fi
 558
 559 # Check for Python & SWIG only on PyUnbound or PyModule
 560 if test x_$ub_test_python != x_no; then
 561
 562    # Check for Python
 563    ub_have_python=no
 564    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 565    AC_PYTHON_DEVEL
 566    if test ! -z "$PYTHON_VERSION"; then
 567         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 568                 AC_ERROR([Python version >= 2.4.0 is required])
 569         fi
 570
 571       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 572       AC_SUBST(PY_MAJOR_VERSION)
 573       # Have Python
 574       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 575       if test -n "$LIBS"; then
 576         LIBS="$PYTHON_LDFLAGS $LIBS"
 577       else
 578         LIBS="$PYTHON_LDFLAGS"
 579       fi
 580       if test -n "$CPPFLAGS"; then
 581         CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 582       else
 583         CPPFLAGS="$PYTHON_CPPFLAGS"
 584       fi
 585       ub_have_python=yes
 586       PC_PY_DEPENDENCY="python"
 587       AC_SUBST(PC_PY_DEPENDENCY)
 588
 589       # Check for SWIG
 590       ub_have_swig=no
 591       AC_ARG_ENABLE(swig-version-check, AC_HELP_STRING([--disable-swig-version-check], [Disable swig version check to build python modules with older swig even though that is unreliable]))
 592       if test "$enable_swig_version_check" = "yes"; then
 593         AC_PROG_SWIG(2.0.1)
 594       else
 595         AC_PROG_SWIG
 596       fi
 597       AC_MSG_CHECKING(SWIG)
 598       if test ! -x "$SWIG"; then
 599          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 600       else
 601          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 602          AC_SUBST(swig, "$SWIG")
 603          AC_MSG_RESULT(present)
 604
 605          # If have Python & SWIG
 606          # Declare PythonMod
 607          if test x_$ub_with_pythonmod != x_no; then
 608             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 609             WITH_PYTHONMODULE=yes
 610             AC_SUBST(WITH_PYTHONMODULE)
 611             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 612             AC_SUBST(PYTHONMOD_OBJ)
 613             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 614             AC_SUBST(PYTHONMOD_HEADER)
 615             PYTHONMOD_INSTALL=pythonmod-install
 616             AC_SUBST(PYTHONMOD_INSTALL)
 617             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 618             AC_SUBST(PYTHONMOD_UNINSTALL)
 619          fi
 620
 621          # Declare PyUnbound
 622          if test x_$ub_with_pyunbound != x_no; then
 623             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 624             WITH_PYUNBOUND=yes
 625             AC_SUBST(WITH_PYUNBOUND)
 626             PYUNBOUND_OBJ="libunbound_wrap.lo"
 627             AC_SUBST(PYUNBOUND_OBJ)
 628             PYUNBOUND_TARGET="_unbound.la"
 629             AC_SUBST(PYUNBOUND_TARGET)
 630             PYUNBOUND_INSTALL=pyunbound-install
 631             AC_SUBST(PYUNBOUND_INSTALL)
 632             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 633             AC_SUBST(PYUNBOUND_UNINSTALL)
 634          fi
 635       fi
 636    else
 637       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 638       ub_with_pyunbound=no
 639       ub_with_pythonmod=no
 640    fi
 641 fi
 642
 643 if test "`uname`" = "NetBSD"; then
 644         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 645         AC_SUBST(NETBSD_LINTFLAGS)
 646 fi
 647 CONFIG_DATE=`date +%Y%m%d`
 648 AC_SUBST(CONFIG_DATE)
 649
 650 # Checks for libraries.
 651
 652 # libnss
 653 USE_NSS="no"
 654 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 655         [use libnss instead of openssl, installed at path.]),
 656         [
 657         USE_NSS="yes"
 658         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 659         if test "$withval" != "" -a "$withval" != "yes"; then
 660                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 661                 LDFLAGS="$LDFLAGS -L$withval/lib"
 662                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 663                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 664         else
 665                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 666                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 667         fi
 668         LIBS="$LIBS -lnss3 -lnspr4"
 669         SSLLIB=""
 670         ]
 671 )
 672
 673 # libnettle
 674 USE_NETTLE="no"
 675 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 676         [use libnettle as crypto library, installed at path.]),
 677         [
 678         USE_NETTLE="yes"
 679         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 680         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 681         if test "$withval" != "" -a "$withval" != "yes"; then
 682                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 683                 LDFLAGS="$LDFLAGS -L$withval/lib"
 684                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 685         else
 686                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 687         fi
 688         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 689         SSLLIB=""
 690         ]
 691 )
 692
 693 # openssl
 694 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 695 ACX_WITH_SSL
 696 ACX_LIB_SSL
 697 SSLLIB="-lssl"
 698
 699 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 700 BAKLIBS="$LIBS"
 701 LIBS="-lssl $LIBS"
 702 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 703 AC_TRY_LINK_FUNC([HMAC_Update], [
 704         AC_MSG_RESULT([no])
 705         LIBS="$BAKLIBS"
 706 ], [
 707         AC_MSG_RESULT([yes])
 708         LIBS="$BAKLIBS"
 709         LIBS="$LIBS -lcrypt32"
 710 ])
 711
 712 AC_MSG_CHECKING([for LibreSSL])
 713 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 714         AC_MSG_RESULT([yes])
 715         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 716         # libressl provides these compat functions, but they may also be
 717         # declared by the OS in libc.  See if they have been declared.
 718         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform,reallocarray])
 719 else
 720         AC_MSG_RESULT([no])
 721 fi
 722 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h],,, [AC_INCLUDES_DEFAULT])
 723 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1 EVP_DigestVerify])
 724
 725 # these check_funcs need -lssl
 726 BAKLIBS="$LIBS"
 727 LIBS="-lssl $LIBS"
 728 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level SSL_set1_host SSL_get0_peername])
 729 LIBS="$BAKLIBS"
 730
 731 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 732 AC_INCLUDES_DEFAULT
 733 #ifdef HAVE_OPENSSL_ERR_H
 734 #include <openssl/err.h>
 735 #endif
 736
 737 #ifdef HAVE_OPENSSL_RAND_H
 738 #include <openssl/rand.h>
 739 #endif
 740
 741 #ifdef HAVE_OPENSSL_CONF_H
 742 #include <openssl/conf.h>
 743 #endif
 744
 745 #ifdef HAVE_OPENSSL_ENGINE_H
 746 #include <openssl/engine.h>
 747 #endif
 748 #include <openssl/ssl.h>
 749 #include <openssl/evp.h>
 750 ])
 751 fi
 752 AC_SUBST(SSLLIB)
 753
 754
 755 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 756 case "$enable_sha1" in
 757         no)
 758         ;;
 759         yes|*)
 760         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 761         ;;
 762 esac
 763
 764
 765 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 766 case "$enable_sha2" in
 767         no)
 768         ;;
 769         yes|*)
 770         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 771         ;;
 772 esac
 773
 774 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 775 case "$enable_subnet" in
 776         yes)
 777         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 778         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 779         AC_SUBST(SUBNET_OBJ)
 780         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 781         AC_SUBST(SUBNET_HEADER)
 782         ;;
 783         no|*)
 784         ;;
 785 esac
 786
 787 # check wether gost also works
 788 AC_DEFUN([AC_CHECK_GOST_WORKS],
 789 [AC_REQUIRE([AC_PROG_CC])
 790 AC_MSG_CHECKING([if GOST works])
 791 if test c${cross_compiling} = cno; then
 792 BAKCFLAGS="$CFLAGS"
 793 if test -n "$ssldir"; then
 794         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 795 fi
 796 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 797 #include <string.h>
 798 #include <openssl/ssl.h>
 799 #include <openssl/evp.h>
 800 #include <openssl/engine.h>
 801 #include <openssl/conf.h>
 802 /* routine to load gost (from sldns) */
 803 int load_gost_id(void)
 804 {
 805         static int gost_id = 0;
 806         const EVP_PKEY_ASN1_METHOD* meth;
 807         ENGINE* e;
 808
 809         if(gost_id) return gost_id;
 810
 811         /* see if configuration loaded gost implementation from other engine*/
 812         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 813         if(meth) {
 814                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 815                 return gost_id;
 816         }
 817
 818         /* see if engine can be loaded already */
 819         e = ENGINE_by_id("gost");
 820         if(!e) {
 821                 /* load it ourself, in case statically linked */
 822                 ENGINE_load_builtin_engines();
 823                 ENGINE_load_dynamic();
 824                 e = ENGINE_by_id("gost");
 825         }
 826         if(!e) {
 827                 /* no gost engine in openssl */
 828                 return 0;
 829         }
 830         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 831                 ENGINE_finish(e);
 832                 ENGINE_free(e);
 833                 return 0;
 834         }
 835
 836         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 837         if(!meth) {
 838                 /* algo not found */
 839                 ENGINE_finish(e);
 840                 ENGINE_free(e);
 841                 return 0;
 842         }
 843         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 844         return gost_id;
 845 }
 846 int main(void) {
 847         EVP_MD_CTX* ctx;
 848         const EVP_MD* md;
 849         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 850         const char* str = "Hello world";
 851         const unsigned char check[] = {
 852                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 853                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 854                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 855                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 856         };
 857         OPENSSL_config(NULL);
 858         (void)load_gost_id();
 859         md = EVP_get_digestbyname("md_gost94");
 860         if(!md) return 1;
 861         memset(digest, 0, sizeof(digest));
 862         ctx = EVP_MD_CTX_create();
 863         if(!ctx) return 2;
 864         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 865         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 866         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 867         /* uncomment to see the hash calculated.
 868                 {int i;
 869                 for(i=0; i<32; i++)
 870                         printf(" %2.2x", (int)digest[i]);
 871                 printf("\n");}
 872         */
 873         if(memcmp(digest, check, sizeof(check)) != 0)
 874                 return 6;
 875         return 0;
 876 }
 877 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 878 CFLAGS="$BAKCFLAGS"
 879 else
 880 eval "ac_cv_c_gost_works=maybe"
 881 fi
 882 AC_MSG_RESULT($ac_cv_c_gost_works)
 883 ])dnl
 884
 885 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 886 use_gost="no"
 887 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 888 case "$enable_gost" in
 889         no)
 890         ;;
 891         *)
 892         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 893         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 894         AC_CHECK_GOST_WORKS
 895         if test "$ac_cv_c_gost_works" != no; then
 896                 use_gost="yes"
 897                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 898         fi
 899         ;;
 900 esac
 901 fi dnl !USE_NSS && !USE_NETTLE
 902
 903 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 904 use_ecdsa="no"
 905 case "$enable_ecdsa" in
 906     no)
 907       ;;
 908     *)
 909       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 910               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 911               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 912               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 913 #include <openssl/evp.h>
 914               ])
 915               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 916               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 917               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
 918                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 919                   AC_MSG_RESULT([no])
 920                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 921                 else
 922                   AC_MSG_RESULT([yes])
 923                 fi
 924               else
 925                 # not OpenSSL, thus likely LibreSSL, which supports it
 926                 AC_MSG_RESULT([yes])
 927               fi
 928       fi
 929       # we now know we have ECDSA and the required curves.
 930       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 931       use_ecdsa="yes"
 932       ;;
 933 esac
 934
 935 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
 936 use_dsa="no"
 937 case "$enable_dsa" in
 938     no)
 939       ;;
 940     *)
 941       # detect if DSA is supported, and turn it off if not.
 942       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 943       AC_CHECK_FUNC(DSA_SIG_new, [
 944       AC_CHECK_TYPE(DSA_SIG*, [
 945       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
 946       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
 947                fi ], [
 948 AC_INCLUDES_DEFAULT
 949 #ifdef HAVE_OPENSSL_ERR_H
 950 #include <openssl/err.h>
 951 #endif
 952
 953 #ifdef HAVE_OPENSSL_RAND_H
 954 #include <openssl/rand.h>
 955 #endif
 956
 957 #ifdef HAVE_OPENSSL_CONF_H
 958 #include <openssl/conf.h>
 959 #endif
 960
 961 #ifdef HAVE_OPENSSL_ENGINE_H
 962 #include <openssl/engine.h>
 963 #endif
 964       ])
 965       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
 966                fi ])
 967       else
 968       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
 969       fi
 970       ;;
 971 esac
 972
 973 AC_ARG_ENABLE(ed25519, AC_HELP_STRING([--disable-ed25519], [Disable ED25519 support]))
 974 use_ed25519="no"
 975 case "$enable_ed25519" in
 976     no)
 977       ;;
 978     *)
 979       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 980               AC_CHECK_DECLS([NID_ED25519], [
 981                 use_ed25519="yes"
 982               ], [ if test "x$enable_ed25519" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED25519 and you used --enable-ed25519.])
 983                 fi ], [AC_INCLUDES_DEFAULT
 984 #include <openssl/evp.h>
 985               ])
 986       fi
 987       if test $USE_NETTLE = "yes"; then
 988                 AC_CHECK_HEADERS([nettle/eddsa.h], use_ed25519="yes",, [AC_INCLUDES_DEFAULT])
 989       fi
 990       if test $use_ed25519 = "yes"; then
 991                 AC_DEFINE_UNQUOTED([USE_ED25519], [1], [Define this to enable ED25519 support.])
 992       fi
 993       ;;
 994 esac
 995
 996 AC_ARG_ENABLE(ed448, AC_HELP_STRING([--disable-ed448], [Disable ED448 support]))
 997 use_ed448="no"
 998 case "$enable_ed448" in
 999     no)
1000       ;;
1001     *)
1002       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1003               AC_CHECK_DECLS([NID_ED448], [
1004                 use_ed448="yes"
1005               ], [ if test "x$enable_ed448" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED448 and you used --enable-ed448.])
1006                 fi ], [AC_INCLUDES_DEFAULT
1007 #include <openssl/evp.h>
1008               ])
1009       fi
1010       if test $use_ed448 = "yes"; then
1011                 AC_DEFINE_UNQUOTED([USE_ED448], [1], [Define this to enable ED448 support.])
1012       fi
1013       ;;
1014 esac
1015
1016 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
1017 case "$enable_event_api" in
1018     yes)
1019       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
1020       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
1021       ;;
1022     *)
1023       ;;
1024 esac
1025
1026 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
1027 case "$enable_tfo_client" in
1028         yes)
1029                 case `uname` in
1030                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1031                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1032                                              [AC_INCLUDES_DEFAULT
1033 #include <netinet/tcp.h>
1034 ])
1035                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1036                           ;;
1037                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1038                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1039                                               [AC_INCLUDES_DEFAULT
1040 #include <sys/socket.h>
1041 ])
1042                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1043                           ;;
1044                 esac
1045         ;;
1046         no|*)
1047                 ;;
1048 esac
1049
1050 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
1051 case "$enable_tfo_server" in
1052         yes)
1053               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
1054 #include <netinet/tcp.h>
1055               ])
1056                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
1057                 ;;
1058         no|*)
1059                 ;;
1060 esac
1061
1062 # check for libevent
1063 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
1064     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
1065     [ ],[ withval="no" ])
1066 if test x_$withval = x_yes -o x_$withval != x_no; then
1067         AC_MSG_CHECKING(for libevent)
1068         if test x_$withval = x_ -o x_$withval = x_yes; then
1069             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1070         fi
1071         for dir in $withval; do
1072             thedir="$dir"
1073             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
1074                 found_libevent="yes"
1075                 dnl assume /usr is in default path.
1076                 if test "$thedir" != "/usr"; then
1077                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
1078                 fi
1079                 break;
1080             fi
1081         done
1082         if test x_$found_libevent != x_yes; then
1083                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
1084                         # libevent source directory
1085                         AC_MSG_RESULT(found in $thedir)
1086                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
1087                         BAK_LDFLAGS_SET="1"
1088                         BAK_LDFLAGS="$LDFLAGS"
1089                         # remove evdns from linking
1090                         mkdir build >/dev/null 2>&1
1091                         mkdir build/libevent >/dev/null 2>&1
1092                         mkdir build/libevent/.libs >/dev/null 2>&1
1093                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1094                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
1095                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1096                         cp $ev_files_o build/libevent
1097                         cp $ev_files_lo build/libevent
1098                         cp $ev_files_libso build/libevent/.libs
1099                         LATE_LDFLAGS="build/libevent/*.lo -lm"
1100                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
1101                 else
1102                         AC_MSG_ERROR([Cannot find the libevent library in $withval
1103 You can restart ./configure --with-libevent=no to use a builtin alternative.
1104 Please note that this alternative is not as capable as libevent when using
1105 large outgoing port ranges.  ])
1106                 fi
1107         else
1108             AC_MSG_RESULT(found in $thedir)
1109             dnl if event2 exists and no event lib in dir itself, use subdir
1110             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1111                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1112                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1113             else
1114                     dnl assume /usr is in default path, do not add "".
1115                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1116                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1117                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1118                     fi
1119             fi
1120         fi
1121         # check for library used by libevent after 1.3c
1122         AC_SEARCH_LIBS([clock_gettime], [rt])
1123
1124         # is the event.h header libev or libevent?
1125         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1126         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1127                 AC_SEARCH_LIBS(event_set, [ev])
1128         ],[
1129                 AC_SEARCH_LIBS(event_set, [event])
1130         ],[AC_INCLUDES_DEFAULT
1131 #include <event.h>
1132         ])
1133         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1134         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1135         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1136         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1137         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1138         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1139         PC_LIBEVENT_DEPENDENCY="libevent"
1140         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1141         if test -n "$BAK_LDFLAGS_SET"; then
1142                 LDFLAGS="$BAK_LDFLAGS"
1143         fi
1144 else
1145         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1146 fi
1147
1148 # check for libexpat
1149 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1150     [specify explicit path for libexpat.]),
1151     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1152 AC_MSG_CHECKING(for libexpat)
1153 found_libexpat="no"
1154 for dir in $withval ; do
1155             if test -f "$dir/include/expat.h"; then
1156                 found_libexpat="yes"
1157                 dnl assume /usr is in default path.
1158                 if test "$dir" != "/usr"; then
1159                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1160                     LDFLAGS="$LDFLAGS -L$dir/lib"
1161                 fi
1162                 AC_MSG_RESULT(found in $dir)
1163                 break;
1164             fi
1165 done
1166 if test x_$found_libexpat != x_yes; then
1167         AC_ERROR([Could not find libexpat, expat.h])
1168 fi
1169 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1170 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1171 #include <expat.h>
1172 ])
1173
1174 # hiredis (redis C client for cachedb)
1175 AC_ARG_WITH(libhiredis, AC_HELP_STRING([--with-libhiredis=path],
1176     [specify explicit path for libhiredis.]),
1177     [ ],[ withval="no" ])
1178 AC_MSG_CHECKING(for libhiredis)
1179 found_libhiredis="no"
1180 if test x_$withval = x_yes -o x_$withval != x_no; then
1181    if test x_$withval = x_ -o x_$withval = x_yes; then
1182             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1183    fi
1184    for dir in $withval ; do
1185             if test -f "$dir/include/hiredis/hiredis.h"; then
1186                 found_libhiredis="yes"
1187                 dnl assume /usr is in default path.
1188                 if test "$dir" != "/usr"; then
1189                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1190                     LDFLAGS="$LDFLAGS -L$dir/lib"
1191                 fi
1192                 AC_MSG_RESULT(found in $dir)
1193                 AC_DEFINE([USE_REDIS], [1], [Define this to use hiredis client.])
1194                 LIBS="$LIBS -lhiredis"
1195                 break;
1196             fi
1197     done
1198     if test x_$found_libhiredis != x_yes; then
1199         AC_ERROR([Could not find libhiredis, hiredis.h])
1200     fi
1201     AC_CHECK_HEADERS([hiredis/hiredis.h],,, [AC_INCLUDES_DEFAULT])
1202     AC_CHECK_DECLS([redisConnect], [], [], [AC_INCLUDES_DEFAULT
1203     #include <hiredis/hiredis.h>
1204     ])
1205 fi
1206
1207 # set static linking if requested
1208 AC_SUBST(staticexe)
1209 staticexe=""
1210 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1211         [ enable to compile executables statically against (event) libs, for debug purposes ]),
1212         , )
1213 if test x_$enable_static_exe = x_yes; then
1214         staticexe="-static"
1215         if test "$on_mingw" = yes; then
1216                 staticexe="-all-static"
1217                 # for static compile, include gdi32 and zlib here.
1218                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1219                         :
1220                 else
1221                         LIBS="$LIBS -lgdi32"
1222                 fi
1223                 LIBS="$LIBS -lz"
1224         fi
1225 fi
1226
1227 # Include systemd.m4 - begin
1228 sinclude(systemd.m4)
1229 # Include systemd.m4 - end
1230
1231 # set lock checking if requested
1232 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1233         [ enable to check lock and unlock calls, for debug purposes ]),
1234         , )
1235 if test x_$enable_lock_checks = x_yes; then
1236         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1237         CHECKLOCK_OBJ="checklocks.lo"
1238         AC_SUBST(CHECKLOCK_OBJ)
1239 fi
1240
1241 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1242 if test "$USE_WINSOCK" = 1; then
1243         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1244         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1245 #include <windows.h>
1246         ])
1247         AC_CHECK_TOOL(WINDRES, windres)
1248         LIBS="$LIBS -liphlpapi"
1249         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1250         AC_SUBST(WINAPPS)
1251         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1252         AC_SUBST(WIN_DAEMON_SRC)
1253         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1254         AC_SUBST(WIN_DAEMON_OBJ)
1255         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1256         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1257         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1258         AC_SUBST(WIN_HOST_OBJ_LINK)
1259         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1260         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1261         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1262         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1263         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1264         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1265 fi
1266 if test $ac_cv_func_getaddrinfo = no; then
1267         AC_LIBOBJ([fake-rfc2553])
1268 fi
1269 # check after getaddrinfo for its libraries
1270 ACX_FUNC_IOCTLSOCKET
1271
1272 # see if daemon(3) exists, and if it is deprecated.
1273 AC_CHECK_FUNCS([daemon])
1274 if test $ac_cv_func_daemon = yes; then
1275         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1276 #include <stdlib.h>
1277 ])
1278 fi
1279
1280 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1281 AC_INCLUDES_DEFAULT
1282 #ifdef HAVE_SYS_UN_H
1283 #include <sys/un.h>
1284 #endif
1285 ])
1286 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1287 AC_INCLUDES_DEFAULT
1288 #if HAVE_SYS_PARAM_H
1289 #include <sys/param.h>
1290 #endif
1291
1292 #ifdef HAVE_SYS_SOCKET_H
1293 #include <sys/socket.h>
1294 #endif
1295
1296 #ifdef HAVE_SYS_UIO_H
1297 #include <sys/uio.h>
1298 #endif
1299
1300 #ifdef HAVE_NETINET_IN_H
1301 #include <netinet/in.h>
1302 #endif
1303
1304 #ifdef HAVE_NETINET_TCP_H
1305 #include <netinet/tcp.h>
1306 #endif
1307
1308 #ifdef HAVE_ARPA_INET_H
1309 #include <arpa/inet.h>
1310 #endif
1311
1312 #ifdef HAVE_WINSOCK2_H
1313 #include <winsock2.h>
1314 #endif
1315
1316 #ifdef HAVE_WS2TCPIP_H
1317 #include <ws2tcpip.h>
1318 #endif
1319 ])
1320 AC_SEARCH_LIBS([setusercontext], [util])
1321 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget])
1322 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1323 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1324
1325 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1326 if echo $build_os | grep darwin8 > /dev/null; then
1327         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1328 fi
1329 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1330 AC_INCLUDES_DEFAULT
1331 #ifdef HAVE_NETINET_IN_H
1332 #include <netinet/in.h>
1333 #endif
1334
1335 #ifdef HAVE_NETINET_TCP_H
1336 #include <netinet/tcp.h>
1337 #endif
1338
1339 #ifdef HAVE_ARPA_INET_H
1340 #include <arpa/inet.h>
1341 #endif
1342
1343 #ifdef HAVE_WINSOCK2_H
1344 #include <winsock2.h>
1345 #endif
1346
1347 #ifdef HAVE_WS2TCPIP_H
1348 #include <ws2tcpip.h>
1349 #endif
1350 ])
1351 AC_REPLACE_FUNCS(inet_aton)
1352 AC_REPLACE_FUNCS(inet_pton)
1353 AC_REPLACE_FUNCS(inet_ntop)
1354 AC_REPLACE_FUNCS(snprintf)
1355 # test if snprintf return the proper length
1356 if test "x$ac_cv_func_snprintf" = xyes; then
1357     if test c${cross_compiling} = cno; then
1358         AC_MSG_CHECKING([for correct snprintf return value])
1359         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1360 [[
1361 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1362 ]])], [AC_MSG_RESULT(yes)], [
1363                 AC_MSG_RESULT(no)
1364                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1365                 AC_LIBOBJ(snprintf)
1366           ])
1367     fi
1368 fi
1369 AC_REPLACE_FUNCS(strlcat)
1370 AC_REPLACE_FUNCS(strlcpy)
1371 AC_REPLACE_FUNCS(memmove)
1372 AC_REPLACE_FUNCS(gmtime_r)
1373 AC_REPLACE_FUNCS(isblank)
1374 dnl without CTIME, ARC4-functions and without reallocarray.
1375 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1376 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1377 AC_REPLACE_FUNCS(reallocarray)
1378 if test "$USE_NSS" = "no"; then
1379         AC_REPLACE_FUNCS(arc4random)
1380         AC_REPLACE_FUNCS(arc4random_uniform)
1381         if test "$ac_cv_func_arc4random" = "no"; then
1382                 AC_LIBOBJ(explicit_bzero)
1383                 AC_LIBOBJ(arc4_lock)
1384                 AC_CHECK_FUNCS([getentropy],,[
1385                     if test "$USE_WINSOCK" = 1; then
1386                         AC_LIBOBJ(getentropy_win)
1387                     else
1388                         case "$host" in
1389                         Darwin|*darwin*)
1390                                 AC_LIBOBJ(getentropy_osx)
1391                         ;;
1392                         *solaris*|*sunos*|SunOS)
1393                                 AC_LIBOBJ(getentropy_solaris)
1394                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1395                                         AC_CHECK_FUNCS([SHA512_Update],,[
1396                                                 AC_LIBOBJ(sha512)
1397                                         ])
1398                                 ], [AC_INCLUDES_DEFAULT])
1399                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1400                                         # this lib needed for sha2 on solaris
1401                                         LIBS="$LIBS -lmd"
1402                                 fi
1403                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1404                         ;;
1405                         *linux*|Linux|*)
1406                                 AC_LIBOBJ(getentropy_linux)
1407                                 AC_CHECK_FUNCS([SHA512_Update],,[
1408                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1409                                         AC_LIBOBJ(sha512)
1410                                 ])
1411                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1412                                 AC_CHECK_FUNCS([getauxval])
1413                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1414                         ;;
1415                         esac
1416                     fi
1417                 ])
1418         fi
1419 fi
1420 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1421 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1422 AC_REPLACE_FUNCS(ctime_r)
1423 AC_REPLACE_FUNCS(strsep)
1424
1425 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1426 case "$enable_allsymbols" in
1427         yes)
1428         COMMON_OBJ_ALL_SYMBOLS=""
1429         UBSYMS=""
1430         EXTRALINK="-L. -L.libs -lunbound"
1431         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1432         ;;
1433         no|*)
1434         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1435         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1436         EXTRALINK=""
1437         ;;
1438 esac
1439 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1440 AC_SUBST(EXTRALINK)
1441 AC_SUBST(UBSYMS)
1442 if test x_$enable_lock_checks = x_yes; then
1443         UBSYMS="-export-symbols clubsyms.def"
1444         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1445         echo lock_protect >> clubsyms.def
1446         echo lock_unprotect >> clubsyms.def
1447         echo lock_get_mem >> clubsyms.def
1448         echo checklock_start >> clubsyms.def
1449         echo checklock_stop >> clubsyms.def
1450         echo checklock_lock >> clubsyms.def
1451         echo checklock_unlock >> clubsyms.def
1452         echo checklock_init >> clubsyms.def
1453         echo checklock_thrcreate >> clubsyms.def
1454         echo checklock_thrjoin >> clubsyms.def
1455 fi
1456
1457 # check for dnstap if requested
1458 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1459     [
1460         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1461         AC_SUBST([ENABLE_DNSTAP], [1])
1462
1463         AC_SUBST([opt_dnstap_socket_path])
1464         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1465         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1466             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1467
1468         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1469         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1470     ],
1471     [
1472         AC_SUBST([ENABLE_DNSTAP], [0])
1473     ]
1474 )
1475
1476 # check for dnscrypt if requested
1477 dnsc_DNSCRYPT([
1478         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1479         AC_SUBST([ENABLE_DNSCRYPT], [1])
1480
1481         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1482         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1483     ],
1484     [
1485         AC_SUBST([ENABLE_DNSCRYPT], [0])
1486     ]
1487 )
1488
1489 # check for cachedb if requested
1490 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1491 case "$enable_cachedb" in
1492     yes)
1493         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1494         ;;
1495     no|*)
1496         # nothing
1497         ;;
1498 esac
1499
1500 # check for ipsecmod if requested
1501 AC_ARG_ENABLE(ipsecmod, AC_HELP_STRING([--enable-ipsecmod], [Enable ipsecmod module that facilitates opportunistic IPsec]))
1502 case "$enable_ipsecmod" in
1503         yes)
1504                 AC_DEFINE([USE_IPSECMOD], [1], [Define to 1 to use ipsecmod support.])
1505                 IPSECMOD_OBJ="ipsecmod.lo ipsecmod-whitelist.lo"
1506                 AC_SUBST(IPSECMOD_OBJ)
1507                 IPSECMOD_HEADER='$(srcdir)/ipsecmod/ipsecmod.h $(srcdir)/ipsecmod/ipsecmod-whitelist.h'
1508                 AC_SUBST(IPSECMOD_HEADER)
1509                 ;;
1510         no|*)
1511                 # nothing
1512                 ;;
1513 esac
1514
1515 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1516 # on openBSD, the implicit rule make $< work.
1517 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1518 # gmake works.
1519 cat >conftest.make <<EOF
1520 all:    conftest.lo
1521
1522 conftest.lo foo.lo bla.lo:
1523         if test -f "\$<"; then touch \$@; fi
1524
1525 .SUFFIXES: .lo
1526 .c.lo:
1527         if test -f "\$<"; then touch \$@; fi
1528
1529 conftest.lo:        conftest.dir/conftest.c
1530 EOF
1531 mkdir conftest.dir
1532 touch conftest.dir/conftest.c
1533 rm -f conftest.lo conftest.c
1534 ${MAKE:-make} -f conftest.make >/dev/null
1535 rm -f conftest.make conftest.c conftest.dir/conftest.c
1536 rm -rf conftest.dir
1537 if test ! -f conftest.lo; then
1538         AC_MSG_RESULT(no)
1539         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1540         SOURCEFILE='`cat .source`'
1541 else
1542         AC_MSG_RESULT(yes)
1543         SOURCEDETERMINE=':'
1544         SOURCEFILE='$<'
1545 fi
1546 rm -f conftest.lo
1547 AC_SUBST(SOURCEDETERMINE)
1548 AC_SUBST(SOURCEFILE)
1549
1550 # see if we want to build the library or everything
1551 ALLTARGET="alltargets"
1552 INSTALLTARGET="install-all"
1553 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1554         [do not build daemon and tool programs]),
1555         [
1556         if test "$withval" = "yes"; then
1557                 ALLTARGET="lib"
1558                 INSTALLTARGET="install-lib"
1559         fi
1560 ])
1561 if test $ALLTARGET = "alltargets"; then
1562         if test $USE_NSS = "yes"; then
1563                 AC_ERROR([--with-nss can only be used in combination with --with-libunbound-only.])
1564         fi
1565         if test $USE_NETTLE = "yes"; then
1566                 AC_ERROR([--with-nettle can only be used in combination with --with-libunbound-only.])
1567         fi
1568 fi
1569
1570 AC_SUBST(ALLTARGET)
1571 AC_SUBST(INSTALLTARGET)
1572
1573 ACX_STRIP_EXT_FLAGS
1574 if test -n "$LATE_LDFLAGS"; then
1575   LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1576 fi
1577 # remove start spaces
1578 LDFLAGS=`echo "$LDFLAGS"|sed -e 's/^ *//'`
1579 LIBS=`echo "$LIBS"|sed -e 's/^ *//'`
1580
1581 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1582
1583 AH_BOTTOM(
1584 dnl this must be first AH_CONFIG, to define the flags before any includes.
1585 AHX_CONFIG_EXT_FLAGS
1586
1587 dnl includes
1588 [
1589 #ifndef UNBOUND_DEBUG
1590 #  define NDEBUG
1591 #endif
1592
1593 /** Use small-ldns codebase */
1594 #define USE_SLDNS 1
1595 #ifdef HAVE_SSL
1596 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1597 #endif
1598
1599 #include <stdio.h>
1600 #include <string.h>
1601 #include <unistd.h>
1602 #include <assert.h>
1603
1604 #if STDC_HEADERS
1605 #include <stdlib.h>
1606 #include <stddef.h>
1607 #endif
1608
1609 #ifdef HAVE_STDARG_H
1610 #include <stdarg.h>
1611 #endif
1612
1613 #ifdef HAVE_STDINT_H
1614 #include <stdint.h>
1615 #endif
1616
1617 #include <errno.h>
1618
1619 #if HAVE_SYS_PARAM_H
1620 #include <sys/param.h>
1621 #endif
1622
1623 #ifdef HAVE_SYS_SOCKET_H
1624 #include <sys/socket.h>
1625 #endif
1626
1627 #ifdef HAVE_SYS_UIO_H
1628 #include <sys/uio.h>
1629 #endif
1630
1631 #ifdef HAVE_NETINET_IN_H
1632 #include <netinet/in.h>
1633 #endif
1634
1635 #ifdef HAVE_NETINET_TCP_H
1636 #include <netinet/tcp.h>
1637 #endif
1638
1639 #ifdef HAVE_ARPA_INET_H
1640 #include <arpa/inet.h>
1641 #endif
1642
1643 #ifdef HAVE_WINSOCK2_H
1644 #include <winsock2.h>
1645 #endif
1646
1647 #ifdef HAVE_WS2TCPIP_H
1648 #include <ws2tcpip.h>
1649 #endif
1650
1651 #ifndef USE_WINSOCK
1652 #define ARG_LL "%ll"
1653 #else
1654 #define ARG_LL "%I64"
1655 #endif
1656
1657 #ifndef AF_LOCAL
1658 #define AF_LOCAL AF_UNIX
1659 #endif
1660 ]
1661
1662 AHX_CONFIG_FORMAT_ATTRIBUTE
1663 AHX_CONFIG_UNUSED_ATTRIBUTE
1664 AHX_CONFIG_FSEEKO
1665 AHX_CONFIG_MAXHOSTNAMELEN
1666 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1667 #define snprintf snprintf_unbound
1668 #define vsnprintf vsnprintf_unbound
1669 #include <stdarg.h>
1670 int snprintf (char *str, size_t count, const char *fmt, ...);
1671 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1672 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1673 AHX_CONFIG_INET_PTON(unbound)
1674 AHX_CONFIG_INET_NTOP(unbound)
1675 AHX_CONFIG_INET_ATON(unbound)
1676 AHX_CONFIG_MEMMOVE(unbound)
1677 AHX_CONFIG_STRLCAT(unbound)
1678 AHX_CONFIG_STRLCPY(unbound)
1679 AHX_CONFIG_GMTIME_R(unbound)
1680 AHX_CONFIG_REALLOCARRAY(unbound)
1681 AHX_CONFIG_W32_SLEEP
1682 AHX_CONFIG_W32_USLEEP
1683 AHX_CONFIG_W32_RANDOM
1684 AHX_CONFIG_W32_SRANDOM
1685 AHX_CONFIG_W32_FD_SET_T
1686 AHX_CONFIG_IPV6_MIN_MTU
1687 AHX_MEMCMP_BROKEN(unbound)
1688
1689 [
1690 #ifndef HAVE_CTIME_R
1691 #define ctime_r unbound_ctime_r
1692 char *ctime_r(const time_t *timep, char *buf);
1693 #endif
1694
1695 #ifndef HAVE_STRSEP
1696 #define strsep unbound_strsep
1697 char *strsep(char **stringp, const char *delim);
1698 #endif
1699
1700 #ifndef HAVE_ISBLANK
1701 #define isblank unbound_isblank
1702 int isblank(int c);
1703 #endif
1704
1705 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
1706 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
1707 #endif
1708
1709 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
1710 int inet_pton(int af, const char* src, void* dst);
1711 #endif
1712
1713 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1714 #define strptime unbound_strptime
1715 struct tm;
1716 char *strptime(const char *s, const char *format, struct tm *tm);
1717 #endif
1718
1719 #ifdef HAVE_LIBRESSL
1720 #  if !HAVE_DECL_STRLCPY
1721 size_t strlcpy(char *dst, const char *src, size_t siz);
1722 #  endif
1723 #  if !HAVE_DECL_STRLCAT
1724 size_t strlcat(char *dst, const char *src, size_t siz);
1725 #  endif
1726 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
1727 uint32_t arc4random(void);
1728 #  endif
1729 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
1730 uint32_t arc4random_uniform(uint32_t upper_bound);
1731 #  endif
1732 #  if !HAVE_DECL_REALLOCARRAY
1733 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1734 #  endif
1735 #endif /* HAVE_LIBRESSL */
1736 #ifndef HAVE_ARC4RANDOM
1737 void explicit_bzero(void* buf, size_t len);
1738 int getentropy(void* buf, size_t len);
1739 uint32_t arc4random(void);
1740 void arc4random_buf(void* buf, size_t n);
1741 void _ARC4_LOCK(void);
1742 void _ARC4_UNLOCK(void);
1743 void _ARC4_LOCK_DESTROY(void);
1744 #endif
1745 #ifndef HAVE_ARC4RANDOM_UNIFORM
1746 uint32_t arc4random_uniform(uint32_t upper_bound);
1747 #endif
1748 #ifdef COMPAT_SHA512
1749 #ifndef SHA512_DIGEST_LENGTH
1750 #define SHA512_BLOCK_LENGTH             128
1751 #define SHA512_DIGEST_LENGTH            64
1752 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
1753 typedef struct _SHA512_CTX {
1754         uint64_t        state[8];
1755         uint64_t        bitcount[2];
1756         uint8_t buffer[SHA512_BLOCK_LENGTH];
1757 } SHA512_CTX;
1758 #endif /* SHA512_DIGEST_LENGTH */
1759 void SHA512_Init(SHA512_CTX*);
1760 void SHA512_Update(SHA512_CTX*, void*, size_t);
1761 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
1762 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
1763 #endif /* COMPAT_SHA512 */
1764
1765
1766
1767 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1768    /* using version of libevent that is not threadsafe. */
1769 #  define LIBEVENT_SIGNAL_PROBLEM 1
1770 #endif
1771
1772 #ifndef CHECKED_INET6
1773 #  define CHECKED_INET6
1774 #  ifdef AF_INET6
1775 #    define INET6
1776 #  else
1777 #    define AF_INET6        28
1778 #  endif
1779 #endif /* CHECKED_INET6 */
1780
1781 #ifndef HAVE_GETADDRINFO
1782 struct sockaddr_storage;
1783 #include "compat/fake-rfc2553.h"
1784 #endif
1785
1786 #ifdef UNBOUND_ALLOC_STATS
1787 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1788 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1789 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1790 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1791 void *unbound_stat_malloc(size_t size);
1792 void *unbound_stat_calloc(size_t nmemb, size_t size);
1793 void unbound_stat_free(void *ptr);
1794 void *unbound_stat_realloc(void *ptr, size_t size);
1795 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1796         const char* func);
1797 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1798         int line, const char* func);
1799 void unbound_stat_free_log(void *ptr, const char* file, int line,
1800         const char* func);
1801 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1802         int line, const char* func);
1803 #elif defined(UNBOUND_ALLOC_LITE)
1804 #  include "util/alloc.h"
1805 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1806
1807 /** default port for DNS traffic. */
1808 #define UNBOUND_DNS_PORT 53
1809 /** default port for DNS over TLS traffic. */
1810 #define UNBOUND_DNS_OVER_TLS_PORT 853
1811 /** default port for unbound control traffic, registered port with IANA,
1812     ub-dns-control  8953/tcp    unbound dns nameserver control */
1813 #define UNBOUND_CONTROL_PORT 8953
1814 /** the version of unbound-control that this software implements */
1815 #define UNBOUND_CONTROL_VERSION 1
1816
1817 ])
1818
1819 dnl if we build from source tree, the man pages need @date@ and @version@
1820 dnl if this is a distro tarball, that was already done by makedist.sh
1821 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
1822 AC_SUBST(date, [`date +'%b %e, %Y'`])
1823
1824 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service])
1825 AC_CONFIG_HEADER([config.h])
1826 AC_OUTPUT