lib/CMakeLists.txt

   1 set(LIBCXX_LIB_CMAKEFILES_DIR "${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}"  PARENT_SCOPE)
   2
   3 # Get sources
   4 file(GLOB LIBCXX_SOURCES ../src/*.cpp)
   5 if(WIN32)
   6   file(GLOB LIBCXX_WIN32_SOURCES ../src/support/win32/*.cpp)
   7   list(APPEND LIBCXX_SOURCES ${LIBCXX_WIN32_SOURCES})
   8 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "SunOS")
   9   file(GLOB LIBCXX_SOLARIS_SOURCES ../src/support/solaris/*.cpp)
  10   list(APPEND LIBCXX_SOURCES ${LIBCXX_SOLARIS_SOURCES})
  11 endif()
  12
  13 # Add all the headers to the project for IDEs.
  14 if (LIBCXX_CONFIGURE_IDE)
  15   file(GLOB_RECURSE LIBCXX_HEADERS ${CMAKE_CURRENT_SOURCE_DIR}/../include/*)
  16   if(WIN32)
  17     file( GLOB LIBCXX_WIN32_HEADERS ${CMAKE_CURRENT_SOURCE_DIR}/../include/support/win32/*.h)
  18     list(APPEND LIBCXX_HEADERS ${LIBCXX_WIN32_HEADERS})
  19   endif()
  20   # Force them all into the headers dir on MSVC, otherwise they end up at
  21   # project scope because they don't have extensions.
  22   if (MSVC_IDE)
  23     source_group("Header Files" FILES ${LIBCXX_HEADERS})
  24   endif()
  25 endif()
  26
  27 if(NOT LIBCXX_INSTALL_LIBRARY)
  28   set(exclude_from_all EXCLUDE_FROM_ALL)
  29 endif()
  30
  31 #if LIBCXX_CXX_ABI_LIBRARY_PATH is defined we want to add it to the search path.
  32 add_link_flags_if(LIBCXX_CXX_ABI_LIBRARY_PATH "-L${LIBCXX_CXX_ABI_LIBRARY_PATH}")
  33
  34 add_library_flags_if(LIBCXX_COVERAGE_LIBRARY "${LIBCXX_COVERAGE_LIBRARY}")
  35
  36 if (APPLE AND (LIBCXX_CXX_ABI_LIBNAME STREQUAL "libcxxabi" OR
  37                LIBCXX_CXX_ABI_LIBNAME STREQUAL "none"))
  38   set(LIBCXX_OSX_REEXPORT_SYSTEM_ABI_LIBRARY ON)
  39 endif()
  40
  41 if (LIBCXX_ENABLE_STATIC_ABI_LIBRARY)
  42   add_library_flags("-Wl,--whole-archive" "-Wl,-Bstatic")
  43   add_library_flags("${LIBCXX_CXX_ABI_LIBRARY}")
  44   add_library_flags("-Wl,-Bdynamic" "-Wl,--no-whole-archive")
  45 elseif (LIBCXX_OSX_REEXPORT_SYSTEM_ABI_LIBRARY)
  46   add_library_flags("${LIBCXX_CXX_ABI_LIBRARY}")
  47 else ()
  48  add_interface_library("${LIBCXX_CXX_ABI_LIBRARY}")
  49 endif()
  50
  51 if (APPLE AND LLVM_USE_SANITIZER)
  52   if (("${LLVM_USE_SANITIZER}" STREQUAL "Address") OR
  53       ("${LLVM_USE_SANITIZER}" STREQUAL "Address;Undefined") OR
  54       ("${LLVM_USE_SANITIZER}" STREQUAL "Undefined;Address"))
  55     set(LIBFILE "libclang_rt.asan_osx_dynamic.dylib")
  56   elseif("${LLVM_USE_SANITIZER}" STREQUAL "Undefined")
  57     set(LIBFILE "libclang_rt.ubsan_osx_dynamic.dylib")
  58   elseif("${LLVM_USE_SANITIZER}" STREQUAL "Thread")
  59     set(LIBFILE "libclang_rt.tsan_osx_dynamic.dylib")
  60   else()
  61     message(WARNING "LLVM_USE_SANITIZER=${LLVM_USE_SANITIZER} is not supported on OS X")
  62   endif()
  63   if (LIBFILE)
  64     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -print-file-name=lib OUTPUT_VARIABLE LIBDIR RESULT_VARIABLE Result)
  65     if (NOT ${Result} EQUAL "0")
  66       message(FATAL "Failed to find library resource directory")
  67     endif()
  68     string(STRIP "${LIBDIR}" LIBDIR)
  69     set(LIBDIR "${LIBDIR}/darwin/")
  70     if (NOT IS_DIRECTORY "${LIBDIR}")
  71       message(FATAL_ERROR "Cannot find compiler-rt directory on OS X required for LLVM_USE_SANITIZER")
  72     endif()
  73     set(LIBCXX_SANITIZER_LIBRARY "${LIBDIR}/${LIBFILE}")
  74     set(LIBCXX_SANITIZER_LIBRARY "${LIBCXX_SANITIZER_LIBRARY}" PARENT_SCOPE)
  75     message(STATUS "Manually linking compiler-rt library: ${LIBCXX_SANITIZER_LIBRARY}")
  76     add_library_flags("${LIBCXX_SANITIZER_LIBRARY}")
  77     add_link_flags("-Wl,-rpath,${LIBDIR}")
  78   endif()
  79 endif()
  80
  81 # Generate private library list.
  82 add_library_flags_if(LIBCXX_HAS_PTHREAD_LIB pthread)
  83 add_library_flags_if(LIBCXX_HAS_C_LIB c)
  84 add_library_flags_if(LIBCXX_HAS_M_LIB m)
  85 add_library_flags_if(LIBCXX_HAS_RT_LIB rt)
  86 add_library_flags_if(LIBCXX_HAS_GCC_S_LIB gcc_s)
  87 add_library_flags_if(LIBCXX_HAVE_CXX_ATOMICS_WITH_LIB atomic)
  88
  89 # Add the unwinder library.
  90 if (LIBCXXABI_USE_LLVM_UNWINDER)
  91   if (TARGET unwind_shared)
  92     add_interface_library(unwind_shared)
  93   elseif (TARGET unwind_static)
  94     add_interface_library(unwind_static)
  95   else()
  96     add_interface_library(unwind)
  97   endif()
  98 endif()
  99
 100 # Setup flags.
 101 if (NOT WIN32)
 102   add_flags_if_supported(-fPIC)
 103 endif()
 104 add_link_flags_if_supported(-nodefaultlibs)
 105
 106 if (LIBCXX_OSX_REEXPORT_SYSTEM_ABI_LIBRARY)
 107   if (NOT DEFINED LIBCXX_LIBCPPABI_VERSION)
 108     set(LIBCXX_LIBCPPABI_VERSION "2") # Default value
 109     execute_process(
 110       COMMAND xcrun --show-sdk-version
 111       OUTPUT_VARIABLE sdk_ver
 112       RESULT_VARIABLE res
 113       OUTPUT_STRIP_TRAILING_WHITESPACE)
 114     if (res EQUAL 0)
 115       message(STATUS "Found SDK version ${sdk_ver}")
 116       string(REPLACE "10." "" sdk_ver "${sdk_ver}")
 117       if (sdk_ver LESS 9)
 118         set(LIBCXX_LIBCPPABI_VERSION "")
 119       else()
 120         set(LIBCXX_LIBCPPABI_VERSION "2")
 121       endif()
 122     endif()
 123   endif()
 124
 125   if ( CMAKE_OSX_DEPLOYMENT_TARGET STREQUAL "10.6" )
 126     add_definitions(-D__STRICT_ANSI__)
 127     add_link_flags(
 128       "-compatibility_version 1"
 129       "-current_version 1"
 130       "-install_name /usr/lib/libc++.1.dylib"
 131       "-Wl,-reexport_library,/usr/lib/libc++abi.dylib"
 132       "-Wl,-unexported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libc++unexp.exp"
 133       "/usr/lib/libSystem.B.dylib")
 134   else()
 135     if (DEFINED CMAKE_OSX_SYSROOT AND NOT CMAKE_OSX_SYSROOT STREQUAL "")
 136       list(FIND CMAKE_OSX_ARCHITECTURES "armv7" OSX_HAS_ARMV7)
 137       if (NOT OSX_HAS_ARMV7 EQUAL -1)
 138         set(OSX_RE_EXPORT_LINE
 139           "${CMAKE_OSX_SYSROOT}/usr/lib/libc++abi.dylib"
 140           "-Wl,-reexported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libc++sjlj-abi.exp")
 141       else()
 142         set(OSX_RE_EXPORT_LINE
 143           "-Wl,-reexport_library,${CMAKE_OSX_SYSROOT}/usr/lib/libc++abi.dylib")
 144       endif()
 145     else()
 146       set(OSX_RE_EXPORT_LINE "/usr/lib/libc++abi.dylib -Wl,-reexported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libc++abi${LIBCXX_LIBCPPABI_VERSION}.exp")
 147     endif()
 148
 149     add_link_flags(
 150       "-compatibility_version 1"
 151       "-install_name /usr/lib/libc++.1.dylib"
 152       "-Wl,-unexported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libc++unexp.exp"
 153       "${OSX_RE_EXPORT_LINE}"
 154       "-Wl,-force_symbols_not_weak_list,${CMAKE_CURRENT_SOURCE_DIR}/notweak.exp"
 155       "-Wl,-force_symbols_weak_list,${CMAKE_CURRENT_SOURCE_DIR}/weak.exp")
 156   endif()
 157 endif()
 158
 159 split_list(LIBCXX_COMPILE_FLAGS)
 160 split_list(LIBCXX_LINK_FLAGS)
 161
 162 # Add a object library that contains the compiled source files.
 163 add_library(cxx_objects OBJECT ${exclude_from_all} ${LIBCXX_SOURCES} ${LIBCXX_HEADERS})
 164
 165 set_target_properties(cxx_objects
 166   PROPERTIES
 167     COMPILE_FLAGS "${LIBCXX_COMPILE_FLAGS}"
 168 )
 169
 170 set(LIBCXX_TARGETS)
 171
 172 # Build the shared library.
 173 if (LIBCXX_ENABLE_SHARED)
 174   add_library(cxx_shared SHARED $<TARGET_OBJECTS:cxx_objects>)
 175   target_link_libraries(cxx_shared ${LIBCXX_LIBRARIES})
 176   set_target_properties(cxx_shared
 177     PROPERTIES
 178       LINK_FLAGS    "${LIBCXX_LINK_FLAGS}"
 179       OUTPUT_NAME   "c++"
 180       VERSION       "${LIBCXX_ABI_VERSION}.0"
 181       SOVERSION     "${LIBCXX_ABI_VERSION}"
 182   )
 183   list(APPEND LIBCXX_TARGETS "cxx_shared")
 184 endif()
 185
 186 # Build the static library.
 187 if (LIBCXX_ENABLE_STATIC)
 188   add_library(cxx_static STATIC $<TARGET_OBJECTS:cxx_objects>)
 189   target_link_libraries(cxx_static ${LIBCXX_LIBRARIES})
 190   set_target_properties(cxx_static
 191     PROPERTIES
 192       LINK_FLAGS    "${LIBCXX_LINK_FLAGS}"
 193       OUTPUT_NAME   "c++"
 194   )
 195   list(APPEND LIBCXX_TARGETS "cxx_static")
 196   # Attempt to merge the libc++.a archive and the ABI library archive into one.
 197   if (LIBCXX_ENABLE_STATIC_ABI_LIBRARY)
 198     set(MERGE_ARCHIVES_SEARCH_PATHS "")
 199     if (LIBCXX_CXX_ABI_LIBRARY_PATH)
 200       set(MERGE_ARCHIVES_SEARCH_PATHS "-L${LIBCXX_CXX_ABI_LIBRARY_PATH}")
 201     endif()
 202     if (TARGET ${LIBCXX_CXX_ABI_LIBRARY})
 203       set(MERGE_ARCHIVES_ABI_TARGET "$<TARGET_LINKER_FILE:${LIBCXX_CXX_ABI_LIBRARY}>")
 204     else()
 205       set(MERGE_ARCHIVES_ABI_TARGET "lib${LIBCXX_CXX_ABI_LIBRARY}.a")
 206     endif()
 207     add_custom_command(TARGET cxx_static POST_BUILD
 208     COMMAND
 209       ${PYTHON_EXECUTABLE} ${LIBCXX_SOURCE_DIR}/utils/merge_archives.py
 210     ARGS
 211       -o $<TARGET_LINKER_FILE:cxx_static>
 212       "$<TARGET_LINKER_FILE:cxx_static>"
 213       "${MERGE_ARCHIVES_ABI_TARGET}"
 214       "${MERGE_ARCHIVES_SEARCH_PATHS}"
 215     WORKING_DIRECTORY ${LIBCXX_BUILD_DIR}
 216     )
 217   endif()
 218 endif()
 219
 220 # Add a meta-target for both libraries.
 221 add_custom_target(cxx DEPENDS ${LIBCXX_TARGETS})
 222
 223 if (LIBCXX_ENABLE_EXPERIMENTAL_LIBRARY)
 224   file(GLOB LIBCXX_EXPERIMENTAL_SOURCES ../src/experimental/*.cpp)
 225   if (LIBCXX_ENABLE_FILESYSTEM)
 226     file(GLOB LIBCXX_FILESYSTEM_SOURCES ../src/experimental/filesystem/*.cpp)
 227   endif()
 228   add_library(cxx_experimental STATIC ${LIBCXX_EXPERIMENTAL_SOURCES} ${LIBCXX_FILESYSTEM_SOURCES})
 229   if (LIBCXX_ENABLE_SHARED)
 230     target_link_libraries(cxx_experimental cxx_shared)
 231   else()
 232     target_link_libraries(cxx_experimental cxx_static)
 233   endif()
 234
 235   set(experimental_flags "${LIBCXX_COMPILE_FLAGS}")
 236   check_flag_supported(-std=c++14)
 237   if (NOT MSVC AND LIBCXX_SUPPORTS_STD_EQ_CXX14_FLAG)
 238     string(REPLACE "-std=c++11" "-std=c++14" experimental_flags "${LIBCXX_COMPILE_FLAGS}")
 239   endif()
 240   set_target_properties(cxx_experimental
 241     PROPERTIES
 242       COMPILE_FLAGS "${experimental_flags}"
 243       OUTPUT_NAME   "c++experimental"
 244   )
 245 endif()
 246
 247 if (LIBCXX_HAS_EXTERNAL_THREAD_API)
 248   file(GLOB LIBCXX_EXTERNAL_THREADING_SUPPORT_SOURCES ../test/support/external_threads.cpp)
 249
 250   if (LIBCXX_ENABLE_SHARED)
 251     add_library(cxx_external_threads SHARED ${LIBCXX_EXTERNAL_THREADING_SUPPORT_SOURCES})
 252   else()
 253     add_library(cxx_external_threads STATIC ${LIBCXX_EXTERNAL_THREADING_SUPPORT_SOURCES})
 254   endif()
 255
 256   set_target_properties(cxx_external_threads
 257     PROPERTIES
 258       LINK_FLAGS    "${LIBCXX_LINK_FLAGS}"
 259       COMPILE_FLAGS "${LIBCXX_COMPILE_FLAGS}"
 260       OUTPUT_NAME   "c++external_threads"
 261   )
 262 endif()
 263
 264 # Generate a linker script inplace of a libc++.so symlink. Rerun this command
 265 # after cxx builds.
 266 if (LIBCXX_ENABLE_SHARED AND LIBCXX_ENABLE_ABI_LINKER_SCRIPT)
 267   # Get the name of the ABI library and handle the case where CXXABI_LIBNAME
 268   # is a target name and not a library. Ex cxxabi_shared.
 269   set(LIBCXX_INTERFACE_LIBRARY_NAMES)
 270   foreach(lib ${LIBCXX_INTERFACE_LIBRARIES})
 271     # FIXME: Handle cxxabi_static and unwind_static.
 272     if (TARGET ${lib})
 273       list(APPEND LIBCXX_INTERFACE_LIBRARY_NAMES "$<TARGET_PROPERTY:${lib},OUTPUT_NAME>")
 274     else()
 275       list(APPEND LIBCXX_INTERFACE_LIBRARY_NAMES "${lib}")
 276     endif()
 277   endforeach()
 278   #split_list(LIBCXX_INTERFACE_LIBRARY_NAMES)
 279   # Generate a linker script inplace of a libc++.so symlink. Rerun this command
 280   # after cxx builds.
 281   add_custom_command(TARGET cxx_shared POST_BUILD
 282     COMMAND
 283       ${PYTHON_EXECUTABLE} ${LIBCXX_SOURCE_DIR}/utils/gen_link_script/gen_link_script.py
 284     ARGS
 285       "$<TARGET_LINKER_FILE:cxx_shared>"
 286       ${LIBCXX_INTERFACE_LIBRARY_NAMES}
 287     WORKING_DIRECTORY ${LIBCXX_BUILD_DIR}
 288   )
 289 endif()
 290
 291 if (LIBCXX_INSTALL_LIBRARY)
 292   if (LIBCXX_INSTALL_EXPERIMENTAL_LIBRARY)
 293     set(experimental_lib cxx_experimental)
 294   endif()
 295   install(TARGETS ${LIBCXX_TARGETS} ${experimental_lib}
 296     LIBRARY DESTINATION lib${LIBCXX_LIBDIR_SUFFIX} COMPONENT cxx
 297     ARCHIVE DESTINATION lib${LIBCXX_LIBDIR_SUFFIX} COMPONENT cxx
 298     )
 299   # NOTE: This install command must go after the cxx install command otherwise
 300   # it will not be executed after the library symlinks are installed.
 301   if (LIBCXX_ENABLE_SHARED AND LIBCXX_ENABLE_ABI_LINKER_SCRIPT)
 302     # Replace the libc++ filename with $<TARGET_LINKER_FILE:cxx>
 303     # after we required CMake 3.0.
 304     install(FILES "${LIBCXX_LIBRARY_DIR}/libc++${CMAKE_SHARED_LIBRARY_SUFFIX}"
 305       DESTINATION lib${LIBCXX_LIBDIR_SUFFIX}
 306       COMPONENT libcxx)
 307   endif()
 308 endif()
 309
 310 if (NOT CMAKE_CONFIGURATION_TYPES AND (LIBCXX_INSTALL_LIBRARY OR
 311                                        LIBCXX_INSTALL_HEADERS))
 312     if(LIBCXX_INSTALL_LIBRARY)
 313       set(lib_install_target cxx)
 314     endif()
 315     if (LIBCXX_INSTALL_EXPERIMENTAL_LIBRARY)
 316       set(experimental_lib_install_target cxx_experimental)
 317     endif()
 318     if(LIBCXX_INSTALL_HEADERS)
 319       set(header_install_target install-cxx-headers)
 320     endif()
 321     add_custom_target(install-cxx
 322                       DEPENDS ${lib_install_target}
 323                               ${experimental_lib_install_target}
 324                               ${header_install_target}
 325                       COMMAND "${CMAKE_COMMAND}"
 326                       -DCMAKE_INSTALL_COMPONENT=cxx
 327                       -P "${LIBCXX_BINARY_DIR}/cmake_install.cmake")
 328     add_custom_target(install-libcxx DEPENDS install-cxx)
 329 endif()