lib/libc/powerpc/gen/_setjmp.S

   1 /*-
   2  * Copyright (c) 2002 Peter Grehan.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  */
  26 /*      $NetBSD: _setjmp.S,v 1.1 1997/03/29 20:55:53 thorpej Exp $      */
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 /*
  32  * C library -- _setjmp, _longjmp
  33  *
  34  *      _longjmp(a,v)
  35  * will generate a "return(v?v:1)" from the last call to
  36  *      _setjmp(a)
  37  * by restoring registers from the stack.
  38  * The previous signal state is NOT restored.
  39  *
  40  * jmpbuf layout:
  41  *     +------------+
  42  *     |   unused   |
  43  *     +------------+
  44  *     |   unused   |
  45  *     |            |
  46  *     | (4 words)  |
  47  *     |            |
  48  *     +------------+
  49  *     | saved regs |
  50  *     |    ...     |
  51  */
  52
  53 ENTRY(_setjmp)
  54         mflr    %r11
  55         mfcr    %r12
  56         mr      %r10,%r1
  57         mr      %r9,%r2
  58         stmw    %r9,20(%r3)
  59
  60         /* FPRs */
  61         stfd    %f14,112+0*8(%r3)
  62         stfd    %f15,112+1*8(%r3)
  63         stfd    %f16,112+2*8(%r3)
  64         stfd    %f17,112+3*8(%r3)
  65         stfd    %f18,112+4*8(%r3)
  66         stfd    %f19,112+5*8(%r3)
  67         stfd    %f20,112+6*8(%r3)
  68         stfd    %f21,112+7*8(%r3)
  69         stfd    %f22,112+8*8(%r3)
  70         stfd    %f23,112+9*8(%r3)
  71         stfd    %f24,112+10*8(%r3)
  72         stfd    %f25,112+11*8(%r3)
  73         stfd    %f26,112+12*8(%r3)
  74         stfd    %f27,112+13*8(%r3)
  75         stfd    %f28,112+14*8(%r3)
  76         stfd    %f29,112+15*8(%r3)
  77         stfd    %f30,112+16*8(%r3)
  78         stfd    %f31,112+17*8(%r3)
  79
  80         li      %r3,0
  81         blr
  82 END(_setjmp)
  83
  84 ENTRY(_longjmp)
  85         lmw     %r9,20(%r3)
  86
  87         /* FPRs */
  88         lfd     %f14,112+0*8(%r3)
  89         lfd     %f15,112+1*8(%r3)
  90         lfd     %f16,112+2*8(%r3)
  91         lfd     %f17,112+3*8(%r3)
  92         lfd     %f18,112+4*8(%r3)
  93         lfd     %f19,112+5*8(%r3)
  94         lfd     %f20,112+6*8(%r3)
  95         lfd     %f21,112+7*8(%r3)
  96         lfd     %f22,112+8*8(%r3)
  97         lfd     %f23,112+9*8(%r3)
  98         lfd     %f24,112+10*8(%r3)
  99         lfd     %f25,112+11*8(%r3)
 100         lfd     %f26,112+12*8(%r3)
 101         lfd     %f27,112+13*8(%r3)
 102         lfd     %f28,112+14*8(%r3)
 103         lfd     %f29,112+15*8(%r3)
 104         lfd     %f30,112+16*8(%r3)
 105         lfd     %f31,112+17*8(%r3)
 106
 107         mtlr    %r11
 108         mtcr    %r12
 109         mr      %r1,%r10
 110         or.     %r3,%r4,%r4
 111         bnelr
 112         li      %r3,1
 113         blr
 114 END(_longjmp)
 115
 116         .section .note.GNU-stack,"",%progbits