lib/libc/powerpc64/gen/_setjmp.S

   1 /*-
   2  * Copyright (c) 2002 Peter Grehan.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  */
  26 /*      $NetBSD: _setjmp.S,v 1.1 1997/03/29 20:55:53 thorpej Exp $      */
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 /*
  32  * C library -- _setjmp, _longjmp
  33  *
  34  *      _longjmp(a,v)
  35  * will generate a "return(v?v:1)" from the last call to
  36  *      _setjmp(a)
  37  * by restoring registers from the stack.
  38  * The previous signal state is NOT restored.
  39  *
  40  * jmpbuf layout:
  41  *     +------------+
  42  *     |   unused   |
  43  *     +------------+
  44  *     |   unused   |
  45  *     |            |
  46  *     | (4 words)  |
  47  *     |            |
  48  *     +------------+
  49  *     | saved regs |
  50  *     |    ...     |
  51  */
  52
  53 ENTRY(_setjmp)
  54         mflr    %r11
  55         mfcr    %r12
  56         mr      %r10,%r1
  57         mr      %r9,%r2
  58         std     %r9,40 + 0*8(%r3)
  59         stfd    %f14,40 + 23*8(%r3)
  60         std     %r10,40 + 1*8(%r3)
  61         stfd    %f15,40 + 24*8(%r3)
  62         std     %r11,40 + 2*8(%r3)
  63         stfd    %f16,40 + 25*8(%r3)
  64         std     %r12,40 + 3*8(%r3)
  65         stfd    %f17,40 + 26*8(%r3)
  66         std     %r13,40 + 4*8(%r3)
  67         stfd    %f18,40 + 27*8(%r3)
  68         std     %r14,40 + 5*8(%r3)
  69         stfd    %f19,40 + 28*8(%r3)
  70         std     %r15,40 + 6*8(%r3)
  71         stfd    %f20,40 + 29*8(%r3)
  72         std     %r16,40 + 7*8(%r3)
  73         stfd    %f21,40 + 30*8(%r3)
  74         std     %r17,40 + 8*8(%r3)
  75         stfd    %f22,40 + 31*8(%r3)
  76         std     %r18,40 + 9*8(%r3)
  77         stfd    %f23,40 + 32*8(%r3)
  78         std     %r19,40 + 10*8(%r3)
  79         stfd    %f24,40 + 33*8(%r3)
  80         std     %r20,40 + 11*8(%r3)
  81         stfd    %f25,40 + 34*8(%r3)
  82         std     %r21,40 + 12*8(%r3)
  83         stfd    %f26,40 + 35*8(%r3)
  84         std     %r22,40 + 13*8(%r3)
  85         stfd    %f27,40 + 36*8(%r3)
  86         std     %r23,40 + 14*8(%r3)
  87         stfd    %f28,40 + 37*8(%r3)
  88         std     %r24,40 + 15*8(%r3)
  89         stfd    %f29,40 + 38*8(%r3)
  90         std     %r25,40 + 16*8(%r3)
  91         stfd    %f30,40 + 39*8(%r3)
  92         std     %r26,40 + 17*8(%r3)
  93         stfd    %f31,40 + 40*8(%r3)
  94         std     %r27,40 + 18*8(%r3)
  95         std     %r28,40 + 19*8(%r3)
  96         std     %r29,40 + 20*8(%r3)
  97         std     %r30,40 + 21*8(%r3)
  98         std     %r31,40 + 22*8(%r3)
  99         li      %r3,0
 100         blr
 101 END(_setjmp)
 102
 103 ENTRY(_longjmp)
 104         ld      %r9,40 + 0*8(%r3)
 105         lfd     %f14,40 + 23*8(%r3)
 106         ld      %r10,40 + 1*8(%r3)
 107         lfd     %f15,40 + 24*8(%r3)
 108         ld      %r11,40 + 2*8(%r3)
 109         lfd     %f16,40 + 25*8(%r3)
 110         ld      %r12,40 + 3*8(%r3)
 111         lfd     %f17,40 + 26*8(%r3)
 112         ld      %r14,40 + 5*8(%r3)
 113         lfd     %f18,40 + 27*8(%r3)
 114         ld      %r15,40 + 6*8(%r3)
 115         lfd     %f19,40 + 28*8(%r3)
 116         ld      %r16,40 + 7*8(%r3)
 117         lfd     %f20,40 + 29*8(%r3)
 118         ld      %r17,40 + 8*8(%r3)
 119         lfd     %f21,40 + 30*8(%r3)
 120         ld      %r18,40 + 9*8(%r3)
 121         lfd     %f22,40 + 31*8(%r3)
 122         ld      %r19,40 + 10*8(%r3)
 123         lfd     %f23,40 + 32*8(%r3)
 124         ld      %r20,40 + 11*8(%r3)
 125         lfd     %f24,40 + 33*8(%r3)
 126         ld      %r21,40 + 12*8(%r3)
 127         lfd     %f25,40 + 34*8(%r3)
 128         ld      %r22,40 + 13*8(%r3)
 129         lfd     %f26,40 + 35*8(%r3)
 130         ld      %r23,40 + 14*8(%r3)
 131         lfd     %f27,40 + 36*8(%r3)
 132         ld      %r24,40 + 15*8(%r3)
 133         lfd     %f28,40 + 37*8(%r3)
 134         ld      %r25,40 + 16*8(%r3)
 135         lfd     %f29,40 + 38*8(%r3)
 136         ld      %r26,40 + 17*8(%r3)
 137         lfd     %f30,40 + 39*8(%r3)
 138         ld      %r27,40 + 18*8(%r3)
 139         lfd     %f31,40 + 40*8(%r3)
 140         ld      %r28,40 + 19*8(%r3)
 141         ld      %r29,40 + 20*8(%r3)
 142         ld      %r30,40 + 21*8(%r3)
 143         ld      %r31,40 + 22*8(%r3)
 144
 145         mtlr    %r11
 146         mtcr    %r12
 147         mr      %r2,%r9
 148         mr      %r1,%r10
 149         or.     %r3,%r4,%r4
 150         bnelr
 151         li      %r3,1
 152         blr
 153 END(_longjmp)
 154
 155         .section .note.GNU-stack,"",%progbits