stand/mips/beri/boot2/relocate.S

   1 /*-
   2  * Copyright (c) 2013-2014 Robert N. M. Watson
   3  * All rights reserved.
   4  *
   5  * This software was developed by SRI International and the University of
   6  * Cambridge Computer Laboratory under DARPA/AFRL contract (FA8750-10-C-0237)
   7  * ("CTSRD"), as part of the DARPA CRASH research programme.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  *
  18  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  19  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  22  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  23  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  24  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  25  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  26  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  27  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  28  * SUCH DAMAGE.
  29  *
  30  * $FreeBSD$
  31  */
  32
  33 .set mips64
  34 .set noreorder
  35 .set nobopt
  36 .set noat
  37
  38 /*
  39  * Save arguments from the BERI firmware for use in C-land, and jump into
  40  * main.  Assume that registers/stack/etc are sufficiently initialised to get
  41  * going.  Notice that we use only temporaries while relocating, as we want to
  42  * retain argument registers to pass in to main().
  43  *
  44  * Note slightly surprising structure: boot2 is linked for a specific address,
  45  * but we may start running the code somewhere else (e.g., in DRAM as inserted
  46  * with JTAG, or in flash).  The starting assembly is therefore PIC, but the
  47  * main body of the code is not PIC.
  48  */
  49
  50
  51                 .text
  52                 .global prerelocate_start
  53                 .ent prerelocate_start
  54 prerelocate_start:
  55
  56                 /*
  57                  * Calculate the actual run-time, pre-relocated value of
  58                  * 'start', which we will use as the source address for
  59                  * memcpy().  Note that although a symbol is used here, this
  60                  * should generate code for a short relative branch, leaving
  61                  * the previous $pc in $ra.
  62                  */
  63                 bal     baltarget
  64                 nop
  65 baltarget:
  66                 dsub    $t1, $ra, 8                             /* Src. */
  67
  68                 /*
  69                  * Relocate boot2 to DRAM where we can write back global
  70                  * variable values; jump to it.  Assume all values are 32-bit
  71                  * aligned.  Use an inline PIC version of memcpy()
  72                  * pre-relocation; strong alignment assumptions.
  73                  */
  74                 dla     $t0, __boot2_base_vaddr__               /* Dst. */
  75                 dla     $t2, __boot_loader_len__                /* Len. */
  76
  77 memcpy_loop:
  78                 beq     $t2, 0, memcopy_done
  79                 nop
  80                 lw      $at, 0($t1)
  81                 sw      $at, 0($t0)
  82                 daddiu  $t0, 4
  83                 daddiu  $t1, 4
  84                 daddi   $t2, -4
  85                 b       memcpy_loop
  86                 nop
  87
  88 memcopy_done:
  89                 /*
  90                  * We can now jump into the relocated code, running from
  91                  * cached DRAM rather than uncached flash.  Note that a
  92                  * relative branch instruction cannot be used.
  93                  */
  94                 dla     $at, relocated_start
  95                 jr      $at
  96                 nop
  97
  98 relocated_start:
  99                 dla     $at, start
 100                 jr      $at
 101                 nop
 102
 103                 .end prerelocate_start