lib/msun/i387/e_exp.S

   1 /*
   2  * Copyright (c) 1993,94 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  */
  30
  31 /*
  32  * Written by:
  33  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  34  */
  35
  36 #include <machine/asm.h>
  37 /* e^x = 2^(x * log2(e)) */
  38 ENTRY(exp)
  39         /*
  40          * If x is +-Inf, then the subtraction would give Inf-Inf = NaN.
  41          * Avoid this.  Also avoid it if x is NaN for convenience.
  42          */
  43         movl    8(%esp),%eax
  44         andl    $0x7fffffff,%eax
  45         cmpl    $0x7ff00000,%eax
  46         jae     x_Inf_or_NaN
  47
  48         fldl    4(%esp)
  49
  50         /*
  51          * Extended precision is needed to reduce the maximum error from
  52          * hundreds of ulps to less than 1 ulp.  Switch to it if necessary.
  53          * We may as well set the rounding mode to to-nearest and mask traps
  54          * if we switch.
  55          */
  56         fstcw   4(%esp)
  57         movl    4(%esp),%eax
  58         andl    $0x0300,%eax
  59         cmpl    $0x0300,%eax            /* RC == 0 && PC == 3? */
  60         je      1f                      /* jump if mode is good */
  61         movl    $0x137f,8(%esp)
  62         fldcw   8(%esp)
  63 1:
  64         fldl2e
  65         fmulp                           /* x * log2(e) */
  66         fst     %st(1)
  67         frndint                         /* int(x * log2(e)) */
  68         fst     %st(2)
  69         fsubrp                          /* fract(x * log2(e)) */
  70         f2xm1                           /* 2^(fract(x * log2(e))) - 1 */
  71         fld1
  72         faddp                           /* 2^(fract(x * log2(e))) */
  73         fscale                          /* e^x */
  74         fstp    %st(1)
  75         je      1f
  76         fldcw   4(%esp)
  77 1:
  78         ret
  79
  80 x_Inf_or_NaN:
  81         /*
  82          * Return 0 if x is -Inf.  Otherwise just return x; when x is Inf
  83          * this gives Inf, and when x is a NaN this gives the same result
  84          * as (x + x) (x quieted).
  85          */
  86         cmpl    $0xfff00000,8(%esp)
  87         jne     x_not_minus_Inf
  88         cmpl    $0,4(%esp)
  89         jne     x_not_minus_Inf
  90         fldz
  91         ret
  92
  93 x_not_minus_Inf:
  94         fldl    4(%esp)
  95         ret
  96 END(exp)
  97
  98         .section .note.GNU-stack,"",%progbits