libexec/rtld-elf/powerpc64/rtld_start.S

   1 /*      $NetBSD: rtld_start.S,v 1.4 2001/09/26 04:06:43 mycroft Exp $   */
   2
   3 /*-
   4  * Copyright (C) 1998   Tsubai Masanari
   5  * All rights reserved.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. The name of the author may not be used to endorse or promote products
  16  *    derived from this software without specific prior written permission.
  17  *
  18  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  19  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  20  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  21  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  22  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  23  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  24  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  25  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  26  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  27  * OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  28  *
  29  * $FreeBSD$
  30  */
  31
  32 #include <machine/asm.h>
  33
  34 .extern _GLOBAL_OFFSET_TABLE_
  35 .extern _DYNAMIC
  36
  37 _ENTRY(_rtld_start)
  38         stdu    %r1,-144(%r1)   /* 16-byte aligned stack for reg saves +
  39                                 exit_proc & obj _rtld args +
  40                                 backchain & lrsave stack frame */
  41
  42         /* Save and restore only initial argv, because _rtld will modify
  43          * argv and envp if invoked explicitly, making it necessary to
  44          * load the (possibly) adjusted values from the stack.
  45          */
  46         std     %r4,104(%r1)    /*  argv */
  47 /*      std     %r6,120(%r1)   *//*  obj (always 0) */
  48 /*      std     %r7,128(%r1)   *//*  cleanup (always 0) */
  49         std     %r8,136(%r1)    /*  ps_strings */
  50
  51         /*
  52          * Perform initial relocation of ld-elf.so. Not as easy as it
  53          * sounds.
  54          *  - perform small forward branch to put PC into link reg
  55          *  - use link-time constants to determine offset to the
  56          *    _DYNAMIC section and the GOT. Add these to the PC to
  57          *    convert to absolute addresses.
  58          *  - call reloc_non_plt_self() to fix up ld-elf.so's relocations
  59          */
  60
  61         bl      1f
  62         .llong  _DYNAMIC-.
  63 1:
  64         mflr    %r3             /* PC value at .llong */
  65         ld      %r4,0(%r3)      /* offset to _DYNAMIC */
  66         add     %r3,%r4,%r3     /* r3 = &_DYNAMIC, absolute value */
  67
  68         ld      %r4,-0x8000(%r2) /* First TOC entry is TOC base */
  69         subf    %r4,%r4,%r2     /* Subtract from real TOC base to get base */
  70
  71         bl      reloc_non_plt_self /* reloc_non_plt_self(&_DYNAMIC,base) */
  72         nop
  73
  74         /*
  75          * The _rtld() function likes to see a stack layout containing
  76          * { argc, argv[0], argv[1] ... argv[N], 0, env[0], ... , env[N] }
  77          * Since the PowerPC stack was 16-byte aligned at exec time, the
  78          * original stack layout has to be found by moving back a word
  79          * from the argv pointer.
  80          */
  81         ld      %r4,104(%r1)
  82         addi    %r3,%r4,-8      /* locate argc ptr, &argv[-1] */
  83         addi    %r4,%r1,128     /* &exit_proc on stack */
  84         addi    %r5,%r1,120     /* &obj_main on stack */
  85
  86         bl      _rtld           /* &_start = _rtld(sp, &exit_proc, &obj_main)*/
  87         nop
  88 #if !defined(_CALL_ELF) || _CALL_ELF == 1
  89         ld      %r2,8(%r3)
  90         ld      %r11,16(%r3)
  91         ld      %r3,0(%r3)
  92 #else
  93         mr      %r12,%r3
  94 #endif
  95         mtlr    %r3
  96
  97         /*
  98          * Restore args, with new obj/exit proc
  99          */
 100         ld      %r4,104(%r1)    /* argv */
 101         ld      %r3,-8(%r4)     /* argc */
 102
 103         /* envp = argv + argc + 1 */
 104         addi    %r5,%r3,1
 105         sldi    %r5,%r5,3       /* x8 */
 106         add     %r5,%r4,%r5
 107
 108         ld      %r6,120(%r1)    /* obj */
 109         ld      %r7,128(%r1)    /* exit proc */
 110         ld      %r8,136(%r1)    /* ps_strings */
 111
 112         blrl    /* _start(argc, argv, envp, obj, cleanup, ps_strings) */
 113
 114         li      %r0,1           /* _exit() */
 115         sc
 116
 117 /*
 118  * _rtld_bind_start()
 119  *
 120  * Call into the MI binder. This routine is reached via the PLT call cell
 121  *
 122  * On entry, %r11 contains an object pointer and %r0 contains the PLT index.
 123  *
 124  * Save all registers, call into the binder to resolve and fixup the external
 125  * routine, and then transfer to the external routine on return.
 126  */
 127         .globl  _rtld_bind
 128
 129 _ENTRY(_rtld_bind_start)
 130         mr      %r12,%r0                # save r0 (index) immediately to r12
 131         mflr    %r0
 132         std     %r0,16(%r1)             # save lr
 133         mfcr    %r0
 134         std     %r0,8(%r1)              # save cr
 135
 136         stdu    %r1,-48-12*8(%r1)       # stack space for 8 regs + header
 137                                         #   + 2 save regs
 138         std     %r3,64+0*8(%r1)         # save r3-r10 (arguments)
 139         std     %r4,64+1*8(%r1)
 140         std     %r5,64+2*8(%r1)
 141         std     %r6,64+3*8(%r1)
 142         std     %r7,64+4*8(%r1)
 143         std     %r8,64+5*8(%r1)
 144         std     %r9,64+6*8(%r1)
 145         std     %r10,64+7*8(%r1)
 146
 147         mr      %r3,%r11
 148         mulli   %r4,%r12,24             # Multiply index by sizeof(Elf_Rela)
 149
 150         bl      _rtld_bind              # target addr = _rtld_bind(obj, reloff)
 151         nop
 152
 153 #if !defined(_CALL_ELF) || _CALL_ELF == 1
 154         ld      %r2,8(%r3)
 155         ld      %r11,16(%r3)
 156         ld      %r3,0(%r3)
 157 #else
 158         mr      %r12,%r3
 159 #endif
 160         mtctr   %r3                     # move absolute target addr into ctr
 161
 162         ld      %r3,64+0*8(%r1)         # restore r3-r10
 163         ld      %r4,64+1*8(%r1)
 164         ld      %r5,64+2*8(%r1)
 165         ld      %r6,64+3*8(%r1)
 166         ld      %r7,64+4*8(%r1)
 167         ld      %r8,64+5*8(%r1)
 168         ld      %r9,64+6*8(%r1)
 169         ld      %r10,64+7*8(%r1)
 170
 171         ld      %r1,0(%r1)              # restore stack
 172         ld      %r0,8(%r1)              # restore cr
 173         mtcr    %r0
 174         ld      %r0,16(%r1)             # restore lr
 175         mtlr    %r0
 176
 177         bctr                            # jump to target
 178
 179         .section .note.GNU-stack,"",%progbits