contrib/unbound/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[6])
  14 m4_define([VERSION_MICRO],[3])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=7
  21 LIBUNBOUND_REVISION=2
  22 LIBUNBOUND_AGE=5
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75
  76 #   Current  -- the number of the binary API that we're implementing
  77 #   Revision -- which iteration of the implementation of the binary
  78 #               API are we supplying?
  79 #   Age      -- How many previous binary API versions do we also
  80 #               support?
  81 #
  82 # If we release a new version that does not change the binary API,
  83 # increment Revision.
  84 #
  85 # If we release a new version that changes the binary API, but does
  86 # not break programs compiled against the old binary API, increment
  87 # Current and Age.  Set Revision to 0, since this is the first
  88 # implementation of the new API.
  89 #
  90 # Otherwise, we're changing the binary API and breaking bakward
  91 # compatibility with old binaries.  Increment Current.  Set Age to 0,
  92 # since we're backward compatible with no previous APIs.  Set Revision
  93 # to 0 too.
  94 AC_SUBST(LIBUNBOUND_CURRENT)
  95 AC_SUBST(LIBUNBOUND_REVISION)
  96 AC_SUBST(LIBUNBOUND_AGE)
  97
  98 CFLAGS="$CFLAGS"
  99 AC_AIX
 100 if test "$ac_cv_header_minix_config_h" = "yes"; then
 101         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 102 fi
 103
 104 dnl
 105 dnl By default set prefix to /usr/local
 106 dnl
 107 case "$prefix" in
 108         NONE)
 109                 prefix="/usr/local"
 110         ;;
 111 esac
 112
 113 # are we on MinGW?
 114 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 115 else
 116         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 117         else on_mingw="no"; fi
 118 fi
 119
 120 #
 121 # Determine configuration file
 122 # the eval is to evaluate shell expansion twice
 123 if test $on_mingw = "no"; then
 124   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 125 else
 126   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 127 fi
 128 AC_ARG_WITH([conf_file],
 129         AC_HELP_STRING([--with-conf-file=path],
 130         [Pathname to the Unbound configuration file]),
 131         [ub_conf_file="$withval"])
 132 AC_SUBST(ub_conf_file)
 133 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 134 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 135 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 136 AC_SUBST(ub_conf_dir)
 137
 138 # Determine run, chroot directory and pidfile locations
 139 AC_ARG_WITH(run-dir,
 140     AC_HELP_STRING([--with-run-dir=path],
 141     [set default directory to chdir to (by default dir part of cfg file)]),
 142     UNBOUND_RUN_DIR="$withval",
 143 if test $on_mingw = no; then
 144     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 145 else
 146     UNBOUND_RUN_DIR=""
 147 fi
 148 )
 149 AC_SUBST(UNBOUND_RUN_DIR)
 150 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 151 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 152
 153 AC_ARG_WITH(chroot-dir,
 154     AC_HELP_STRING([--with-chroot-dir=path],
 155     [set default directory to chroot to (by default same as run-dir)]),
 156     UNBOUND_CHROOT_DIR="$withval",
 157 if test $on_mingw = no; then
 158     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 159 else
 160     UNBOUND_CHROOT_DIR=""
 161 fi
 162 )
 163 AC_SUBST(UNBOUND_CHROOT_DIR)
 164 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 165 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 166
 167 AC_ARG_WITH(share-dir,
 168     AC_HELP_STRING([--with-share-dir=path],
 169     [set default directory with shared data (by default same as share/unbound)]),
 170     UNBOUND_SHARE_DIR="$withval",
 171     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 172 AC_SUBST(UNBOUND_SHARE_DIR)
 173 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 174
 175 AC_ARG_WITH(pidfile,
 176     AC_HELP_STRING([--with-pidfile=filename],
 177     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 178     UNBOUND_PIDFILE="$withval",
 179 if test $on_mingw = no; then
 180     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 181 else
 182     UNBOUND_PIDFILE=""
 183 fi
 184 )
 185 AC_SUBST(UNBOUND_PIDFILE)
 186 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 187 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 188
 189 AC_ARG_WITH(rootkey-file,
 190     AC_HELP_STRING([--with-rootkey-file=filename],
 191     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 192     UNBOUND_ROOTKEY_FILE="$withval",
 193 if test $on_mingw = no; then
 194     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 195 else
 196     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 197 fi
 198 )
 199 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 200 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 201 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 202
 203 AC_ARG_WITH(rootcert-file,
 204     AC_HELP_STRING([--with-rootcert-file=filename],
 205     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 206     UNBOUND_ROOTCERT_FILE="$withval",
 207 if test $on_mingw = no; then
 208     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 209 else
 210     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 211 fi
 212 )
 213 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 214 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 215 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 216
 217 AC_ARG_WITH(username,
 218     AC_HELP_STRING([--with-username=user],
 219     [set default user that unbound changes to (default user is unbound)]),
 220     UNBOUND_USERNAME="$withval",
 221     UNBOUND_USERNAME="unbound")
 222 AC_SUBST(UNBOUND_USERNAME)
 223 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 224
 225 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 226 ACX_RSRC_VERSION(wnvs)
 227 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 228
 229 # Checks for typedefs, structures, and compiler characteristics.
 230 AC_C_CONST
 231 AC_LANG_C
 232 # allow user to override the -g -O2 flags.
 233 if test "x$CFLAGS" = "x" ; then
 234 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 235 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 236 fi
 237 AC_PROG_CC
 238 ACX_DEPFLAG
 239 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 240
 241 # debug mode flags warnings
 242 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 243 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 244 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 245 else debug_enabled="$enable_checking"; fi
 246 AC_SUBST(debug_enabled)
 247 case "$debug_enabled" in
 248         yes)
 249                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 250                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 251                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 252                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 253                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 254                 ;;
 255         no|*)
 256                 # nothing to do.
 257                 ;;
 258 esac
 259 ACX_CHECK_FLTO
 260 ACX_CHECK_PIE
 261 ACX_CHECK_RELRO_NOW
 262
 263 AC_C_INLINE
 264 ACX_CHECK_FORMAT_ATTRIBUTE
 265 ACX_CHECK_UNUSED_ATTRIBUTE
 266
 267 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 268 [AC_REQUIRE([AC_PROG_CC])
 269 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 270 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 271 [ac_cv_c_weak_attribute=no
 272 AC_TRY_COMPILE(
 273 [ #include <stdio.h>
 274 __attribute__((weak)) void f(int x) { printf("%d", x); }
 275 ], [
 276    f(1);
 277 ],
 278 [ac_cv_c_weak_attribute="yes"],
 279 [ac_cv_c_weak_attribute="no"])
 280 ])
 281
 282 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 283 if test $ac_cv_c_weak_attribute = yes; then
 284   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 285 fi
 286 ])dnl End of CHECK_WEAK_ATTRIBUTE
 287
 288 CHECK_WEAK_ATTRIBUTE
 289
 290 if test "$srcdir" != "."; then
 291         CPPFLAGS="$CPPFLAGS -I$srcdir"
 292 fi
 293
 294 AC_DEFUN([ACX_YYLEX_DESTROY], [
 295         AC_MSG_CHECKING([for yylex_destroy])
 296         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 297                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 298                 AC_MSG_RESULT(yes)
 299         else AC_MSG_RESULT(no); fi
 300 ])
 301
 302 AC_PROG_LEX
 303 ACX_YYLEX_DESTROY
 304 AC_PROG_YACC
 305 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 306 AC_CHECK_TOOL(STRIP, strip)
 307 ACX_LIBTOOL_C_ONLY
 308
 309 # Checks for header files.
 310 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 311
 312 # check for types.
 313 # Using own tests for int64* because autoconf builtin only give 32bit.
 314 AC_CHECK_TYPE(int8_t, signed char)
 315 AC_CHECK_TYPE(int16_t, short)
 316 AC_CHECK_TYPE(int32_t, int)
 317 AC_CHECK_TYPE(int64_t, long long)
 318 AC_CHECK_TYPE(uint8_t, unsigned char)
 319 AC_CHECK_TYPE(uint16_t, unsigned short)
 320 AC_CHECK_TYPE(uint32_t, unsigned int)
 321 AC_CHECK_TYPE(uint64_t, unsigned long long)
 322 AC_TYPE_SIZE_T
 323 AC_CHECK_TYPE(ssize_t, int)
 324 AC_TYPE_UID_T
 325 AC_TYPE_PID_T
 326 AC_TYPE_OFF_T
 327 ACX_TYPE_U_CHAR
 328 ACX_TYPE_RLIM_T
 329 ACX_TYPE_SOCKLEN_T
 330 ACX_TYPE_IN_ADDR_T
 331 ACX_TYPE_IN_PORT_T
 332 ACX_CHECK_MEMCMP_SIGNED
 333
 334 AC_CHECK_SIZEOF(time_t,,[
 335 AC_INCLUDES_DEFAULT
 336 #ifdef TIME_WITH_SYS_TIME
 337 # include <sys/time.h>
 338 # include <time.h>
 339 #else
 340 # ifdef HAVE_SYS_TIME_H
 341 #  include <sys/time.h>
 342 # else
 343 #  include <time.h>
 344 # endif
 345 #endif
 346 ])
 347
 348 # add option to disable the evil rpath
 349 ACX_ARG_RPATH
 350 AC_SUBST(RUNTIME_PATH)
 351
 352 # check to see if libraries are needed for these functions.
 353 AC_SEARCH_LIBS([inet_pton], [nsl])
 354 AC_SEARCH_LIBS([socket], [socket])
 355
 356 # check wether strptime also works
 357 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 358 [AC_REQUIRE([AC_PROG_CC])
 359 AC_MSG_CHECKING(whether strptime works)
 360 if test c${cross_compiling} = cno; then
 361 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 362 #define _XOPEN_SOURCE 600
 363 #include <time.h>
 364 int main(void) { struct tm tm; char *res;
 365 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 366 if (!res) return 2;
 367 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 368 if (!res) return 1; return 0; }
 369 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 370 else
 371 eval "ac_cv_c_strptime_works=maybe"
 372 fi
 373 AC_MSG_RESULT($ac_cv_c_strptime_works)
 374 if test $ac_cv_c_strptime_works = no; then
 375 AC_LIBOBJ(strptime)
 376 else
 377 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 378 fi
 379 ])dnl
 380
 381 # check some functions of the OS before linking libs (while still runnable).
 382 AC_FUNC_CHOWN
 383 AC_FUNC_FORK
 384 AC_TYPE_SIGNAL
 385 AC_FUNC_FSEEKO
 386 ACX_SYS_LARGEFILE
 387 ACX_CHECK_NONBLOCKING_BROKEN
 388 ACX_MKDIR_ONE_ARG
 389 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 390
 391 # set memory allocation checking if requested
 392 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 393         [ enable to memory allocation statistics, for debug purposes ]),
 394         , )
 395 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 396         [ enable for lightweight alloc assertions, for debug purposes ]),
 397         , )
 398 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 399         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 400         , )
 401 if test x_$enable_alloc_nonregional = x_yes; then
 402         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 403 fi
 404 if test x_$enable_alloc_checks = x_yes; then
 405         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 406 else
 407         if test x_$enable_alloc_lite = x_yes; then
 408                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 409         else
 410                 ACX_FUNC_MALLOC([unbound])
 411         fi
 412 fi
 413
 414 # check windows threads (we use them, not pthreads, on windows).
 415 if test "$on_mingw" = "yes"; then
 416 # check windows threads
 417         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 418         AC_MSG_CHECKING([for CreateThread])
 419         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 420 #ifdef HAVE_WINDOWS_H
 421 #include <windows.h>
 422 #endif
 423 ], [
 424         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 425 ])],
 426         AC_MSG_RESULT(yes)
 427         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 428 ,
 429         AC_MSG_RESULT(no)
 430 )
 431
 432 else
 433 # not on mingw, check thread libraries.
 434
 435 # check for thread library.
 436 # check this first, so that the pthread lib does not get linked in via
 437 # libssl or libpython, and thus distorts the tests, and we end up using
 438 # the non-threadsafe C libraries.
 439 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 440  [use pthreads library, or --without-pthreads to disable threading support.]),
 441  [ ],[ withval="yes" ])
 442 ub_have_pthreads=no
 443 if test x_$withval != x_no; then
 444         AX_PTHREAD([
 445                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 446                 LIBS="$PTHREAD_LIBS $LIBS"
 447                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 448                 CC="$PTHREAD_CC"
 449                 ub_have_pthreads=yes
 450                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 451
 452                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 453                 AC_MSG_CHECKING([if -pthread unused during linking])
 454                 # catch clang warning 'argument unused during compilation'
 455                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 456 [[
 457 int main(void) {return 0;}
 458 ]])])
 459                 pthread_unused="yes"
 460                 # first compile
 461                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 462                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 463                 if test $? = 0; then
 464                         # then link
 465                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 466                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 467                         if test $? -ne 0; then
 468                                 AC_MSG_RESULT(yes)
 469                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 470                                 PTHREAD_CFLAGS_ONLY="-pthread"
 471                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 472                         else
 473                                 AC_MSG_RESULT(no)
 474                         fi
 475                 else
 476                         AC_MSG_RESULT(no)
 477                 fi # endif cc successful
 478                 rm -f conftest conftest.c conftest.o
 479                 fi # endif -pthread in CFLAGS
 480
 481                 ])
 482 fi
 483
 484 # check solaris thread library
 485 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 486         [use solaris native thread library.]), [ ],[ withval="no" ])
 487 ub_have_sol_threads=no
 488 if test x_$withval != x_no; then
 489         if test x_$ub_have_pthreads != x_no; then
 490             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 491         else
 492         AC_SEARCH_LIBS(thr_create, [thread],
 493         [
 494                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 495
 496                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 497                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 498                 ub_have_sol_threads=yes
 499         ] , [
 500                 AC_ERROR([no solaris threads found.])
 501         ])
 502         fi
 503 fi
 504
 505 fi # end of non-mingw check of thread libraries
 506
 507 # Check for PyUnbound
 508 AC_ARG_WITH(pyunbound,
 509    AC_HELP_STRING([--with-pyunbound],
 510    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 511    [], [ withval="no" ])
 512
 513 ub_test_python=no
 514 ub_with_pyunbound=no
 515 if test x_$withval != x_no; then
 516    ub_with_pyunbound=yes
 517    ub_test_python=yes
 518 fi
 519
 520 # Check for Python module
 521 AC_ARG_WITH(pythonmodule,
 522    AC_HELP_STRING([--with-pythonmodule],
 523    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 524    [], [ withval="no" ])
 525
 526 ub_with_pythonmod=no
 527 if test x_$withval != x_no; then
 528    ub_with_pythonmod=yes
 529    ub_test_python=yes
 530 fi
 531
 532 # Check for Python & SWIG only on PyUnbound or PyModule
 533 if test x_$ub_test_python != x_no; then
 534
 535    # Check for Python
 536    ub_have_python=no
 537    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 538    AC_PYTHON_DEVEL
 539    if test ! -z "$PYTHON_VERSION"; then
 540         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 541                 AC_ERROR([Python version >= 2.4.0 is required])
 542         fi
 543
 544       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 545       AC_SUBST(PY_MAJOR_VERSION)
 546       # Have Python
 547       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 548       LIBS="$PYTHON_LDFLAGS $LIBS"
 549       CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 550       ub_have_python=yes
 551       PC_PY_DEPENDENCY="python"
 552       AC_SUBST(PC_PY_DEPENDENCY)
 553
 554       # Check for SWIG
 555       ub_have_swig=no
 556       AC_PROG_SWIG(2.0.1)
 557       AC_MSG_CHECKING(SWIG)
 558       if test ! -x "$SWIG"; then
 559          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 560       else
 561          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 562          AC_SUBST(swig, "$SWIG")
 563          AC_MSG_RESULT(present)
 564
 565          # If have Python & SWIG
 566          # Declare PythonMod
 567          if test x_$ub_with_pythonmod != x_no; then
 568             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 569             WITH_PYTHONMODULE=yes
 570             AC_SUBST(WITH_PYTHONMODULE)
 571             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 572             AC_SUBST(PYTHONMOD_OBJ)
 573             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 574             AC_SUBST(PYTHONMOD_HEADER)
 575             PYTHONMOD_INSTALL=pythonmod-install
 576             AC_SUBST(PYTHONMOD_INSTALL)
 577             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 578             AC_SUBST(PYTHONMOD_UNINSTALL)
 579          fi
 580
 581          # Declare PyUnbound
 582          if test x_$ub_with_pyunbound != x_no; then
 583             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 584             WITH_PYUNBOUND=yes
 585             AC_SUBST(WITH_PYUNBOUND)
 586             PYUNBOUND_OBJ="libunbound_wrap.lo"
 587             AC_SUBST(PYUNBOUND_OBJ)
 588             PYUNBOUND_TARGET="_unbound.la"
 589             AC_SUBST(PYUNBOUND_TARGET)
 590             PYUNBOUND_INSTALL=pyunbound-install
 591             AC_SUBST(PYUNBOUND_INSTALL)
 592             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 593             AC_SUBST(PYUNBOUND_UNINSTALL)
 594          fi
 595       fi
 596    else
 597       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 598       ub_with_pyunbound=no
 599       ub_with_pythonmod=no
 600    fi
 601 fi
 602
 603 if test "`uname`" = "NetBSD"; then
 604         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 605         AC_SUBST(NETBSD_LINTFLAGS)
 606 fi
 607 CONFIG_DATE=`date +%Y%m%d`
 608 AC_SUBST(CONFIG_DATE)
 609
 610 # Checks for libraries.
 611
 612 # libnss
 613 USE_NSS="no"
 614 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 615         [use libnss instead of openssl, installed at path.]),
 616         [
 617         USE_NSS="yes"
 618         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 619         if test "$withval" != "" -a "$withval" != "yes"; then
 620                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 621                 LDFLAGS="$LDFLAGS -L$withval/lib"
 622                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 623                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 624         else
 625                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 626                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 627         fi
 628         LIBS="$LIBS -lnss3 -lnspr4"
 629         SSLLIB=""
 630         ]
 631 )
 632
 633 # libnettle
 634 USE_NETTLE="no"
 635 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 636         [use libnettle as crypto library, installed at path.]),
 637         [
 638         USE_NETTLE="yes"
 639         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 640         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 641         if test "$withval" != "" -a "$withval" != "yes"; then
 642                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 643                 LDFLAGS="$LDFLAGS -L$withval/lib"
 644                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 645         else
 646                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 647         fi
 648         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 649         SSLLIB=""
 650         ]
 651 )
 652
 653 # openssl
 654 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 655 ACX_WITH_SSL
 656 ACX_LIB_SSL
 657 SSLLIB="-lssl"
 658
 659 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 660 BAKLIBS="$LIBS"
 661 LIBS="-lssl $LIBS"
 662 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 663 AC_TRY_LINK_FUNC([HMAC_Update], [
 664         AC_MSG_RESULT([no])
 665         LIBS="$BAKLIBS"
 666 ], [
 667         AC_MSG_RESULT([yes])
 668         LIBS="$BAKLIBS"
 669         LIBS="$LIBS -lcrypt32"
 670 ])
 671
 672 AC_MSG_CHECKING([for LibreSSL])
 673 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 674         AC_MSG_RESULT([yes])
 675         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 676         # libressl provides these compat functions, but they may also be
 677         # declared by the OS in libc.  See if they have been declared.
 678         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform,reallocarray])
 679 else
 680         AC_MSG_RESULT([no])
 681 fi
 682 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h],,, [AC_INCLUDES_DEFAULT])
 683 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1])
 684
 685 # these check_funcs need -lssl
 686 BAKLIBS="$LIBS"
 687 LIBS="-lssl $LIBS"
 688 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level])
 689 LIBS="$BAKLIBS"
 690
 691 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 692 AC_INCLUDES_DEFAULT
 693 #ifdef HAVE_OPENSSL_ERR_H
 694 #include <openssl/err.h>
 695 #endif
 696
 697 #ifdef HAVE_OPENSSL_RAND_H
 698 #include <openssl/rand.h>
 699 #endif
 700
 701 #ifdef HAVE_OPENSSL_CONF_H
 702 #include <openssl/conf.h>
 703 #endif
 704
 705 #ifdef HAVE_OPENSSL_ENGINE_H
 706 #include <openssl/engine.h>
 707 #endif
 708 #include <openssl/ssl.h>
 709 #include <openssl/evp.h>
 710 ])
 711 fi
 712 AC_SUBST(SSLLIB)
 713
 714
 715 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 716 case "$enable_sha1" in
 717         no)
 718         ;;
 719         yes|*)
 720         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 721         ;;
 722 esac
 723
 724
 725 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 726 case "$enable_sha2" in
 727         no)
 728         ;;
 729         yes|*)
 730         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 731         ;;
 732 esac
 733
 734 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 735 case "$enable_subnet" in
 736         yes)
 737         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 738         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 739         AC_SUBST(SUBNET_OBJ)
 740         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 741         AC_SUBST(SUBNET_HEADER)
 742         ;;
 743         no|*)
 744         ;;
 745 esac
 746
 747 # check wether gost also works
 748 AC_DEFUN([AC_CHECK_GOST_WORKS],
 749 [AC_REQUIRE([AC_PROG_CC])
 750 AC_MSG_CHECKING([if GOST works])
 751 if test c${cross_compiling} = cno; then
 752 BAKCFLAGS="$CFLAGS"
 753 if test -n "$ssldir"; then
 754         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 755 fi
 756 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 757 #include <string.h>
 758 #include <openssl/ssl.h>
 759 #include <openssl/evp.h>
 760 #include <openssl/engine.h>
 761 #include <openssl/conf.h>
 762 /* routine to load gost (from sldns) */
 763 int load_gost_id(void)
 764 {
 765         static int gost_id = 0;
 766         const EVP_PKEY_ASN1_METHOD* meth;
 767         ENGINE* e;
 768
 769         if(gost_id) return gost_id;
 770
 771         /* see if configuration loaded gost implementation from other engine*/
 772         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 773         if(meth) {
 774                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 775                 return gost_id;
 776         }
 777
 778         /* see if engine can be loaded already */
 779         e = ENGINE_by_id("gost");
 780         if(!e) {
 781                 /* load it ourself, in case statically linked */
 782                 ENGINE_load_builtin_engines();
 783                 ENGINE_load_dynamic();
 784                 e = ENGINE_by_id("gost");
 785         }
 786         if(!e) {
 787                 /* no gost engine in openssl */
 788                 return 0;
 789         }
 790         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 791                 ENGINE_finish(e);
 792                 ENGINE_free(e);
 793                 return 0;
 794         }
 795
 796         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 797         if(!meth) {
 798                 /* algo not found */
 799                 ENGINE_finish(e);
 800                 ENGINE_free(e);
 801                 return 0;
 802         }
 803         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 804         return gost_id;
 805 }
 806 int main(void) {
 807         EVP_MD_CTX* ctx;
 808         const EVP_MD* md;
 809         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 810         const char* str = "Hello world";
 811         const unsigned char check[] = {
 812                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 813                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 814                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 815                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 816         };
 817         OPENSSL_config(NULL);
 818         (void)load_gost_id();
 819         md = EVP_get_digestbyname("md_gost94");
 820         if(!md) return 1;
 821         memset(digest, 0, sizeof(digest));
 822         ctx = EVP_MD_CTX_create();
 823         if(!ctx) return 2;
 824         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 825         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 826         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 827         /* uncomment to see the hash calculated.
 828                 {int i;
 829                 for(i=0; i<32; i++)
 830                         printf(" %2.2x", (int)digest[i]);
 831                 printf("\n");}
 832         */
 833         if(memcmp(digest, check, sizeof(check)) != 0)
 834                 return 6;
 835         return 0;
 836 }
 837 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 838 CFLAGS="$BAKCFLAGS"
 839 else
 840 eval "ac_cv_c_gost_works=maybe"
 841 fi
 842 AC_MSG_RESULT($ac_cv_c_gost_works)
 843 ])dnl
 844
 845 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 846 use_gost="no"
 847 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 848 case "$enable_gost" in
 849         no)
 850         ;;
 851         *)
 852         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 853         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 854         AC_CHECK_GOST_WORKS
 855         if test "$ac_cv_c_gost_works" != no; then
 856                 use_gost="yes"
 857                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 858         fi
 859         ;;
 860 esac
 861 fi dnl !USE_NSS && !USE_NETTLE
 862
 863 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 864 use_ecdsa="no"
 865 case "$enable_ecdsa" in
 866     no)
 867       ;;
 868     *)
 869       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 870               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 871               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 872               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 873 #include <openssl/evp.h>
 874               ])
 875               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 876               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 877               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
 878                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 879                   AC_MSG_RESULT([no])
 880                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 881                 else
 882                   AC_MSG_RESULT([yes])
 883                 fi
 884               else
 885                 # not OpenSSL, thus likely LibreSSL, which supports it
 886                 AC_MSG_RESULT([yes])
 887               fi
 888       fi
 889       # we now know we have ECDSA and the required curves.
 890       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 891       use_ecdsa="yes"
 892       ;;
 893 esac
 894
 895 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
 896 use_dsa="no"
 897 case "$enable_dsa" in
 898     no)
 899       ;;
 900     *)
 901       # detect if DSA is supported, and turn it off if not.
 902       AC_CHECK_FUNC(DSA_SIG_new, [
 903       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
 904       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
 905                fi ])
 906       ;;
 907 esac
 908
 909
 910 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
 911 case "$enable_event_api" in
 912     yes)
 913       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
 914       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
 915       ;;
 916     *)
 917       ;;
 918 esac
 919
 920 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
 921 case "$enable_tfo_client" in
 922         yes)
 923                 case `uname` in
 924                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
 925                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
 926                                              [AC_INCLUDES_DEFAULT
 927 #include <netinet/tcp.h>
 928 ])
 929                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
 930                           ;;
 931                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
 932                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
 933                                               [AC_INCLUDES_DEFAULT
 934 #include <sys/socket.h>
 935 ])
 936                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
 937                           ;;
 938                 esac
 939         ;;
 940         no|*)
 941                 ;;
 942 esac
 943
 944 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
 945 case "$enable_tfo_server" in
 946         yes)
 947               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
 948 #include <netinet/tcp.h>
 949               ])
 950                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
 951                 ;;
 952         no|*)
 953                 ;;
 954 esac
 955
 956 # check for libevent
 957 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
 958     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
 959     [ ],[ withval="no" ])
 960 if test x_$withval = x_yes -o x_$withval != x_no; then
 961         AC_MSG_CHECKING(for libevent)
 962         if test x_$withval = x_ -o x_$withval = x_yes; then
 963             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
 964         fi
 965         for dir in $withval; do
 966             thedir="$dir"
 967             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
 968                 found_libevent="yes"
 969                 dnl assume /usr is in default path.
 970                 if test "$thedir" != "/usr"; then
 971                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
 972                 fi
 973                 break;
 974             fi
 975         done
 976         if test x_$found_libevent != x_yes; then
 977                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
 978                         # libevent source directory
 979                         AC_MSG_RESULT(found in $thedir)
 980                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
 981                         BAK_LDFLAGS_SET="1"
 982                         BAK_LDFLAGS="$LDFLAGS"
 983                         # remove evdns from linking
 984                         mkdir build >/dev/null 2>&1
 985                         mkdir build/libevent >/dev/null 2>&1
 986                         mkdir build/libevent/.libs >/dev/null 2>&1
 987                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
 988                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
 989                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
 990                         cp $ev_files_o build/libevent
 991                         cp $ev_files_lo build/libevent
 992                         cp $ev_files_libso build/libevent/.libs
 993                         LATE_LDFLAGS="build/libevent/*.lo -lm"
 994                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
 995                 else
 996                         AC_MSG_ERROR([Cannot find the libevent library in $withval
 997 You can restart ./configure --with-libevent=no to use a builtin alternative.
 998 Please note that this alternative is not as capable as libevent when using
 999 large outgoing port ranges.  ])
1000                 fi
1001         else
1002             AC_MSG_RESULT(found in $thedir)
1003             dnl if event2 exists and no event lib in dir itself, use subdir
1004             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1005                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1006                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1007             else
1008                     dnl assume /usr is in default path, do not add "".
1009                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1010                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1011                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1012                     fi
1013             fi
1014         fi
1015         # check for library used by libevent after 1.3c
1016         AC_SEARCH_LIBS([clock_gettime], [rt])
1017
1018         # is the event.h header libev or libevent?
1019         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1020         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1021                 AC_SEARCH_LIBS(event_set, [ev])
1022         ],[
1023                 AC_SEARCH_LIBS(event_set, [event])
1024         ],[AC_INCLUDES_DEFAULT
1025 #include <event.h>
1026         ])
1027         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1028         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1029         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1030         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1031         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1032         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1033         PC_LIBEVENT_DEPENDENCY="libevent"
1034         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1035         if test -n "$BAK_LDFLAGS_SET"; then
1036                 LDFLAGS="$BAK_LDFLAGS"
1037         fi
1038 else
1039         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1040 fi
1041
1042 # check for libexpat
1043 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1044     [specify explicit path for libexpat.]),
1045     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1046 AC_MSG_CHECKING(for libexpat)
1047 found_libexpat="no"
1048 for dir in $withval ; do
1049             if test -f "$dir/include/expat.h"; then
1050                 found_libexpat="yes"
1051                 dnl assume /usr is in default path.
1052                 if test "$dir" != "/usr"; then
1053                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1054                     LDFLAGS="$LDFLAGS -L$dir/lib"
1055                 fi
1056                 AC_MSG_RESULT(found in $dir)
1057                 break;
1058             fi
1059 done
1060 if test x_$found_libexpat != x_yes; then
1061         AC_ERROR([Could not find libexpat, expat.h])
1062 fi
1063 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1064 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1065 #include <expat.h>
1066 ])
1067
1068 # set static linking if requested
1069 AC_SUBST(staticexe)
1070 staticexe=""
1071 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1072         [ enable to compile executables statically against (event) libs, for debug purposes ]),
1073         , )
1074 if test x_$enable_static_exe = x_yes; then
1075         staticexe="-static"
1076         if test "$on_mingw" = yes; then
1077                 staticexe="-all-static"
1078                 # for static compile, include gdi32 and zlib here.
1079                 LIBS="$LIBS -lgdi32 -lz"
1080         fi
1081 fi
1082
1083 # Include systemd.m4 - begin
1084 sinclude(systemd.m4)
1085 # Include systemd.m4 - end
1086
1087 # set lock checking if requested
1088 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1089         [ enable to check lock and unlock calls, for debug purposes ]),
1090         , )
1091 if test x_$enable_lock_checks = x_yes; then
1092         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1093         CHECKLOCK_OBJ="checklocks.lo"
1094         AC_SUBST(CHECKLOCK_OBJ)
1095 fi
1096
1097 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1098 if test "$USE_WINSOCK" = 1; then
1099         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1100         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1101 #include <windows.h>
1102         ])
1103         AC_CHECK_TOOL(WINDRES, windres)
1104         LIBS="$LIBS -liphlpapi"
1105         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1106         AC_SUBST(WINAPPS)
1107         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1108         AC_SUBST(WIN_DAEMON_SRC)
1109         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1110         AC_SUBST(WIN_DAEMON_OBJ)
1111         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1112         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1113         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1114         AC_SUBST(WIN_HOST_OBJ_LINK)
1115         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1116         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1117         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1118         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1119         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1120         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1121 fi
1122 if test $ac_cv_func_getaddrinfo = no; then
1123         AC_LIBOBJ([fake-rfc2553])
1124 fi
1125 # check after getaddrinfo for its libraries
1126 ACX_FUNC_IOCTLSOCKET
1127
1128 # see if daemon(3) exists, and if it is deprecated.
1129 AC_CHECK_FUNCS([daemon])
1130 if test $ac_cv_func_daemon = yes; then
1131         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1132 #include <stdlib.h>
1133 ])
1134 fi
1135
1136 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1137 AC_INCLUDES_DEFAULT
1138 #ifdef HAVE_SYS_UN_H
1139 #include <sys/un.h>
1140 #endif
1141 ])
1142 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1143 AC_INCLUDES_DEFAULT
1144 #if HAVE_SYS_PARAM_H
1145 #include <sys/param.h>
1146 #endif
1147
1148 #ifdef HAVE_SYS_SOCKET_H
1149 #include <sys/socket.h>
1150 #endif
1151
1152 #ifdef HAVE_SYS_UIO_H
1153 #include <sys/uio.h>
1154 #endif
1155
1156 #ifdef HAVE_NETINET_IN_H
1157 #include <netinet/in.h>
1158 #endif
1159
1160 #ifdef HAVE_NETINET_TCP_H
1161 #include <netinet/tcp.h>
1162 #endif
1163
1164 #ifdef HAVE_ARPA_INET_H
1165 #include <arpa/inet.h>
1166 #endif
1167
1168 #ifdef HAVE_WINSOCK2_H
1169 #include <winsock2.h>
1170 #endif
1171
1172 #ifdef HAVE_WS2TCPIP_H
1173 #include <ws2tcpip.h>
1174 #endif
1175 ])
1176 AC_SEARCH_LIBS([setusercontext], [util])
1177 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget])
1178 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1179 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1180
1181 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1182 if echo $build_os | grep darwin8 > /dev/null; then
1183         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1184 fi
1185 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1186 AC_INCLUDES_DEFAULT
1187 #ifdef HAVE_NETINET_IN_H
1188 #include <netinet/in.h>
1189 #endif
1190
1191 #ifdef HAVE_NETINET_TCP_H
1192 #include <netinet/tcp.h>
1193 #endif
1194
1195 #ifdef HAVE_ARPA_INET_H
1196 #include <arpa/inet.h>
1197 #endif
1198
1199 #ifdef HAVE_WINSOCK2_H
1200 #include <winsock2.h>
1201 #endif
1202
1203 #ifdef HAVE_WS2TCPIP_H
1204 #include <ws2tcpip.h>
1205 #endif
1206 ])
1207 AC_REPLACE_FUNCS(inet_aton)
1208 AC_REPLACE_FUNCS(inet_pton)
1209 AC_REPLACE_FUNCS(inet_ntop)
1210 AC_REPLACE_FUNCS(snprintf)
1211 # test if snprintf return the proper length
1212 if test "x$ac_cv_func_snprintf" = xyes; then
1213     if test c${cross_compiling} = cno; then
1214         AC_MSG_CHECKING([for correct snprintf return value])
1215         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1216 [[
1217 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1218 ]])], [AC_MSG_RESULT(yes)], [
1219                 AC_MSG_RESULT(no)
1220                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1221                 AC_LIBOBJ(snprintf)
1222           ])
1223     fi
1224 fi
1225 AC_REPLACE_FUNCS(strlcat)
1226 AC_REPLACE_FUNCS(strlcpy)
1227 AC_REPLACE_FUNCS(memmove)
1228 AC_REPLACE_FUNCS(gmtime_r)
1229 AC_REPLACE_FUNCS(isblank)
1230 dnl without CTIME, ARC4-functions and without reallocarray.
1231 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1232 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1233 AC_REPLACE_FUNCS(reallocarray)
1234 if test "$USE_NSS" = "no"; then
1235         AC_REPLACE_FUNCS(arc4random)
1236         AC_REPLACE_FUNCS(arc4random_uniform)
1237         if test "$ac_cv_func_arc4random" = "no"; then
1238                 AC_LIBOBJ(explicit_bzero)
1239                 AC_LIBOBJ(arc4_lock)
1240                 AC_CHECK_FUNCS([getentropy],,[
1241                     if test "$USE_WINSOCK" = 1; then
1242                         AC_LIBOBJ(getentropy_win)
1243                     else
1244                         case "$host" in
1245                         Darwin|*darwin*)
1246                                 AC_LIBOBJ(getentropy_osx)
1247                         ;;
1248                         *solaris*|*sunos*|SunOS)
1249                                 AC_LIBOBJ(getentropy_solaris)
1250                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1251                                         AC_CHECK_FUNCS([SHA512_Update],,[
1252                                                 AC_LIBOBJ(sha512)
1253                                         ])
1254                                 ], [AC_INCLUDES_DEFAULT])
1255                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1256                                         # this lib needed for sha2 on solaris
1257                                         LIBS="$LIBS -lmd"
1258                                 fi
1259                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1260                         ;;
1261                         *linux*|Linux|*)
1262                                 AC_LIBOBJ(getentropy_linux)
1263                                 AC_CHECK_FUNCS([SHA512_Update],,[
1264                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1265                                         AC_LIBOBJ(sha512)
1266                                 ])
1267                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1268                                 AC_CHECK_FUNCS([getauxval])
1269                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1270                         ;;
1271                         esac
1272                     fi
1273                 ])
1274         fi
1275 fi
1276 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1277 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1278 AC_REPLACE_FUNCS(ctime_r)
1279 AC_REPLACE_FUNCS(strsep)
1280
1281 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1282 case "$enable_allsymbols" in
1283         yes)
1284         COMMON_OBJ_ALL_SYMBOLS=""
1285         UBSYMS=""
1286         EXTRALINK="-L. -L.libs -lunbound"
1287         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1288         ;;
1289         no|*)
1290         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1291         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1292         EXTRALINK=""
1293         ;;
1294 esac
1295 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1296 AC_SUBST(EXTRALINK)
1297 AC_SUBST(UBSYMS)
1298 if test x_$enable_lock_checks = x_yes; then
1299         UBSYMS="-export-symbols clubsyms.def"
1300         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1301         echo lock_protect >> clubsyms.def
1302         echo lock_unprotect >> clubsyms.def
1303         echo lock_get_mem >> clubsyms.def
1304         echo checklock_start >> clubsyms.def
1305         echo checklock_stop >> clubsyms.def
1306         echo checklock_lock >> clubsyms.def
1307         echo checklock_unlock >> clubsyms.def
1308         echo checklock_init >> clubsyms.def
1309         echo checklock_thrcreate >> clubsyms.def
1310         echo checklock_thrjoin >> clubsyms.def
1311 fi
1312
1313 # check for dnstap if requested
1314 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1315     [
1316         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1317         AC_SUBST([ENABLE_DNSTAP], [1])
1318
1319         AC_SUBST([opt_dnstap_socket_path])
1320         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1321         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1322             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1323
1324         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1325         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1326     ],
1327     [
1328         AC_SUBST([ENABLE_DNSTAP], [0])
1329     ]
1330 )
1331
1332 # check for dnscrypt if requested
1333 dnsc_DNSCRYPT([
1334         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1335         AC_SUBST([ENABLE_DNSCRYPT], [1])
1336
1337         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1338         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1339     ],
1340     [
1341         AC_SUBST([ENABLE_DNSCRYPT], [0])
1342     ]
1343 )
1344
1345 # check for cachedb if requested
1346 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1347 case "$enable_cachedb" in
1348     yes)
1349         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1350         ;;
1351     no|*)
1352         # nothing
1353         ;;
1354 esac
1355
1356 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1357 # on openBSD, the implicit rule make $< work.
1358 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1359 # gmake works.
1360 cat >conftest.make <<EOF
1361 all:    conftest.lo
1362
1363 conftest.lo foo.lo bla.lo:
1364         if test -f "\$<"; then touch \$@; fi
1365
1366 .SUFFIXES: .lo
1367 .c.lo:
1368         if test -f "\$<"; then touch \$@; fi
1369
1370 conftest.lo:        conftest.dir/conftest.c
1371 EOF
1372 mkdir conftest.dir
1373 touch conftest.dir/conftest.c
1374 rm -f conftest.lo conftest.c
1375 ${MAKE:-make} -f conftest.make >/dev/null
1376 rm -f conftest.make conftest.c conftest.dir/conftest.c
1377 rm -rf conftest.dir
1378 if test ! -f conftest.lo; then
1379         AC_MSG_RESULT(no)
1380         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1381         SOURCEFILE='`cat .source`'
1382 else
1383         AC_MSG_RESULT(yes)
1384         SOURCEDETERMINE=':'
1385         SOURCEFILE='$<'
1386 fi
1387 rm -f conftest.lo
1388 AC_SUBST(SOURCEDETERMINE)
1389 AC_SUBST(SOURCEFILE)
1390
1391 # see if we want to build the library or everything
1392 ALLTARGET="alltargets"
1393 INSTALLTARGET="install-all"
1394 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1395         [do not build daemon and tool programs]),
1396         [
1397         if test "$withval" = "yes"; then
1398                 ALLTARGET="lib"
1399                 INSTALLTARGET="install-lib"
1400         fi
1401 ])
1402 AC_SUBST(ALLTARGET)
1403 AC_SUBST(INSTALLTARGET)
1404
1405 ACX_STRIP_EXT_FLAGS
1406 LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1407
1408 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1409
1410 AH_BOTTOM(
1411 dnl this must be first AH_CONFIG, to define the flags before any includes.
1412 AHX_CONFIG_EXT_FLAGS
1413
1414 dnl includes
1415 [
1416 #ifndef UNBOUND_DEBUG
1417 #  define NDEBUG
1418 #endif
1419
1420 /** Use small-ldns codebase */
1421 #define USE_SLDNS 1
1422 #ifdef HAVE_SSL
1423 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1424 #endif
1425
1426 #include <stdio.h>
1427 #include <string.h>
1428 #include <unistd.h>
1429 #include <assert.h>
1430
1431 #if STDC_HEADERS
1432 #include <stdlib.h>
1433 #include <stddef.h>
1434 #endif
1435
1436 #ifdef HAVE_STDARG_H
1437 #include <stdarg.h>
1438 #endif
1439
1440 #ifdef HAVE_STDINT_H
1441 #include <stdint.h>
1442 #endif
1443
1444 #include <errno.h>
1445
1446 #if HAVE_SYS_PARAM_H
1447 #include <sys/param.h>
1448 #endif
1449
1450 #ifdef HAVE_SYS_SOCKET_H
1451 #include <sys/socket.h>
1452 #endif
1453
1454 #ifdef HAVE_SYS_UIO_H
1455 #include <sys/uio.h>
1456 #endif
1457
1458 #ifdef HAVE_NETINET_IN_H
1459 #include <netinet/in.h>
1460 #endif
1461
1462 #ifdef HAVE_NETINET_TCP_H
1463 #include <netinet/tcp.h>
1464 #endif
1465
1466 #ifdef HAVE_ARPA_INET_H
1467 #include <arpa/inet.h>
1468 #endif
1469
1470 #ifdef HAVE_WINSOCK2_H
1471 #include <winsock2.h>
1472 #endif
1473
1474 #ifdef HAVE_WS2TCPIP_H
1475 #include <ws2tcpip.h>
1476 #endif
1477
1478 #ifndef USE_WINSOCK
1479 #define ARG_LL "%ll"
1480 #else
1481 #define ARG_LL "%I64"
1482 #endif
1483
1484 #ifndef AF_LOCAL
1485 #define AF_LOCAL AF_UNIX
1486 #endif
1487 ]
1488
1489 AHX_CONFIG_FORMAT_ATTRIBUTE
1490 AHX_CONFIG_UNUSED_ATTRIBUTE
1491 AHX_CONFIG_FSEEKO
1492 AHX_CONFIG_MAXHOSTNAMELEN
1493 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1494 #define snprintf snprintf_unbound
1495 #define vsnprintf vsnprintf_unbound
1496 #include <stdarg.h>
1497 int snprintf (char *str, size_t count, const char *fmt, ...);
1498 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1499 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1500 AHX_CONFIG_INET_PTON(unbound)
1501 AHX_CONFIG_INET_NTOP(unbound)
1502 AHX_CONFIG_INET_ATON(unbound)
1503 AHX_CONFIG_MEMMOVE(unbound)
1504 AHX_CONFIG_STRLCAT(unbound)
1505 AHX_CONFIG_STRLCPY(unbound)
1506 AHX_CONFIG_GMTIME_R(unbound)
1507 AHX_CONFIG_REALLOCARRAY(unbound)
1508 AHX_CONFIG_W32_SLEEP
1509 AHX_CONFIG_W32_USLEEP
1510 AHX_CONFIG_W32_RANDOM
1511 AHX_CONFIG_W32_SRANDOM
1512 AHX_CONFIG_W32_FD_SET_T
1513 AHX_CONFIG_IPV6_MIN_MTU
1514 AHX_MEMCMP_BROKEN(unbound)
1515
1516 [
1517 #ifndef HAVE_CTIME_R
1518 #define ctime_r unbound_ctime_r
1519 char *ctime_r(const time_t *timep, char *buf);
1520 #endif
1521
1522 #ifndef HAVE_STRSEP
1523 #define strsep unbound_strsep
1524 char *strsep(char **stringp, const char *delim);
1525 #endif
1526
1527 #ifndef HAVE_ISBLANK
1528 #define isblank unbound_isblank
1529 int isblank(int c);
1530 #endif
1531
1532 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
1533 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
1534 #endif
1535
1536 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
1537 int inet_pton(int af, const char* src, void* dst);
1538 #endif
1539
1540 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1541 #define strptime unbound_strptime
1542 struct tm;
1543 char *strptime(const char *s, const char *format, struct tm *tm);
1544 #endif
1545
1546 #ifdef HAVE_LIBRESSL
1547 #  if !HAVE_DECL_STRLCPY
1548 size_t strlcpy(char *dst, const char *src, size_t siz);
1549 #  endif
1550 #  if !HAVE_DECL_STRLCAT
1551 size_t strlcat(char *dst, const char *src, size_t siz);
1552 #  endif
1553 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
1554 uint32_t arc4random(void);
1555 #  endif
1556 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
1557 uint32_t arc4random_uniform(uint32_t upper_bound);
1558 #  endif
1559 #  if !HAVE_DECL_REALLOCARRAY
1560 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1561 #  endif
1562 #endif /* HAVE_LIBRESSL */
1563 #ifndef HAVE_ARC4RANDOM
1564 void explicit_bzero(void* buf, size_t len);
1565 int getentropy(void* buf, size_t len);
1566 uint32_t arc4random(void);
1567 void arc4random_buf(void* buf, size_t n);
1568 void _ARC4_LOCK(void);
1569 void _ARC4_UNLOCK(void);
1570 #endif
1571 #ifndef HAVE_ARC4RANDOM_UNIFORM
1572 uint32_t arc4random_uniform(uint32_t upper_bound);
1573 #endif
1574 #ifdef COMPAT_SHA512
1575 #ifndef SHA512_DIGEST_LENGTH
1576 #define SHA512_BLOCK_LENGTH             128
1577 #define SHA512_DIGEST_LENGTH            64
1578 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
1579 typedef struct _SHA512_CTX {
1580         uint64_t        state[8];
1581         uint64_t        bitcount[2];
1582         uint8_t buffer[SHA512_BLOCK_LENGTH];
1583 } SHA512_CTX;
1584 #endif /* SHA512_DIGEST_LENGTH */
1585 void SHA512_Init(SHA512_CTX*);
1586 void SHA512_Update(SHA512_CTX*, void*, size_t);
1587 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
1588 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
1589 #endif /* COMPAT_SHA512 */
1590
1591
1592
1593 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1594    /* using version of libevent that is not threadsafe. */
1595 #  define LIBEVENT_SIGNAL_PROBLEM 1
1596 #endif
1597
1598 #ifndef CHECKED_INET6
1599 #  define CHECKED_INET6
1600 #  ifdef AF_INET6
1601 #    define INET6
1602 #  else
1603 #    define AF_INET6        28
1604 #  endif
1605 #endif /* CHECKED_INET6 */
1606
1607 #ifndef HAVE_GETADDRINFO
1608 struct sockaddr_storage;
1609 #include "compat/fake-rfc2553.h"
1610 #endif
1611
1612 #ifdef UNBOUND_ALLOC_STATS
1613 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1614 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1615 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1616 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1617 void *unbound_stat_malloc(size_t size);
1618 void *unbound_stat_calloc(size_t nmemb, size_t size);
1619 void unbound_stat_free(void *ptr);
1620 void *unbound_stat_realloc(void *ptr, size_t size);
1621 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1622         const char* func);
1623 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1624         int line, const char* func);
1625 void unbound_stat_free_log(void *ptr, const char* file, int line,
1626         const char* func);
1627 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1628         int line, const char* func);
1629 #elif defined(UNBOUND_ALLOC_LITE)
1630 #  include "util/alloc.h"
1631 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1632
1633 /** default port for DNS traffic. */
1634 #define UNBOUND_DNS_PORT 53
1635 /** default port for unbound control traffic, registered port with IANA,
1636     ub-dns-control  8953/tcp    unbound dns nameserver control */
1637 #define UNBOUND_CONTROL_PORT 8953
1638 /** the version of unbound-control that this software implements */
1639 #define UNBOUND_CONTROL_VERSION 1
1640
1641 ])
1642
1643 dnl if we build from source tree, the man pages need @date@ and @version@
1644 dnl if this is a distro tarball, that was already done by makedist.sh
1645 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
1646 AC_SUBST(date, [`date +'%b %e, %Y'`])
1647
1648 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service])
1649 AC_CONFIG_HEADER([config.h])
1650 AC_OUTPUT