lib/libc/arm/aeabi/aeabi_asm_double.S

   1 /*
   2  * Copyright (C) 2014 Andrew Turner
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  */
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 #define PCR_Z   (1 << 30)
  32 #define PCR_C   (1 << 29)
  33
  34 /*
  35  * These functions return the result in the CPSR register.
  36  *
  37  * For __aeabi_cdcmple:
  38  *      Z C
  39  *   LT 0 0
  40  *   EQ 1 1
  41  * else 0 1
  42  *
  43  * __aeabi_cdrcmple is the same as __aeabi_cdcmple, however the arguments
  44  * have been swapped.
  45  */
  46 ENTRY(__aeabi_cdcmple)
  47         push    {r4, r5, r6, r7, ip, lr}
  48
  49         /* Backup the input registers */
  50         mov     r4, r0
  51         mov     r5, r1
  52         mov     r6, r2
  53         mov     r7, r3
  54         /* Is it less than? */
  55         bl      __aeabi_dcmplt
  56         cmp     r0, #1
  57         bne     1f
  58         /* Yes, clear Z and C */
  59         mov     ip, #(0)
  60         b       99f
  61
  62 1:
  63         /* Restore the input regsters for the next function call */
  64         mov     r0, r4
  65         mov     r1, r5
  66         mov     r2, r6
  67         mov     r3, r7
  68         /* Is it equal? */
  69         bl      __aeabi_dcmpeq
  70         cmp     r0, #1
  71         bne     2f
  72         /* Yes, set Z and C */
  73         mov     ip, #(PCR_Z | PCR_C)
  74         b 99f
  75
  76 2:
  77         /* Not less than or equal, set C and clear Z */
  78         mov     ip, #(PCR_C)
  79
  80 99:
  81         msr     cpsr_c, ip
  82         pop     {r4, r5, r6, r7, ip, pc}
  83 END(__aeabi_cdcmple)
  84
  85 ENTRY(__aeabi_cdrcmple)
  86         /* Swap the first half of the arguments */
  87         mov     ip, r0
  88         mov     r0, r2
  89         mov     r2, ip
  90
  91         /* And the second half */
  92         mov     ip, r1
  93         mov     r1, r3
  94         mov     r3, ip
  95
  96         b       __aeabi_cdcmple
  97 END(__aeabi_cdrcmple)
  98
  99 /*
 100  * This is just like __aeabi_cdcmple except it will not throw an exception
 101  * in the presence of a quiet NaN. If either argument is a signalling NaN we
 102  * will still signal.
 103  */
 104 ENTRY(__aeabi_cdcmpeq)
 105         /* Check if we can call __aeabi_cfcmple safely */
 106         push    {r0, r1, r2, r3, r4, lr}
 107         bl      __aeabi_cdcmpeq_helper
 108         cmp     r0, #1
 109         pop     {r0, r1, r2, r3, r4, lr}
 110         beq     1f
 111
 112         bl      __aeabi_cdcmple
 113         RET
 114
 115 1:
 116         mov     ip, #(PCR_C)
 117         msr     cpsr_c, ip
 118         RET
 119 END(__aeabi_cdcmpeq)
 120
 121         .section .note.GNU-stack,"",%progbits