lib/libc/powerpc64/gen/sigsetjmp.S

   1 /*-
   2  * Copyright (c) 2002 Peter Grehan.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  */
  26 /*      $NetBSD: sigsetjmp.S,v 1.4 1998/10/03 12:30:38 tsubai Exp $     */
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 /*
  32  * C library -- sigsetjmp, siglongjmp
  33  *
  34  *      siglongjmp(a,v)
  35  * will generate a "return(v?v:1)" from the last call to
  36  *      sigsetjmp(a, savemask)
  37  * by restoring registers from the stack.
  38  * The previous signal state is restored if savemask is non-zero
  39  *
  40  * jmpbuf layout:
  41  *     +------------+
  42  *     |  savemask  |
  43  *     +------------+
  44  *     | sig state  |
  45  *     |            |
  46  *     | (4 words)  |
  47  *     |            |
  48  *     +------------+
  49  *     | saved regs |
  50  *     |    ...     |
  51  */
  52
  53
  54 #include <sys/syscall.h>
  55
  56 ENTRY(sigsetjmp)
  57         mr      %r6,%r3
  58         stw     %r4,0(%r3)
  59         or.     %r7,%r4,%r4
  60         beq     1f
  61         li      %r3,1                   /* SIG_BLOCK, but doesn't matter */
  62                                         /*            since set == NULL  */
  63         li      %r4,0                   /* set = NULL */
  64         mr      %r5,%r6                 /* &oset */
  65         addi    %r5,%r5,4
  66         li      %r0, SYS_sigprocmask   /* sigprocmask(SIG_BLOCK, NULL, &oset)*/
  67         sc                              /* assume no error       XXX */
  68 1:
  69         mflr    %r11
  70         mfcr    %r12
  71         mr      %r10,%r1
  72         mr      %r9,%r2
  73
  74         std     %r9,40 + 0*8(%r6)
  75         stfd    %f14,40 + 23*8(%r6)
  76         std     %r10,40 + 1*8(%r6)
  77         stfd    %f15,40 + 24*8(%r6)
  78         std     %r11,40 + 2*8(%r6)
  79         stfd    %f16,40 + 25*8(%r6)
  80         std     %r12,40 + 3*8(%r6)
  81         stfd    %f17,40 + 26*8(%r6)
  82         std     %r13,40 + 4*8(%r6)
  83         stfd    %f18,40 + 27*8(%r6)
  84         std     %r14,40 + 5*8(%r6)
  85         stfd    %f19,40 + 28*8(%r6)
  86         std     %r15,40 + 6*8(%r6)
  87         stfd    %f20,40 + 29*8(%r6)
  88         std     %r16,40 + 7*8(%r6)
  89         stfd    %f21,40 + 30*8(%r6)
  90         std     %r17,40 + 8*8(%r6)
  91         stfd    %f22,40 + 31*8(%r6)
  92         std     %r18,40 + 9*8(%r6)
  93         stfd    %f23,40 + 32*8(%r6)
  94         std     %r19,40 + 10*8(%r6)
  95         stfd    %f24,40 + 33*8(%r6)
  96         std     %r20,40 + 11*8(%r6)
  97         stfd    %f25,40 + 34*8(%r6)
  98         std     %r21,40 + 12*8(%r6)
  99         stfd    %f26,40 + 35*8(%r6)
 100         std     %r22,40 + 13*8(%r6)
 101         stfd    %f27,40 + 36*8(%r6)
 102         std     %r23,40 + 14*8(%r6)
 103         stfd    %f28,40 + 37*8(%r6)
 104         std     %r24,40 + 15*8(%r6)
 105         stfd    %f29,40 + 38*8(%r6)
 106         std     %r25,40 + 16*8(%r6)
 107         stfd    %f30,40 + 39*8(%r6)
 108         std     %r26,40 + 17*8(%r6)
 109         stfd    %f31,40 + 40*8(%r6)
 110         std     %r27,40 + 18*8(%r6)
 111         std     %r28,40 + 19*8(%r6)
 112         std     %r29,40 + 20*8(%r6)
 113         std     %r30,40 + 21*8(%r6)
 114         std     %r31,40 + 22*8(%r6)
 115
 116         li      %r3,0
 117         blr
 118 END(sigsetjmp)
 119
 120 ENTRY(siglongjmp)
 121         ld      %r9,40 + 0*8(%r3)
 122         lfd     %f14,40 + 23*8(%r3)
 123         ld      %r10,40 + 1*8(%r3)
 124         lfd     %f15,40 + 24*8(%r3)
 125         ld      %r11,40 + 2*8(%r3)
 126         lfd     %f16,40 + 25*8(%r3)
 127         ld      %r12,40 + 3*8(%r3)
 128         lfd     %f17,40 + 26*8(%r3)
 129         ld      %r14,40 + 5*8(%r3)
 130         lfd     %f18,40 + 27*8(%r3)
 131         ld      %r15,40 + 6*8(%r3)
 132         lfd     %f19,40 + 28*8(%r3)
 133         ld      %r16,40 + 7*8(%r3)
 134         lfd     %f20,40 + 29*8(%r3)
 135         ld      %r17,40 + 8*8(%r3)
 136         lfd     %f21,40 + 30*8(%r3)
 137         ld      %r18,40 + 9*8(%r3)
 138         lfd     %f22,40 + 31*8(%r3)
 139         ld      %r19,40 + 10*8(%r3)
 140         lfd     %f23,40 + 32*8(%r3)
 141         ld      %r20,40 + 11*8(%r3)
 142         lfd     %f24,40 + 33*8(%r3)
 143         ld      %r21,40 + 12*8(%r3)
 144         lfd     %f25,40 + 34*8(%r3)
 145         ld      %r22,40 + 13*8(%r3)
 146         lfd     %f26,40 + 35*8(%r3)
 147         ld      %r23,40 + 14*8(%r3)
 148         lfd     %f27,40 + 36*8(%r3)
 149         ld      %r24,40 + 15*8(%r3)
 150         lfd     %f28,40 + 37*8(%r3)
 151         ld      %r25,40 + 16*8(%r3)
 152         lfd     %f29,40 + 38*8(%r3)
 153         ld      %r26,40 + 17*8(%r3)
 154         lfd     %f30,40 + 39*8(%r3)
 155         ld      %r27,40 + 18*8(%r3)
 156         lfd     %f31,40 + 40*8(%r3)
 157         ld      %r28,40 + 19*8(%r3)
 158         ld      %r29,40 + 20*8(%r3)
 159         ld      %r30,40 + 21*8(%r3)
 160         ld      %r31,40 + 22*8(%r3)
 161
 162         lwz     %r7,0(%r3)
 163         mr      %r6,%r4
 164         mtlr    %r11
 165         mtcr    %r12
 166         mr      %r2,%r9
 167         mr      %r1,%r10
 168         or.     %r7,%r7,%r7
 169         beq     1f
 170         mr      %r4,%r3
 171         li      %r3,3                   /* SIG_SETMASK */
 172         addi    %r4,%r4,4               /* &set */
 173         li      %r5,0                   /* oset = NULL */
 174         li      %r0,SYS_sigprocmask     /* sigprocmask(SIG_SET, &set, NULL) */
 175         sc                              /* assume no error       XXX */
 176 1:
 177         or.     %r3,%r6,%r6
 178         bnelr
 179         li      %r3,1
 180         blr
 181 END(siglongjmp)
 182
 183         .section .note.GNU-stack,"",%progbits