libexec/rtld-elf/aarch64/rtld_start.S

   1 /*-
   2  * Copyright (c) 2014 The FreeBSD Foundation
   3  * All rights reserved.
   4  *
   5  * This software was developed by Andrew Turner under
   6  * sponsorship from the FreeBSD Foundation.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #include <machine/asm.h>
  31 __FBSDID("$FreeBSD$");
  32
  33 ENTRY(.rtld_start)
  34         mov     x19, x0         /* Put ps_strings in a callee-saved register */
  35         mov     x20, sp         /* And the stack pointer */
  36
  37         sub     sp, sp, #16     /* Make room for obj_main & exit proc */
  38
  39         mov     x1, sp          /* exit_proc */
  40         add     x2, x1, #8      /* obj_main */
  41         bl      _rtld           /* Call the loader */
  42         mov     x8, x0          /* Backup the entry point */
  43
  44         ldr     x2, [sp]        /* Load cleanup */
  45         ldr     x1, [sp, #8]    /* Load obj_main */
  46         mov     x0, x19         /* Restore ps_strings */
  47         mov     sp, x20         /* Restore the stack pointer */
  48         br      x8              /* Jump to the entry point */
  49 END(.rtld_start)
  50
  51 /*
  52  * sp + 0 = &GOT[x + 3]
  53  * sp + 8 = RA
  54  * x16 = &GOT[2]
  55  * x17 = &_rtld_bind_start
  56  */
  57 ENTRY(_rtld_bind_start)
  58         .cfi_startproc
  59         mov     x17, sp
  60
  61         /* Save frame pointer and SP */
  62         stp     x29, x30, [sp, #-16]!
  63         mov     x29, sp
  64         .cfi_def_cfa x29, 16
  65         .cfi_offset x30, -8
  66         .cfi_offset x29, -16
  67
  68         /* Save the arguments */
  69         stp     x0, x1, [sp, #-16]!
  70         stp     x2, x3, [sp, #-16]!
  71         stp     x4, x5, [sp, #-16]!
  72         stp     x6, x7, [sp, #-16]!
  73         stp     x8, xzr, [sp, #-16]!
  74
  75         /* Save any floating-point arguments */
  76         stp     q0, q1, [sp, #-32]!
  77         stp     q2, q3, [sp, #-32]!
  78         stp     q4, q5, [sp, #-32]!
  79         stp     q6, q7, [sp, #-32]!
  80
  81         /* Calculate reloff */
  82         ldr     x2, [x17, #0]   /* Get the address of the entry */
  83         sub     x1, x2, x16     /* Find its offset */
  84         sub     x1, x1, #8      /* Adjust for x16 not being at offset 0 */
  85         /* Each rela item has 3 entriesso we need reloff = 3 * index */
  86         lsl     x3, x1, #1      /* x3 = 2 * offset */
  87         add     x1, x1, x3      /* x1 = x3 + offset = 3 * offset */
  88
  89         /* Load obj */
  90         ldr     x0, [x16, #-8]
  91
  92         /* Call into rtld */
  93         bl      _rtld_bind
  94
  95         /* Backup the address to branch to */
  96         mov     x16, x0
  97
  98         /* restore the arguments */
  99         ldp     q6, q7, [sp], #32
 100         ldp     q4, q5, [sp], #32
 101         ldp     q2, q3, [sp], #32
 102         ldp     q0, q1, [sp], #32
 103         ldp     x8, xzr, [sp], #16
 104         ldp     x6, x7, [sp], #16
 105         ldp     x4, x5, [sp], #16
 106         ldp     x2, x3, [sp], #16
 107         ldp     x0, x1, [sp], #16
 108
 109         /* Restore frame pointer */
 110         ldp     x29, xzr, [sp], #16
 111
 112          /* Restore link register saved by the plt code */
 113         ldp     xzr, x30, [sp], #16
 114
 115         /* Call into the correct function */
 116         br      x16
 117         .cfi_endproc
 118 END(_rtld_bind_start)
 119
 120 /*
 121  * uint64_t _rtld_tlsdesc(struct tlsdesc *);
 122  *
 123  * struct tlsdesc {
 124  *  uint64_t ptr;
 125  *  uint64_t data;
 126  * };
 127  *
 128  * Returns the data.
 129  */
 130 ENTRY(_rtld_tlsdesc)
 131         ldr     x0, [x0, #8]
 132         ret
 133 END(_rtld_tlsdesc)
 134
 135 /*
 136  * uint64_t _rtld_tlsdesc_dynamic(struct tlsdesc *);
 137  *
 138  * TODO: We could lookup the saved index here to skip saving the entire stack.
 139  */
 140 ENTRY(_rtld_tlsdesc_dynamic)
 141         /* Store any registers we may use in rtld_tlsdesc_handle */
 142         stp     x29, x30, [sp, #-(10 * 16)]!
 143         mov     x29, sp
 144         stp     x1, x2,   [sp, #(1 * 16)]
 145         stp     x3, x4,   [sp, #(2 * 16)]
 146         stp     x5, x6,   [sp, #(3 * 16)]
 147         stp     x7, x8,   [sp, #(4 * 16)]
 148         stp     x9, x10,  [sp, #(5 * 16)]
 149         stp     x11, x12, [sp, #(6 * 16)]
 150         stp     x13, x14, [sp, #(7 * 16)]
 151         stp     x15, x16, [sp, #(8 * 16)]
 152         stp     x17, x18, [sp, #(9 * 16)]
 153
 154         /* Find the tls offset */
 155         ldr     x0, [x0, #8]
 156         mov     x1, #1
 157         bl      rtld_tlsdesc_handle
 158
 159         /* Restore the registers */
 160         ldp     x17, x18, [sp, #(9 * 16)]
 161         ldp     x15, x16, [sp, #(8 * 16)]
 162         ldp     x13, x14, [sp, #(7 * 16)]
 163         ldp     x11, x12, [sp, #(6 * 16)]
 164         ldp     x9, x10,  [sp, #(5 * 16)]
 165         ldp     x7, x8,   [sp, #(4 * 16)]
 166         ldp     x5, x6,   [sp, #(3 * 16)]
 167         ldp     x3, x4,   [sp, #(2 * 16)]
 168         ldp     x1, x2,   [sp, #(1 * 16)]
 169         ldp     x29, x30, [sp], #(10 * 16)
 170
 171         ret
 172 END(_rtld_tlsdesc_dynamic)