sys/amd64/amd64/cpu_switch.S

   1 /*-
   2  * Copyright (c) 2003 Peter Wemm.
   3  * Copyright (c) 1990 The Regents of the University of California.
   4  * All rights reserved.
   5  *
   6  * This code is derived from software contributed to Berkeley by
   7  * William Jolitz.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 4. Neither the name of the University nor the names of its contributors
  18  *    may be used to endorse or promote products derived from this software
  19  *    without specific prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  31  * SUCH DAMAGE.
  32  *
  33  * $FreeBSD$
  34  */
  35
  36 #include <machine/asmacros.h>
  37 #include <machine/specialreg.h>
  38
  39 #include "assym.s"
  40 #include "opt_sched.h"
  41
  42 /*****************************************************************************/
  43 /* Scheduling                                                                */
  44 /*****************************************************************************/
  45
  46         .text
  47
  48 #ifdef SMP
  49 #define LK      lock ;
  50 #else
  51 #define LK
  52 #endif
  53
  54 #if defined(SCHED_ULE) && defined(SMP)
  55 #define SETLK   xchgq
  56 #else
  57 #define SETLK   movq
  58 #endif
  59
  60 /*
  61  * cpu_throw()
  62  *
  63  * This is the second half of cpu_switch(). It is used when the current
  64  * thread is either a dummy or slated to die, and we no longer care
  65  * about its state.  This is only a slight optimization and is probably
  66  * not worth it anymore.  Note that we need to clear the pm_active bits so
  67  * we do need the old proc if it still exists.
  68  * %rdi = oldtd
  69  * %rsi = newtd
  70  */
  71 ENTRY(cpu_throw)
  72         movq    %rsi,%r12
  73         movq    %rsi,%rdi
  74         call    pmap_activate_sw
  75         jmp     sw1
  76 END(cpu_throw)
  77
  78 /*
  79  * cpu_switch(old, new, mtx)
  80  *
  81  * Save the current thread state, then select the next thread to run
  82  * and load its state.
  83  * %rdi = oldtd
  84  * %rsi = newtd
  85  * %rdx = mtx
  86  */
  87 ENTRY(cpu_switch)
  88         /* Switch to new thread.  First, save context. */
  89         movq    TD_PCB(%rdi),%r8
  90
  91         movq    (%rsp),%rax                     /* Hardware registers */
  92         movq    %r15,PCB_R15(%r8)
  93         movq    %r14,PCB_R14(%r8)
  94         movq    %r13,PCB_R13(%r8)
  95         movq    %r12,PCB_R12(%r8)
  96         movq    %rbp,PCB_RBP(%r8)
  97         movq    %rsp,PCB_RSP(%r8)
  98         movq    %rbx,PCB_RBX(%r8)
  99         movq    %rax,PCB_RIP(%r8)
 100
 101         testl   $PCB_FULL_IRET,PCB_FLAGS(%r8)
 102         jnz     2f
 103         orl     $PCB_FULL_IRET,PCB_FLAGS(%r8)
 104         testl   $TDP_KTHREAD,TD_PFLAGS(%rdi)
 105         jnz     2f
 106         testb   $CPUID_STDEXT_FSGSBASE,cpu_stdext_feature(%rip)
 107         jz      2f
 108         movl    %fs,%eax
 109         cmpl    $KUF32SEL,%eax
 110         jne     1f
 111         rdfsbase %rax
 112         movq    %rax,PCB_FSBASE(%r8)
 113 1:      movl    %gs,%eax
 114         cmpl    $KUG32SEL,%eax
 115         jne     2f
 116         movq    %rdx,%r12
 117         movl    $MSR_KGSBASE,%ecx               /* Read user gs base */
 118         rdmsr
 119         shlq    $32,%rdx
 120         orq     %rdx,%rax
 121         movq    %rax,PCB_GSBASE(%r8)
 122         movq    %r12,%rdx
 123
 124 2:
 125         testl   $PCB_DBREGS,PCB_FLAGS(%r8)
 126         jnz     store_dr                        /* static predict not taken */
 127 done_store_dr:
 128
 129         /* have we used fp, and need a save? */
 130         cmpq    %rdi,PCPU(FPCURTHREAD)
 131         jne     3f
 132         movq    PCB_SAVEFPU(%r8),%r8
 133         clts
 134         cmpl    $0,use_xsave
 135         jne     1f
 136         fxsave  (%r8)
 137         jmp     2f
 138 1:      movq    %rdx,%rcx
 139         movl    xsave_mask,%eax
 140         movl    xsave_mask+4,%edx
 141         .globl  ctx_switch_xsave
 142 ctx_switch_xsave:
 143         /* This is patched to xsaveopt if supported, see fpuinit_bsp1() */
 144         xsave   (%r8)
 145         movq    %rcx,%rdx
 146 2:      smsw    %ax
 147         orb     $CR0_TS,%al
 148         lmsw    %ax
 149         xorl    %eax,%eax
 150         movq    %rax,PCPU(FPCURTHREAD)
 151 3:
 152         /* Save is done.  Now fire up new thread. Leave old vmspace. */
 153         movq    %rsi,%r12
 154         movq    %rdi,%r13
 155         movq    %rdx,%r15
 156         movq    %rsi,%rdi
 157         callq   pmap_activate_sw
 158         SETLK   %r15,TD_LOCK(%r13)              /* Release the old thread */
 159 sw1:
 160         movq    TD_PCB(%r12),%r8
 161 #if defined(SCHED_ULE) && defined(SMP)
 162         /* Wait for the new thread to become unblocked */
 163         movq    $blocked_lock, %rdx
 164 1:
 165         movq    TD_LOCK(%r12),%rcx
 166         cmpq    %rcx, %rdx
 167         pause
 168         je      1b
 169 #endif
 170         /*
 171          * At this point, we've switched address spaces and are ready
 172          * to load up the rest of the next context.
 173          */
 174
 175         /* Skip loading LDT and user fsbase/gsbase for kthreads */
 176         testl   $TDP_KTHREAD,TD_PFLAGS(%r12)
 177         jnz     do_kthread
 178
 179         /*
 180          * Load ldt register
 181          */
 182         movq    TD_PROC(%r12),%rcx
 183         cmpq    $0, P_MD+MD_LDT(%rcx)
 184         jne     do_ldt
 185         xorl    %eax,%eax
 186 ld_ldt: lldt    %ax
 187
 188         /* Restore fs base in GDT */
 189         movl    PCB_FSBASE(%r8),%eax
 190         movq    PCPU(FS32P),%rdx
 191         movw    %ax,2(%rdx)
 192         shrl    $16,%eax
 193         movb    %al,4(%rdx)
 194         shrl    $8,%eax
 195         movb    %al,7(%rdx)
 196
 197         /* Restore gs base in GDT */
 198         movl    PCB_GSBASE(%r8),%eax
 199         movq    PCPU(GS32P),%rdx
 200         movw    %ax,2(%rdx)
 201         shrl    $16,%eax
 202         movb    %al,4(%rdx)
 203         shrl    $8,%eax
 204         movb    %al,7(%rdx)
 205
 206 do_kthread:
 207         /* Do we need to reload tss ? */
 208         movq    PCPU(TSSP),%rax
 209         movq    PCB_TSSP(%r8),%rdx
 210         testq   %rdx,%rdx
 211         cmovzq  PCPU(COMMONTSSP),%rdx
 212         cmpq    %rax,%rdx
 213         jne     do_tss
 214 done_tss:
 215         movq    %r8,PCPU(RSP0)
 216         movq    %r8,PCPU(CURPCB)
 217         /* Update the TSS_RSP0 pointer for the next interrupt */
 218         movq    %r8,COMMON_TSS_RSP0(%rdx)
 219         movq    %r12,PCPU(CURTHREAD)            /* into next thread */
 220
 221         /* Test if debug registers should be restored. */
 222         testl   $PCB_DBREGS,PCB_FLAGS(%r8)
 223         jnz     load_dr                         /* static predict not taken */
 224 done_load_dr:
 225
 226         /* Restore context. */
 227         movq    PCB_R15(%r8),%r15
 228         movq    PCB_R14(%r8),%r14
 229         movq    PCB_R13(%r8),%r13
 230         movq    PCB_R12(%r8),%r12
 231         movq    PCB_RBP(%r8),%rbp
 232         movq    PCB_RSP(%r8),%rsp
 233         movq    PCB_RBX(%r8),%rbx
 234         movq    PCB_RIP(%r8),%rax
 235         movq    %rax,(%rsp)
 236         ret
 237
 238         /*
 239          * We order these strangely for several reasons.
 240          * 1: I wanted to use static branch prediction hints
 241          * 2: Most athlon64/opteron cpus don't have them.  They define
 242          *    a forward branch as 'predict not taken'.  Intel cores have
 243          *    the 'rep' prefix to invert this.
 244          * So, to make it work on both forms of cpu we do the detour.
 245          * We use jumps rather than call in order to avoid the stack.
 246          */
 247
 248 store_dr:
 249         movq    %dr7,%rax                       /* yes, do the save */
 250         movq    %dr0,%r15
 251         movq    %dr1,%r14
 252         movq    %dr2,%r13
 253         movq    %dr3,%r12
 254         movq    %dr6,%r11
 255         movq    %r15,PCB_DR0(%r8)
 256         movq    %r14,PCB_DR1(%r8)
 257         movq    %r13,PCB_DR2(%r8)
 258         movq    %r12,PCB_DR3(%r8)
 259         movq    %r11,PCB_DR6(%r8)
 260         movq    %rax,PCB_DR7(%r8)
 261         andq    $0x0000fc00, %rax               /* disable all watchpoints */
 262         movq    %rax,%dr7
 263         jmp     done_store_dr
 264
 265 load_dr:
 266         movq    %dr7,%rax
 267         movq    PCB_DR0(%r8),%r15
 268         movq    PCB_DR1(%r8),%r14
 269         movq    PCB_DR2(%r8),%r13
 270         movq    PCB_DR3(%r8),%r12
 271         movq    PCB_DR6(%r8),%r11
 272         movq    PCB_DR7(%r8),%rcx
 273         movq    %r15,%dr0
 274         movq    %r14,%dr1
 275         /* Preserve reserved bits in %dr7 */
 276         andq    $0x0000fc00,%rax
 277         andq    $~0x0000fc00,%rcx
 278         movq    %r13,%dr2
 279         movq    %r12,%dr3
 280         orq     %rcx,%rax
 281         movq    %r11,%dr6
 282         movq    %rax,%dr7
 283         jmp     done_load_dr
 284
 285 do_tss: movq    %rdx,PCPU(TSSP)
 286         movq    %rdx,%rcx
 287         movq    PCPU(TSS),%rax
 288         movw    %cx,2(%rax)
 289         shrq    $16,%rcx
 290         movb    %cl,4(%rax)
 291         shrq    $8,%rcx
 292         movb    %cl,7(%rax)
 293         shrq    $8,%rcx
 294         movl    %ecx,8(%rax)
 295         movb    $0x89,5(%rax)   /* unset busy */
 296         movl    $TSSSEL,%eax
 297         ltr     %ax
 298         jmp     done_tss
 299
 300 do_ldt: movq    PCPU(LDT),%rax
 301         movq    P_MD+MD_LDT_SD(%rcx),%rdx
 302         movq    %rdx,(%rax)
 303         movq    P_MD+MD_LDT_SD+8(%rcx),%rdx
 304         movq    %rdx,8(%rax)
 305         movl    $LDTSEL,%eax
 306         jmp     ld_ldt
 307 END(cpu_switch)
 308
 309 /*
 310  * savectx(pcb)
 311  * Update pcb, saving current processor state.
 312  */
 313 ENTRY(savectx)
 314         /* Save caller's return address. */
 315         movq    (%rsp),%rax
 316         movq    %rax,PCB_RIP(%rdi)
 317
 318         movq    %rbx,PCB_RBX(%rdi)
 319         movq    %rsp,PCB_RSP(%rdi)
 320         movq    %rbp,PCB_RBP(%rdi)
 321         movq    %r12,PCB_R12(%rdi)
 322         movq    %r13,PCB_R13(%rdi)
 323         movq    %r14,PCB_R14(%rdi)
 324         movq    %r15,PCB_R15(%rdi)
 325
 326         movq    %cr0,%rax
 327         movq    %rax,PCB_CR0(%rdi)
 328         movq    %cr2,%rax
 329         movq    %rax,PCB_CR2(%rdi)
 330         movq    %cr3,%rax
 331         movq    %rax,PCB_CR3(%rdi)
 332         movq    %cr4,%rax
 333         movq    %rax,PCB_CR4(%rdi)
 334
 335         movq    %dr0,%rax
 336         movq    %rax,PCB_DR0(%rdi)
 337         movq    %dr1,%rax
 338         movq    %rax,PCB_DR1(%rdi)
 339         movq    %dr2,%rax
 340         movq    %rax,PCB_DR2(%rdi)
 341         movq    %dr3,%rax
 342         movq    %rax,PCB_DR3(%rdi)
 343         movq    %dr6,%rax
 344         movq    %rax,PCB_DR6(%rdi)
 345         movq    %dr7,%rax
 346         movq    %rax,PCB_DR7(%rdi)
 347
 348         movl    $MSR_FSBASE,%ecx
 349         rdmsr
 350         movl    %eax,PCB_FSBASE(%rdi)
 351         movl    %edx,PCB_FSBASE+4(%rdi)
 352         movl    $MSR_GSBASE,%ecx
 353         rdmsr
 354         movl    %eax,PCB_GSBASE(%rdi)
 355         movl    %edx,PCB_GSBASE+4(%rdi)
 356         movl    $MSR_KGSBASE,%ecx
 357         rdmsr
 358         movl    %eax,PCB_KGSBASE(%rdi)
 359         movl    %edx,PCB_KGSBASE+4(%rdi)
 360         movl    $MSR_EFER,%ecx
 361         rdmsr
 362         movl    %eax,PCB_EFER(%rdi)
 363         movl    %edx,PCB_EFER+4(%rdi)
 364         movl    $MSR_STAR,%ecx
 365         rdmsr
 366         movl    %eax,PCB_STAR(%rdi)
 367         movl    %edx,PCB_STAR+4(%rdi)
 368         movl    $MSR_LSTAR,%ecx
 369         rdmsr
 370         movl    %eax,PCB_LSTAR(%rdi)
 371         movl    %edx,PCB_LSTAR+4(%rdi)
 372         movl    $MSR_CSTAR,%ecx
 373         rdmsr
 374         movl    %eax,PCB_CSTAR(%rdi)
 375         movl    %edx,PCB_CSTAR+4(%rdi)
 376         movl    $MSR_SF_MASK,%ecx
 377         rdmsr
 378         movl    %eax,PCB_SFMASK(%rdi)
 379         movl    %edx,PCB_SFMASK+4(%rdi)
 380
 381         sgdt    PCB_GDT(%rdi)
 382         sidt    PCB_IDT(%rdi)
 383         sldt    PCB_LDT(%rdi)
 384         str     PCB_TR(%rdi)
 385
 386         movl    $1,%eax
 387         ret
 388 END(savectx)
 389
 390 /*
 391  * resumectx(pcb)
 392  * Resuming processor state from pcb.
 393  */
 394 ENTRY(resumectx)
 395         /* Switch to KPML4phys. */
 396         movq    KPML4phys,%rax
 397         movq    %rax,%cr3
 398
 399         /* Force kernel segment registers. */
 400         movl    $KDSEL,%eax
 401         movw    %ax,%ds
 402         movw    %ax,%es
 403         movw    %ax,%ss
 404         movl    $KUF32SEL,%eax
 405         movw    %ax,%fs
 406         movl    $KUG32SEL,%eax
 407         movw    %ax,%gs
 408
 409         movl    $MSR_FSBASE,%ecx
 410         movl    PCB_FSBASE(%rdi),%eax
 411         movl    4 + PCB_FSBASE(%rdi),%edx
 412         wrmsr
 413         movl    $MSR_GSBASE,%ecx
 414         movl    PCB_GSBASE(%rdi),%eax
 415         movl    4 + PCB_GSBASE(%rdi),%edx
 416         wrmsr
 417         movl    $MSR_KGSBASE,%ecx
 418         movl    PCB_KGSBASE(%rdi),%eax
 419         movl    4 + PCB_KGSBASE(%rdi),%edx
 420         wrmsr
 421
 422         /* Restore EFER one more time. */
 423         movl    $MSR_EFER,%ecx
 424         movl    PCB_EFER(%rdi),%eax
 425         wrmsr
 426
 427         /* Restore fast syscall stuff. */
 428         movl    $MSR_STAR,%ecx
 429         movl    PCB_STAR(%rdi),%eax
 430         movl    4 + PCB_STAR(%rdi),%edx
 431         wrmsr
 432         movl    $MSR_LSTAR,%ecx
 433         movl    PCB_LSTAR(%rdi),%eax
 434         movl    4 + PCB_LSTAR(%rdi),%edx
 435         wrmsr
 436         movl    $MSR_CSTAR,%ecx
 437         movl    PCB_CSTAR(%rdi),%eax
 438         movl    4 + PCB_CSTAR(%rdi),%edx
 439         wrmsr
 440         movl    $MSR_SF_MASK,%ecx
 441         movl    PCB_SFMASK(%rdi),%eax
 442         wrmsr
 443
 444         /* Restore CR0, CR2, CR4 and CR3. */
 445         movq    PCB_CR0(%rdi),%rax
 446         movq    %rax,%cr0
 447         movq    PCB_CR2(%rdi),%rax
 448         movq    %rax,%cr2
 449         movq    PCB_CR4(%rdi),%rax
 450         movq    %rax,%cr4
 451         movq    PCB_CR3(%rdi),%rax
 452         movq    %rax,%cr3
 453
 454         /* Restore descriptor tables. */
 455         lidt    PCB_IDT(%rdi)
 456         lldt    PCB_LDT(%rdi)
 457
 458 #define SDT_SYSTSS      9
 459 #define SDT_SYSBSY      11
 460
 461         /* Clear "task busy" bit and reload TR. */
 462         movq    PCPU(TSS),%rax
 463         andb    $(~SDT_SYSBSY | SDT_SYSTSS),5(%rax)
 464         movw    PCB_TR(%rdi),%ax
 465         ltr     %ax
 466
 467 #undef  SDT_SYSTSS
 468 #undef  SDT_SYSBSY
 469
 470         /* Restore debug registers. */
 471         movq    PCB_DR0(%rdi),%rax
 472         movq    %rax,%dr0
 473         movq    PCB_DR1(%rdi),%rax
 474         movq    %rax,%dr1
 475         movq    PCB_DR2(%rdi),%rax
 476         movq    %rax,%dr2
 477         movq    PCB_DR3(%rdi),%rax
 478         movq    %rax,%dr3
 479         movq    PCB_DR6(%rdi),%rax
 480         movq    %rax,%dr6
 481         movq    PCB_DR7(%rdi),%rax
 482         movq    %rax,%dr7
 483
 484         /* Restore other callee saved registers. */
 485         movq    PCB_R15(%rdi),%r15
 486         movq    PCB_R14(%rdi),%r14
 487         movq    PCB_R13(%rdi),%r13
 488         movq    PCB_R12(%rdi),%r12
 489         movq    PCB_RBP(%rdi),%rbp
 490         movq    PCB_RSP(%rdi),%rsp
 491         movq    PCB_RBX(%rdi),%rbx
 492
 493         /* Restore return address. */
 494         movq    PCB_RIP(%rdi),%rax
 495         movq    %rax,(%rsp)
 496
 497         xorl    %eax,%eax
 498         ret
 499 END(resumectx)