lib/libc/arm/gen/_setjmp.S

   1 /*      $NetBSD: _setjmp.S,v 1.12 2013/04/19 13:45:45 matt Exp $        */
   2
   3 /*
   4  * Copyright (c) 1997 Mark Brinicombe
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. All advertising materials mentioning features or use of this software
  16  *    must display the following acknowledgement:
  17  *      This product includes software developed by Mark Brinicombe
  18  * 4. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #if !defined(__SOFTFP__) && !defined(__VFP_FP__) && !defined(__ARM_PCS)
  36 #error FPA is not supported anymore
  37 #endif
  38
  39 #if !defined(_STANDALONE)
  40         .fpu    vfp
  41 #endif
  42
  43 #include <machine/asm.h>
  44 #include <machine/setjmp.h>
  45
  46 __FBSDID("$FreeBSD$");
  47
  48 /*
  49  * C library -- _setjmp, _longjmp
  50  *
  51  *      _longjmp(a,v)
  52  * will generate a "return(v)" from the last call to
  53  *      _setjmp(a)
  54  * by restoring registers from the stack.
  55  * The previous signal state is NOT restored.
  56  *
  57  * Note: r0 is the return value
  58  *       r1-r3,ip are scratch registers in functions
  59  */
  60
  61 ENTRY(_setjmp)
  62         ldr     r1, .L_setjmp_magic
  63
  64 #if !defined(_STANDALONE) && __ARM_ARCH >= 6 && !defined(SOFTFLOAT_FOR_GCC)
  65         add     r2, r0, #(_JB_REG_D8 * 4)
  66         vstmia  r2, {d8-d15}
  67         vmrs    r2, fpscr
  68         str     r2, [r0, #(_JB_REG_FPSCR * 4)]
  69 #endif /* !_STANDALONE && __ARM_ARCH >= 6 */
  70
  71         str     r1, [r0]
  72
  73         add     r0, r0, #(_JB_REG_R4 * 4)
  74         /* Store integer registers */
  75 #ifndef __thumb__
  76         stmia   r0, {r4-r14}
  77 #else
  78         stmia   r0, {r4-r12}
  79         str     r13, [r0, #((_JB_REG_R13 - _JB_REG_R4) * 4)]
  80         str     r14, [r0, #((_JB_REG_R14 - _JB_REG_R4) * 4)]
  81 #endif
  82
  83         mov     r0, #0x00000000
  84         RET
  85 END(_setjmp)
  86
  87 .L_setjmp_magic:
  88         .word   _JB_MAGIC__SETJMP
  89
  90 WEAK_ALIAS(___longjmp, _longjmp)
  91 ENTRY(_longjmp)
  92         ldr     r2, [r0]                        /* get magic from jmp_buf */
  93         ldr     ip, .L_setjmp_magic             /* load magic */
  94         teq     ip, r2                          /* magic correct? */
  95         bne     botch                           /*   no, botch */
  96
  97 #if !defined(_STANDALONE) && __ARM_ARCH >= 6 && !defined(SOFTFLOAT_FOR_GCC)
  98         add     ip, r0, #(_JB_REG_D8 * 4)
  99         vldmia  ip, {d8-d15}
 100         ldr     ip, [r0, #(_JB_REG_FPSCR * 4)]
 101         vmsr    fpscr, ip
 102 #endif /* !_STANDALONE && __ARM_ARCH >= 6 */
 103
 104         add     r0, r0, #(_JB_REG_R4 * 4)
 105         /* Restore integer registers */
 106 #ifndef __thumb__
 107         ldmia   r0, {r4-r14}
 108 #else
 109         ldmia   r0, {r4-r12}
 110         ldr     r13, [r0, #((_JB_REG_R13 - _JB_REG_R4) * 4)]
 111         ldr     r14, [r0, #((_JB_REG_R14 - _JB_REG_R4) * 4)]
 112 #endif
 113
 114         /* Validate sp and r14 */
 115         teq     sp, #0
 116         it      ne
 117         teqne   r14, #0
 118         it      eq
 119         beq     botch
 120
 121         /* Set return value */
 122         movs    r0, r1
 123         it      eq
 124         moveq   r0, #0x00000001
 125         RET
 126
 127         /* validation failed, die die die. */
 128 botch:
 129 #if !defined(_STANDALONE)
 130         bl      PIC_SYM(_C_LABEL(longjmperror), PLT)
 131         bl      PIC_SYM(_C_LABEL(abort), PLT)
 132 1:      b       1b              /* Cannot get here */
 133 #else
 134         b       .
 135 #endif
 136 END(_longjmp)
 137
 138         .section .note.GNU-stack,"",%progbits