lib/libc/i386/gen/sigsetjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  *      @(#)setjmp.s    5.1 (Berkeley) 4/23/90"
  37  */
  38
  39 #if defined(LIBC_SCCS) && !defined(lint)
  40         .text
  41         .asciz "$Id: sigsetjmp.S,v 1.1 1993/12/05 13:01:05 ats Exp $"
  42 #endif /* LIBC_SCCS and not lint */
  43 #include <machine/asm.h>
  44 __FBSDID("$FreeBSD$");
  45
  46 #include "SYS.h"
  47
  48 /*-
  49  * TODO:
  50  *      Rename sigsetjmp to __sigsetjmp and siglongjmp to __siglongjmp,
  51  *      remove the other *jmp functions and define everything in terms
  52  *      of the renamed functions.  This requires compiler support for
  53  *      the renamed functions (introduced in gcc-2.5.3; previous versions
  54  *      only supported *jmp with 0 or 1 leading underscores).
  55  *
  56  *      Restore _all_ the registers and the signal mask atomically.  Can
  57  *      use sigreturn() if sigreturn() works.
  58  */
  59
  60 ENTRY(sigsetjmp)
  61         movl    8(%esp),%eax
  62         movl    4(%esp),%ecx
  63         movl    %eax,44(%ecx)
  64         testl   %eax,%eax
  65         jz      2f
  66         PIC_PROLOGUE
  67         leal    28(%ecx), %eax
  68         pushl   %eax                    /* (sigset_t*)oset */
  69         pushl   $0                      /* (sigset_t*)set  */
  70         pushl   $1                      /* SIG_BLOCK       */
  71         call    PIC_PLT(CNAME(_sigprocmask))
  72         addl    $12,%esp
  73         PIC_EPILOGUE
  74         movl    4(%esp),%ecx
  75 2:      movl    0(%esp),%edx
  76         movl    %edx, 0(%ecx)
  77         movl    %ebx, 4(%ecx)
  78         movl    %esp, 8(%ecx)
  79         movl    %ebp,12(%ecx)
  80         movl    %esi,16(%ecx)
  81         movl    %edi,20(%ecx)
  82         fnstcw  24(%ecx)
  83         xorl    %eax,%eax
  84         ret
  85
  86         .weak CNAME(siglongjmp);
  87         .set CNAME(siglongjmp),CNAME(__siglongjmp);
  88 ENTRY(__siglongjmp);
  89         movl    4(%esp),%edx
  90         cmpl    $0,44(%edx)
  91         jz      2f
  92         PIC_PROLOGUE
  93         pushl   $0                      /* (sigset_t*)oset */
  94         leal    28(%edx), %eax
  95         pushl   %eax                    /* (sigset_t*)set  */
  96         pushl   $3                      /* SIG_SETMASK     */
  97         call    PIC_PLT(CNAME(_sigprocmask))
  98         addl    $12,%esp
  99         PIC_EPILOGUE
 100         movl    4(%esp),%edx
 101 2:      movl    8(%esp),%eax
 102         movl    0(%edx),%ecx
 103         movl    4(%edx),%ebx
 104         movl    8(%edx),%esp
 105         movl    12(%edx),%ebp
 106         movl    16(%edx),%esi
 107         movl    20(%edx),%edi
 108         fninit
 109         fldcw   24(%edx)
 110         testl   %eax,%eax
 111         jnz     1f
 112         incl    %eax
 113 1:      movl    %ecx,0(%esp)
 114         ret