lib/libc/powerpcspe/gen/setjmp.S

   1 /*-
   2  * Copyright (c) 2016 Justin Hibbits
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  */
  26 /*      $NetBSD: setjmp.S,v 1.3 1998/10/03 12:30:38 tsubai Exp $        */
  27
  28 #include <machine/asm.h>
  29 __FBSDID("$FreeBSD$");
  30
  31 #include <sys/syscall.h>
  32
  33 /*
  34  * C library -- setjmp, longjmp
  35  *
  36  *      longjmp(a,v)
  37  * will generate a "return(v?v:1)" from the last call to
  38  *      setjmp(a)
  39  * by restoring registers from the stack.
  40  * The previous signal state is restored.
  41  *
  42  * jmpbuf layout:
  43  *     +------------+
  44  *     |   unused   |
  45  *     +------------+
  46  *     | sig state  |
  47  *     |            |
  48  *     | (4 words)  |
  49  *     |            |
  50  *     +------------+
  51  *     | saved regs |
  52  *     |    ...     |
  53  */
  54
  55 ENTRY(setjmp)
  56         mr      %r6,%r3
  57         li      %r3,1                   /* SIG_BLOCK, but doesn't matter */
  58                                         /*            since set == NULL  */
  59         li      %r4,0                   /* set = NULL */
  60         mr      %r5,%r6                 /* &oset */
  61         addi    %r5,%r5,4
  62         li      %r0, SYS_sigprocmask    /*sigprocmask(SIG_BLOCK, NULL, &oset)*/
  63         sc                              /*assume no error       XXX */
  64         mflr    %r11                    /* r11 <- link reg */
  65         mfcr    %r12                    /* r12 <- condition reg */
  66         mr      %r10,%r1                /* r10 <- stackptr */
  67         mr      %r9,%r2                 /*  r9 <- global ptr */
  68         evstdd  %r9,24+0*8(%r6)
  69         evstdd  %r10,24+1*8(%r6)
  70         evstdd  %r11,24+2*8(%r6)
  71         evstdd  %r12,24+3*8(%r6)
  72         evstdd  %r13,24+4*8(%r6)
  73         evstdd  %r14,24+5*8(%r6)
  74         evstdd  %r15,24+6*8(%r6)
  75         evstdd  %r16,24+7*8(%r6)
  76         evstdd  %r17,24+8*8(%r6)
  77         evstdd  %r18,24+9*8(%r6)
  78         evstdd  %r19,24+10*8(%r6)
  79         evstdd  %r20,24+11*8(%r6)
  80         evstdd  %r21,24+12*8(%r6)
  81         evstdd  %r22,24+13*8(%r6)
  82         evstdd  %r23,24+14*8(%r6)
  83         evstdd  %r24,24+15*8(%r6)
  84         evstdd  %r25,24+16*8(%r6)
  85         evstdd  %r26,24+17*8(%r6)
  86         evstdd  %r27,24+18*8(%r6)
  87         evstdd  %r28,24+19*8(%r6)
  88         evstdd  %r29,24+20*8(%r6)
  89         evstdd  %r30,24+21*8(%r6)
  90         evstdd  %r31,24+22*8(%r6)
  91
  92         li      %r3,0                   /* return (0) */
  93         blr
  94 END(setjmp)
  95
  96         WEAK_REFERENCE(CNAME(__longjmp), longjmp)
  97 ENTRY(__longjmp)
  98         evldd   %r9,24+0*8(%r3)
  99         evldd   %r10,24+1*8(%r3)
 100         evldd   %r11,24+2*8(%r3)
 101         evldd   %r12,24+3*8(%r3)
 102         evldd   %r13,24+4*8(%r3)
 103         evldd   %r14,24+5*8(%r3)
 104         evldd   %r15,24+6*8(%r3)
 105         evldd   %r16,24+7*8(%r3)
 106         evldd   %r17,24+8*8(%r3)
 107         evldd   %r18,24+9*8(%r3)
 108         evldd   %r19,24+10*8(%r3)
 109         evldd   %r20,24+11*8(%r3)
 110         evldd   %r21,24+12*8(%r3)
 111         evldd   %r22,24+13*8(%r3)
 112         evldd   %r23,24+14*8(%r3)
 113         evldd   %r24,24+15*8(%r3)
 114         evldd   %r25,24+16*8(%r3)
 115         evldd   %r26,24+17*8(%r3)
 116         evldd   %r27,24+18*8(%r3)
 117         evldd   %r28,24+19*8(%r3)
 118         evldd   %r29,24+20*8(%r3)
 119         evldd   %r30,24+21*8(%r3)
 120         evldd   %r31,24+22*8(%r3)
 121
 122         mr      %r6,%r4                 /* save val param */
 123         mtlr    %r11                    /* r11 -> link reg */
 124         mtcr    %r12                    /* r12 -> condition reg */
 125         mr      %r1,%r10                /* r10 -> stackptr */
 126         mr      %r4,%r3
 127         li      %r3,3                   /* SIG_SETMASK */
 128         addi    %r4,%r4,4               /* &set */
 129         li      %r5,0                   /* oset = NULL */
 130         li      %r0,SYS_sigprocmask     /* sigprocmask(SIG_SET, &set, NULL) */
 131         sc                              /* assume no error       XXX */
 132         or.     %r3,%r6,%r6
 133         bnelr
 134         li      %r3,1
 135         blr
 136 END(__longjmp)
 137
 138         .section .note.GNU-stack,"",%progbits