sys/amd64/amd64/cpu_switch.S

   1 /*-
   2  * Copyright (c) 2003 Peter Wemm.
   3  * Copyright (c) 1990 The Regents of the University of California.
   4  * All rights reserved.
   5  *
   6  * This code is derived from software contributed to Berkeley by
   7  * William Jolitz.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 4. Neither the name of the University nor the names of its contributors
  18  *    may be used to endorse or promote products derived from this software
  19  *    without specific prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  31  * SUCH DAMAGE.
  32  *
  33  * $FreeBSD$
  34  */
  35
  36 #include <machine/asmacros.h>
  37 #include <machine/specialreg.h>
  38
  39 #include "assym.s"
  40 #include "opt_sched.h"
  41
  42 /*****************************************************************************/
  43 /* Scheduling                                                                */
  44 /*****************************************************************************/
  45
  46         .text
  47
  48 #ifdef SMP
  49 #define LK      lock ;
  50 #else
  51 #define LK
  52 #endif
  53
  54 #if defined(SCHED_ULE) && defined(SMP)
  55 #define SETLK   xchgq
  56 #else
  57 #define SETLK   movq
  58 #endif
  59
  60 /*
  61  * cpu_throw()
  62  *
  63  * This is the second half of cpu_switch(). It is used when the current
  64  * thread is either a dummy or slated to die, and we no longer care
  65  * about its state.  This is only a slight optimization and is probably
  66  * not worth it anymore.  Note that we need to clear the pm_active bits so
  67  * we do need the old proc if it still exists.
  68  * %rdi = oldtd
  69  * %rsi = newtd
  70  */
  71 ENTRY(cpu_throw)
  72         movq    %rsi,%r12
  73         movq    %rsi,%rdi
  74         call    pmap_activate_sw
  75         jmp     sw1
  76 END(cpu_throw)
  77
  78 /*
  79  * cpu_switch(old, new, mtx)
  80  *
  81  * Save the current thread state, then select the next thread to run
  82  * and load its state.
  83  * %rdi = oldtd
  84  * %rsi = newtd
  85  * %rdx = mtx
  86  */
  87 ENTRY(cpu_switch)
  88         /* Switch to new thread.  First, save context. */
  89         movq    TD_PCB(%rdi),%r8
  90
  91         movq    (%rsp),%rax                     /* Hardware registers */
  92         movq    %r15,PCB_R15(%r8)
  93         movq    %r14,PCB_R14(%r8)
  94         movq    %r13,PCB_R13(%r8)
  95         movq    %r12,PCB_R12(%r8)
  96         movq    %rbp,PCB_RBP(%r8)
  97         movq    %rsp,PCB_RSP(%r8)
  98         movq    %rbx,PCB_RBX(%r8)
  99         movq    %rax,PCB_RIP(%r8)
 100
 101         testl   $PCB_FULL_IRET,PCB_FLAGS(%r8)
 102         jnz     2f
 103         orl     $PCB_FULL_IRET,PCB_FLAGS(%r8)
 104         testl   $TDP_KTHREAD,TD_PFLAGS(%rdi)
 105         jnz     2f
 106         testb   $CPUID_STDEXT_FSGSBASE,cpu_stdext_feature(%rip)
 107         jz      2f
 108         movl    %fs,%eax
 109         cmpl    $KUF32SEL,%eax
 110         jne     1f
 111         rdfsbase %rax
 112         movq    %rax,PCB_FSBASE(%r8)
 113 1:      movl    %gs,%eax
 114         cmpl    $KUG32SEL,%eax
 115         jne     2f
 116         movq    %rdx,%r12
 117         movl    $MSR_KGSBASE,%ecx               /* Read user gs base */
 118         rdmsr
 119         shlq    $32,%rdx
 120         orq     %rdx,%rax
 121         movq    %rax,PCB_GSBASE(%r8)
 122         movq    %r12,%rdx
 123
 124 2:
 125         testl   $PCB_DBREGS,PCB_FLAGS(%r8)
 126         jnz     store_dr                        /* static predict not taken */
 127 done_store_dr:
 128
 129         /* have we used fp, and need a save? */
 130         cmpq    %rdi,PCPU(FPCURTHREAD)
 131         jne     3f
 132         movq    PCB_SAVEFPU(%r8),%r8
 133         clts
 134         cmpl    $0,use_xsave
 135         jne     1f
 136         fxsave  (%r8)
 137         jmp     2f
 138 1:      movq    %rdx,%rcx
 139         movl    xsave_mask,%eax
 140         movl    xsave_mask+4,%edx
 141         .globl  ctx_switch_xsave
 142 ctx_switch_xsave:
 143         /* This is patched to xsaveopt if supported, see fpuinit_bsp1() */
 144         xsave   (%r8)
 145         movq    %rcx,%rdx
 146 2:      smsw    %ax
 147         orb     $CR0_TS,%al
 148         lmsw    %ax
 149         xorl    %eax,%eax
 150         movq    %rax,PCPU(FPCURTHREAD)
 151 3:
 152         /* Save is done.  Now fire up new thread. Leave old vmspace. */
 153         movq    %rsi,%r12
 154         movq    %rdi,%r13
 155         movq    %rdx,%r15
 156         movq    %rsi,%rdi
 157         callq   pmap_activate_sw
 158         SETLK   %r15,TD_LOCK(%r13)              /* Release the old thread */
 159 sw1:
 160         movq    TD_PCB(%r12),%r8
 161 #if defined(SCHED_ULE) && defined(SMP)
 162         /* Wait for the new thread to become unblocked */
 163         movq    $blocked_lock, %rdx
 164 1:
 165         movq    TD_LOCK(%r12),%rcx
 166         cmpq    %rcx, %rdx
 167         pause
 168         je      1b
 169 #endif
 170         /*
 171          * At this point, we've switched address spaces and are ready
 172          * to load up the rest of the next context.
 173          */
 174
 175         /* Skip loading LDT and user fsbase/gsbase for kthreads */
 176         testl   $TDP_KTHREAD,TD_PFLAGS(%r12)
 177         jnz     do_kthread
 178
 179         /*
 180          * Load ldt register
 181          */
 182         movq    TD_PROC(%r12),%rcx
 183         cmpq    $0, P_MD+MD_LDT(%rcx)
 184         jne     do_ldt
 185         xorl    %eax,%eax
 186 ld_ldt: lldt    %ax
 187
 188         /* Restore fs base in GDT */
 189         movl    PCB_FSBASE(%r8),%eax
 190         movq    PCPU(FS32P),%rdx
 191         movw    %ax,2(%rdx)
 192         shrl    $16,%eax
 193         movb    %al,4(%rdx)
 194         shrl    $8,%eax
 195         movb    %al,7(%rdx)
 196
 197         /* Restore gs base in GDT */
 198         movl    PCB_GSBASE(%r8),%eax
 199         movq    PCPU(GS32P),%rdx
 200         movw    %ax,2(%rdx)
 201         shrl    $16,%eax
 202         movb    %al,4(%rdx)
 203         shrl    $8,%eax
 204         movb    %al,7(%rdx)
 205
 206 do_kthread:
 207         /* Do we need to reload tss ? */
 208         movq    PCPU(TSSP),%rax
 209         movq    PCB_TSSP(%r8),%rdx
 210         testq   %rdx,%rdx
 211         cmovzq  PCPU(COMMONTSSP),%rdx
 212         cmpq    %rax,%rdx
 213         jne     do_tss
 214 done_tss:
 215         movq    %r8,PCPU(RSP0)
 216         movq    %r8,PCPU(CURPCB)
 217         /* Update the TSS_RSP0 pointer for the next interrupt */
 218         cmpb    $0,pti(%rip)
 219         jne     1f
 220         movq    %r8,TSS_RSP0(%rdx)
 221 1:      movq    %r12,PCPU(CURTHREAD)            /* into next thread */
 222
 223         /* Test if debug registers should be restored. */
 224         testl   $PCB_DBREGS,PCB_FLAGS(%r8)
 225         jnz     load_dr                         /* static predict not taken */
 226 done_load_dr:
 227
 228         /* Restore context. */
 229         movq    PCB_R15(%r8),%r15
 230         movq    PCB_R14(%r8),%r14
 231         movq    PCB_R13(%r8),%r13
 232         movq    PCB_R12(%r8),%r12
 233         movq    PCB_RBP(%r8),%rbp
 234         movq    PCB_RSP(%r8),%rsp
 235         movq    PCB_RBX(%r8),%rbx
 236         movq    PCB_RIP(%r8),%rax
 237         movq    %rax,(%rsp)
 238         ret
 239
 240         /*
 241          * We order these strangely for several reasons.
 242          * 1: I wanted to use static branch prediction hints
 243          * 2: Most athlon64/opteron cpus don't have them.  They define
 244          *    a forward branch as 'predict not taken'.  Intel cores have
 245          *    the 'rep' prefix to invert this.
 246          * So, to make it work on both forms of cpu we do the detour.
 247          * We use jumps rather than call in order to avoid the stack.
 248          */
 249
 250 store_dr:
 251         movq    %dr7,%rax                       /* yes, do the save */
 252         movq    %dr0,%r15
 253         movq    %dr1,%r14
 254         movq    %dr2,%r13
 255         movq    %dr3,%r12
 256         movq    %dr6,%r11
 257         movq    %r15,PCB_DR0(%r8)
 258         movq    %r14,PCB_DR1(%r8)
 259         movq    %r13,PCB_DR2(%r8)
 260         movq    %r12,PCB_DR3(%r8)
 261         movq    %r11,PCB_DR6(%r8)
 262         movq    %rax,PCB_DR7(%r8)
 263         andq    $0x0000fc00, %rax               /* disable all watchpoints */
 264         movq    %rax,%dr7
 265         jmp     done_store_dr
 266
 267 load_dr:
 268         movq    %dr7,%rax
 269         movq    PCB_DR0(%r8),%r15
 270         movq    PCB_DR1(%r8),%r14
 271         movq    PCB_DR2(%r8),%r13
 272         movq    PCB_DR3(%r8),%r12
 273         movq    PCB_DR6(%r8),%r11
 274         movq    PCB_DR7(%r8),%rcx
 275         movq    %r15,%dr0
 276         movq    %r14,%dr1
 277         /* Preserve reserved bits in %dr7 */
 278         andq    $0x0000fc00,%rax
 279         andq    $~0x0000fc00,%rcx
 280         movq    %r13,%dr2
 281         movq    %r12,%dr3
 282         orq     %rcx,%rax
 283         movq    %r11,%dr6
 284         movq    %rax,%dr7
 285         jmp     done_load_dr
 286
 287 do_tss: movq    %rdx,PCPU(TSSP)
 288         movq    %rdx,%rcx
 289         movq    PCPU(TSS),%rax
 290         movw    %cx,2(%rax)
 291         shrq    $16,%rcx
 292         movb    %cl,4(%rax)
 293         shrq    $8,%rcx
 294         movb    %cl,7(%rax)
 295         shrq    $8,%rcx
 296         movl    %ecx,8(%rax)
 297         movb    $0x89,5(%rax)   /* unset busy */
 298         cmpb    $0,pti(%rip)
 299         je      1f
 300         movq    PCPU(PRVSPACE),%rax
 301         addq    $PC_PTI_STACK+PC_PTI_STACK_SZ*8,%rax
 302         movq    %rax,TSS_RSP0(%rdx)
 303 1:      movl    $TSSSEL,%eax
 304         ltr     %ax
 305         jmp     done_tss
 306
 307 do_ldt: movq    PCPU(LDT),%rax
 308         movq    P_MD+MD_LDT_SD(%rcx),%rdx
 309         movq    %rdx,(%rax)
 310         movq    P_MD+MD_LDT_SD+8(%rcx),%rdx
 311         movq    %rdx,8(%rax)
 312         movl    $LDTSEL,%eax
 313         jmp     ld_ldt
 314 END(cpu_switch)
 315
 316 /*
 317  * savectx(pcb)
 318  * Update pcb, saving current processor state.
 319  */
 320 ENTRY(savectx)
 321         /* Save caller's return address. */
 322         movq    (%rsp),%rax
 323         movq    %rax,PCB_RIP(%rdi)
 324
 325         movq    %rbx,PCB_RBX(%rdi)
 326         movq    %rsp,PCB_RSP(%rdi)
 327         movq    %rbp,PCB_RBP(%rdi)
 328         movq    %r12,PCB_R12(%rdi)
 329         movq    %r13,PCB_R13(%rdi)
 330         movq    %r14,PCB_R14(%rdi)
 331         movq    %r15,PCB_R15(%rdi)
 332
 333         movq    %cr0,%rax
 334         movq    %rax,PCB_CR0(%rdi)
 335         movq    %cr2,%rax
 336         movq    %rax,PCB_CR2(%rdi)
 337         movq    %cr3,%rax
 338         movq    %rax,PCB_CR3(%rdi)
 339         movq    %cr4,%rax
 340         movq    %rax,PCB_CR4(%rdi)
 341
 342         movq    %dr0,%rax
 343         movq    %rax,PCB_DR0(%rdi)
 344         movq    %dr1,%rax
 345         movq    %rax,PCB_DR1(%rdi)
 346         movq    %dr2,%rax
 347         movq    %rax,PCB_DR2(%rdi)
 348         movq    %dr3,%rax
 349         movq    %rax,PCB_DR3(%rdi)
 350         movq    %dr6,%rax
 351         movq    %rax,PCB_DR6(%rdi)
 352         movq    %dr7,%rax
 353         movq    %rax,PCB_DR7(%rdi)
 354
 355         movl    $MSR_FSBASE,%ecx
 356         rdmsr
 357         movl    %eax,PCB_FSBASE(%rdi)
 358         movl    %edx,PCB_FSBASE+4(%rdi)
 359         movl    $MSR_GSBASE,%ecx
 360         rdmsr
 361         movl    %eax,PCB_GSBASE(%rdi)
 362         movl    %edx,PCB_GSBASE+4(%rdi)
 363         movl    $MSR_KGSBASE,%ecx
 364         rdmsr
 365         movl    %eax,PCB_KGSBASE(%rdi)
 366         movl    %edx,PCB_KGSBASE+4(%rdi)
 367         movl    $MSR_EFER,%ecx
 368         rdmsr
 369         movl    %eax,PCB_EFER(%rdi)
 370         movl    %edx,PCB_EFER+4(%rdi)
 371         movl    $MSR_STAR,%ecx
 372         rdmsr
 373         movl    %eax,PCB_STAR(%rdi)
 374         movl    %edx,PCB_STAR+4(%rdi)
 375         movl    $MSR_LSTAR,%ecx
 376         rdmsr
 377         movl    %eax,PCB_LSTAR(%rdi)
 378         movl    %edx,PCB_LSTAR+4(%rdi)
 379         movl    $MSR_CSTAR,%ecx
 380         rdmsr
 381         movl    %eax,PCB_CSTAR(%rdi)
 382         movl    %edx,PCB_CSTAR+4(%rdi)
 383         movl    $MSR_SF_MASK,%ecx
 384         rdmsr
 385         movl    %eax,PCB_SFMASK(%rdi)
 386         movl    %edx,PCB_SFMASK+4(%rdi)
 387
 388         sgdt    PCB_GDT(%rdi)
 389         sidt    PCB_IDT(%rdi)
 390         sldt    PCB_LDT(%rdi)
 391         str     PCB_TR(%rdi)
 392
 393         movl    $1,%eax
 394         ret
 395 END(savectx)
 396
 397 /*
 398  * resumectx(pcb)
 399  * Resuming processor state from pcb.
 400  */
 401 ENTRY(resumectx)
 402         /* Switch to KPML4phys. */
 403         movq    KPML4phys,%rax
 404         movq    %rax,%cr3
 405
 406         /* Force kernel segment registers. */
 407         movl    $KDSEL,%eax
 408         movw    %ax,%ds
 409         movw    %ax,%es
 410         movw    %ax,%ss
 411         movl    $KUF32SEL,%eax
 412         movw    %ax,%fs
 413         movl    $KUG32SEL,%eax
 414         movw    %ax,%gs
 415
 416         movl    $MSR_FSBASE,%ecx
 417         movl    PCB_FSBASE(%rdi),%eax
 418         movl    4 + PCB_FSBASE(%rdi),%edx
 419         wrmsr
 420         movl    $MSR_GSBASE,%ecx
 421         movl    PCB_GSBASE(%rdi),%eax
 422         movl    4 + PCB_GSBASE(%rdi),%edx
 423         wrmsr
 424         movl    $MSR_KGSBASE,%ecx
 425         movl    PCB_KGSBASE(%rdi),%eax
 426         movl    4 + PCB_KGSBASE(%rdi),%edx
 427         wrmsr
 428
 429         /* Restore EFER one more time. */
 430         movl    $MSR_EFER,%ecx
 431         movl    PCB_EFER(%rdi),%eax
 432         wrmsr
 433
 434         /* Restore fast syscall stuff. */
 435         movl    $MSR_STAR,%ecx
 436         movl    PCB_STAR(%rdi),%eax
 437         movl    4 + PCB_STAR(%rdi),%edx
 438         wrmsr
 439         movl    $MSR_LSTAR,%ecx
 440         movl    PCB_LSTAR(%rdi),%eax
 441         movl    4 + PCB_LSTAR(%rdi),%edx
 442         wrmsr
 443         movl    $MSR_CSTAR,%ecx
 444         movl    PCB_CSTAR(%rdi),%eax
 445         movl    4 + PCB_CSTAR(%rdi),%edx
 446         wrmsr
 447         movl    $MSR_SF_MASK,%ecx
 448         movl    PCB_SFMASK(%rdi),%eax
 449         wrmsr
 450
 451         /* Restore CR0, CR2, CR4 and CR3. */
 452         movq    PCB_CR0(%rdi),%rax
 453         movq    %rax,%cr0
 454         movq    PCB_CR2(%rdi),%rax
 455         movq    %rax,%cr2
 456         movq    PCB_CR4(%rdi),%rax
 457         movq    %rax,%cr4
 458         movq    PCB_CR3(%rdi),%rax
 459         movq    %rax,%cr3
 460
 461         /* Restore descriptor tables. */
 462         lidt    PCB_IDT(%rdi)
 463         lldt    PCB_LDT(%rdi)
 464
 465 #define SDT_SYSTSS      9
 466 #define SDT_SYSBSY      11
 467
 468         /* Clear "task busy" bit and reload TR. */
 469         movq    PCPU(TSS),%rax
 470         andb    $(~SDT_SYSBSY | SDT_SYSTSS),5(%rax)
 471         movw    PCB_TR(%rdi),%ax
 472         ltr     %ax
 473
 474 #undef  SDT_SYSTSS
 475 #undef  SDT_SYSBSY
 476
 477         /* Restore debug registers. */
 478         movq    PCB_DR0(%rdi),%rax
 479         movq    %rax,%dr0
 480         movq    PCB_DR1(%rdi),%rax
 481         movq    %rax,%dr1
 482         movq    PCB_DR2(%rdi),%rax
 483         movq    %rax,%dr2
 484         movq    PCB_DR3(%rdi),%rax
 485         movq    %rax,%dr3
 486         movq    PCB_DR6(%rdi),%rax
 487         movq    %rax,%dr6
 488         movq    PCB_DR7(%rdi),%rax
 489         movq    %rax,%dr7
 490
 491         /* Restore other callee saved registers. */
 492         movq    PCB_R15(%rdi),%r15
 493         movq    PCB_R14(%rdi),%r14
 494         movq    PCB_R13(%rdi),%r13
 495         movq    PCB_R12(%rdi),%r12
 496         movq    PCB_RBP(%rdi),%rbp
 497         movq    PCB_RSP(%rdi),%rsp
 498         movq    PCB_RBX(%rdi),%rbx
 499
 500         /* Restore return address. */
 501         movq    PCB_RIP(%rdi),%rax
 502         movq    %rax,(%rsp)
 503
 504         xorl    %eax,%eax
 505         ret
 506 END(resumectx)