contrib/unbound/configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 AC_PREREQ(2.56)
   4 sinclude(acx_nlnetlabs.m4)
   5 sinclude(ax_pthread.m4)
   6 sinclude(acx_python.m4)
   7 sinclude(ac_pkg_swig.m4)
   8 sinclude(dnstap/dnstap.m4)
   9 sinclude(dnscrypt/dnscrypt.m4)
  10
  11 # must be numbers. ac_defun because of later processing
  12 m4_define([VERSION_MAJOR],[1])
  13 m4_define([VERSION_MINOR],[7])
  14 m4_define([VERSION_MICRO],[3])
  15 AC_INIT(unbound, m4_defn([VERSION_MAJOR]).m4_defn([VERSION_MINOR]).m4_defn([VERSION_MICRO]), unbound-bugs@nlnetlabs.nl, unbound)
  16 AC_SUBST(UNBOUND_VERSION_MAJOR, [VERSION_MAJOR])
  17 AC_SUBST(UNBOUND_VERSION_MINOR, [VERSION_MINOR])
  18 AC_SUBST(UNBOUND_VERSION_MICRO, [VERSION_MICRO])
  19
  20 LIBUNBOUND_CURRENT=7
  21 LIBUNBOUND_REVISION=11
  22 LIBUNBOUND_AGE=5
  23 # 1.0.0 had 0:12:0
  24 # 1.0.1 had 0:13:0
  25 # 1.0.2 had 0:14:0
  26 # 1.1.0 had 0:15:0
  27 # 1.1.1 had 0:16:0
  28 # 1.2.0 had 0:17:0
  29 # 1.2.1 had 0:18:0
  30 # 1.3.0 had 1:0:0   # ub_cancel and -export-symbols.
  31 # 1.3.1 had 1:1:0
  32 # 1.3.2 had 1:2:0
  33 # 1.3.3 had 1:3:0
  34 # 1.3.4 had 1:4:0
  35 # 1.4.0-snapshots had 1:5:0
  36 # 1.4.0 had 1:5:0 (not 2:0:0)   # ub_result.why_bogus
  37 # 1.4.1 had 2:1:0
  38 # 1.4.2 had 2:2:0
  39 # 1.4.3 had 2:3:0
  40 # 1.4.4 had 2:4:0
  41 # 1.4.5 had 2:5:0
  42 # 1.4.6 had 2:6:0
  43 # 1.4.7 had 2:7:0
  44 # 1.4.8 had 2:8:0
  45 # 1.4.9 had 2:9:0
  46 # 1.4.10 had 2:10:0
  47 # 1.4.11 had 2:11:0
  48 # 1.4.12 had 2:12:0
  49 # 1.4.13 had 2:13:0
  50 # and 1.4.13p1 and 1.4.13.p2
  51 # 1.4.14 had 2:14:0
  52 # 1.4.15 had 3:0:1 # adds ub_version()
  53 # 1.4.16 had 3:1:1
  54 # 1.4.17 had 3:2:1
  55 # 1.4.18 had 3:3:1
  56 # 1.4.19 had 3:4:1
  57 # 1.4.20 had 4:0:2 # adds libunbound.ttl # but shipped 3:5:1
  58 # 1.4.21 had 4:1:2
  59 # 1.4.22 had 4:1:2
  60 # 1.5.0 had 5:3:3 # adds ub_ctx_add_ta_autr
  61 # 1.5.1 had 5:3:3
  62 # 1.5.2 had 5:5:3
  63 # 1.5.3 had 5:6:3
  64 # 1.5.4 had 5:7:3
  65 # 1.5.5 had 5:8:3
  66 # 1.5.6 had 5:9:3
  67 # 1.5.7 had 5:10:3
  68 # 1.5.8 had 6:0:4 # adds ub_ctx_set_stub
  69 # 1.5.9 had 6:1:4
  70 # 1.5.10 had 6:2:4
  71 # 1.6.0 had 6:3:4
  72 # 1.6.1 had 7:0:5 # ub_callback_t typedef renamed to ub_callback_type
  73 # 1.6.2 had 7:1:5
  74 # 1.6.3 had 7:2:5
  75 # 1.6.4 had 7:3:5
  76 # 1.6.5 had 7:4:5
  77 # 1.6.6 had 7:5:5
  78 # 1.6.7 had 7:6:5
  79 # 1.6.8 had 7:7:5
  80 # 1.7.0 had 7:8:5
  81 # 1.7.1 had 7:9:5
  82 # 1.7.2 had 7:10:5
  83 # 1.7.3 had 7:11:5
  84
  85 #   Current  -- the number of the binary API that we're implementing
  86 #   Revision -- which iteration of the implementation of the binary
  87 #               API are we supplying?
  88 #   Age      -- How many previous binary API versions do we also
  89 #               support?
  90 #
  91 # If we release a new version that does not change the binary API,
  92 # increment Revision.
  93 #
  94 # If we release a new version that changes the binary API, but does
  95 # not break programs compiled against the old binary API, increment
  96 # Current and Age.  Set Revision to 0, since this is the first
  97 # implementation of the new API.
  98 #
  99 # Otherwise, we're changing the binary API and breaking backward
 100 # compatibility with old binaries.  Increment Current.  Set Age to 0,
 101 # since we're backward compatible with no previous APIs.  Set Revision
 102 # to 0 too.
 103 AC_SUBST(LIBUNBOUND_CURRENT)
 104 AC_SUBST(LIBUNBOUND_REVISION)
 105 AC_SUBST(LIBUNBOUND_AGE)
 106
 107 CFLAGS="$CFLAGS"
 108 AC_AIX
 109 if test "$ac_cv_header_minix_config_h" = "yes"; then
 110         AC_DEFINE(_NETBSD_SOURCE,1, [Enable for compile on Minix])
 111 fi
 112
 113 dnl
 114 dnl By default set prefix to /usr/local
 115 dnl
 116 case "$prefix" in
 117         NONE)
 118                 prefix="/usr/local"
 119         ;;
 120 esac
 121 case "$exec_prefix" in
 122         NONE)
 123                 exec_prefix="$prefix"
 124         ;;
 125 esac
 126
 127 # are we on MinGW?
 128 if uname -s 2>&1 | grep MINGW32 >/dev/null; then on_mingw="yes"
 129 else
 130         if echo $host $target | grep mingw32 >/dev/null; then on_mingw="yes"
 131         else on_mingw="no"; fi
 132 fi
 133
 134 #
 135 # Determine configuration file
 136 # the eval is to evaluate shell expansion twice
 137 UNBOUND_SBIN_DIR=`eval echo "${sbindir}"`
 138 AC_SUBST(UNBOUND_SBIN_DIR)
 139 UNBOUND_SYSCONF_DIR=`eval echo "${sysconfdir}"`
 140 AC_SUBST(UNBOUND_SYSCONF_DIR)
 141 UNBOUND_LOCALSTATE_DIR=`eval echo "${localstatedir}"`
 142 AC_SUBST(UNBOUND_LOCALSTATE_DIR)
 143 if test $on_mingw = "no"; then
 144   ub_conf_file=`eval echo "${sysconfdir}/unbound/unbound.conf"`
 145 else
 146   ub_conf_file="C:\\Program Files\\Unbound\\service.conf"
 147 fi
 148 AC_ARG_WITH([conf_file],
 149         AC_HELP_STRING([--with-conf-file=path],
 150         [Pathname to the Unbound configuration file]),
 151         [ub_conf_file="$withval"])
 152 AC_SUBST(ub_conf_file)
 153 ACX_ESCAPE_BACKSLASH($ub_conf_file, hdr_config)
 154 AC_DEFINE_UNQUOTED(CONFIGFILE, ["$hdr_config"], [Pathname to the Unbound configuration file])
 155 ub_conf_dir=`AS_DIRNAME(["$ub_conf_file"])`
 156 AC_SUBST(ub_conf_dir)
 157
 158 # Determine run, chroot directory and pidfile locations
 159 AC_ARG_WITH(run-dir,
 160     AC_HELP_STRING([--with-run-dir=path],
 161     [set default directory to chdir to (by default dir part of cfg file)]),
 162     UNBOUND_RUN_DIR="$withval",
 163 if test $on_mingw = no; then
 164     UNBOUND_RUN_DIR=`dirname "$ub_conf_file"`
 165 else
 166     UNBOUND_RUN_DIR=""
 167 fi
 168 )
 169 AC_SUBST(UNBOUND_RUN_DIR)
 170 ACX_ESCAPE_BACKSLASH($UNBOUND_RUN_DIR, hdr_run)
 171 AC_DEFINE_UNQUOTED(RUN_DIR, ["$hdr_run"], [Directory to chdir to])
 172
 173 AC_ARG_WITH(chroot-dir,
 174     AC_HELP_STRING([--with-chroot-dir=path],
 175     [set default directory to chroot to (by default same as run-dir)]),
 176     UNBOUND_CHROOT_DIR="$withval",
 177 if test $on_mingw = no; then
 178     UNBOUND_CHROOT_DIR="$UNBOUND_RUN_DIR"
 179 else
 180     UNBOUND_CHROOT_DIR=""
 181 fi
 182 )
 183 AC_SUBST(UNBOUND_CHROOT_DIR)
 184 ACX_ESCAPE_BACKSLASH($UNBOUND_CHROOT_DIR, hdr_chroot)
 185 AC_DEFINE_UNQUOTED(CHROOT_DIR, ["$hdr_chroot"], [Directory to chroot to])
 186
 187 AC_ARG_WITH(share-dir,
 188     AC_HELP_STRING([--with-share-dir=path],
 189     [set default directory with shared data (by default same as share/unbound)]),
 190     UNBOUND_SHARE_DIR="$withval",
 191     UNBOUND_SHARE_DIR="$UNBOUND_RUN_DIR")
 192 AC_SUBST(UNBOUND_SHARE_DIR)
 193 AC_DEFINE_UNQUOTED(SHARE_DIR, ["$UNBOUND_SHARE_DIR"], [Shared data])
 194
 195 AC_ARG_WITH(pidfile,
 196     AC_HELP_STRING([--with-pidfile=filename],
 197     [set default pathname to unbound pidfile (default run-dir/unbound.pid)]),
 198     UNBOUND_PIDFILE="$withval",
 199 if test $on_mingw = no; then
 200     UNBOUND_PIDFILE="$UNBOUND_RUN_DIR/unbound.pid"
 201 else
 202     UNBOUND_PIDFILE=""
 203 fi
 204 )
 205 AC_SUBST(UNBOUND_PIDFILE)
 206 ACX_ESCAPE_BACKSLASH($UNBOUND_PIDFILE, hdr_pid)
 207 AC_DEFINE_UNQUOTED(PIDFILE, ["$hdr_pid"], [default pidfile location])
 208
 209 AC_ARG_WITH(rootkey-file,
 210     AC_HELP_STRING([--with-rootkey-file=filename],
 211     [set default pathname to root key file (default run-dir/root.key). This file is read and written.]),
 212     UNBOUND_ROOTKEY_FILE="$withval",
 213 if test $on_mingw = no; then
 214     UNBOUND_ROOTKEY_FILE="$UNBOUND_RUN_DIR/root.key"
 215 else
 216     UNBOUND_ROOTKEY_FILE="C:\\Program Files\\Unbound\\root.key"
 217 fi
 218 )
 219 AC_SUBST(UNBOUND_ROOTKEY_FILE)
 220 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTKEY_FILE, hdr_rkey)
 221 AC_DEFINE_UNQUOTED(ROOT_ANCHOR_FILE, ["$hdr_rkey"], [default rootkey location])
 222
 223 AC_ARG_WITH(rootcert-file,
 224     AC_HELP_STRING([--with-rootcert-file=filename],
 225     [set default pathname to root update certificate file (default run-dir/icannbundle.pem).  This file need not exist if you are content with the builtin.]),
 226     UNBOUND_ROOTCERT_FILE="$withval",
 227 if test $on_mingw = no; then
 228     UNBOUND_ROOTCERT_FILE="$UNBOUND_RUN_DIR/icannbundle.pem"
 229 else
 230     UNBOUND_ROOTCERT_FILE="C:\\Program Files\\Unbound\\icannbundle.pem"
 231 fi
 232 )
 233 AC_SUBST(UNBOUND_ROOTCERT_FILE)
 234 ACX_ESCAPE_BACKSLASH($UNBOUND_ROOTCERT_FILE, hdr_rpem)
 235 AC_DEFINE_UNQUOTED(ROOT_CERT_FILE, ["$hdr_rpem"], [default rootcert location])
 236
 237 AC_ARG_WITH(username,
 238     AC_HELP_STRING([--with-username=user],
 239     [set default user that unbound changes to (default user is unbound)]),
 240     UNBOUND_USERNAME="$withval",
 241     UNBOUND_USERNAME="unbound")
 242 AC_SUBST(UNBOUND_USERNAME)
 243 AC_DEFINE_UNQUOTED(UB_USERNAME, ["$UNBOUND_USERNAME"], [default username])
 244
 245 AC_DEFINE(WINVER, 0x0502, [the version of the windows API enabled])
 246 ACX_RSRC_VERSION(wnvs)
 247 AC_DEFINE_UNQUOTED(RSRC_PACKAGE_VERSION, [$wnvs], [version number for resource files])
 248
 249 # Checks for typedefs, structures, and compiler characteristics.
 250 AC_C_CONST
 251 AC_LANG_C
 252 # allow user to override the -g -O2 flags.
 253 default_cflags=no
 254 if test "x$CFLAGS" = "x" ; then
 255 ACX_CHECK_COMPILER_FLAG(g, [CFLAGS="$CFLAGS -g"])
 256 ACX_CHECK_COMPILER_FLAG(O2, [CFLAGS="$CFLAGS -O2"])
 257 default_cflags=yes
 258 fi
 259 AC_PROG_CC
 260 ACX_DEPFLAG
 261 ACX_DETERMINE_EXT_FLAGS_UNBOUND
 262
 263 # debug mode flags warnings
 264 AC_ARG_ENABLE(checking, AC_HELP_STRING([--enable-checking], [Enable warnings, asserts, makefile-dependencies]))
 265 AC_ARG_ENABLE(debug, AC_HELP_STRING([--enable-debug], [same as enable-checking]))
 266 if test "$enable_debug" = "yes"; then debug_enabled="$enable_debug";
 267 else debug_enabled="$enable_checking"; fi
 268 AC_SUBST(debug_enabled)
 269 case "$debug_enabled" in
 270         yes)
 271                 ACX_CHECK_COMPILER_FLAG(W, [CFLAGS="$CFLAGS -W"])
 272                 ACX_CHECK_COMPILER_FLAG(Wall, [CFLAGS="$CFLAGS -Wall"])
 273                 ACX_CHECK_COMPILER_FLAG(Wextra, [CFLAGS="$CFLAGS -Wextra"])
 274                 ACX_CHECK_COMPILER_FLAG(Wdeclaration-after-statement, [CFLAGS="$CFLAGS -Wdeclaration-after-statement"])
 275                 AC_DEFINE([UNBOUND_DEBUG], [], [define this to enable debug checks.])
 276                 ;;
 277         no|*)
 278                 # nothing to do.
 279                 ;;
 280 esac
 281 if test "$default_cflags" = "yes"; then
 282         # only when CFLAGS was "" at the start, if the users wants to
 283         # override we shouldn't add default cflags, because they wouldn't
 284         # be able to turn off these options and set the CFLAGS wanted.
 285         ACX_CHECK_FLTO
 286         ACX_CHECK_PIE
 287         ACX_CHECK_RELRO_NOW
 288 fi
 289
 290 AC_C_INLINE
 291 ACX_CHECK_FORMAT_ATTRIBUTE
 292 ACX_CHECK_UNUSED_ATTRIBUTE
 293
 294 AC_DEFUN([CHECK_WEAK_ATTRIBUTE],
 295 [AC_REQUIRE([AC_PROG_CC])
 296 AC_MSG_CHECKING(whether the C compiler (${CC-cc}) accepts the "weak" attribute)
 297 AC_CACHE_VAL(ac_cv_c_weak_attribute,
 298 [ac_cv_c_weak_attribute=no
 299 AC_TRY_COMPILE(
 300 [ #include <stdio.h>
 301 __attribute__((weak)) void f(int x) { printf("%d", x); }
 302 ], [
 303    f(1);
 304 ],
 305 [ac_cv_c_weak_attribute="yes"],
 306 [ac_cv_c_weak_attribute="no"])
 307 ])
 308
 309 AC_MSG_RESULT($ac_cv_c_weak_attribute)
 310 if test $ac_cv_c_weak_attribute = yes; then
 311   AC_DEFINE(HAVE_ATTR_WEAK, 1, [Whether the C compiler accepts the "weak" attribute])
 312 fi
 313 ])dnl End of CHECK_WEAK_ATTRIBUTE
 314
 315 CHECK_WEAK_ATTRIBUTE
 316
 317 if test "$srcdir" != "."; then
 318         CPPFLAGS="$CPPFLAGS -I$srcdir"
 319 fi
 320
 321 AC_DEFUN([ACX_YYLEX_DESTROY], [
 322         AC_MSG_CHECKING([for yylex_destroy])
 323         if echo %% | $LEX -t 2>&1 | grep yylex_destroy >/dev/null 2>&1; then
 324                 AC_DEFINE(LEX_HAS_YYLEX_DESTROY, 1, [if lex has yylex_destroy])
 325                 AC_MSG_RESULT(yes)
 326         else AC_MSG_RESULT(no); fi
 327 ])
 328
 329 AC_PROG_LEX
 330 ACX_YYLEX_DESTROY
 331 AC_PROG_YACC
 332 AC_CHECK_PROG(doxygen, doxygen, doxygen)
 333 AC_CHECK_TOOL(STRIP, strip)
 334 ACX_LIBTOOL_C_ONLY
 335
 336 # Checks for header files.
 337 AC_CHECK_HEADERS([stdarg.h stdbool.h netinet/in.h netinet/tcp.h sys/param.h sys/socket.h sys/un.h sys/uio.h sys/resource.h arpa/inet.h syslog.h netdb.h sys/wait.h pwd.h glob.h grp.h login_cap.h winsock2.h ws2tcpip.h endian.h sys/endian.h libkern/OSByteOrder.h sys/ipc.h sys/shm.h],,, [AC_INCLUDES_DEFAULT])
 338
 339 # check for types.
 340 # Using own tests for int64* because autoconf builtin only give 32bit.
 341 AC_CHECK_TYPE(int8_t, signed char)
 342 AC_CHECK_TYPE(int16_t, short)
 343 AC_CHECK_TYPE(int32_t, int)
 344 AC_CHECK_TYPE(int64_t, long long)
 345 AC_CHECK_TYPE(uint8_t, unsigned char)
 346 AC_CHECK_TYPE(uint16_t, unsigned short)
 347 AC_CHECK_TYPE(uint32_t, unsigned int)
 348 AC_CHECK_TYPE(uint64_t, unsigned long long)
 349 AC_TYPE_SIZE_T
 350 AC_CHECK_TYPE(ssize_t, int)
 351 AC_TYPE_UID_T
 352 AC_TYPE_PID_T
 353 AC_TYPE_OFF_T
 354 ACX_TYPE_U_CHAR
 355 ACX_TYPE_RLIM_T
 356 ACX_TYPE_SOCKLEN_T
 357 ACX_TYPE_IN_ADDR_T
 358 ACX_TYPE_IN_PORT_T
 359 ACX_CHECK_MEMCMP_SIGNED
 360
 361 AC_CHECK_SIZEOF(time_t,,[
 362 AC_INCLUDES_DEFAULT
 363 #ifdef TIME_WITH_SYS_TIME
 364 # include <sys/time.h>
 365 # include <time.h>
 366 #else
 367 # ifdef HAVE_SYS_TIME_H
 368 #  include <sys/time.h>
 369 # else
 370 #  include <time.h>
 371 # endif
 372 #endif
 373 ])
 374
 375 # add option to disable the evil rpath
 376 ACX_ARG_RPATH
 377 AC_SUBST(RUNTIME_PATH)
 378
 379 # check to see if libraries are needed for these functions.
 380 AC_SEARCH_LIBS([inet_pton], [nsl])
 381 AC_SEARCH_LIBS([socket], [socket])
 382
 383 # check wether strptime also works
 384 AC_DEFUN([AC_CHECK_STRPTIME_WORKS],
 385 [AC_REQUIRE([AC_PROG_CC])
 386 AC_MSG_CHECKING(whether strptime works)
 387 if test c${cross_compiling} = cno; then
 388 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 389 #define _XOPEN_SOURCE 600
 390 #include <time.h>
 391 int main(void) { struct tm tm; char *res;
 392 res = strptime("2010-07-15T00:00:00+00:00", "%t%Y%t-%t%m%t-%t%d%tT%t%H%t:%t%M%t:%t%S%t", &tm);
 393 if (!res) return 2;
 394 res = strptime("20070207111842", "%Y%m%d%H%M%S", &tm);
 395 if (!res) return 1; return 0; }
 396 ]])] , [eval "ac_cv_c_strptime_works=yes"], [eval "ac_cv_c_strptime_works=no"])
 397 else
 398 eval "ac_cv_c_strptime_works=maybe"
 399 fi
 400 AC_MSG_RESULT($ac_cv_c_strptime_works)
 401 if test $ac_cv_c_strptime_works = no; then
 402 AC_LIBOBJ(strptime)
 403 else
 404 AC_DEFINE_UNQUOTED([STRPTIME_WORKS], 1, [use default strptime.])
 405 fi
 406 ])dnl
 407
 408 # check some functions of the OS before linking libs (while still runnable).
 409 AC_FUNC_CHOWN
 410 AC_FUNC_FORK
 411 AC_TYPE_SIGNAL
 412 AC_FUNC_FSEEKO
 413 ACX_SYS_LARGEFILE
 414 ACX_CHECK_NONBLOCKING_BROKEN
 415 ACX_MKDIR_ONE_ARG
 416 AC_CHECK_FUNCS([strptime],[AC_CHECK_STRPTIME_WORKS],[AC_LIBOBJ([strptime])])
 417
 418 # set memory allocation checking if requested
 419 AC_ARG_ENABLE(alloc-checks, AC_HELP_STRING([--enable-alloc-checks],
 420         [ enable to memory allocation statistics, for debug purposes ]),
 421         , )
 422 AC_ARG_ENABLE(alloc-lite, AC_HELP_STRING([--enable-alloc-lite],
 423         [ enable for lightweight alloc assertions, for debug purposes ]),
 424         , )
 425 AC_ARG_ENABLE(alloc-nonregional, AC_HELP_STRING([--enable-alloc-nonregional],
 426         [ enable nonregional allocs, slow but exposes regional allocations to other memory purifiers, for debug purposes ]),
 427         , )
 428 if test x_$enable_alloc_nonregional = x_yes; then
 429         AC_DEFINE(UNBOUND_ALLOC_NONREGIONAL, 1, [use malloc not regions, for debug use])
 430 fi
 431 if test x_$enable_alloc_checks = x_yes; then
 432         AC_DEFINE(UNBOUND_ALLOC_STATS, 1, [use statistics for allocs and frees, for debug use])
 433 else
 434         if test x_$enable_alloc_lite = x_yes; then
 435                 AC_DEFINE(UNBOUND_ALLOC_LITE, 1, [use to enable lightweight alloc assertions, for debug use])
 436         else
 437                 ACX_FUNC_MALLOC([unbound])
 438         fi
 439 fi
 440
 441 # check windows threads (we use them, not pthreads, on windows).
 442 if test "$on_mingw" = "yes"; then
 443 # check windows threads
 444         AC_CHECK_HEADERS([windows.h],,, [AC_INCLUDES_DEFAULT])
 445         AC_MSG_CHECKING([for CreateThread])
 446         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
 447 #ifdef HAVE_WINDOWS_H
 448 #include <windows.h>
 449 #endif
 450 ], [
 451         HANDLE t = CreateThread(NULL, 0, NULL, NULL, 0, NULL);
 452 ])],
 453         AC_MSG_RESULT(yes)
 454         AC_DEFINE(HAVE_WINDOWS_THREADS, 1, [Using Windows threads])
 455 ,
 456         AC_MSG_RESULT(no)
 457 )
 458
 459 else
 460 # not on mingw, check thread libraries.
 461
 462 # check for thread library.
 463 # check this first, so that the pthread lib does not get linked in via
 464 # libssl or libpython, and thus distorts the tests, and we end up using
 465 # the non-threadsafe C libraries.
 466 AC_ARG_WITH(pthreads, AC_HELP_STRING([--with-pthreads],
 467  [use pthreads library, or --without-pthreads to disable threading support.]),
 468  [ ],[ withval="yes" ])
 469 ub_have_pthreads=no
 470 if test x_$withval != x_no; then
 471         AX_PTHREAD([
 472                 AC_DEFINE(HAVE_PTHREAD,1,[Define if you have POSIX threads libraries and header files.])
 473                 if test -n "$PTHREAD_LIBS"; then
 474                   LIBS="$PTHREAD_LIBS $LIBS"
 475                 fi
 476                 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 477                 CC="$PTHREAD_CC"
 478                 ub_have_pthreads=yes
 479                 AC_CHECK_TYPES([pthread_spinlock_t, pthread_rwlock_t],,,[#include <pthread.h>])
 480
 481                 if echo "$CFLAGS" | $GREP -e "-pthread" >/dev/null; then
 482                 AC_MSG_CHECKING([if -pthread unused during linking])
 483                 # catch clang warning 'argument unused during compilation'
 484                 AC_LANG_CONFTEST([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
 485 [[
 486 int main(void) {return 0;}
 487 ]])])
 488                 pthread_unused="yes"
 489                 # first compile
 490                 echo "$CC $CFLAGS -c conftest.c -o conftest.o" >&AS_MESSAGE_LOG_FD
 491                 $CC $CFLAGS -c conftest.c -o conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 492                 if test $? = 0; then
 493                         # then link
 494                         echo "$CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest contest.o" >&AS_MESSAGE_LOG_FD
 495                         $CC $CFLAGS -Werror $LDFLAGS $LIBS -o conftest conftest.o 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
 496                         if test $? -ne 0; then
 497                                 AC_MSG_RESULT(yes)
 498                                 CFLAGS=`echo "$CFLAGS" | sed -e 's/-pthread//'`
 499                                 PTHREAD_CFLAGS_ONLY="-pthread"
 500                                 AC_SUBST(PTHREAD_CFLAGS_ONLY)
 501                         else
 502                                 AC_MSG_RESULT(no)
 503                         fi
 504                 else
 505                         AC_MSG_RESULT(no)
 506                 fi # endif cc successful
 507                 rm -f conftest conftest.c conftest.o
 508                 fi # endif -pthread in CFLAGS
 509
 510                 ])
 511 fi
 512
 513 # check solaris thread library
 514 AC_ARG_WITH(solaris-threads, AC_HELP_STRING([--with-solaris-threads],
 515         [use solaris native thread library.]), [ ],[ withval="no" ])
 516 ub_have_sol_threads=no
 517 if test x_$withval != x_no; then
 518         if test x_$ub_have_pthreads != x_no; then
 519             AC_WARN([Have pthreads already, ignoring --with-solaris-threads])
 520         else
 521         AC_SEARCH_LIBS(thr_create, [thread],
 522         [
 523                 AC_DEFINE(HAVE_SOLARIS_THREADS, 1, [Using Solaris threads])
 524
 525                 ACX_CHECK_COMPILER_FLAG(mt, [CFLAGS="$CFLAGS -mt"],
 526                         [CFLAGS="$CFLAGS -D_REENTRANT"])
 527                 ub_have_sol_threads=yes
 528         ] , [
 529                 AC_ERROR([no solaris threads found.])
 530         ])
 531         fi
 532 fi
 533
 534 fi # end of non-mingw check of thread libraries
 535
 536 # Check for PyUnbound
 537 AC_ARG_WITH(pyunbound,
 538    AC_HELP_STRING([--with-pyunbound],
 539    [build PyUnbound, or --without-pyunbound to skip it. (default=no)]),
 540    [], [ withval="no" ])
 541
 542 ub_test_python=no
 543 ub_with_pyunbound=no
 544 if test x_$withval != x_no; then
 545    ub_with_pyunbound=yes
 546    ub_test_python=yes
 547 fi
 548
 549 # Check for Python module
 550 AC_ARG_WITH(pythonmodule,
 551    AC_HELP_STRING([--with-pythonmodule],
 552    [build Python module, or --without-pythonmodule to disable script engine. (default=no)]),
 553    [], [ withval="no" ])
 554
 555 ub_with_pythonmod=no
 556 if test x_$withval != x_no; then
 557    ub_with_pythonmod=yes
 558    ub_test_python=yes
 559 fi
 560
 561 # Check for Python & SWIG only on PyUnbound or PyModule
 562 if test x_$ub_test_python != x_no; then
 563
 564    # Check for Python
 565    ub_have_python=no
 566    ac_save_LIBS="$LIBS" dnl otherwise AC_PYTHON_DEVEL thrashes $LIBS
 567    AC_PYTHON_DEVEL
 568    if test ! -z "$PYTHON_VERSION"; then
 569         if test `$PYTHON -c "print('$PYTHON_VERSION' >= '2.4.0')"` = "False"; then
 570                 AC_ERROR([Python version >= 2.4.0 is required])
 571         fi
 572
 573       [PY_MAJOR_VERSION="`$PYTHON -c \"import sys; print(sys.version_info[0])\"`"]
 574       AC_SUBST(PY_MAJOR_VERSION)
 575       # Have Python
 576       AC_DEFINE(HAVE_PYTHON,1,[Define if you have Python libraries and header files.])
 577       if test -n "$LIBS"; then
 578         LIBS="$PYTHON_LDFLAGS $LIBS"
 579       else
 580         LIBS="$PYTHON_LDFLAGS"
 581       fi
 582       if test -n "$CPPFLAGS"; then
 583         CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
 584       else
 585         CPPFLAGS="$PYTHON_CPPFLAGS"
 586       fi
 587       ub_have_python=yes
 588       PC_PY_DEPENDENCY="python"
 589       AC_SUBST(PC_PY_DEPENDENCY)
 590
 591       # Check for SWIG
 592       ub_have_swig=no
 593       AC_ARG_ENABLE(swig-version-check, AC_HELP_STRING([--disable-swig-version-check], [Disable swig version check to build python modules with older swig even though that is unreliable]))
 594       if test "$enable_swig_version_check" = "yes"; then
 595         AC_PROG_SWIG(2.0.1)
 596       else
 597         AC_PROG_SWIG
 598       fi
 599       AC_MSG_CHECKING(SWIG)
 600       if test ! -x "$SWIG"; then
 601          AC_ERROR([failed to find swig tool, install it, or do not build Python module and PyUnbound])
 602       else
 603          AC_DEFINE(HAVE_SWIG, 1, [Define if you have Swig libraries and header files.])
 604          AC_SUBST(swig, "$SWIG")
 605          AC_MSG_RESULT(present)
 606
 607          # If have Python & SWIG
 608          # Declare PythonMod
 609          if test x_$ub_with_pythonmod != x_no; then
 610             AC_DEFINE(WITH_PYTHONMODULE, 1, [Define if you want Python module.])
 611             WITH_PYTHONMODULE=yes
 612             AC_SUBST(WITH_PYTHONMODULE)
 613             PYTHONMOD_OBJ="pythonmod.lo pythonmod_utils.lo"
 614             AC_SUBST(PYTHONMOD_OBJ)
 615             PYTHONMOD_HEADER='$(srcdir)/pythonmod/pythonmod.h'
 616             AC_SUBST(PYTHONMOD_HEADER)
 617             PYTHONMOD_INSTALL=pythonmod-install
 618             AC_SUBST(PYTHONMOD_INSTALL)
 619             PYTHONMOD_UNINSTALL=pythonmod-uninstall
 620             AC_SUBST(PYTHONMOD_UNINSTALL)
 621          fi
 622
 623          # Declare PyUnbound
 624          if test x_$ub_with_pyunbound != x_no; then
 625             AC_DEFINE(WITH_PYUNBOUND, 1, [Define if you want PyUnbound.])
 626             WITH_PYUNBOUND=yes
 627             AC_SUBST(WITH_PYUNBOUND)
 628             PYUNBOUND_OBJ="libunbound_wrap.lo"
 629             AC_SUBST(PYUNBOUND_OBJ)
 630             PYUNBOUND_TARGET="_unbound.la"
 631             AC_SUBST(PYUNBOUND_TARGET)
 632             PYUNBOUND_INSTALL=pyunbound-install
 633             AC_SUBST(PYUNBOUND_INSTALL)
 634             PYUNBOUND_UNINSTALL=pyunbound-uninstall
 635             AC_SUBST(PYUNBOUND_UNINSTALL)
 636          fi
 637       fi
 638    else
 639       AC_MSG_RESULT([*** Python libraries not found, won't build PythonMod or PyUnbound ***])
 640       ub_with_pyunbound=no
 641       ub_with_pythonmod=no
 642    fi
 643 fi
 644
 645 if test "`uname`" = "NetBSD"; then
 646         NETBSD_LINTFLAGS='"-D__RENAME(x)=" -D_NETINET_IN_H_'
 647         AC_SUBST(NETBSD_LINTFLAGS)
 648 fi
 649 CONFIG_DATE=`date +%Y%m%d`
 650 AC_SUBST(CONFIG_DATE)
 651
 652 # Checks for libraries.
 653
 654 # libnss
 655 USE_NSS="no"
 656 AC_ARG_WITH([nss], AC_HELP_STRING([--with-nss=path],
 657         [use libnss instead of openssl, installed at path.]),
 658         [
 659         USE_NSS="yes"
 660         AC_DEFINE(HAVE_NSS, 1, [Use libnss for crypto])
 661         if test "$withval" != "" -a "$withval" != "yes"; then
 662                 CPPFLAGS="$CPPFLAGS -I$withval/include/nss3"
 663                 LDFLAGS="$LDFLAGS -L$withval/lib"
 664                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 665                 CPPFLAGS="-I$withval/include/nspr4 $CPPFLAGS"
 666         else
 667                 CPPFLAGS="$CPPFLAGS -I/usr/include/nss3"
 668                 CPPFLAGS="-I/usr/include/nspr4 $CPPFLAGS"
 669         fi
 670         LIBS="$LIBS -lnss3 -lnspr4"
 671         SSLLIB=""
 672         ]
 673 )
 674
 675 # libnettle
 676 USE_NETTLE="no"
 677 AC_ARG_WITH([nettle], AC_HELP_STRING([--with-nettle=path],
 678         [use libnettle as crypto library, installed at path.]),
 679         [
 680         USE_NETTLE="yes"
 681         AC_DEFINE(HAVE_NETTLE, 1, [Use libnettle for crypto])
 682         AC_CHECK_HEADERS([nettle/dsa-compat.h],,, [AC_INCLUDES_DEFAULT])
 683         if test "$withval" != "" -a "$withval" != "yes"; then
 684                 CPPFLAGS="$CPPFLAGS -I$withval/include/nettle"
 685                 LDFLAGS="$LDFLAGS -L$withval/lib"
 686                 ACX_RUNTIME_PATH_ADD([$withval/lib])
 687         else
 688                 CPPFLAGS="$CPPFLAGS -I/usr/include/nettle"
 689         fi
 690         LIBS="$LIBS -lhogweed -lnettle -lgmp"
 691         SSLLIB=""
 692         ]
 693 )
 694
 695 # openssl
 696 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 697 ACX_WITH_SSL
 698 ACX_LIB_SSL
 699 SSLLIB="-lssl"
 700
 701 # check if -lcrypt32 is needed because CAPIENG needs that. (on windows)
 702 BAKLIBS="$LIBS"
 703 LIBS="-lssl $LIBS"
 704 AC_MSG_CHECKING([if libssl needs -lcrypt32])
 705 AC_TRY_LINK_FUNC([HMAC_Update], [
 706         AC_MSG_RESULT([no])
 707         LIBS="$BAKLIBS"
 708 ], [
 709         AC_MSG_RESULT([yes])
 710         LIBS="$BAKLIBS"
 711         LIBS="$LIBS -lcrypt32"
 712 ])
 713
 714 AC_MSG_CHECKING([for LibreSSL])
 715 if grep VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "LibreSSL" >/dev/null; then
 716         AC_MSG_RESULT([yes])
 717         AC_DEFINE([HAVE_LIBRESSL], [1], [Define if we have LibreSSL])
 718         # libressl provides these compat functions, but they may also be
 719         # declared by the OS in libc.  See if they have been declared.
 720         AC_CHECK_DECLS([strlcpy,strlcat,arc4random,arc4random_uniform,reallocarray])
 721 else
 722         AC_MSG_RESULT([no])
 723 fi
 724 AC_CHECK_HEADERS([openssl/conf.h openssl/engine.h openssl/bn.h openssl/dh.h openssl/dsa.h openssl/rsa.h],,, [AC_INCLUDES_DEFAULT])
 725 AC_CHECK_FUNCS([OPENSSL_config EVP_sha1 EVP_sha256 EVP_sha512 FIPS_mode EVP_MD_CTX_new OpenSSL_add_all_digests OPENSSL_init_crypto EVP_cleanup ERR_load_crypto_strings CRYPTO_cleanup_all_ex_data ERR_free_strings RAND_cleanup DSA_SIG_set0 EVP_dss1 EVP_DigestVerify])
 726
 727 # these check_funcs need -lssl
 728 BAKLIBS="$LIBS"
 729 LIBS="-lssl $LIBS"
 730 AC_CHECK_FUNCS([OPENSSL_init_ssl SSL_CTX_set_security_level SSL_set1_host SSL_get0_peername])
 731 LIBS="$BAKLIBS"
 732
 733 AC_CHECK_DECLS([SSL_COMP_get_compression_methods,sk_SSL_COMP_pop_free,SSL_CTX_set_ecdh_auto], [], [], [
 734 AC_INCLUDES_DEFAULT
 735 #ifdef HAVE_OPENSSL_ERR_H
 736 #include <openssl/err.h>
 737 #endif
 738
 739 #ifdef HAVE_OPENSSL_RAND_H
 740 #include <openssl/rand.h>
 741 #endif
 742
 743 #ifdef HAVE_OPENSSL_CONF_H
 744 #include <openssl/conf.h>
 745 #endif
 746
 747 #ifdef HAVE_OPENSSL_ENGINE_H
 748 #include <openssl/engine.h>
 749 #endif
 750 #include <openssl/ssl.h>
 751 #include <openssl/evp.h>
 752 ])
 753 fi
 754 AC_SUBST(SSLLIB)
 755
 756
 757 AC_ARG_ENABLE(sha1, AC_HELP_STRING([--disable-sha1], [Disable SHA1 RRSIG support, does not disable nsec3 support]))
 758 case "$enable_sha1" in
 759         no)
 760         ;;
 761         yes|*)
 762         AC_DEFINE([USE_SHA1], [1], [Define this to enable SHA1 support.])
 763         ;;
 764 esac
 765
 766
 767 AC_ARG_ENABLE(sha2, AC_HELP_STRING([--disable-sha2], [Disable SHA256 and SHA512 RRSIG support]))
 768 case "$enable_sha2" in
 769         no)
 770         ;;
 771         yes|*)
 772         AC_DEFINE([USE_SHA2], [1], [Define this to enable SHA256 and SHA512 support.])
 773         ;;
 774 esac
 775
 776 AC_ARG_ENABLE(subnet, AC_HELP_STRING([--enable-subnet], [Enable client subnet]))
 777 case "$enable_subnet" in
 778         yes)
 779         AC_DEFINE([CLIENT_SUBNET], [1], [Define this to enable client subnet option.])
 780         SUBNET_OBJ="edns-subnet.lo subnetmod.lo addrtree.lo subnet-whitelist.lo"
 781         AC_SUBST(SUBNET_OBJ)
 782         SUBNET_HEADER='$(srcdir)/edns-subnet/subnetmod.h $(srcdir)/edns-subnet/edns-subnet.h $(srcdir)/edns-subnet/subnet-whitelist.h $(srcdir)/edns-subnet/addrtree.h'
 783         AC_SUBST(SUBNET_HEADER)
 784         ;;
 785         no|*)
 786         ;;
 787 esac
 788
 789 # check wether gost also works
 790 AC_DEFUN([AC_CHECK_GOST_WORKS],
 791 [AC_REQUIRE([AC_PROG_CC])
 792 AC_MSG_CHECKING([if GOST works])
 793 if test c${cross_compiling} = cno; then
 794 BAKCFLAGS="$CFLAGS"
 795 if test -n "$ssldir"; then
 796         CFLAGS="$CFLAGS -Wl,-rpath,$ssldir/lib"
 797 fi
 798 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 799 #include <string.h>
 800 #include <openssl/ssl.h>
 801 #include <openssl/evp.h>
 802 #include <openssl/engine.h>
 803 #include <openssl/conf.h>
 804 /* routine to load gost (from sldns) */
 805 int load_gost_id(void)
 806 {
 807         static int gost_id = 0;
 808         const EVP_PKEY_ASN1_METHOD* meth;
 809         ENGINE* e;
 810
 811         if(gost_id) return gost_id;
 812
 813         /* see if configuration loaded gost implementation from other engine*/
 814         meth = EVP_PKEY_asn1_find_str(NULL, "gost2001", -1);
 815         if(meth) {
 816                 EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 817                 return gost_id;
 818         }
 819
 820         /* see if engine can be loaded already */
 821         e = ENGINE_by_id("gost");
 822         if(!e) {
 823                 /* load it ourself, in case statically linked */
 824                 ENGINE_load_builtin_engines();
 825                 ENGINE_load_dynamic();
 826                 e = ENGINE_by_id("gost");
 827         }
 828         if(!e) {
 829                 /* no gost engine in openssl */
 830                 return 0;
 831         }
 832         if(!ENGINE_set_default(e, ENGINE_METHOD_ALL)) {
 833                 ENGINE_finish(e);
 834                 ENGINE_free(e);
 835                 return 0;
 836         }
 837
 838         meth = EVP_PKEY_asn1_find_str(&e, "gost2001", -1);
 839         if(!meth) {
 840                 /* algo not found */
 841                 ENGINE_finish(e);
 842                 ENGINE_free(e);
 843                 return 0;
 844         }
 845         EVP_PKEY_asn1_get0_info(&gost_id, NULL, NULL, NULL, NULL, meth);
 846         return gost_id;
 847 }
 848 int main(void) {
 849         EVP_MD_CTX* ctx;
 850         const EVP_MD* md;
 851         unsigned char digest[64]; /* its a 256-bit digest, so uses 32 bytes */
 852         const char* str = "Hello world";
 853         const unsigned char check[] = {
 854                 0x40 , 0xed , 0xf8 , 0x56 , 0x5a , 0xc5 , 0x36 , 0xe1 ,
 855                 0x33 , 0x7c , 0x7e , 0x87 , 0x62 , 0x1c , 0x42 , 0xe0 ,
 856                 0x17 , 0x1b , 0x5e , 0xce , 0xa8 , 0x46 , 0x65 , 0x4d ,
 857                 0x8d , 0x3e , 0x22 , 0x9b , 0xe1 , 0x30 , 0x19 , 0x9d
 858         };
 859         OPENSSL_config(NULL);
 860         (void)load_gost_id();
 861         md = EVP_get_digestbyname("md_gost94");
 862         if(!md) return 1;
 863         memset(digest, 0, sizeof(digest));
 864         ctx = EVP_MD_CTX_create();
 865         if(!ctx) return 2;
 866         if(!EVP_DigestInit_ex(ctx, md, NULL)) return 3;
 867         if(!EVP_DigestUpdate(ctx, str, 10)) return 4;
 868         if(!EVP_DigestFinal_ex(ctx, digest, NULL)) return 5;
 869         /* uncomment to see the hash calculated.
 870                 {int i;
 871                 for(i=0; i<32; i++)
 872                         printf(" %2.2x", (int)digest[i]);
 873                 printf("\n");}
 874         */
 875         if(memcmp(digest, check, sizeof(check)) != 0)
 876                 return 6;
 877         return 0;
 878 }
 879 ]])] , [eval "ac_cv_c_gost_works=yes"], [eval "ac_cv_c_gost_works=no"])
 880 CFLAGS="$BAKCFLAGS"
 881 else
 882 eval "ac_cv_c_gost_works=maybe"
 883 fi
 884 AC_MSG_RESULT($ac_cv_c_gost_works)
 885 ])dnl
 886
 887 AC_ARG_ENABLE(gost, AC_HELP_STRING([--disable-gost], [Disable GOST support]))
 888 use_gost="no"
 889 if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 890 case "$enable_gost" in
 891         no)
 892         ;;
 893         *)
 894         AC_CHECK_FUNC(EVP_PKEY_set_type_str, [:],[AC_MSG_ERROR([OpenSSL 1.0.0 is needed for GOST support])])
 895         AC_CHECK_FUNC(EC_KEY_new, [], [AC_MSG_ERROR([OpenSSL does not support ECC, needed for GOST support])])
 896         AC_CHECK_GOST_WORKS
 897         if test "$ac_cv_c_gost_works" != no; then
 898                 use_gost="yes"
 899                 AC_DEFINE([USE_GOST], [1], [Define this to enable GOST support.])
 900         fi
 901         ;;
 902 esac
 903 fi dnl !USE_NSS && !USE_NETTLE
 904
 905 AC_ARG_ENABLE(ecdsa, AC_HELP_STRING([--disable-ecdsa], [Disable ECDSA support]))
 906 use_ecdsa="no"
 907 case "$enable_ecdsa" in
 908     no)
 909       ;;
 910     *)
 911       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 912               AC_CHECK_FUNC(ECDSA_sign, [], [AC_MSG_ERROR([OpenSSL does not support ECDSA: please upgrade or rerun with --disable-ecdsa])])
 913               AC_CHECK_FUNC(SHA384_Init, [], [AC_MSG_ERROR([OpenSSL does not support SHA384: please upgrade or rerun with --disable-ecdsa])])
 914               AC_CHECK_DECLS([NID_X9_62_prime256v1, NID_secp384r1], [], [AC_MSG_ERROR([OpenSSL does not support the ECDSA curves: please upgrade or rerun with --disable-ecdsa])], [AC_INCLUDES_DEFAULT
 915 #include <openssl/evp.h>
 916               ])
 917               # see if OPENSSL 1.0.0 or later (has EVP MD and Verify independency)
 918               AC_MSG_CHECKING([if openssl supports SHA2 and ECDSA with EVP])
 919               if grep OPENSSL_VERSION_TEXT $ssldir/include/openssl/opensslv.h | grep "OpenSSL" >/dev/null; then
 920                 if grep OPENSSL_VERSION_NUMBER $ssldir/include/openssl/opensslv.h | grep 0x0 >/dev/null; then
 921                   AC_MSG_RESULT([no])
 922                   AC_DEFINE_UNQUOTED([USE_ECDSA_EVP_WORKAROUND], [1], [Define this to enable an EVP workaround for older openssl])
 923                 else
 924                   AC_MSG_RESULT([yes])
 925                 fi
 926               else
 927                 # not OpenSSL, thus likely LibreSSL, which supports it
 928                 AC_MSG_RESULT([yes])
 929               fi
 930       fi
 931       # we now know we have ECDSA and the required curves.
 932       AC_DEFINE_UNQUOTED([USE_ECDSA], [1], [Define this to enable ECDSA support.])
 933       use_ecdsa="yes"
 934       ;;
 935 esac
 936
 937 AC_ARG_ENABLE(dsa, AC_HELP_STRING([--disable-dsa], [Disable DSA support]))
 938 use_dsa="no"
 939 case "$enable_dsa" in
 940     no)
 941       ;;
 942     *)
 943       # detect if DSA is supported, and turn it off if not.
 944       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 945       AC_CHECK_FUNC(DSA_SIG_new, [
 946       AC_CHECK_TYPE(DSA_SIG*, [
 947       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
 948       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
 949                fi ], [
 950 AC_INCLUDES_DEFAULT
 951 #ifdef HAVE_OPENSSL_ERR_H
 952 #include <openssl/err.h>
 953 #endif
 954
 955 #ifdef HAVE_OPENSSL_RAND_H
 956 #include <openssl/rand.h>
 957 #endif
 958
 959 #ifdef HAVE_OPENSSL_CONF_H
 960 #include <openssl/conf.h>
 961 #endif
 962
 963 #ifdef HAVE_OPENSSL_ENGINE_H
 964 #include <openssl/engine.h>
 965 #endif
 966       ])
 967       ], [if test "x$enable_dsa" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support DSA and you used --enable-dsa.])
 968                fi ])
 969       else
 970       AC_DEFINE_UNQUOTED([USE_DSA], [1], [Define this to enable DSA support.])
 971       fi
 972       ;;
 973 esac
 974
 975 AC_ARG_ENABLE(ed25519, AC_HELP_STRING([--disable-ed25519], [Disable ED25519 support]))
 976 use_ed25519="no"
 977 case "$enable_ed25519" in
 978     no)
 979       ;;
 980     *)
 981       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
 982               AC_CHECK_DECLS([NID_ED25519], [
 983                 use_ed25519="yes"
 984               ], [ if test "x$enable_ed25519" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED25519 and you used --enable-ed25519.])
 985                 fi ], [AC_INCLUDES_DEFAULT
 986 #include <openssl/evp.h>
 987               ])
 988       fi
 989       if test $USE_NETTLE = "yes"; then
 990                 AC_CHECK_HEADERS([nettle/eddsa.h], use_ed25519="yes",, [AC_INCLUDES_DEFAULT])
 991       fi
 992       if test $use_ed25519 = "yes"; then
 993                 AC_DEFINE_UNQUOTED([USE_ED25519], [1], [Define this to enable ED25519 support.])
 994       fi
 995       ;;
 996 esac
 997
 998 AC_ARG_ENABLE(ed448, AC_HELP_STRING([--disable-ed448], [Disable ED448 support]))
 999 use_ed448="no"
1000 case "$enable_ed448" in
1001     no)
1002       ;;
1003     *)
1004       if test $USE_NSS = "no" -a $USE_NETTLE = "no"; then
1005               AC_CHECK_DECLS([NID_ED448], [
1006                 use_ed448="yes"
1007               ], [ if test "x$enable_ed448" = "xyes"; then AC_MSG_ERROR([OpenSSL does not support ED448 and you used --enable-ed448.])
1008                 fi ], [AC_INCLUDES_DEFAULT
1009 #include <openssl/evp.h>
1010               ])
1011       fi
1012       if test $use_ed448 = "yes"; then
1013                 AC_DEFINE_UNQUOTED([USE_ED448], [1], [Define this to enable ED448 support.])
1014       fi
1015       ;;
1016 esac
1017
1018 AC_ARG_ENABLE(event-api, AC_HELP_STRING([--enable-event-api], [Enable (experimental) pluggable event base libunbound API installed to unbound-event.h]))
1019 case "$enable_event_api" in
1020     yes)
1021       AC_SUBST(UNBOUND_EVENT_INSTALL, [unbound-event-install])
1022       AC_SUBST(UNBOUND_EVENT_UNINSTALL, [unbound-event-uninstall])
1023       ;;
1024     *)
1025       ;;
1026 esac
1027
1028 AC_ARG_ENABLE(tfo-client, AC_HELP_STRING([--enable-tfo-client], [Enable TCP Fast Open for client mode]))
1029 case "$enable_tfo_client" in
1030         yes)
1031                 case `uname` in
1032                         Linux) AC_CHECK_DECL([MSG_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1033                                              [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1034                                              [AC_INCLUDES_DEFAULT
1035 #include <netinet/tcp.h>
1036 ])
1037                                         AC_DEFINE_UNQUOTED([USE_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1038                           ;;
1039                         Darwin) AC_CHECK_DECL([CONNECT_RESUME_ON_READ_WRITE], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support client mode TFO])],
1040                                               [AC_MSG_ERROR([TCP Fast Open is not available for client mode: please rerun without --enable-tfo-client])],
1041                                               [AC_INCLUDES_DEFAULT
1042 #include <sys/socket.h>
1043 ])
1044                                         AC_DEFINE_UNQUOTED([USE_OSX_MSG_FASTOPEN], [1], [Define this to enable client TCP Fast Open.])
1045                           ;;
1046                 esac
1047         ;;
1048         no|*)
1049                 ;;
1050 esac
1051
1052 AC_ARG_ENABLE(tfo-server, AC_HELP_STRING([--enable-tfo-server], [Enable TCP Fast Open for server mode]))
1053 case "$enable_tfo_server" in
1054         yes)
1055               AC_CHECK_DECL([TCP_FASTOPEN], [AC_MSG_WARN([Check the platform specific TFO kernel parameters are correctly configured to support server mode TFO])], [AC_MSG_ERROR([TCP Fast Open is not available for server mode: please rerun without --enable-tfo-server])], [AC_INCLUDES_DEFAULT
1056 #include <netinet/tcp.h>
1057               ])
1058                 AC_DEFINE_UNQUOTED([USE_TCP_FASTOPEN], [1], [Define this to enable server TCP Fast Open.])
1059                 ;;
1060         no|*)
1061                 ;;
1062 esac
1063
1064 # check for libevent
1065 AC_ARG_WITH(libevent, AC_HELP_STRING([--with-libevent=pathname],
1066     [use libevent (will check /usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr  or you can specify an explicit path). Slower, but allows use of large outgoing port ranges.]),
1067     [ ],[ withval="no" ])
1068 if test x_$withval = x_yes -o x_$withval != x_no; then
1069         AC_MSG_CHECKING(for libevent)
1070         if test x_$withval = x_ -o x_$withval = x_yes; then
1071             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1072         fi
1073         for dir in $withval; do
1074             thedir="$dir"
1075             if test -f "$dir/include/event.h" -o -f "$dir/include/event2/event.h"; then
1076                 found_libevent="yes"
1077                 dnl assume /usr is in default path.
1078                 if test "$thedir" != "/usr"; then
1079                     CPPFLAGS="$CPPFLAGS -I$thedir/include"
1080                 fi
1081                 break;
1082             fi
1083         done
1084         if test x_$found_libevent != x_yes; then
1085                 if test -f "$dir/event.h" -a \( -f "$dir/libevent.la" -o -f "$dir/libev.la" \) ; then
1086                         # libevent source directory
1087                         AC_MSG_RESULT(found in $thedir)
1088                         CPPFLAGS="$CPPFLAGS -I$thedir -I$thedir/include"
1089                         BAK_LDFLAGS_SET="1"
1090                         BAK_LDFLAGS="$LDFLAGS"
1091                         # remove evdns from linking
1092                         mkdir build >/dev/null 2>&1
1093                         mkdir build/libevent >/dev/null 2>&1
1094                         mkdir build/libevent/.libs >/dev/null 2>&1
1095                         ev_files_o=`ls $thedir/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1096                         ev_files_lo=`ls $thedir/*.lo | grep -v evdns\.lo | grep -v bufferevent_openssl\.lo`
1097                         ev_files_libso=`ls $thedir/.libs/*.o | grep -v evdns\.o | grep -v bufferevent_openssl\.o`
1098                         cp $ev_files_o build/libevent
1099                         cp $ev_files_lo build/libevent
1100                         cp $ev_files_libso build/libevent/.libs
1101                         LATE_LDFLAGS="build/libevent/*.lo -lm"
1102                         LDFLAGS="build/libevent/*.o $LDFLAGS -lm"
1103                 else
1104                         AC_MSG_ERROR([Cannot find the libevent library in $withval
1105 You can restart ./configure --with-libevent=no to use a builtin alternative.
1106 Please note that this alternative is not as capable as libevent when using
1107 large outgoing port ranges.  ])
1108                 fi
1109         else
1110             AC_MSG_RESULT(found in $thedir)
1111             dnl if event2 exists and no event lib in dir itself, use subdir
1112             if test ! -f $thedir/lib/libevent.a -a ! -f $thedir/lib/libevent.so -a -d "$thedir/lib/event2"; then
1113                     LDFLAGS="$LDFLAGS -L$thedir/lib/event2"
1114                     ACX_RUNTIME_PATH_ADD([$thedir/lib/event2])
1115             else
1116                     dnl assume /usr is in default path, do not add "".
1117                     if test "$thedir" != "/usr" -a "$thedir" != ""; then
1118                         LDFLAGS="$LDFLAGS -L$thedir/lib"
1119                         ACX_RUNTIME_PATH_ADD([$thedir/lib])
1120                     fi
1121             fi
1122         fi
1123         # check for library used by libevent after 1.3c
1124         AC_SEARCH_LIBS([clock_gettime], [rt])
1125
1126         # is the event.h header libev or libevent?
1127         AC_CHECK_HEADERS([event.h],,, [AC_INCLUDES_DEFAULT])
1128         AC_CHECK_DECL(EV_VERSION_MAJOR, [
1129                 AC_SEARCH_LIBS(event_set, [ev])
1130         ],[
1131                 AC_SEARCH_LIBS(event_set, [event])
1132         ],[AC_INCLUDES_DEFAULT
1133 #include <event.h>
1134         ])
1135         AC_CHECK_FUNCS([event_base_free]) # only in libevent 1.2 and later
1136         AC_CHECK_FUNCS([event_base_once]) # only in libevent 1.4.1 and later
1137         AC_CHECK_FUNCS([event_base_new]) # only in libevent 1.4.1 and later
1138         AC_CHECK_FUNCS([event_base_get_method]) # only in libevent 1.4.3 and later
1139         AC_CHECK_FUNCS([ev_loop]) # only in libev. (tested on 3.51)
1140         AC_CHECK_FUNCS([ev_default_loop]) # only in libev. (tested on 4.00)
1141         PC_LIBEVENT_DEPENDENCY="libevent"
1142         AC_SUBST(PC_LIBEVENT_DEPENDENCY)
1143         if test -n "$BAK_LDFLAGS_SET"; then
1144                 LDFLAGS="$BAK_LDFLAGS"
1145         fi
1146 else
1147         AC_DEFINE(USE_MINI_EVENT, 1, [Define if you want to use internal select based events])
1148 fi
1149
1150 # check for libexpat
1151 AC_ARG_WITH(libexpat, AC_HELP_STRING([--with-libexpat=path],
1152     [specify explicit path for libexpat.]),
1153     [ ],[ withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr" ])
1154 AC_MSG_CHECKING(for libexpat)
1155 found_libexpat="no"
1156 for dir in $withval ; do
1157             if test -f "$dir/include/expat.h"; then
1158                 found_libexpat="yes"
1159                 dnl assume /usr is in default path.
1160                 if test "$dir" != "/usr"; then
1161                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1162                     LDFLAGS="$LDFLAGS -L$dir/lib"
1163                 fi
1164                 AC_MSG_RESULT(found in $dir)
1165                 break;
1166             fi
1167 done
1168 if test x_$found_libexpat != x_yes; then
1169         AC_ERROR([Could not find libexpat, expat.h])
1170 fi
1171 AC_CHECK_HEADERS([expat.h],,, [AC_INCLUDES_DEFAULT])
1172 AC_CHECK_DECLS([XML_StopParser], [], [], [AC_INCLUDES_DEFAULT
1173 #include <expat.h>
1174 ])
1175
1176 # hiredis (redis C client for cachedb)
1177 AC_ARG_WITH(libhiredis, AC_HELP_STRING([--with-libhiredis=path],
1178     [specify explicit path for libhiredis.]),
1179     [ ],[ withval="no" ])
1180 AC_MSG_CHECKING(for libhiredis)
1181 found_libhiredis="no"
1182 if test x_$withval = x_yes -o x_$withval != x_no; then
1183    if test x_$withval = x_ -o x_$withval = x_yes; then
1184             withval="/usr/local /opt/local /usr/lib /usr/pkg /usr/sfw /usr"
1185    fi
1186    for dir in $withval ; do
1187             if test -f "$dir/include/hiredis/hiredis.h"; then
1188                 found_libhiredis="yes"
1189                 dnl assume /usr is in default path.
1190                 if test "$dir" != "/usr"; then
1191                     CPPFLAGS="$CPPFLAGS -I$dir/include"
1192                     LDFLAGS="$LDFLAGS -L$dir/lib"
1193                 fi
1194                 AC_MSG_RESULT(found in $dir)
1195                 AC_DEFINE([USE_REDIS], [1], [Define this to use hiredis client.])
1196                 LIBS="$LIBS -lhiredis"
1197                 break;
1198             fi
1199     done
1200     if test x_$found_libhiredis != x_yes; then
1201         AC_ERROR([Could not find libhiredis, hiredis.h])
1202     fi
1203     AC_CHECK_HEADERS([hiredis/hiredis.h],,, [AC_INCLUDES_DEFAULT])
1204     AC_CHECK_DECLS([redisConnect], [], [], [AC_INCLUDES_DEFAULT
1205     #include <hiredis/hiredis.h>
1206     ])
1207 fi
1208
1209 # set static linking if requested
1210 AC_SUBST(staticexe)
1211 staticexe=""
1212 AC_ARG_ENABLE(static-exe, AC_HELP_STRING([--enable-static-exe],
1213         [ enable to compile executables statically against (event) libs, for debug purposes ]),
1214         , )
1215 if test x_$enable_static_exe = x_yes; then
1216         staticexe="-static"
1217         if test "$on_mingw" = yes; then
1218                 staticexe="-all-static"
1219                 # for static compile, include gdi32 and zlib here.
1220                 if echo $LIBS | grep 'lgdi32' >/dev/null; then
1221                         :
1222                 else
1223                         LIBS="$LIBS -lgdi32"
1224                 fi
1225                 LIBS="$LIBS -lz"
1226         fi
1227 fi
1228
1229 # Include systemd.m4 - begin
1230 sinclude(systemd.m4)
1231 # Include systemd.m4 - end
1232
1233 # set lock checking if requested
1234 AC_ARG_ENABLE(lock_checks, AC_HELP_STRING([--enable-lock-checks],
1235         [ enable to check lock and unlock calls, for debug purposes ]),
1236         , )
1237 if test x_$enable_lock_checks = x_yes; then
1238         AC_DEFINE(ENABLE_LOCK_CHECKS, 1, [Define if you want to use debug lock checking (slow).])
1239         CHECKLOCK_OBJ="checklocks.lo"
1240         AC_SUBST(CHECKLOCK_OBJ)
1241 fi
1242
1243 ACX_CHECK_GETADDRINFO_WITH_INCLUDES
1244 if test "$USE_WINSOCK" = 1; then
1245         AC_DEFINE(UB_ON_WINDOWS, 1, [Use win32 resources and API])
1246         AC_CHECK_HEADERS([iphlpapi.h],,, [AC_INCLUDES_DEFAULT
1247 #include <windows.h>
1248         ])
1249         AC_CHECK_TOOL(WINDRES, windres)
1250         LIBS="$LIBS -liphlpapi -lcrypt32"
1251         WINAPPS="unbound-service-install.exe unbound-service-remove.exe anchor-update.exe"
1252         AC_SUBST(WINAPPS)
1253         WIN_DAEMON_SRC="winrc/win_svc.c winrc/w_inst.c"
1254         AC_SUBST(WIN_DAEMON_SRC)
1255         WIN_DAEMON_OBJ="win_svc.lo w_inst.lo"
1256         AC_SUBST(WIN_DAEMON_OBJ)
1257         WIN_DAEMON_OBJ_LINK="rsrc_unbound.o"
1258         AC_SUBST(WIN_DAEMON_OBJ_LINK)
1259         WIN_HOST_OBJ_LINK="rsrc_unbound_host.o"
1260         AC_SUBST(WIN_HOST_OBJ_LINK)
1261         WIN_UBANCHOR_OBJ_LINK="rsrc_unbound_anchor.o log.lo locks.lo"
1262         AC_SUBST(WIN_UBANCHOR_OBJ_LINK)
1263         WIN_CONTROL_OBJ_LINK="rsrc_unbound_control.o"
1264         AC_SUBST(WIN_CONTROL_OBJ_LINK)
1265         WIN_CHECKCONF_OBJ_LINK="rsrc_unbound_checkconf.o"
1266         AC_SUBST(WIN_CHECKCONF_OBJ_LINK)
1267 fi
1268 if test $ac_cv_func_getaddrinfo = no; then
1269         AC_LIBOBJ([fake-rfc2553])
1270 fi
1271 # check after getaddrinfo for its libraries
1272 ACX_FUNC_IOCTLSOCKET
1273
1274 # see if daemon(3) exists, and if it is deprecated.
1275 AC_CHECK_FUNCS([daemon])
1276 if test $ac_cv_func_daemon = yes; then
1277         ACX_FUNC_DEPRECATED([daemon], [(void)daemon(0, 0);], [
1278 #include <stdlib.h>
1279 ])
1280 fi
1281
1282 AC_CHECK_MEMBERS([struct sockaddr_un.sun_len],,,[
1283 AC_INCLUDES_DEFAULT
1284 #ifdef HAVE_SYS_UN_H
1285 #include <sys/un.h>
1286 #endif
1287 ])
1288 AC_CHECK_MEMBERS([struct in_pktinfo.ipi_spec_dst],,,[
1289 AC_INCLUDES_DEFAULT
1290 #if HAVE_SYS_PARAM_H
1291 #include <sys/param.h>
1292 #endif
1293
1294 #ifdef HAVE_SYS_SOCKET_H
1295 #include <sys/socket.h>
1296 #endif
1297
1298 #ifdef HAVE_SYS_UIO_H
1299 #include <sys/uio.h>
1300 #endif
1301
1302 #ifdef HAVE_NETINET_IN_H
1303 #include <netinet/in.h>
1304 #endif
1305
1306 #ifdef HAVE_NETINET_TCP_H
1307 #include <netinet/tcp.h>
1308 #endif
1309
1310 #ifdef HAVE_ARPA_INET_H
1311 #include <arpa/inet.h>
1312 #endif
1313
1314 #ifdef HAVE_WINSOCK2_H
1315 #include <winsock2.h>
1316 #endif
1317
1318 #ifdef HAVE_WS2TCPIP_H
1319 #include <ws2tcpip.h>
1320 #endif
1321 ])
1322 AC_SEARCH_LIBS([setusercontext], [util])
1323 AC_CHECK_FUNCS([tzset sigprocmask fcntl getpwnam endpwent getrlimit setrlimit setsid chroot kill chown sleep usleep random srandom recvmsg sendmsg writev socketpair glob initgroups strftime localtime_r setusercontext _beginthreadex endservent endprotoent fsync shmget accept4])
1324 AC_CHECK_FUNCS([setresuid],,[AC_CHECK_FUNCS([setreuid])])
1325 AC_CHECK_FUNCS([setresgid],,[AC_CHECK_FUNCS([setregid])])
1326
1327 # check if setreuid en setregid fail, on MacOSX10.4(darwin8).
1328 if echo $target_os | grep darwin8 > /dev/null; then
1329         AC_DEFINE(DARWIN_BROKEN_SETREUID, 1, [Define this if on macOSX10.4-darwin8 and setreuid and setregid do not work])
1330 fi
1331 AC_CHECK_DECLS([inet_pton,inet_ntop], [], [], [
1332 AC_INCLUDES_DEFAULT
1333 #ifdef HAVE_NETINET_IN_H
1334 #include <netinet/in.h>
1335 #endif
1336
1337 #ifdef HAVE_NETINET_TCP_H
1338 #include <netinet/tcp.h>
1339 #endif
1340
1341 #ifdef HAVE_ARPA_INET_H
1342 #include <arpa/inet.h>
1343 #endif
1344
1345 #ifdef HAVE_WINSOCK2_H
1346 #include <winsock2.h>
1347 #endif
1348
1349 #ifdef HAVE_WS2TCPIP_H
1350 #include <ws2tcpip.h>
1351 #endif
1352 ])
1353 AC_REPLACE_FUNCS(inet_aton)
1354 AC_REPLACE_FUNCS(inet_pton)
1355 AC_REPLACE_FUNCS(inet_ntop)
1356 AC_REPLACE_FUNCS(snprintf)
1357 # test if snprintf return the proper length
1358 if test "x$ac_cv_func_snprintf" = xyes; then
1359     if test c${cross_compiling} = cno; then
1360         AC_MSG_CHECKING([for correct snprintf return value])
1361         AC_RUN_IFELSE([AC_LANG_SOURCE(AC_INCLUDES_DEFAULT
1362 [[
1363 int main(void) { return !(snprintf(NULL, 0, "test") == 4); }
1364 ]])], [AC_MSG_RESULT(yes)], [
1365                 AC_MSG_RESULT(no)
1366                 AC_DEFINE([SNPRINTF_RET_BROKEN], [], [define if (v)snprintf does not return length needed, (but length used)])
1367                 AC_LIBOBJ(snprintf)
1368           ])
1369     fi
1370 fi
1371 AC_REPLACE_FUNCS(strlcat)
1372 AC_REPLACE_FUNCS(strlcpy)
1373 AC_REPLACE_FUNCS(memmove)
1374 AC_REPLACE_FUNCS(gmtime_r)
1375 AC_REPLACE_FUNCS(isblank)
1376 dnl without CTIME, ARC4-functions and without reallocarray.
1377 LIBOBJ_WITHOUT_CTIMEARC4="$LIBOBJS"
1378 AC_SUBST(LIBOBJ_WITHOUT_CTIMEARC4)
1379 AC_REPLACE_FUNCS(reallocarray)
1380 if test "$USE_NSS" = "no"; then
1381         AC_REPLACE_FUNCS(arc4random)
1382         AC_REPLACE_FUNCS(arc4random_uniform)
1383         if test "$ac_cv_func_arc4random" = "no"; then
1384                 AC_LIBOBJ(explicit_bzero)
1385                 AC_LIBOBJ(arc4_lock)
1386                 AC_CHECK_FUNCS([getentropy],,[
1387                     if test "$USE_WINSOCK" = 1; then
1388                         AC_LIBOBJ(getentropy_win)
1389                     else
1390                         case "$host" in
1391                         Darwin|*darwin*)
1392                                 AC_LIBOBJ(getentropy_osx)
1393                         ;;
1394                         *solaris*|*sunos*|SunOS)
1395                                 AC_LIBOBJ(getentropy_solaris)
1396                                 AC_CHECK_HEADERS([sys/sha2.h],, [
1397                                         AC_CHECK_FUNCS([SHA512_Update],,[
1398                                                 AC_LIBOBJ(sha512)
1399                                         ])
1400                                 ], [AC_INCLUDES_DEFAULT])
1401                                 if test "$ac_cv_header_sys_sha2_h" = "yes"; then
1402                                         # this lib needed for sha2 on solaris
1403                                         LIBS="$LIBS -lmd"
1404                                 fi
1405                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1406                         ;;
1407                         *linux*|Linux|*)
1408                                 AC_LIBOBJ(getentropy_linux)
1409                                 AC_CHECK_FUNCS([SHA512_Update],,[
1410                                         AC_DEFINE([COMPAT_SHA512], [1], [Do sha512 definitions in config.h])
1411                                         AC_LIBOBJ(sha512)
1412                                 ])
1413                                 AC_CHECK_HEADERS([sys/sysctl.h],,, [AC_INCLUDES_DEFAULT])
1414                                 AC_CHECK_FUNCS([getauxval])
1415                                 AC_SEARCH_LIBS([clock_gettime], [rt])
1416                         ;;
1417                         esac
1418                     fi
1419                 ])
1420         fi
1421 fi
1422 LIBOBJ_WITHOUT_CTIME="$LIBOBJS"
1423 AC_SUBST(LIBOBJ_WITHOUT_CTIME)
1424 AC_REPLACE_FUNCS(ctime_r)
1425 AC_REPLACE_FUNCS(strsep)
1426
1427 AC_ARG_ENABLE(allsymbols, AC_HELP_STRING([--enable-allsymbols], [export all symbols from libunbound and link binaries to it, smaller install size but libunbound export table is polluted by internal symbols]))
1428 case "$enable_allsymbols" in
1429         yes)
1430         COMMON_OBJ_ALL_SYMBOLS=""
1431         UBSYMS=""
1432         EXTRALINK="-L. -L.libs -lunbound"
1433         AC_DEFINE(EXPORT_ALL_SYMBOLS, 1, [Define this if you enabled-allsymbols from libunbound to link binaries to it for smaller install size, but the libunbound export table is polluted by internal symbols])
1434         ;;
1435         no|*)
1436         COMMON_OBJ_ALL_SYMBOLS='$(COMMON_OBJ)'
1437         UBSYMS='-export-symbols $(srcdir)/libunbound/ubsyms.def'
1438         EXTRALINK=""
1439         ;;
1440 esac
1441 AC_SUBST(COMMON_OBJ_ALL_SYMBOLS)
1442 AC_SUBST(EXTRALINK)
1443 AC_SUBST(UBSYMS)
1444 if test x_$enable_lock_checks = x_yes; then
1445         UBSYMS="-export-symbols clubsyms.def"
1446         cp ${srcdir}/libunbound/ubsyms.def clubsyms.def
1447         echo lock_protect >> clubsyms.def
1448         echo lock_unprotect >> clubsyms.def
1449         echo lock_get_mem >> clubsyms.def
1450         echo checklock_start >> clubsyms.def
1451         echo checklock_stop >> clubsyms.def
1452         echo checklock_lock >> clubsyms.def
1453         echo checklock_unlock >> clubsyms.def
1454         echo checklock_init >> clubsyms.def
1455         echo checklock_thrcreate >> clubsyms.def
1456         echo checklock_thrjoin >> clubsyms.def
1457 fi
1458
1459 # check for dnstap if requested
1460 dt_DNSTAP([$UNBOUND_RUN_DIR/dnstap.sock],
1461     [
1462         AC_DEFINE([USE_DNSTAP], [1], [Define to 1 to enable dnstap support])
1463         AC_SUBST([ENABLE_DNSTAP], [1])
1464
1465         AC_SUBST([opt_dnstap_socket_path])
1466         ACX_ESCAPE_BACKSLASH($opt_dnstap_socket_path, hdr_dnstap_socket_path)
1467         AC_DEFINE_UNQUOTED(DNSTAP_SOCKET_PATH,
1468             ["$hdr_dnstap_socket_path"], [default dnstap socket path])
1469
1470         AC_SUBST([DNSTAP_SRC], ["dnstap/dnstap.c dnstap/dnstap.pb-c.c"])
1471         AC_SUBST([DNSTAP_OBJ], ["dnstap.lo dnstap.pb-c.lo"])
1472     ],
1473     [
1474         AC_SUBST([ENABLE_DNSTAP], [0])
1475     ]
1476 )
1477
1478 # check for dnscrypt if requested
1479 dnsc_DNSCRYPT([
1480         AC_DEFINE([USE_DNSCRYPT], [1], [Define to 1 to enable dnscrypt support])
1481         AC_SUBST([ENABLE_DNSCRYPT], [1])
1482
1483         AC_SUBST([DNSCRYPT_SRC], ["dnscrypt/dnscrypt.c"])
1484         AC_SUBST([DNSCRYPT_OBJ], ["dnscrypt.lo"])
1485     ],
1486     [
1487         AC_SUBST([ENABLE_DNSCRYPT], [0])
1488     ]
1489 )
1490
1491 # check for cachedb if requested
1492 AC_ARG_ENABLE(cachedb, AC_HELP_STRING([--enable-cachedb], [enable cachedb module that can use external cache storage]))
1493 # turn on cachedb when hiredis support is enabled.
1494 if test "$found_libhiredis" = "yes"; then enable_cachedb="yes"; fi
1495 case "$enable_cachedb" in
1496     yes)
1497         AC_DEFINE([USE_CACHEDB], [1], [Define to 1 to use cachedb support])
1498         ;;
1499     no|*)
1500         # nothing
1501         ;;
1502 esac
1503
1504 # check for ipsecmod if requested
1505 AC_ARG_ENABLE(ipsecmod, AC_HELP_STRING([--enable-ipsecmod], [Enable ipsecmod module that facilitates opportunistic IPsec]))
1506 case "$enable_ipsecmod" in
1507         yes)
1508                 AC_DEFINE([USE_IPSECMOD], [1], [Define to 1 to use ipsecmod support.])
1509                 IPSECMOD_OBJ="ipsecmod.lo ipsecmod-whitelist.lo"
1510                 AC_SUBST(IPSECMOD_OBJ)
1511                 IPSECMOD_HEADER='$(srcdir)/ipsecmod/ipsecmod.h $(srcdir)/ipsecmod/ipsecmod-whitelist.h'
1512                 AC_SUBST(IPSECMOD_HEADER)
1513                 ;;
1514         no|*)
1515                 # nothing
1516                 ;;
1517 esac
1518
1519 AC_MSG_CHECKING([if ${MAKE:-make} supports $< with implicit rule in scope])
1520 # on openBSD, the implicit rule make $< work.
1521 # on Solaris, it does not work ($? is changed sources, $^ lists dependencies).
1522 # gmake works.
1523 cat >conftest.make <<EOF
1524 all:    conftest.lo
1525
1526 conftest.lo foo.lo bla.lo:
1527         if test -f "\$<"; then touch \$@; fi
1528
1529 .SUFFIXES: .lo
1530 .c.lo:
1531         if test -f "\$<"; then touch \$@; fi
1532
1533 conftest.lo:        conftest.dir/conftest.c
1534 EOF
1535 mkdir conftest.dir
1536 touch conftest.dir/conftest.c
1537 rm -f conftest.lo conftest.c
1538 ${MAKE:-make} -f conftest.make >/dev/null
1539 rm -f conftest.make conftest.c conftest.dir/conftest.c
1540 rm -rf conftest.dir
1541 if test ! -f conftest.lo; then
1542         AC_MSG_RESULT(no)
1543         SOURCEDETERMINE='echo "$^" | awk "-F " "{print \$$1;}" > .source'
1544         SOURCEFILE='`cat .source`'
1545 else
1546         AC_MSG_RESULT(yes)
1547         SOURCEDETERMINE=':'
1548         SOURCEFILE='$<'
1549 fi
1550 rm -f conftest.lo
1551 AC_SUBST(SOURCEDETERMINE)
1552 AC_SUBST(SOURCEFILE)
1553
1554 # see if we want to build the library or everything
1555 ALLTARGET="alltargets"
1556 INSTALLTARGET="install-all"
1557 AC_ARG_WITH(libunbound-only, AC_HELP_STRING([--with-libunbound-only],
1558         [do not build daemon and tool programs]),
1559         [
1560         if test "$withval" = "yes"; then
1561                 ALLTARGET="lib"
1562                 INSTALLTARGET="install-lib"
1563         fi
1564 ])
1565 if test $ALLTARGET = "alltargets"; then
1566         if test $USE_NSS = "yes"; then
1567                 AC_ERROR([--with-nss can only be used in combination with --with-libunbound-only.])
1568         fi
1569         if test $USE_NETTLE = "yes"; then
1570                 AC_ERROR([--with-nettle can only be used in combination with --with-libunbound-only.])
1571         fi
1572 fi
1573
1574 AC_SUBST(ALLTARGET)
1575 AC_SUBST(INSTALLTARGET)
1576
1577 ACX_STRIP_EXT_FLAGS
1578 if test -n "$LATE_LDFLAGS"; then
1579   LDFLAGS="$LATE_LDFLAGS $LDFLAGS"
1580 fi
1581 # remove start spaces
1582 LDFLAGS=`echo "$LDFLAGS"|sed -e 's/^ *//'`
1583 LIBS=`echo "$LIBS"|sed -e 's/^ *//'`
1584
1585 AC_DEFINE_UNQUOTED([MAXSYSLOGMSGLEN], [10240], [Define to the maximum message length to pass to syslog.])
1586
1587 AH_BOTTOM(
1588 dnl this must be first AH_CONFIG, to define the flags before any includes.
1589 AHX_CONFIG_EXT_FLAGS
1590
1591 dnl includes
1592 [
1593 #ifndef UNBOUND_DEBUG
1594 #  define NDEBUG
1595 #endif
1596
1597 /** Use small-ldns codebase */
1598 #define USE_SLDNS 1
1599 #ifdef HAVE_SSL
1600 #  define LDNS_BUILD_CONFIG_HAVE_SSL 1
1601 #endif
1602
1603 #include <stdio.h>
1604 #include <string.h>
1605 #include <unistd.h>
1606 #include <assert.h>
1607
1608 #if STDC_HEADERS
1609 #include <stdlib.h>
1610 #include <stddef.h>
1611 #endif
1612
1613 #ifdef HAVE_STDARG_H
1614 #include <stdarg.h>
1615 #endif
1616
1617 #ifdef HAVE_STDINT_H
1618 #include <stdint.h>
1619 #endif
1620
1621 #include <errno.h>
1622
1623 #if HAVE_SYS_PARAM_H
1624 #include <sys/param.h>
1625 #endif
1626
1627 #ifdef HAVE_SYS_SOCKET_H
1628 #include <sys/socket.h>
1629 #endif
1630
1631 #ifdef HAVE_SYS_UIO_H
1632 #include <sys/uio.h>
1633 #endif
1634
1635 #ifdef HAVE_NETINET_IN_H
1636 #include <netinet/in.h>
1637 #endif
1638
1639 #ifdef HAVE_NETINET_TCP_H
1640 #include <netinet/tcp.h>
1641 #endif
1642
1643 #ifdef HAVE_ARPA_INET_H
1644 #include <arpa/inet.h>
1645 #endif
1646
1647 #ifdef HAVE_WINSOCK2_H
1648 #include <winsock2.h>
1649 #endif
1650
1651 #ifdef HAVE_WS2TCPIP_H
1652 #include <ws2tcpip.h>
1653 #endif
1654
1655 #ifndef USE_WINSOCK
1656 #define ARG_LL "%ll"
1657 #else
1658 #define ARG_LL "%I64"
1659 #endif
1660
1661 #ifndef AF_LOCAL
1662 #define AF_LOCAL AF_UNIX
1663 #endif
1664 ]
1665
1666 AHX_CONFIG_FORMAT_ATTRIBUTE
1667 AHX_CONFIG_UNUSED_ATTRIBUTE
1668 AHX_CONFIG_FSEEKO
1669 AHX_CONFIG_MAXHOSTNAMELEN
1670 #if !defined(HAVE_SNPRINTF) || defined(SNPRINTF_RET_BROKEN)
1671 #define snprintf snprintf_unbound
1672 #define vsnprintf vsnprintf_unbound
1673 #include <stdarg.h>
1674 int snprintf (char *str, size_t count, const char *fmt, ...);
1675 int vsnprintf (char *str, size_t count, const char *fmt, va_list arg);
1676 #endif /* HAVE_SNPRINTF or SNPRINTF_RET_BROKEN */
1677 AHX_CONFIG_INET_PTON(unbound)
1678 AHX_CONFIG_INET_NTOP(unbound)
1679 AHX_CONFIG_INET_ATON(unbound)
1680 AHX_CONFIG_MEMMOVE(unbound)
1681 AHX_CONFIG_STRLCAT(unbound)
1682 AHX_CONFIG_STRLCPY(unbound)
1683 AHX_CONFIG_GMTIME_R(unbound)
1684 AHX_CONFIG_REALLOCARRAY(unbound)
1685 AHX_CONFIG_W32_SLEEP
1686 AHX_CONFIG_W32_USLEEP
1687 AHX_CONFIG_W32_RANDOM
1688 AHX_CONFIG_W32_SRANDOM
1689 AHX_CONFIG_W32_FD_SET_T
1690 AHX_CONFIG_IPV6_MIN_MTU
1691 AHX_MEMCMP_BROKEN(unbound)
1692
1693 [
1694 #ifndef HAVE_CTIME_R
1695 #define ctime_r unbound_ctime_r
1696 char *ctime_r(const time_t *timep, char *buf);
1697 #endif
1698
1699 #ifndef HAVE_STRSEP
1700 #define strsep unbound_strsep
1701 char *strsep(char **stringp, const char *delim);
1702 #endif
1703
1704 #ifndef HAVE_ISBLANK
1705 #define isblank unbound_isblank
1706 int isblank(int c);
1707 #endif
1708
1709 #if defined(HAVE_INET_NTOP) && !HAVE_DECL_INET_NTOP
1710 const char *inet_ntop(int af, const void *src, char *dst, size_t size);
1711 #endif
1712
1713 #if defined(HAVE_INET_PTON) && !HAVE_DECL_INET_PTON
1714 int inet_pton(int af, const char* src, void* dst);
1715 #endif
1716
1717 #if !defined(HAVE_STRPTIME) || !defined(STRPTIME_WORKS)
1718 #define strptime unbound_strptime
1719 struct tm;
1720 char *strptime(const char *s, const char *format, struct tm *tm);
1721 #endif
1722
1723 #ifdef HAVE_LIBRESSL
1724 #  if !HAVE_DECL_STRLCPY
1725 size_t strlcpy(char *dst, const char *src, size_t siz);
1726 #  endif
1727 #  if !HAVE_DECL_STRLCAT
1728 size_t strlcat(char *dst, const char *src, size_t siz);
1729 #  endif
1730 #  if !HAVE_DECL_ARC4RANDOM && defined(HAVE_ARC4RANDOM)
1731 uint32_t arc4random(void);
1732 #  endif
1733 #  if !HAVE_DECL_ARC4RANDOM_UNIFORM && defined(HAVE_ARC4RANDOM_UNIFORM)
1734 uint32_t arc4random_uniform(uint32_t upper_bound);
1735 #  endif
1736 #  if !HAVE_DECL_REALLOCARRAY
1737 void *reallocarray(void *ptr, size_t nmemb, size_t size);
1738 #  endif
1739 #endif /* HAVE_LIBRESSL */
1740 #ifndef HAVE_ARC4RANDOM
1741 void explicit_bzero(void* buf, size_t len);
1742 int getentropy(void* buf, size_t len);
1743 uint32_t arc4random(void);
1744 void arc4random_buf(void* buf, size_t n);
1745 void _ARC4_LOCK(void);
1746 void _ARC4_UNLOCK(void);
1747 void _ARC4_LOCK_DESTROY(void);
1748 #endif
1749 #ifndef HAVE_ARC4RANDOM_UNIFORM
1750 uint32_t arc4random_uniform(uint32_t upper_bound);
1751 #endif
1752 #ifdef COMPAT_SHA512
1753 #ifndef SHA512_DIGEST_LENGTH
1754 #define SHA512_BLOCK_LENGTH             128
1755 #define SHA512_DIGEST_LENGTH            64
1756 #define SHA512_DIGEST_STRING_LENGTH     (SHA512_DIGEST_LENGTH * 2 + 1)
1757 typedef struct _SHA512_CTX {
1758         uint64_t        state[8];
1759         uint64_t        bitcount[2];
1760         uint8_t buffer[SHA512_BLOCK_LENGTH];
1761 } SHA512_CTX;
1762 #endif /* SHA512_DIGEST_LENGTH */
1763 void SHA512_Init(SHA512_CTX*);
1764 void SHA512_Update(SHA512_CTX*, void*, size_t);
1765 void SHA512_Final(uint8_t[SHA512_DIGEST_LENGTH], SHA512_CTX*);
1766 unsigned char *SHA512(void* data, unsigned int data_len, unsigned char *digest);
1767 #endif /* COMPAT_SHA512 */
1768
1769
1770
1771 #if defined(HAVE_EVENT_H) && !defined(HAVE_EVENT_BASE_ONCE) && !(defined(HAVE_EV_LOOP) || defined(HAVE_EV_DEFAULT_LOOP)) && (defined(HAVE_PTHREAD) || defined(HAVE_SOLARIS_THREADS))
1772    /* using version of libevent that is not threadsafe. */
1773 #  define LIBEVENT_SIGNAL_PROBLEM 1
1774 #endif
1775
1776 #ifndef CHECKED_INET6
1777 #  define CHECKED_INET6
1778 #  ifdef AF_INET6
1779 #    define INET6
1780 #  else
1781 #    define AF_INET6        28
1782 #  endif
1783 #endif /* CHECKED_INET6 */
1784
1785 #ifndef HAVE_GETADDRINFO
1786 struct sockaddr_storage;
1787 #include "compat/fake-rfc2553.h"
1788 #endif
1789
1790 #ifdef UNBOUND_ALLOC_STATS
1791 #  define malloc(s) unbound_stat_malloc_log(s, __FILE__, __LINE__, __func__)
1792 #  define calloc(n,s) unbound_stat_calloc_log(n, s, __FILE__, __LINE__, __func__)
1793 #  define free(p) unbound_stat_free_log(p, __FILE__, __LINE__, __func__)
1794 #  define realloc(p,s) unbound_stat_realloc_log(p, s, __FILE__, __LINE__, __func__)
1795 void *unbound_stat_malloc(size_t size);
1796 void *unbound_stat_calloc(size_t nmemb, size_t size);
1797 void unbound_stat_free(void *ptr);
1798 void *unbound_stat_realloc(void *ptr, size_t size);
1799 void *unbound_stat_malloc_log(size_t size, const char* file, int line,
1800         const char* func);
1801 void *unbound_stat_calloc_log(size_t nmemb, size_t size, const char* file,
1802         int line, const char* func);
1803 void unbound_stat_free_log(void *ptr, const char* file, int line,
1804         const char* func);
1805 void *unbound_stat_realloc_log(void *ptr, size_t size, const char* file,
1806         int line, const char* func);
1807 #elif defined(UNBOUND_ALLOC_LITE)
1808 #  include "util/alloc.h"
1809 #endif /* UNBOUND_ALLOC_LITE and UNBOUND_ALLOC_STATS */
1810
1811 /** default port for DNS traffic. */
1812 #define UNBOUND_DNS_PORT 53
1813 /** default port for DNS over TLS traffic. */
1814 #define UNBOUND_DNS_OVER_TLS_PORT 853
1815 /** default port for unbound control traffic, registered port with IANA,
1816     ub-dns-control  8953/tcp    unbound dns nameserver control */
1817 #define UNBOUND_CONTROL_PORT 8953
1818 /** the version of unbound-control that this software implements */
1819 #define UNBOUND_CONTROL_VERSION 1
1820
1821 ])
1822
1823 dnl if we build from source tree, the man pages need @date@ and @version@
1824 dnl if this is a distro tarball, that was already done by makedist.sh
1825 AC_SUBST(version, [VERSION_MAJOR.VERSION_MINOR.VERSION_MICRO])
1826 AC_SUBST(date, [`date +'%b %e, %Y'`])
1827
1828 AC_CONFIG_FILES([Makefile doc/example.conf doc/libunbound.3 doc/unbound.8 doc/unbound-anchor.8 doc/unbound-checkconf.8 doc/unbound.conf.5 doc/unbound-control.8 doc/unbound-host.1 smallapp/unbound-control-setup.sh dnstap/dnstap_config.h dnscrypt/dnscrypt_config.h contrib/libunbound.pc contrib/unbound.socket contrib/unbound.service])
1829 AC_CONFIG_HEADER([config.h])
1830 AC_OUTPUT