lib/libc/amd64/gen/sigsetjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  *      @(#)setjmp.s    5.1 (Berkeley) 4/23/90"
  37  */
  38
  39 #if defined(LIBC_SCCS) && !defined(lint)
  40         .text
  41         .asciz "$Id: sigsetjmp.S,v 1.1 1993/12/05 13:01:05 ats Exp $"
  42 #endif /* LIBC_SCCS and not lint */
  43 #include <machine/asm.h>
  44 __FBSDID("$FreeBSD$");
  45
  46 #include "SYS.h"
  47
  48 /*-
  49  * TODO:
  50  *      Rename sigsetjmp to __sigsetjmp and siglongjmp to __siglongjmp,
  51  *      remove the other *jmp functions and define everything in terms
  52  *      of the renamed functions.  This requires compiler support for
  53  *      the renamed functions (introduced in gcc-2.5.3; previous versions
  54  *      only supported *jmp with 0 or 1 leading underscores).
  55  *
  56  *      Restore _all_ the registers and the signal mask atomically.  Can
  57  *      use sigreturn() if sigreturn() works.
  58  */
  59
  60 ENTRY(sigsetjmp)
  61         movl    %esi,88(%rdi)           /* 11; savemask */
  62         testl   %esi,%esi
  63         jz      2f
  64         pushq   %rdi
  65         movq    %rdi,%rcx
  66         movq    $1,%rdi                 /* SIG_BLOCK       */
  67         movq    $0,%rsi                 /* (sigset_t*)set  */
  68         leaq    72(%rcx),%rdx           /* 9,10 (sigset_t*)oset */
  69         call    PIC_PLT(CNAME(_sigprocmask))
  70         popq    %rdi
  71 2:      movq    %rdi,%rcx
  72         movq    0(%rsp),%rdx            /* retval */
  73         movq    %rdx, 0(%rcx)           /* 0; retval */
  74         movq    %rbx, 8(%rcx)           /* 1; rbx */
  75         movq    %rsp,16(%rcx)           /* 2; rsp */
  76         movq    %rbp,24(%rcx)           /* 3; rbp */
  77         movq    %r12,32(%rcx)           /* 4; r12 */
  78         movq    %r13,40(%rcx)           /* 5; r13 */
  79         movq    %r14,48(%rcx)           /* 6; r14 */
  80         movq    %r15,56(%rcx)           /* 7; r15 */
  81         fnstcw  64(%rcx)                /* 8; fpu cw */
  82         xorq    %rax,%rax
  83         ret
  84
  85         .weak CNAME(siglongjmp)
  86         .set CNAME(siglongjmp),CNAME(__siglongjmp)
  87 ENTRY(__siglongjmp)
  88         cmpl    $0,88(%rdi)
  89         jz      2f
  90         movq    %rdi,%rdx
  91         pushq   %rdi
  92         pushq   %rsi
  93         movq    $3,%rdi                 /* SIG_SETMASK     */
  94         leaq    72(%rdx),%rsi           /* (sigset_t*)set  */
  95         movq    $0,%rdx                 /* (sigset_t*)oset */
  96         call    PIC_PLT(CNAME(_sigprocmask))
  97         popq    %rsi
  98         popq    %rdi                    /* jmpbuf */
  99 2:      movq    %rdi,%rdx
 100         movq    %rsi,%rax               /* retval */
 101         movq    0(%rdx),%rcx
 102         movq    8(%rdx),%rbx
 103         movq    16(%rdx),%rsp
 104         movq    24(%rdx),%rbp
 105         movq    32(%rdx),%r12
 106         movq    40(%rdx),%r13
 107         movq    48(%rdx),%r14
 108         movq    56(%rdx),%r15
 109         fninit
 110         fldcw   64(%rdx)
 111         testq   %rax,%rax
 112         jnz     1f
 113         incq    %rax
 114 1:      movq    %rcx,0(%rsp)
 115         ret