lib/CMakeLists.txt

   1 set(LIBCXX_LIB_CMAKEFILES_DIR "${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}"  PARENT_SCOPE)
   2
   3 # Get sources
   4 file(GLOB LIBCXX_SOURCES ../src/*.cpp)
   5 if(WIN32)
   6   file(GLOB LIBCXX_WIN32_SOURCES ../src/support/win32/*.cpp)
   7   list(APPEND LIBCXX_SOURCES ${LIBCXX_WIN32_SOURCES})
   8 elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "SunOS")
   9   file(GLOB LIBCXX_SOLARIS_SOURCES ../src/support/solaris/*.cpp)
  10   list(APPEND LIBCXX_SOURCES ${LIBCXX_SOLARIS_SOURCES})
  11 endif()
  12
  13 # Add all the headers to the project for IDEs.
  14 if (LIBCXX_CONFIGURE_IDE)
  15   file(GLOB_RECURSE LIBCXX_HEADERS ${CMAKE_CURRENT_SOURCE_DIR}/../include/*)
  16   if(WIN32)
  17     file( GLOB LIBCXX_WIN32_HEADERS ${CMAKE_CURRENT_SOURCE_DIR}/../include/support/win32/*.h)
  18     list(APPEND LIBCXX_HEADERS ${LIBCXX_WIN32_HEADERS})
  19   endif()
  20   # Force them all into the headers dir on MSVC, otherwise they end up at
  21   # project scope because they don't have extensions.
  22   if (MSVC_IDE)
  23     source_group("Header Files" FILES ${LIBCXX_HEADERS})
  24   endif()
  25 endif()
  26
  27 if(NOT LIBCXX_INSTALL_LIBRARY)
  28   set(exclude_from_all EXCLUDE_FROM_ALL)
  29 endif()
  30
  31 # If LIBCXX_CXX_ABI_LIBRARY_PATH is defined we want to add it to the search path.
  32 add_link_flags_if(LIBCXX_CXX_ABI_LIBRARY_PATH
  33                   "${CMAKE_LIBRARY_PATH_FLAG}${LIBCXX_CXX_ABI_LIBRARY_PATH}")
  34
  35 add_library_flags_if(LIBCXX_COVERAGE_LIBRARY "${LIBCXX_COVERAGE_LIBRARY}")
  36
  37 if (APPLE AND (LIBCXX_CXX_ABI_LIBNAME STREQUAL "libcxxabi" OR
  38                LIBCXX_CXX_ABI_LIBNAME STREQUAL "default"))
  39   set(LIBCXX_OSX_REEXPORT_SYSTEM_ABI_LIBRARY ON)
  40 endif()
  41
  42 if (LIBCXX_ENABLE_STATIC_ABI_LIBRARY)
  43   add_library_flags("-Wl,--whole-archive" "-Wl,-Bstatic")
  44   add_library_flags("${LIBCXX_CXX_ABI_LIBRARY}")
  45   add_library_flags("-Wl,-Bdynamic" "-Wl,--no-whole-archive")
  46 elseif (LIBCXX_OSX_REEXPORT_SYSTEM_ABI_LIBRARY)
  47   add_library_flags("${LIBCXX_CXX_ABI_LIBRARY}")
  48 else ()
  49  add_interface_library("${LIBCXX_CXX_ABI_LIBRARY}")
  50 endif()
  51
  52 if (APPLE AND LLVM_USE_SANITIZER)
  53   if (("${LLVM_USE_SANITIZER}" STREQUAL "Address") OR
  54       ("${LLVM_USE_SANITIZER}" STREQUAL "Address;Undefined") OR
  55       ("${LLVM_USE_SANITIZER}" STREQUAL "Undefined;Address"))
  56     set(LIBFILE "libclang_rt.asan_osx_dynamic.dylib")
  57   elseif("${LLVM_USE_SANITIZER}" STREQUAL "Undefined")
  58     set(LIBFILE "libclang_rt.ubsan_osx_dynamic.dylib")
  59   elseif("${LLVM_USE_SANITIZER}" STREQUAL "Thread")
  60     set(LIBFILE "libclang_rt.tsan_osx_dynamic.dylib")
  61   else()
  62     message(WARNING "LLVM_USE_SANITIZER=${LLVM_USE_SANITIZER} is not supported on OS X")
  63   endif()
  64   if (LIBFILE)
  65     execute_process(COMMAND ${CMAKE_CXX_COMPILER} -print-file-name=lib OUTPUT_VARIABLE LIBDIR RESULT_VARIABLE Result)
  66     if (NOT ${Result} EQUAL "0")
  67       message(FATAL "Failed to find library resource directory")
  68     endif()
  69     string(STRIP "${LIBDIR}" LIBDIR)
  70     set(LIBDIR "${LIBDIR}/darwin/")
  71     if (NOT IS_DIRECTORY "${LIBDIR}")
  72       message(FATAL_ERROR "Cannot find compiler-rt directory on OS X required for LLVM_USE_SANITIZER")
  73     endif()
  74     set(LIBCXX_SANITIZER_LIBRARY "${LIBDIR}/${LIBFILE}")
  75     set(LIBCXX_SANITIZER_LIBRARY "${LIBCXX_SANITIZER_LIBRARY}" PARENT_SCOPE)
  76     message(STATUS "Manually linking compiler-rt library: ${LIBCXX_SANITIZER_LIBRARY}")
  77     add_library_flags("${LIBCXX_SANITIZER_LIBRARY}")
  78     add_link_flags("-Wl,-rpath,${LIBDIR}")
  79   endif()
  80 endif()
  81
  82 # Generate private library list.
  83 add_library_flags_if(LIBCXX_HAS_PTHREAD_LIB pthread)
  84 add_library_flags_if(LIBCXX_HAS_C_LIB c)
  85 add_library_flags_if(LIBCXX_HAS_M_LIB m)
  86 add_library_flags_if(LIBCXX_HAS_RT_LIB rt)
  87 add_library_flags_if(LIBCXX_HAS_GCC_S_LIB gcc_s)
  88 add_library_flags_if(LIBCXX_HAVE_CXX_ATOMICS_WITH_LIB atomic)
  89
  90 # Add the unwinder library.
  91 if (LIBCXXABI_USE_LLVM_UNWINDER)
  92   if (TARGET unwind_shared)
  93     add_interface_library(unwind_shared)
  94   elseif (TARGET unwind_static)
  95     add_interface_library(unwind_static)
  96   else()
  97     add_interface_library(unwind)
  98   endif()
  99 endif()
 100
 101 # Setup flags.
 102 if (NOT WIN32)
 103   add_flags_if_supported(-fPIC)
 104 endif()
 105 add_link_flags_if_supported(-nodefaultlibs)
 106
 107 if (LIBCXX_OSX_REEXPORT_SYSTEM_ABI_LIBRARY)
 108   if (NOT DEFINED LIBCXX_LIBCPPABI_VERSION)
 109     set(LIBCXX_LIBCPPABI_VERSION "2") # Default value
 110     execute_process(
 111       COMMAND xcrun --show-sdk-version
 112       OUTPUT_VARIABLE sdk_ver
 113       RESULT_VARIABLE res
 114       OUTPUT_STRIP_TRAILING_WHITESPACE)
 115     if (res EQUAL 0)
 116       message(STATUS "Found SDK version ${sdk_ver}")
 117       string(REPLACE "10." "" sdk_ver "${sdk_ver}")
 118       if (sdk_ver LESS 9)
 119         set(LIBCXX_LIBCPPABI_VERSION "")
 120       else()
 121         set(LIBCXX_LIBCPPABI_VERSION "2")
 122       endif()
 123     endif()
 124   endif()
 125
 126   if ( CMAKE_OSX_DEPLOYMENT_TARGET STREQUAL "10.6" )
 127     add_definitions(-D__STRICT_ANSI__)
 128     add_link_flags(
 129       "-compatibility_version 1"
 130       "-current_version 1"
 131       "-install_name /usr/lib/libc++.1.dylib"
 132       "-Wl,-reexport_library,/usr/lib/libc++abi.dylib"
 133       "-Wl,-unexported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libc++unexp.exp"
 134       "/usr/lib/libSystem.B.dylib")
 135   else()
 136     if (DEFINED CMAKE_OSX_SYSROOT AND NOT CMAKE_OSX_SYSROOT STREQUAL "")
 137       list(FIND CMAKE_OSX_ARCHITECTURES "armv7" OSX_HAS_ARMV7)
 138       if (NOT OSX_HAS_ARMV7 EQUAL -1)
 139         set(OSX_RE_EXPORT_LINE
 140           "${CMAKE_OSX_SYSROOT}/usr/lib/libc++abi.dylib"
 141           "-Wl,-reexported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libc++sjlj-abi.exp")
 142       else()
 143         set(OSX_RE_EXPORT_LINE
 144           "-Wl,-reexport_library,${CMAKE_OSX_SYSROOT}/usr/lib/libc++abi.dylib")
 145       endif()
 146     else()
 147       set(OSX_RE_EXPORT_LINE "/usr/lib/libc++abi.dylib -Wl,-reexported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libc++abi${LIBCXX_LIBCPPABI_VERSION}.exp")
 148     endif()
 149
 150     add_link_flags(
 151       "-compatibility_version 1"
 152       "-install_name /usr/lib/libc++.1.dylib"
 153       "-Wl,-unexported_symbols_list,${CMAKE_CURRENT_SOURCE_DIR}/libc++unexp.exp"
 154       "${OSX_RE_EXPORT_LINE}"
 155       "-Wl,-force_symbols_not_weak_list,${CMAKE_CURRENT_SOURCE_DIR}/notweak.exp"
 156       "-Wl,-force_symbols_weak_list,${CMAKE_CURRENT_SOURCE_DIR}/weak.exp")
 157   endif()
 158 endif()
 159
 160 split_list(LIBCXX_COMPILE_FLAGS)
 161 split_list(LIBCXX_LINK_FLAGS)
 162
 163 # Add a object library that contains the compiled source files.
 164 add_library(cxx_objects OBJECT ${exclude_from_all} ${LIBCXX_SOURCES} ${LIBCXX_HEADERS})
 165 if(WIN32 AND NOT MINGW)
 166   target_compile_definitions(cxx_objects
 167                              PRIVATE
 168                                # Ignore the -MSC_VER mismatch, as we may build
 169                                # with a different compatibility version.
 170                                _ALLOW_MSC_VER_MISMATCH
 171                                # Don't check the msvcprt iterator debug levels
 172                                # as we will define the iterator types; libc++
 173                                # uses a different macro to identify the debug
 174                                # level.
 175                                _ALLOW_ITERATOR_DEBUG_LEVEL_MISMATCH
 176                                # We are building the c++ runtime, don't pull in
 177                                # msvcprt.
 178                                _CRTBLD
 179                                # Don't warn on the use of "deprecated"
 180                                # "insecure" functions which are standards
 181                                # specified.
 182                                _CRT_SECURE_NO_WARNINGS
 183                                # Use the ISO conforming behaviour for conversion
 184                                # in printf, scanf.
 185                                _CRT_STDIO_ISO_WIDE_SPECIFIERS)
 186 endif()
 187
 188 set_target_properties(cxx_objects
 189   PROPERTIES
 190     COMPILE_FLAGS "${LIBCXX_COMPILE_FLAGS}"
 191 )
 192
 193 set(LIBCXX_TARGETS)
 194
 195 # Build the shared library.
 196 if (LIBCXX_ENABLE_SHARED)
 197   add_library(cxx_shared SHARED $<TARGET_OBJECTS:cxx_objects>)
 198   target_link_libraries(cxx_shared ${LIBCXX_LIBRARIES})
 199   set_target_properties(cxx_shared
 200     PROPERTIES
 201       LINK_FLAGS    "${LIBCXX_LINK_FLAGS}"
 202       OUTPUT_NAME   "c++"
 203       VERSION       "${LIBCXX_ABI_VERSION}.0"
 204       SOVERSION     "${LIBCXX_ABI_VERSION}"
 205   )
 206   list(APPEND LIBCXX_TARGETS "cxx_shared")
 207   if(WIN32 AND NOT MINGW AND NOT "${CMAKE_HOST_SYSTEM_NAME}" STREQUAL "Windows")
 208     # Since we most likely do not have a mt.exe replacement, disable the
 209     # manifest bundling.  This allows a normal cmake invocation to pass which
 210     # will attempt to use the manifest tool to generate the bundled manifest
 211     set_target_properties(cxx_shared PROPERTIES
 212                           APPEND_STRING PROPERTY LINK_FLAGS " /MANIFEST:NO")
 213   endif()
 214 endif()
 215
 216 # Build the static library.
 217 if (LIBCXX_ENABLE_STATIC)
 218   add_library(cxx_static STATIC $<TARGET_OBJECTS:cxx_objects>)
 219   target_link_libraries(cxx_static ${LIBCXX_LIBRARIES})
 220   set_target_properties(cxx_static
 221     PROPERTIES
 222       LINK_FLAGS    "${LIBCXX_LINK_FLAGS}"
 223       OUTPUT_NAME   "c++"
 224   )
 225   list(APPEND LIBCXX_TARGETS "cxx_static")
 226   # Attempt to merge the libc++.a archive and the ABI library archive into one.
 227   if (LIBCXX_ENABLE_STATIC_ABI_LIBRARY)
 228     set(MERGE_ARCHIVES_SEARCH_PATHS "")
 229     if (LIBCXX_CXX_ABI_LIBRARY_PATH)
 230       set(MERGE_ARCHIVES_SEARCH_PATHS "-L${LIBCXX_CXX_ABI_LIBRARY_PATH}")
 231     endif()
 232     if (TARGET ${LIBCXX_CXX_ABI_LIBRARY})
 233       set(MERGE_ARCHIVES_ABI_TARGET "$<TARGET_LINKER_FILE:${LIBCXX_CXX_ABI_LIBRARY}>")
 234     else()
 235       set(MERGE_ARCHIVES_ABI_TARGET
 236           "${CMAKE_STATIC_LIBRARY_PREFIX}${LIBCXX_CXX_ABI_LIBRARY}${CMAKE_STATIC_LIBRARY_SUFFIX}")
 237     endif()
 238     add_custom_command(TARGET cxx_static POST_BUILD
 239     COMMAND
 240       ${PYTHON_EXECUTABLE} ${LIBCXX_SOURCE_DIR}/utils/merge_archives.py
 241     ARGS
 242       -o $<TARGET_LINKER_FILE:cxx_static>
 243       "$<TARGET_LINKER_FILE:cxx_static>"
 244       "${MERGE_ARCHIVES_ABI_TARGET}"
 245       "${MERGE_ARCHIVES_SEARCH_PATHS}"
 246     WORKING_DIRECTORY ${LIBCXX_BUILD_DIR}
 247     )
 248   endif()
 249 endif()
 250
 251 # Add a meta-target for both libraries.
 252 add_custom_target(cxx DEPENDS ${LIBCXX_TARGETS})
 253
 254 if (LIBCXX_ENABLE_EXPERIMENTAL_LIBRARY)
 255   file(GLOB LIBCXX_EXPERIMENTAL_SOURCES ../src/experimental/*.cpp)
 256   if (LIBCXX_ENABLE_FILESYSTEM)
 257     file(GLOB LIBCXX_FILESYSTEM_SOURCES ../src/experimental/filesystem/*.cpp)
 258   endif()
 259   add_library(cxx_experimental STATIC ${LIBCXX_EXPERIMENTAL_SOURCES} ${LIBCXX_FILESYSTEM_SOURCES})
 260   if (LIBCXX_ENABLE_SHARED)
 261     target_link_libraries(cxx_experimental cxx_shared)
 262   else()
 263     target_link_libraries(cxx_experimental cxx_static)
 264   endif()
 265
 266   set(experimental_flags "${LIBCXX_COMPILE_FLAGS}")
 267   check_flag_supported(-std=c++14)
 268   if (NOT MSVC AND LIBCXX_SUPPORTS_STD_EQ_CXX14_FLAG)
 269     string(REPLACE "-std=c++11" "-std=c++14" experimental_flags "${LIBCXX_COMPILE_FLAGS}")
 270   endif()
 271   set_target_properties(cxx_experimental
 272     PROPERTIES
 273       COMPILE_FLAGS "${experimental_flags}"
 274       OUTPUT_NAME   "c++experimental"
 275   )
 276 endif()
 277
 278 if (LIBCXX_BUILD_EXTERNAL_THREAD_LIBRARY)
 279   file(GLOB LIBCXX_EXTERNAL_THREADING_SUPPORT_SOURCES ../test/support/external_threads.cpp)
 280
 281   if (LIBCXX_ENABLE_SHARED)
 282     add_library(cxx_external_threads SHARED ${LIBCXX_EXTERNAL_THREADING_SUPPORT_SOURCES})
 283   else()
 284     add_library(cxx_external_threads STATIC ${LIBCXX_EXTERNAL_THREADING_SUPPORT_SOURCES})
 285   endif()
 286
 287   set_target_properties(cxx_external_threads
 288     PROPERTIES
 289       LINK_FLAGS    "${LIBCXX_LINK_FLAGS}"
 290       COMPILE_FLAGS "${LIBCXX_COMPILE_FLAGS}"
 291       OUTPUT_NAME   "c++external_threads"
 292   )
 293 endif()
 294
 295 # Generate a linker script inplace of a libc++.so symlink. Rerun this command
 296 # after cxx builds.
 297 if (LIBCXX_ENABLE_SHARED AND LIBCXX_ENABLE_ABI_LINKER_SCRIPT)
 298   # Get the name of the ABI library and handle the case where CXXABI_LIBNAME
 299   # is a target name and not a library. Ex cxxabi_shared.
 300   set(LIBCXX_INTERFACE_LIBRARY_NAMES)
 301   foreach(lib ${LIBCXX_INTERFACE_LIBRARIES})
 302     # FIXME: Handle cxxabi_static and unwind_static.
 303     if (TARGET ${lib})
 304       list(APPEND LIBCXX_INTERFACE_LIBRARY_NAMES "$<TARGET_PROPERTY:${lib},OUTPUT_NAME>")
 305     else()
 306       list(APPEND LIBCXX_INTERFACE_LIBRARY_NAMES "${lib}")
 307     endif()
 308   endforeach()
 309   #split_list(LIBCXX_INTERFACE_LIBRARY_NAMES)
 310   # Generate a linker script inplace of a libc++.so symlink. Rerun this command
 311   # after cxx builds.
 312   add_custom_command(TARGET cxx_shared POST_BUILD
 313     COMMAND
 314       ${PYTHON_EXECUTABLE} ${LIBCXX_SOURCE_DIR}/utils/gen_link_script/gen_link_script.py
 315     ARGS
 316       "$<TARGET_LINKER_FILE:cxx_shared>"
 317       ${LIBCXX_INTERFACE_LIBRARY_NAMES}
 318     WORKING_DIRECTORY ${LIBCXX_BUILD_DIR}
 319   )
 320 endif()
 321
 322 if (LIBCXX_INSTALL_LIBRARY)
 323   if (LIBCXX_INSTALL_EXPERIMENTAL_LIBRARY)
 324     set(experimental_lib cxx_experimental)
 325   endif()
 326   install(TARGETS ${LIBCXX_TARGETS} ${experimental_lib}
 327     LIBRARY DESTINATION lib${LIBCXX_LIBDIR_SUFFIX} COMPONENT cxx
 328     ARCHIVE DESTINATION lib${LIBCXX_LIBDIR_SUFFIX} COMPONENT cxx
 329     )
 330   # NOTE: This install command must go after the cxx install command otherwise
 331   # it will not be executed after the library symlinks are installed.
 332   if (LIBCXX_ENABLE_SHARED AND LIBCXX_ENABLE_ABI_LINKER_SCRIPT)
 333     # Replace the libc++ filename with $<TARGET_LINKER_FILE:cxx>
 334     # after we required CMake 3.0.
 335     install(FILES "${LIBCXX_LIBRARY_DIR}/libc++${CMAKE_SHARED_LIBRARY_SUFFIX}"
 336       DESTINATION lib${LIBCXX_LIBDIR_SUFFIX}
 337       COMPONENT libcxx)
 338   endif()
 339 endif()
 340
 341 if (NOT CMAKE_CONFIGURATION_TYPES AND (LIBCXX_INSTALL_LIBRARY OR
 342                                        LIBCXX_INSTALL_HEADERS))
 343     if(LIBCXX_INSTALL_LIBRARY)
 344       set(lib_install_target cxx)
 345     endif()
 346     if (LIBCXX_INSTALL_EXPERIMENTAL_LIBRARY)
 347       set(experimental_lib_install_target cxx_experimental)
 348     endif()
 349     if(LIBCXX_INSTALL_HEADERS)
 350       set(header_install_target install-cxx-headers)
 351     endif()
 352     add_custom_target(install-cxx
 353                       DEPENDS ${lib_install_target}
 354                               ${experimental_lib_install_target}
 355                               ${header_install_target}
 356                       COMMAND "${CMAKE_COMMAND}"
 357                       -DCMAKE_INSTALL_COMPONENT=cxx
 358                       -P "${LIBCXX_BINARY_DIR}/cmake_install.cmake")
 359     add_custom_target(install-libcxx DEPENDS install-cxx)
 360 endif()