lib/libc/arm/gen/setjmp.S

   1 /*      $NetBSD: setjmp.S,v 1.14 2013/04/19 13:45:45 matt Exp $ */
   2
   3 /*
   4  * Copyright (c) 1997 Mark Brinicombe
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. All advertising materials mentioning features or use of this software
  16  *    must display the following acknowledgement:
  17  *      This product includes software developed by Mark Brinicombe
  18  * 4. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  */
  34
  35 #if !defined(__SOFTFP__) && !defined(__VFP_FP__) && !defined(__ARM_PCS)
  36 #error FPA is not supported anymore
  37 #endif
  38
  39         .fpu    vfp
  40
  41 #include <machine/asm.h>
  42 #include <machine/setjmp.h>
  43
  44 __FBSDID("$FreeBSD$");
  45
  46 /*
  47  * C library -- setjmp, longjmp
  48  *
  49  *      longjmp(a,v)
  50  * will generate a "return(v)" from the last call to
  51  *      setjmp(a)
  52  * by restoring registers from the stack.
  53  * The previous signal state is restored.
  54  */
  55
  56 ENTRY(setjmp)
  57         /* Block all signals and retrieve the old signal mask */
  58         stmfd   sp!, {r0, r14}
  59         add     r2, r0, #(_JB_SIGMASK * 4)      /* oset */
  60         mov     r1, #0x00000000                 /* set */
  61         mov     r0, #0x00000001                 /* SIG_BLOCK */
  62         bl      PIC_SYM(_C_LABEL(sigprocmask), PLT)
  63         ldmfd   sp!, {r0, r14}
  64
  65         ldr     r1, .Lsetjmp_magic
  66
  67 #if __ARM_ARCH >= 6
  68         add     r2, r0, #(_JB_REG_D8 * 4)
  69         vstmia  r2, {d8-d15}
  70         vmrs    r2, fpscr
  71         str     r2, [r0, #(_JB_REG_FPSCR * 4)]
  72 #endif
  73
  74         str     r1, [r0]                /* store magic */
  75
  76         /* Store integer registers */
  77         add     r0, r0, #(_JB_REG_R4 * 4)
  78 #ifndef __thumb__
  79         stmia   r0, {r4-r14}
  80 #else
  81         stmia   r0, {r4-r12}
  82         str     r13, [r0, #((_JB_REG_R13 - _JB_REG_R4) * 4)]
  83         str     r14, [r0, #((_JB_REG_R14 - _JB_REG_R4) * 4)]
  84 #endif
  85         mov     r0, #0x00000000
  86         RET
  87
  88 .Lsetjmp_magic:
  89         .word   _JB_MAGIC_SETJMP
  90 END(setjmp)
  91
  92 .weak _C_LABEL(longjmp)
  93 .set _C_LABEL(longjmp), _C_LABEL(__longjmp)
  94 ENTRY(__longjmp)
  95         ldr     r2, [r0]
  96         ldr     ip, .Lsetjmp_magic
  97         teq     r2, ip
  98         bne     .Lbotch
  99
 100         /* Restore the signal mask. */
 101         stmfd   sp!, {r0-r2, r14}
 102         mov     r2, #0x00000000
 103         add     r1, r0, #(_JB_SIGMASK * 4)      /* Signal mask */
 104         mov     r0, #3                          /* SIG_SETMASK */
 105         bl      PIC_SYM(_C_LABEL(sigprocmask), PLT)
 106         ldmfd   sp!, {r0-r2, r14}
 107
 108 #if __ARM_ARCH >= 6
 109         add     ip, r0, #(_JB_REG_D8 * 4)
 110         vldmia  ip, {d8-d15}
 111         ldr     ip, [r0, #(_JB_REG_FPSCR * 4)]
 112         vmsr    fpscr, ip
 113 #endif
 114
 115         add     r0, r0, #(_JB_REG_R4 * 4)
 116         /* Restore integer registers */
 117 #ifndef __thumb__
 118         ldmia   r0, {r4-r14}
 119 #else
 120         ldmia   r0, {r4-r12}
 121         ldr     r13, [r0, #((_JB_REG_R13 - _JB_REG_R4) * 4)]
 122         ldr     r14, [r0, #((_JB_REG_R14 - _JB_REG_R4) * 4)]
 123 #endif
 124
 125         /* Validate sp and r14 */
 126         teq     sp, #0
 127         it      ne
 128         teqne   r14, #0
 129         it      eq
 130         beq     .Lbotch
 131
 132         /* Set return value */
 133         movs    r0, r1
 134         it      eq
 135         moveq   r0, #0x00000001
 136         RET
 137
 138         /* validation failed, die die die. */
 139 .Lbotch:
 140         bl      PIC_SYM(_C_LABEL(longjmperror), PLT)
 141         bl      PIC_SYM(_C_LABEL(abort), PLT)
 142 1:      b       1b              /* Cannot get here */
 143 END(__longjmp)
 144
 145         .section .note.GNU-stack,"",%progbits