stand/forth/screen.4th

   1 \ Copyright (c) 2003 Scott Long <scottl@FreeBSD.org>
   2 \ Copyright (c) 2015 Devin Teske <dteske@FreeBSD.org>
   3 \ All rights reserved.
   4 \
   5 \ Redistribution and use in source and binary forms, with or without
   6 \ modification, are permitted provided that the following conditions
   7 \ are met:
   8 \ 1. Redistributions of source code must retain the above copyright
   9 \    notice, this list of conditions and the following disclaimer.
  10 \ 2. Redistributions in binary form must reproduce the above copyright
  11 \    notice, this list of conditions and the following disclaimer in the
  12 \    documentation and/or other materials provided with the distribution.
  13 \
  14 \ THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15 \ ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16 \ IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17 \ ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18 \ FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19 \ DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20 \ OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21 \ HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22 \ LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23 \ OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24 \ SUCH DAMAGE.
  25 \
  26
  27 marker task-screen.4th
  28
  29 \ emit Esc-[
  30 : escc ( -- ) 27 emit [char] [ emit ;
  31
  32 \ Home cursor ( Esc-[H )
  33 : ho ( -- ) escc [char] H emit ;
  34
  35 \ Clear from current position to end of display ( Esc-[J )
  36 : cld ( -- ) escc [char] J emit ;
  37
  38 \ clear screen
  39 : clear ( -- ) ho cld ;
  40
  41 \ reset to initial state
  42 : ris ( -- ) 27 emit [char] c emit ;
  43
  44 \ move cursor to x rows, y cols (1-based coords) ( Esc-[%d;%dH )
  45 : at-xy ( x y -- ) escc .# [char] ; emit .# [char] H emit ;
  46
  47 \ Set foreground color ( Esc-[3%dm )
  48 : fg ( x -- ) escc 3 .# .# [char] m emit ;
  49
  50 \ Set background color ( Esc-[4%dm )
  51 : bg ( x -- ) escc 4 .# .# [char] m emit ;
  52
  53 \ Mode end (clear attributes)
  54 : me ( -- ) escc [char] m emit ;
  55
  56 \ Enable bold mode ( Esc-[1m )
  57 : b ( -- ) escc 1 .# [char] m emit ;
  58
  59 \ Disable bold mode ( Esc-[22m )
  60 : -b ( -- ) escc 22 .# [char] m emit ;
  61
  62 \ Enable inverse foreground/background mode ( Esc-[7m )
  63 : inv ( -- ) escc 7 .# [char] m emit ;
  64
  65 \ Disable inverse foreground/background mode ( Esc-[27m )
  66 : -inv ( -- ) escc 27 .# [char] m emit ;
  67
  68 \ Convert all occurrences of given character (c) in string (c-addr/u) to Esc
  69 : escc! ( c-addr/u c -- c-addr/u )
  70         2 pick 2 pick
  71         begin dup 0> while
  72                 over c@ 3 pick = if over 27 swap c! then
  73                 1- swap 1+ swap
  74         repeat
  75         2drop drop
  76 ;