lib/libc/net/nsparser.y

   1 %{
   2 /*      $NetBSD: nsparser.y,v 1.3 1999/01/25 00:16:18 lukem Exp $       */
   3
   4 /*-
   5  * Copyright (c) 1997, 1998, 1999 The NetBSD Foundation, Inc.
   6  * All rights reserved.
   7  *
   8  * This code is derived from software contributed to The NetBSD Foundation
   9  * by Luke Mewburn.
  10  *
  11  * Redistribution and use in source and binary forms, with or without
  12  * modification, are permitted provided that the following conditions
  13  * are met:
  14  * 1. Redistributions of source code must retain the above copyright
  15  *    notice, this list of conditions and the following disclaimer.
  16  * 2. Redistributions in binary form must reproduce the above copyright
  17  *    notice, this list of conditions and the following disclaimer in the
  18  *    documentation and/or other materials provided with the distribution.
  19  * 3. All advertising materials mentioning features or use of this software
  20  *    must display the following acknowledgement:
  21  *        This product includes software developed by the NetBSD
  22  *        Foundation, Inc. and its contributors.
  23  * 4. Neither the name of The NetBSD Foundation nor the names of its
  24  *    contributors may be used to endorse or promote products derived
  25  *    from this software without specific prior written permission.
  26  *
  27  * THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
  28  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  29  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  30  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
  31  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  32  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  33  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  34  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  35  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  36  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  37  * POSSIBILITY OF SUCH DAMAGE.
  38  */
  39
  40 #include <sys/cdefs.h>
  41 __FBSDID("$FreeBSD$");
  42
  43 #include "namespace.h"
  44 #define _NS_PRIVATE
  45 #include <nsswitch.h>
  46 #include <stdio.h>
  47 #include <string.h>
  48 #include <syslog.h>
  49 #include "un-namespace.h"
  50
  51 static  void    _nsaddsrctomap(const char *);
  52
  53 static  ns_dbt          curdbt;
  54 static  ns_src          cursrc;
  55 %}
  56
  57 %union {
  58         char *str;
  59         int   mapval;
  60 }
  61
  62 %token  NL
  63 %token  SUCCESS UNAVAIL NOTFOUND TRYAGAIN
  64 %token  RETURN CONTINUE
  65 %token  ERRORTOKEN
  66 %token  <str> STRING
  67
  68 %type   <mapval> Status Action
  69
  70 %%
  71
  72 File
  73         :       /* empty */
  74         | Lines
  75         ;
  76
  77 Lines
  78         : Entry
  79         | Lines Entry
  80         ;
  81
  82 Entry
  83         : NL
  84         | Database ':' NL
  85         | Database ':' Srclist NL
  86                 {
  87                         _nsdbtput(&curdbt);
  88                 }
  89         | error NL
  90                 {
  91                         yyerrok;
  92                 }
  93         ;
  94
  95 Database
  96         : STRING
  97                 {
  98                         curdbt.name = yylval.str;
  99                         curdbt.srclist = NULL;
 100                         curdbt.srclistsize = 0;
 101                 }
 102         ;
 103
 104 Srclist
 105         : Item
 106         | Srclist Item
 107         ;
 108
 109 Item
 110         : STRING
 111                 {
 112                         cursrc.flags = NS_TERMINATE;
 113                         _nsaddsrctomap($1);
 114                 }
 115         | STRING '[' { cursrc.flags = NS_SUCCESS; } Criteria ']'
 116                 {
 117                         _nsaddsrctomap($1);
 118                 }
 119         ;
 120
 121 Criteria
 122         : Criterion
 123         | Criteria Criterion
 124         ;
 125
 126 Criterion
 127         : Status '=' Action
 128                 {
 129                         if ($3)      /* if action == RETURN set RETURN bit */
 130                                 cursrc.flags |= $1;
 131                         else         /* else unset it */
 132                                 cursrc.flags &= ~$1;
 133                 }
 134         ;
 135
 136 Status
 137         : SUCCESS       { $$ = NS_SUCCESS; }
 138         | UNAVAIL       { $$ = NS_UNAVAIL; }
 139         | NOTFOUND      { $$ = NS_NOTFOUND; }
 140         | TRYAGAIN      { $$ = NS_TRYAGAIN; }
 141         ;
 142
 143 Action
 144         : RETURN        { $$ = NS_ACTION_RETURN; }
 145         | CONTINUE      { $$ = NS_ACTION_CONTINUE; }
 146         ;
 147
 148 %%
 149
 150 static void
 151 _nsaddsrctomap(elem)
 152         const char *elem;
 153 {
 154         int             i, lineno;
 155         extern int      _nsyylineno;
 156         extern char *   _nsyytext;
 157
 158         lineno = _nsyylineno - (*_nsyytext == '\n' ? 1 : 0);
 159         if (curdbt.srclistsize > 0) {
 160                 if (((strcasecmp(elem, NSSRC_COMPAT) == 0) &&
 161                     (strcasecmp(curdbt.srclist[0].name, NSSRC_CACHE) != 0)) ||
 162                     (strcasecmp(curdbt.srclist[0].name, NSSRC_COMPAT) == 0)) {
 163                         syslog(LOG_ERR,
 164             "NSSWITCH(nsparser): %s line %d: 'compat' used with sources, other than 'cache'",
 165                             _PATH_NS_CONF, lineno);
 166                         return;
 167                 }
 168         }
 169         for (i = 0; i < curdbt.srclistsize; i++) {
 170                 if (strcasecmp(curdbt.srclist[i].name, elem) == 0) {
 171                         syslog(LOG_ERR,
 172                        "NSSWITCH(nsparser): %s line %d: duplicate source '%s'",
 173                             _PATH_NS_CONF, lineno, elem);
 174                         return;
 175                 }
 176         }
 177         cursrc.name = elem;
 178         _nsdbtaddsrc(&curdbt, &cursrc);
 179 }