runtime/CMakeLists.txt

   1 # TODO: Set the install directory.
   2
   3 include(ExternalProject)
   4
   5 set(known_subdirs
   6   "libcxx"
   7   )
   8
   9 foreach (dir ${known_subdirs})
  10   if (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${dir}/CMakeLists.txt)
  11     add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${dir})
  12   endif()
  13 endforeach()
  14
  15 function(get_ext_project_build_command out_var target)
  16   if (CMAKE_GENERATOR MATCHES "Make")
  17     # Use special command for Makefiles to support parallelism.
  18     set(${out_var} "$(MAKE)" "${target}" PARENT_SCOPE)
  19   else()
  20     set(${out_var} ${CMAKE_COMMAND} --build . --target ${target}
  21                                     --config $<CONFIGURATION> PARENT_SCOPE)
  22   endif()
  23 endfunction()
  24
  25 set(COMPILER_RT_SRC_ROOT ${LLVM_MAIN_SRC_DIR}/projects/compiler-rt)
  26 # Fallback to the external path, if the other one isn't available.
  27 # This is the same behavior (try "internal", then check the LLVM_EXTERNAL_...
  28 # variable) as in add_llvm_external_project
  29 if(NOT EXISTS ${COMPILER_RT_SRC_ROOT})
  30   # We don't want to set it if LLVM_EXTERNAL_COMPILER_RT_SOURCE_DIR is ""
  31   if(${LLVM_EXTERNAL_COMPILER_RT_SOURCE_DIR})
  32     set(COMPILER_RT_SRC_ROOT ${LLVM_EXTERNAL_COMPILER_RT_SOURCE_DIR})
  33   endif()
  34 endif()
  35
  36 if(LLVM_BUILD_EXTERNAL_COMPILER_RT AND EXISTS ${COMPILER_RT_SRC_ROOT}/)
  37
  38   # Add compiler-rt as an external project.
  39   set(COMPILER_RT_PREFIX ${CMAKE_BINARY_DIR}/projects/compiler-rt)
  40
  41   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/compiler-rt-stamps/)
  42   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/compiler-rt-bins/)
  43
  44   add_custom_target(compiler-rt-clear
  45     COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
  46     COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
  47     COMMENT "Clobberring compiler-rt build and stamp directories"
  48     )
  49
  50   # Find all variables that start with COMPILER_RT and populate a variable with
  51   # them.
  52   get_cmake_property(variableNames VARIABLES)
  53   foreach(variableName ${variableNames})
  54     if(variableName MATCHES "^COMPILER_RT")
  55       string(REPLACE ";" "\;" value "${${variableName}}")
  56       list(APPEND COMPILER_RT_PASSTHROUGH_VARIABLES
  57         -D${variableName}=${value})
  58     endif()
  59   endforeach()
  60
  61   ExternalProject_Add(compiler-rt
  62     DEPENDS llvm-config clang
  63     PREFIX ${COMPILER_RT_PREFIX}
  64     SOURCE_DIR ${COMPILER_RT_SRC_ROOT}
  65     STAMP_DIR ${STAMP_DIR}
  66     BINARY_DIR ${BINARY_DIR}
  67     CMAKE_ARGS ${CLANG_COMPILER_RT_CMAKE_ARGS}
  68                -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang
  69                -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++
  70                -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
  71                -DCMAKE_MAKE_PROGRAM=${CMAKE_MAKE_PROGRAM}
  72                -DLLVM_CONFIG_PATH=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-config
  73                -DLLVM_LIT_ARGS=${LLVM_LIT_ARGS}
  74                -DCOMPILER_RT_OUTPUT_DIR=${LLVM_LIBRARY_OUTPUT_INTDIR}/clang/${CLANG_VERSION}
  75                -DCOMPILER_RT_EXEC_OUTPUT_DIR=${LLVM_RUNTIME_OUTPUT_INTDIR}
  76                -DCOMPILER_RT_INSTALL_PATH:STRING=lib${LLVM_LIBDIR_SUFFIX}/clang/${CLANG_VERSION}
  77                -DCOMPILER_RT_INCLUDE_TESTS=${LLVM_INCLUDE_TESTS}
  78                -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
  79                -DLLVM_LIBDIR_SUFFIX=${LLVM_LIBDIR_SUFFIX}
  80                -DCMAKE_OSX_DEPLOYMENT_TARGET=${CMAKE_OSX_DEPLOYMENT_TARGET}
  81                -DCMAKE_OSX_SYSROOT:PATH=${CMAKE_OSX_SYSROOT}
  82                ${COMPILER_RT_PASSTHROUGH_VARIABLES}
  83     INSTALL_COMMAND ""
  84     STEP_TARGETS configure build
  85     USES_TERMINAL_CONFIGURE 1
  86     USES_TERMINAL_BUILD 1
  87     USES_TERMINAL_INSTALL 1
  88     )
  89
  90   get_ext_project_build_command(run_clean_compiler_rt clean)
  91   ExternalProject_Add_Step(compiler-rt clean
  92     COMMAND ${run_clean_compiler_rt}
  93     COMMENT "Cleaning compiler-rt..."
  94     DEPENDEES configure
  95     DEPENDERS build
  96     DEPENDS clang
  97     WORKING_DIRECTORY ${BINARY_DIR}
  98     )
  99
 100   install(CODE "execute_process\(COMMAND \${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=\${CMAKE_INSTALL_PREFIX} -P ${BINARY_DIR}/cmake_install.cmake \)"
 101     COMPONENT compiler-rt)
 102
 103   add_custom_target(install-compiler-rt
 104                     DEPENDS compiler-rt
 105                     COMMAND "${CMAKE_COMMAND}"
 106                              -DCMAKE_INSTALL_COMPONENT=compiler-rt
 107                              -P "${CMAKE_BINARY_DIR}/cmake_install.cmake"
 108                     USES_TERMINAL)
 109
 110   # Add top-level targets that build specific compiler-rt runtimes.
 111   set(COMPILER_RT_RUNTIMES asan builtins dfsan lsan msan profile tsan ubsan)
 112   foreach(runtime ${COMPILER_RT_RUNTIMES})
 113     get_ext_project_build_command(build_runtime_cmd ${runtime})
 114     add_custom_target(${runtime}
 115       COMMAND ${build_runtime_cmd}
 116       DEPENDS compiler-rt-configure
 117       WORKING_DIRECTORY ${BINARY_DIR}
 118       VERBATIM USES_TERMINAL)
 119   endforeach()
 120
 121   if(LLVM_INCLUDE_TESTS)
 122     # Add binaries that compiler-rt tests depend on.
 123     set(COMPILER_RT_TEST_DEPENDENCIES
 124       FileCheck count not llvm-nm llvm-objdump llvm-symbolizer)
 125
 126     # Add top-level targets for various compiler-rt test suites.
 127     set(COMPILER_RT_TEST_SUITES check-asan check-asan-dynamic check-dfsan
 128       check-lsan check-msan check-sanitizer check-tsan check-ubsan
 129       check-profile check-cfi check-cfi-and-supported check-safestack)
 130     foreach(test_suite ${COMPILER_RT_TEST_SUITES})
 131       get_ext_project_build_command(run_test_suite ${test_suite})
 132       add_custom_target(${test_suite}
 133         COMMAND ${run_test_suite}
 134         DEPENDS compiler-rt-build ${COMPILER_RT_TEST_DEPENDENCIES}
 135         WORKING_DIRECTORY ${BINARY_DIR}
 136         VERBATIM
 137         USES_TERMINAL
 138         )
 139     endforeach()
 140
 141     # Add special target to run all compiler-rt test suites.
 142     get_ext_project_build_command(run_check_compiler_rt check-all)
 143     add_custom_target(check-compiler-rt
 144       COMMAND ${run_check_compiler_rt}
 145       DEPENDS compiler-rt-build ${COMPILER_RT_TEST_DEPENDENCIES}
 146       WORKING_DIRECTORY ${BINARY_DIR}
 147       VERBATIM USES_TERMINAL)
 148
 149     # Add special target to run all compiler-rt test suites.
 150     get_ext_project_build_command(run_check_compiler_rt compiler-rt-test-depends)
 151     add_custom_target(compiler-rt-test-depends
 152       COMMAND ${run_check_compiler_rt}
 153       DEPENDS compiler-rt-build ${COMPILER_RT_TEST_DEPENDENCIES}
 154       WORKING_DIRECTORY ${BINARY_DIR}
 155       VERBATIM USES_TERMINAL)
 156     set_property(GLOBAL APPEND PROPERTY LLVM_ADDITIONAL_TEST_DEPENDS compiler-rt-test-depends)
 157     set_property(GLOBAL APPEND PROPERTY LLVM_ADDITIONAL_TEST_TARGETS check-compiler-rt)
 158   endif()
 159 endif()