sys/amd64/amd64/cpu_switch.S

   1 /*-
   2  * Copyright (c) 2003 Peter Wemm.
   3  * Copyright (c) 1990 The Regents of the University of California.
   4  * All rights reserved.
   5  *
   6  * This code is derived from software contributed to Berkeley by
   7  * William Jolitz.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. Neither the name of the University nor the names of its contributors
  18  *    may be used to endorse or promote products derived from this software
  19  *    without specific prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  31  * SUCH DAMAGE.
  32  *
  33  * $FreeBSD$
  34  */
  35
  36 #include <machine/asmacros.h>
  37 #include <machine/specialreg.h>
  38
  39 #include "assym.inc"
  40 #include "opt_sched.h"
  41
  42 /*****************************************************************************/
  43 /* Scheduling                                                                */
  44 /*****************************************************************************/
  45
  46         .text
  47
  48 /*
  49  * cpu_throw()
  50  *
  51  * This is the second half of cpu_switch(). It is used when the current
  52  * thread is either a dummy or slated to die, and we no longer care
  53  * about its state.  This is only a slight optimization and is probably
  54  * not worth it anymore.  Note that we need to clear the pm_active bits so
  55  * we do need the old proc if it still exists.
  56  * %rdi = oldtd
  57  * %rsi = newtd
  58  */
  59 ENTRY(cpu_throw)
  60         movq    %rsi,%r12
  61         movq    %rsi,%rdi
  62         call    pmap_activate_sw
  63         jmp     sw1
  64 END(cpu_throw)
  65
  66 /*
  67  * cpu_switch(old, new, mtx)
  68  *
  69  * Save the current thread state, then select the next thread to run
  70  * and load its state.
  71  * %rdi = oldtd
  72  * %rsi = newtd
  73  * %rdx = mtx
  74  */
  75 ENTRY(cpu_switch)
  76         /* Switch to new thread.  First, save context. */
  77         leaq    TD_MD_PCB(%rdi),%r8
  78
  79         movq    (%rsp),%rax                     /* Hardware registers */
  80         movq    %r15,PCB_R15(%r8)
  81         movq    %r14,PCB_R14(%r8)
  82         movq    %r13,PCB_R13(%r8)
  83         movq    %r12,PCB_R12(%r8)
  84         movq    %rbp,PCB_RBP(%r8)
  85         movq    %rsp,PCB_RSP(%r8)
  86         movq    %rbx,PCB_RBX(%r8)
  87         movq    %rax,PCB_RIP(%r8)
  88
  89         testl   $PCB_FULL_IRET,PCB_FLAGS(%r8)
  90         jnz     2f
  91         orl     $PCB_FULL_IRET,PCB_FLAGS(%r8)
  92         testl   $TDP_KTHREAD,TD_PFLAGS(%rdi)
  93         jnz     2f
  94         testb   $CPUID_STDEXT_FSGSBASE,cpu_stdext_feature(%rip)
  95         jz      2f
  96         movl    %fs,%eax
  97         cmpl    $KUF32SEL,%eax
  98         jne     1f
  99         rdfsbase %rax
 100         movq    %rax,PCB_FSBASE(%r8)
 101 1:      movl    %gs,%eax
 102         cmpl    $KUG32SEL,%eax
 103         jne     2f
 104         movq    %rdx,%r12
 105         movl    $MSR_KGSBASE,%ecx               /* Read user gs base */
 106         rdmsr
 107         shlq    $32,%rdx
 108         orq     %rdx,%rax
 109         movq    %rax,PCB_GSBASE(%r8)
 110         movq    %r12,%rdx
 111
 112 2:
 113         testl   $PCB_DBREGS,PCB_FLAGS(%r8)
 114         jnz     store_dr                        /* static predict not taken */
 115 done_store_dr:
 116
 117         /* have we used fp, and need a save? */
 118         cmpq    %rdi,PCPU(FPCURTHREAD)
 119         jne     2f
 120         movq    PCB_SAVEFPU(%r8),%r8
 121         clts
 122         cmpl    $0,use_xsave(%rip)
 123         jne     1f
 124         fxsave  (%r8)
 125         jmp     2f
 126 1:      movq    %rdx,%rcx
 127         movl    xsave_mask,%eax
 128         movl    xsave_mask+4,%edx
 129         .globl  ctx_switch_xsave
 130 ctx_switch_xsave:
 131         /* This is patched to xsaveopt if supported, see fpuinit_bsp1() */
 132         xsave   (%r8)
 133         movq    %rcx,%rdx
 134 2:
 135         /* Save is done.  Now fire up new thread. Leave old vmspace. */
 136         movq    %rsi,%r12
 137         movq    %rdi,%r13
 138         movq    %rdx,%r15
 139         movq    %rsi,%rdi
 140         callq   pmap_activate_sw
 141         movq    %r15,TD_LOCK(%r13)              /* Release the old thread */
 142 sw1:
 143         leaq    TD_MD_PCB(%r12),%r8
 144 #if defined(SCHED_ULE) && defined(SMP)
 145         movq    $blocked_lock, %rdx
 146         movq    TD_LOCK(%r12),%rcx
 147         cmpq    %rcx, %rdx
 148         je      sw1wait
 149 sw1cont:
 150 #endif
 151         /*
 152          * At this point, we've switched address spaces and are ready
 153          * to load up the rest of the next context.
 154          */
 155
 156         /* Skip loading LDT and user fsbase/gsbase for kthreads */
 157         testl   $TDP_KTHREAD,TD_PFLAGS(%r12)
 158         jnz     do_kthread
 159
 160         /*
 161          * Load ldt register
 162          */
 163         movq    TD_PROC(%r12),%rcx
 164         cmpq    $0, P_MD+MD_LDT(%rcx)
 165         jne     do_ldt
 166         xorl    %eax,%eax
 167 ld_ldt: lldt    %ax
 168
 169         /* Restore fs base in GDT */
 170         movl    PCB_FSBASE(%r8),%eax
 171         movq    PCPU(FS32P),%rdx
 172         movw    %ax,2(%rdx)
 173         shrl    $16,%eax
 174         movb    %al,4(%rdx)
 175         shrl    $8,%eax
 176         movb    %al,7(%rdx)
 177
 178         /* Restore gs base in GDT */
 179         movl    PCB_GSBASE(%r8),%eax
 180         movq    PCPU(GS32P),%rdx
 181         movw    %ax,2(%rdx)
 182         shrl    $16,%eax
 183         movb    %al,4(%rdx)
 184         shrl    $8,%eax
 185         movb    %al,7(%rdx)
 186
 187 do_kthread:
 188         /* Do we need to reload tss ? */
 189         movq    PCPU(TSSP),%rax
 190         movq    PCB_TSSP(%r8),%rdx
 191         movq    PCPU(PRVSPACE),%r13
 192         addq    $PC_COMMONTSS,%r13
 193         testq   %rdx,%rdx
 194         cmovzq  %r13,%rdx
 195         cmpq    %rax,%rdx
 196         jne     do_tss
 197 done_tss:
 198         movq    TD_MD_STACK_BASE(%r12),%r9
 199         movq    %r9,PCPU(RSP0)
 200         movq    %r8,PCPU(CURPCB)
 201         movq    PCPU(PTI_RSP0),%rax
 202         cmpq    $~0,PCPU(UCR3)
 203         cmove   %r9,%rax
 204         movq    %rax,TSS_RSP0(%rdx)
 205         movq    %r12,PCPU(CURTHREAD)            /* into next thread */
 206
 207         /* Test if debug registers should be restored. */
 208         testl   $PCB_DBREGS,PCB_FLAGS(%r8)
 209         jnz     load_dr                         /* static predict not taken */
 210 done_load_dr:
 211
 212         /* Restore context. */
 213         movq    PCB_R15(%r8),%r15
 214         movq    PCB_R14(%r8),%r14
 215         movq    PCB_R13(%r8),%r13
 216         movq    PCB_R12(%r8),%r12
 217         movq    PCB_RBP(%r8),%rbp
 218         movq    PCB_RSP(%r8),%rsp
 219         movq    PCB_RBX(%r8),%rbx
 220         movq    PCB_RIP(%r8),%rax
 221         movq    %rax,(%rsp)
 222         movq    PCPU(CURTHREAD),%rdi
 223         call    fpu_activate_sw
 224         cmpb    $0,cpu_flush_rsb_ctxsw(%rip)
 225         jne     rsb_flush
 226         ret
 227
 228         /*
 229          * We order these strangely for several reasons.
 230          * 1: I wanted to use static branch prediction hints
 231          * 2: Most athlon64/opteron cpus don't have them.  They define
 232          *    a forward branch as 'predict not taken'.  Intel cores have
 233          *    the 'rep' prefix to invert this.
 234          * So, to make it work on both forms of cpu we do the detour.
 235          * We use jumps rather than call in order to avoid the stack.
 236          */
 237
 238 store_dr:
 239         movq    %dr7,%rax                       /* yes, do the save */
 240         movq    %dr0,%r15
 241         movq    %dr1,%r14
 242         movq    %dr2,%r13
 243         movq    %dr3,%r12
 244         movq    %dr6,%r11
 245         movq    %r15,PCB_DR0(%r8)
 246         movq    %r14,PCB_DR1(%r8)
 247         movq    %r13,PCB_DR2(%r8)
 248         movq    %r12,PCB_DR3(%r8)
 249         movq    %r11,PCB_DR6(%r8)
 250         movq    %rax,PCB_DR7(%r8)
 251         andq    $0x0000fc00, %rax               /* disable all watchpoints */
 252         movq    %rax,%dr7
 253         jmp     done_store_dr
 254
 255 load_dr:
 256         movq    %dr7,%rax
 257         movq    PCB_DR0(%r8),%r15
 258         movq    PCB_DR1(%r8),%r14
 259         movq    PCB_DR2(%r8),%r13
 260         movq    PCB_DR3(%r8),%r12
 261         movq    PCB_DR6(%r8),%r11
 262         movq    PCB_DR7(%r8),%rcx
 263         movq    %r15,%dr0
 264         movq    %r14,%dr1
 265         /* Preserve reserved bits in %dr7 */
 266         andq    $0x0000fc00,%rax
 267         andq    $~0x0000fc00,%rcx
 268         movq    %r13,%dr2
 269         movq    %r12,%dr3
 270         orq     %rcx,%rax
 271         movq    %r11,%dr6
 272         movq    %rax,%dr7
 273         jmp     done_load_dr
 274
 275 do_tss: movq    %rdx,PCPU(TSSP)
 276         movq    %rdx,%rcx
 277         movq    PCPU(TSS),%rax
 278         movw    %cx,2(%rax)
 279         shrq    $16,%rcx
 280         movb    %cl,4(%rax)
 281         shrq    $8,%rcx
 282         movb    %cl,7(%rax)
 283         shrq    $8,%rcx
 284         movl    %ecx,8(%rax)
 285         movb    $0x89,5(%rax)   /* unset busy */
 286         movl    $TSSSEL,%eax
 287         ltr     %ax
 288         jmp     done_tss
 289
 290 do_ldt: movq    PCPU(LDT),%rax
 291         movq    P_MD+MD_LDT_SD(%rcx),%rdx
 292         movq    %rdx,(%rax)
 293         movq    P_MD+MD_LDT_SD+8(%rcx),%rdx
 294         movq    %rdx,8(%rax)
 295         movl    $LDTSEL,%eax
 296         jmp     ld_ldt
 297 END(cpu_switch)
 298
 299 /*
 300  * savectx(pcb)
 301  * Update pcb, saving current processor state.
 302  */
 303 ENTRY(savectx)
 304         /* Save caller's return address. */
 305         movq    (%rsp),%rax
 306         movq    %rax,PCB_RIP(%rdi)
 307
 308         movq    %rbx,PCB_RBX(%rdi)
 309         movq    %rsp,PCB_RSP(%rdi)
 310         movq    %rbp,PCB_RBP(%rdi)
 311         movq    %r12,PCB_R12(%rdi)
 312         movq    %r13,PCB_R13(%rdi)
 313         movq    %r14,PCB_R14(%rdi)
 314         movq    %r15,PCB_R15(%rdi)
 315
 316         movq    %cr0,%rax
 317         movq    %rax,PCB_CR0(%rdi)
 318         movq    %cr2,%rax
 319         movq    %rax,PCB_CR2(%rdi)
 320         movq    %cr3,%rax
 321         movq    %rax,PCB_CR3(%rdi)
 322         movq    %cr4,%rax
 323         movq    %rax,PCB_CR4(%rdi)
 324
 325         movq    %dr0,%rax
 326         movq    %rax,PCB_DR0(%rdi)
 327         movq    %dr1,%rax
 328         movq    %rax,PCB_DR1(%rdi)
 329         movq    %dr2,%rax
 330         movq    %rax,PCB_DR2(%rdi)
 331         movq    %dr3,%rax
 332         movq    %rax,PCB_DR3(%rdi)
 333         movq    %dr6,%rax
 334         movq    %rax,PCB_DR6(%rdi)
 335         movq    %dr7,%rax
 336         movq    %rax,PCB_DR7(%rdi)
 337
 338         movl    $MSR_FSBASE,%ecx
 339         rdmsr
 340         movl    %eax,PCB_FSBASE(%rdi)
 341         movl    %edx,PCB_FSBASE+4(%rdi)
 342         movl    $MSR_GSBASE,%ecx
 343         rdmsr
 344         movl    %eax,PCB_GSBASE(%rdi)
 345         movl    %edx,PCB_GSBASE+4(%rdi)
 346         movl    $MSR_KGSBASE,%ecx
 347         rdmsr
 348         movl    %eax,PCB_KGSBASE(%rdi)
 349         movl    %edx,PCB_KGSBASE+4(%rdi)
 350         movl    $MSR_EFER,%ecx
 351         rdmsr
 352         movl    %eax,PCB_EFER(%rdi)
 353         movl    %edx,PCB_EFER+4(%rdi)
 354         movl    $MSR_STAR,%ecx
 355         rdmsr
 356         movl    %eax,PCB_STAR(%rdi)
 357         movl    %edx,PCB_STAR+4(%rdi)
 358         movl    $MSR_LSTAR,%ecx
 359         rdmsr
 360         movl    %eax,PCB_LSTAR(%rdi)
 361         movl    %edx,PCB_LSTAR+4(%rdi)
 362         movl    $MSR_CSTAR,%ecx
 363         rdmsr
 364         movl    %eax,PCB_CSTAR(%rdi)
 365         movl    %edx,PCB_CSTAR+4(%rdi)
 366         movl    $MSR_SF_MASK,%ecx
 367         rdmsr
 368         movl    %eax,PCB_SFMASK(%rdi)
 369         movl    %edx,PCB_SFMASK+4(%rdi)
 370
 371         sgdt    PCB_GDT(%rdi)
 372         sidt    PCB_IDT(%rdi)
 373         sldt    PCB_LDT(%rdi)
 374         str     PCB_TR(%rdi)
 375
 376         movl    $1,%eax
 377         ret
 378 END(savectx)
 379
 380 /*
 381  * resumectx(pcb)
 382  * Resuming processor state from pcb.
 383  */
 384 ENTRY(resumectx)
 385         /* Switch to KPML4phys. */
 386         movq    KPML4phys,%rax
 387         movq    %rax,%cr3
 388
 389         /* Force kernel segment registers. */
 390         movl    $KDSEL,%eax
 391         movw    %ax,%ds
 392         movw    %ax,%es
 393         movw    %ax,%ss
 394         movl    $KUF32SEL,%eax
 395         movw    %ax,%fs
 396         movl    $KUG32SEL,%eax
 397         movw    %ax,%gs
 398
 399         movl    $MSR_FSBASE,%ecx
 400         movl    PCB_FSBASE(%rdi),%eax
 401         movl    4 + PCB_FSBASE(%rdi),%edx
 402         wrmsr
 403         movl    $MSR_GSBASE,%ecx
 404         movl    PCB_GSBASE(%rdi),%eax
 405         movl    4 + PCB_GSBASE(%rdi),%edx
 406         wrmsr
 407         movl    $MSR_KGSBASE,%ecx
 408         movl    PCB_KGSBASE(%rdi),%eax
 409         movl    4 + PCB_KGSBASE(%rdi),%edx
 410         wrmsr
 411
 412         /* Restore EFER one more time. */
 413         movl    $MSR_EFER,%ecx
 414         movl    PCB_EFER(%rdi),%eax
 415         wrmsr
 416
 417         /* Restore fast syscall stuff. */
 418         movl    $MSR_STAR,%ecx
 419         movl    PCB_STAR(%rdi),%eax
 420         movl    4 + PCB_STAR(%rdi),%edx
 421         wrmsr
 422         movl    $MSR_LSTAR,%ecx
 423         movl    PCB_LSTAR(%rdi),%eax
 424         movl    4 + PCB_LSTAR(%rdi),%edx
 425         wrmsr
 426         movl    $MSR_CSTAR,%ecx
 427         movl    PCB_CSTAR(%rdi),%eax
 428         movl    4 + PCB_CSTAR(%rdi),%edx
 429         wrmsr
 430         movl    $MSR_SF_MASK,%ecx
 431         movl    PCB_SFMASK(%rdi),%eax
 432         wrmsr
 433
 434         /* Restore CR0, CR2, CR4 and CR3. */
 435         movq    PCB_CR0(%rdi),%rax
 436         movq    %rax,%cr0
 437         movq    PCB_CR2(%rdi),%rax
 438         movq    %rax,%cr2
 439         movq    PCB_CR4(%rdi),%rax
 440         movq    %rax,%cr4
 441         movq    PCB_CR3(%rdi),%rax
 442         movq    %rax,%cr3
 443
 444         /* Restore descriptor tables. */
 445         lidt    PCB_IDT(%rdi)
 446         lldt    PCB_LDT(%rdi)
 447
 448 #define SDT_SYSTSS      9
 449 #define SDT_SYSBSY      11
 450
 451         /* Clear "task busy" bit and reload TR. */
 452         movq    PCPU(TSS),%rax
 453         andb    $(~SDT_SYSBSY | SDT_SYSTSS),5(%rax)
 454         movw    PCB_TR(%rdi),%ax
 455         ltr     %ax
 456
 457 #undef  SDT_SYSTSS
 458 #undef  SDT_SYSBSY
 459
 460         /* Restore debug registers. */
 461         movq    PCB_DR0(%rdi),%rax
 462         movq    %rax,%dr0
 463         movq    PCB_DR1(%rdi),%rax
 464         movq    %rax,%dr1
 465         movq    PCB_DR2(%rdi),%rax
 466         movq    %rax,%dr2
 467         movq    PCB_DR3(%rdi),%rax
 468         movq    %rax,%dr3
 469         movq    PCB_DR6(%rdi),%rax
 470         movq    %rax,%dr6
 471         movq    PCB_DR7(%rdi),%rax
 472         movq    %rax,%dr7
 473
 474         /* Restore other callee saved registers. */
 475         movq    PCB_R15(%rdi),%r15
 476         movq    PCB_R14(%rdi),%r14
 477         movq    PCB_R13(%rdi),%r13
 478         movq    PCB_R12(%rdi),%r12
 479         movq    PCB_RBP(%rdi),%rbp
 480         movq    PCB_RSP(%rdi),%rsp
 481         movq    PCB_RBX(%rdi),%rbx
 482
 483         /* Restore return address. */
 484         movq    PCB_RIP(%rdi),%rax
 485         movq    %rax,(%rsp)
 486
 487         xorl    %eax,%eax
 488         ret
 489 END(resumectx)
 490
 491 /* Wait for the new thread to become unblocked */
 492 #if defined(SCHED_ULE) && defined(SMP)
 493 sw1wait:
 494 1:
 495         pause
 496         movq    TD_LOCK(%r12),%rcx
 497         cmpq    %rcx, %rdx
 498         je      1b
 499         jmp     sw1cont
 500 #endif