lib/libc/alpha/gen/setjmp.S

   1 /*      $NetBSD: setjmp.S,v 1.3 1997/12/05 02:06:27 thorpej Exp $       */
   2
   3 /*
   4  * Copyright (c) 1994, 1995 Carnegie-Mellon University.
   5  * All rights reserved.
   6  *
   7  * Author: Chris G. Demetriou
   8  *
   9  * Permission to use, copy, modify and distribute this software and
  10  * its documentation is hereby granted, provided that both the copyright
  11  * notice and this permission notice appear in all copies of the
  12  * software, derivative works or modified versions, and any portions
  13  * thereof, and that both notices appear in supporting documentation.
  14  *
  15  * CARNEGIE MELLON ALLOWS FREE USE OF THIS SOFTWARE IN ITS "AS IS"
  16  * CONDITION.  CARNEGIE MELLON DISCLAIMS ANY LIABILITY OF ANY KIND
  17  * FOR ANY DAMAGES WHATSOEVER RESULTING FROM THE USE OF THIS SOFTWARE.
  18  *
  19  * Carnegie Mellon requests users of this software to return to
  20  *
  21  *  Software Distribution Coordinator  or  Software.Distribution@CS.CMU.EDU
  22  *  School of Computer Science
  23  *  Carnegie Mellon University
  24  *  Pittsburgh PA 15213-3890
  25  *
  26  * any improvements or extensions that they make and grant Carnegie the
  27  * rights to redistribute these changes.
  28  *
  29  * $FreeBSD$
  30  */
  31
  32 #include "SYS.h"
  33
  34 /*
  35  * C library -- setjmp, longjmp
  36  *
  37  *      longjmp(a,v)
  38  * will generate a "return(v)" from
  39  * the last call to
  40  *      setjmp(a)
  41  * by restoring registers from the stack,
  42  * and the previous signal state.
  43  */
  44
  45         .set    noreorder
  46
  47 LEAF(setjmp, 1)
  48         LDGP(pv)
  49         stq     ra, (2 * 8)(a0)                 /* sc_pc = return address */
  50         stq     s0, (( 9 + 4) * 8)(a0)          /* saved bits of sc_regs */
  51         stq     s1, ((10 + 4) * 8)(a0)
  52         stq     s2, ((11 + 4) * 8)(a0)
  53         stq     s3, ((12 + 4) * 8)(a0)
  54         stq     s4, ((13 + 4) * 8)(a0)
  55         stq     s5, ((14 + 4) * 8)(a0)
  56         stq     s6, ((15 + 4) * 8)(a0)
  57         stq     ra, ((26 + 4) * 8)(a0)
  58         stq     sp, ((30 + 4) * 8)(a0)
  59
  60         /*
  61          * get signal information
  62          */
  63         mov     a0, s0                          /* squirrel away ptr to sc */
  64
  65         /* see what's blocked */
  66         lda     a2, (71 * 8)(a0)                /* oset: sc_reserved */
  67         mov     zero, a1                        /* set:  NULL */
  68         addq    a1, 1, a0                       /* how:  SIG_BLOCK */
  69         PCALL(sigprocmask)                      /* see what's blocked */
  70
  71         lda     sp, -24(sp)                     /* sizeof struct sigaltstack */
  72         mov     zero, a0
  73         mov     sp, a1
  74         PCALL(sigaltstack)
  75         ldl     t0, 16(sp)                      /* offset of ss_flags */
  76         lda     sp, 24(sp)                      /* sizeof struct sigaltstack */
  77         ldq     ra, ((26 + 4) * 8)(s0)          /* restore return address */
  78         blt     v0, botch                       /* check for error */
  79         and     t0, 0x1, t0                     /* get SA_ONSTACK flag */
  80         stq     t0, (0 * 8)(s0)                 /* and save it in sc_onstack */
  81         /*
  82          * Restore old s0 and a0, and continue saving registers
  83          */
  84         mov     s0, a0
  85         ldq     s0, (( 9 + 4) * 8)(a0)
  86
  87         ldiq    t0, 0xacedbade                  /* sigcontext magic number */
  88         stq     t0, ((31 + 4) * 8)(a0)          /* magic in sc_regs[31] */
  89         /* Too bad we can't check if we actually used FP */
  90         ldiq    t0, 1
  91         stq     t0, (36 * 8)(a0)                /* say we've used FP.  */
  92         stt     fs0, ((2 + 37) * 8)(a0)         /* saved bits of sc_fpregs */
  93         stt     fs1, ((3 + 37) * 8)(a0)
  94         stt     fs2, ((4 + 37) * 8)(a0)
  95         stt     fs3, ((5 + 37) * 8)(a0)
  96         stt     fs4, ((6 + 37) * 8)(a0)
  97         stt     fs5, ((7 + 37) * 8)(a0)
  98         stt     fs6, ((8 + 37) * 8)(a0)
  99         stt     fs7, ((9 + 37) * 8)(a0)
 100         mf_fpcr ft0                             /* get FP control reg */
 101         stt     ft0, (69 * 8)(a0)               /* and store it in sc_fpcr */
 102         stq     zero, (70 * 8)(a0)              /* FP software control XXX */
 103         stq     zero, (71 * 8)(a0)              /* sc_reserved[0] */
 104         stq     zero, (72 * 8)(a0)              /* sc_reserved[1] */
 105         stq     zero, (73 * 8)(a0)              /* sc_xxx[0] */
 106         stq     zero, (74 * 8)(a0)              /* sc_xxx[1] */
 107         stq     zero, (75 * 8)(a0)              /* sc_xxx[2] */
 108         stq     zero, (76 * 8)(a0)              /* sc_xxx[3] */
 109         stq     zero, (77 * 8)(a0)              /* sc_xxx[4] */
 110         stq     zero, (78 * 8)(a0)              /* sc_xxx[5] */
 111         stq     zero, (79 * 8)(a0)              /* sc_xxx[6] */
 112         stq     zero, (80 * 8)(a0)              /* sc_xxx[7] */
 113
 114         mov     zero, v0                        /* return zero */
 115         RET
 116 END(setjmp)
 117
 118 #ifdef _THREAD_SAFE
 119 LEAF(__longjmp, 2)
 120 #else
 121 XLEAF(__longjmp, 2)
 122 LEAF(longjmp, 2)
 123 #endif
 124         LDGP(pv)
 125         stq     a1, (( 0 + 4) * 8)(a0)          /* save return value */
 126         PCALL(sigreturn)                        /* use sigreturn to return */
 127
 128 botch:
 129         CALL(longjmperror)
 130         CALL(abort)
 131         RET                                     /* "can't" get here... */
 132 #ifdef _THREAD_SAFE
 133 END(__longjmp)
 134 #else
 135 END(longjmp)
 136 #endif