sys/amd64/amd64/exception.S

   1 /*-
   2  * Copyright (c) 1989, 1990 William F. Jolitz.
   3  * Copyright (c) 1990 The Regents of the University of California.
   4  * Copyright (c) 2007-2018 The FreeBSD Foundation
   5  * All rights reserved.
   6  *
   7  * Portions of this software were developed by A. Joseph Koshy under
   8  * sponsorship from the FreeBSD Foundation and Google, Inc.
   9  *
  10  * Portions of this software were developed by
  11  * Konstantin Belousov <kib@FreeBSD.org> under sponsorship from
  12  * the FreeBSD Foundation.
  13  *
  14  * Redistribution and use in source and binary forms, with or without
  15  * modification, are permitted provided that the following conditions
  16  * are met:
  17  * 1. Redistributions of source code must retain the above copyright
  18  *    notice, this list of conditions and the following disclaimer.
  19  * 2. Redistributions in binary form must reproduce the above copyright
  20  *    notice, this list of conditions and the following disclaimer in the
  21  *    documentation and/or other materials provided with the distribution.
  22  * 3. Neither the name of the University nor the names of its contributors
  23  *    may be used to endorse or promote products derived from this software
  24  *    without specific prior written permission.
  25  *
  26  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  27  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  28  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  29  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  30  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  31  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  32  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  33  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  34  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  35  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  36  * SUCH DAMAGE.
  37  *
  38  * $FreeBSD$
  39  */
  40
  41 #include "opt_atpic.h"
  42 #include "opt_hwpmc_hooks.h"
  43
  44 #include "assym.inc"
  45
  46 #include <machine/psl.h>
  47 #include <machine/asmacros.h>
  48 #include <machine/trap.h>
  49 #include <machine/specialreg.h>
  50 #include <machine/pmap.h>
  51
  52 #ifdef KDTRACE_HOOKS
  53         .bss
  54         .globl  dtrace_invop_jump_addr
  55         .align  8
  56         .type   dtrace_invop_jump_addr,@object
  57         .size   dtrace_invop_jump_addr,8
  58 dtrace_invop_jump_addr:
  59         .zero   8
  60         .globl  dtrace_invop_calltrap_addr
  61         .align  8
  62         .type   dtrace_invop_calltrap_addr,@object
  63         .size   dtrace_invop_calltrap_addr,8
  64 dtrace_invop_calltrap_addr:
  65         .zero   8
  66 #endif
  67         .text
  68 #ifdef HWPMC_HOOKS
  69         ENTRY(start_exceptions)
  70 #endif
  71
  72 /*****************************************************************************/
  73 /* Trap handling                                                             */
  74 /*****************************************************************************/
  75 /*
  76  * Trap and fault vector routines.
  77  *
  78  * All traps are 'interrupt gates', SDT_SYSIGT.  An interrupt gate pushes
  79  * state on the stack but also disables interrupts.  This is important for
  80  * us for the use of the swapgs instruction.  We cannot be interrupted
  81  * until the GS.base value is correct.  For most traps, we automatically
  82  * then enable interrupts if the interrupted context had them enabled.
  83  * This is equivalent to the i386 port's use of SDT_SYS386TGT.
  84  *
  85  * The cpu will push a certain amount of state onto the kernel stack for
  86  * the current process.  See amd64/include/frame.h.
  87  * This includes the current RFLAGS (status register, which includes
  88  * the interrupt disable state prior to the trap), the code segment register,
  89  * and the return instruction pointer are pushed by the cpu.  The cpu
  90  * will also push an 'error' code for certain traps.  We push a dummy
  91  * error code for those traps where the cpu doesn't in order to maintain
  92  * a consistent frame.  We also push a contrived 'trap number'.
  93  *
  94  * The CPU does not push the general registers, so we must do that, and we
  95  * must restore them prior to calling 'iret'.  The CPU adjusts %cs and %ss
  96  * but does not mess with %ds, %es, %gs or %fs.  We swap the %gs base for
  97  * for the kernel mode operation shortly, without changes to the selector
  98  * loaded.  Since superuser long mode works with any selectors loaded into
  99  * segment registers other then %cs, which makes them mostly unused in long
 100  * mode, and kernel does not reference %fs, leave them alone.  The segment
 101  * registers are reloaded on return to the usermode.
 102  */
 103
 104 MCOUNT_LABEL(user)
 105 MCOUNT_LABEL(btrap)
 106
 107 /* Traps that we leave interrupts disabled for. */
 108         .macro  TRAP_NOEN       l, trapno
 109         PTI_ENTRY       \l,\l\()_pti_k,\l\()_pti_u
 110 \l\()_pti_k:
 111         subq    $TF_RIP,%rsp
 112         movl    $\trapno,TF_TRAPNO(%rsp)
 113         movq    $0,TF_ADDR(%rsp)
 114         movq    $0,TF_ERR(%rsp)
 115         jmp     alltraps_noen_k
 116 \l\()_pti_u:
 117         subq    $TF_RIP,%rsp
 118         movl    $\trapno,TF_TRAPNO(%rsp)
 119         movq    $0,TF_ADDR(%rsp)
 120         movq    $0,TF_ERR(%rsp)
 121         jmp     alltraps_noen_u
 122
 123         .globl  X\l
 124         .type   X\l,@function
 125 X\l:
 126         subq    $TF_RIP,%rsp
 127         movl    $\trapno,TF_TRAPNO(%rsp)
 128         movq    $0,TF_ADDR(%rsp)
 129         movq    $0,TF_ERR(%rsp)
 130         testb   $SEL_RPL_MASK,TF_CS(%rsp)
 131         jz      alltraps_noen_k
 132         swapgs
 133         lfence
 134         jmp     alltraps_noen_u
 135         .endm
 136
 137         TRAP_NOEN       bpt, T_BPTFLT
 138 #ifdef KDTRACE_HOOKS
 139         TRAP_NOEN       dtrace_ret, T_DTRACE_RET
 140 #endif
 141
 142 /* Regular traps; The cpu does not supply tf_err for these. */
 143         .macro  TRAP    l, trapno
 144         PTI_ENTRY       \l,\l\()_pti_k,\l\()_pti_u
 145 \l\()_pti_k:
 146         subq    $TF_RIP,%rsp
 147         movl    $\trapno,TF_TRAPNO(%rsp)
 148         movq    $0,TF_ADDR(%rsp)
 149         movq    $0,TF_ERR(%rsp)
 150         jmp     alltraps_k
 151 \l\()_pti_u:
 152         subq    $TF_RIP,%rsp
 153         movl    $\trapno,TF_TRAPNO(%rsp)
 154         movq    $0,TF_ADDR(%rsp)
 155         movq    $0,TF_ERR(%rsp)
 156         jmp     alltraps_u
 157
 158         .globl  X\l
 159         .type   X\l,@function
 160 X\l:
 161         subq    $TF_RIP,%rsp
 162         movl    $\trapno,TF_TRAPNO(%rsp)
 163         movq    $0,TF_ADDR(%rsp)
 164         movq    $0,TF_ERR(%rsp)
 165         testb   $SEL_RPL_MASK,TF_CS(%rsp)
 166         jz      alltraps_k
 167         swapgs
 168         lfence
 169         jmp     alltraps_u
 170         .endm
 171
 172         TRAP    div, T_DIVIDE
 173         TRAP    ofl, T_OFLOW
 174         TRAP    bnd, T_BOUND
 175         TRAP    ill, T_PRIVINFLT
 176         TRAP    dna, T_DNA
 177         TRAP    fpusegm, T_FPOPFLT
 178         TRAP    rsvd, T_RESERVED
 179         TRAP    fpu, T_ARITHTRAP
 180         TRAP    xmm, T_XMMFLT
 181
 182 /* This group of traps have tf_err already pushed by the cpu. */
 183         .macro  TRAP_ERR        l, trapno
 184         PTI_ENTRY       \l,\l\()_pti_k,\l\()_pti_u,has_err=1
 185 \l\()_pti_k:
 186         subq    $TF_ERR,%rsp
 187         movl    $\trapno,TF_TRAPNO(%rsp)
 188         movq    $0,TF_ADDR(%rsp)
 189         jmp     alltraps_k
 190 \l\()_pti_u:
 191         subq    $TF_ERR,%rsp
 192         movl    $\trapno,TF_TRAPNO(%rsp)
 193         movq    $0,TF_ADDR(%rsp)
 194         jmp     alltraps_u
 195         .globl  X\l
 196         .type   X\l,@function
 197 X\l:
 198         subq    $TF_ERR,%rsp
 199         movl    $\trapno,TF_TRAPNO(%rsp)
 200         movq    $0,TF_ADDR(%rsp)
 201         testb   $SEL_RPL_MASK,TF_CS(%rsp)
 202         jz      alltraps_k
 203         swapgs
 204         lfence
 205         jmp     alltraps_u
 206         .endm
 207
 208         TRAP_ERR        tss, T_TSSFLT
 209         TRAP_ERR        align, T_ALIGNFLT
 210
 211         /*
 212          * alltraps_u/k entry points.
 213          * SWAPGS must be already performed by prologue,
 214          * if this is the first time in the kernel from userland.
 215          * Reenable interrupts if they were enabled before the trap.
 216          * This approximates SDT_SYS386TGT on the i386 port.
 217          */
 218         SUPERALIGN_TEXT
 219         .globl  alltraps_u
 220         .type   alltraps_u,@function
 221 alltraps_u:
 222         movq    %rdi,TF_RDI(%rsp)
 223         movq    %rdx,TF_RDX(%rsp)
 224         movq    %rax,TF_RAX(%rsp)
 225         movq    %rcx,TF_RCX(%rsp)
 226         movq    PCPU(CURPCB),%rdi
 227         andl    $~PCB_FULL_IRET,PCB_FLAGS(%rdi)
 228         call    handle_ibrs_entry
 229         jmp     alltraps_save_segs
 230         SUPERALIGN_TEXT
 231         .globl  alltraps_k
 232         .type   alltraps_k,@function
 233 alltraps_k:
 234         lfence
 235         movq    %rdi,TF_RDI(%rsp)
 236         movq    %rdx,TF_RDX(%rsp)
 237         movq    %rax,TF_RAX(%rsp)
 238         movq    %rcx,TF_RCX(%rsp)
 239 alltraps_save_segs:
 240         SAVE_SEGS
 241         testl   $PSL_I,TF_RFLAGS(%rsp)
 242         jz      alltraps_pushregs_no_rax
 243         sti
 244 alltraps_pushregs_no_rax:
 245         movq    %rsi,TF_RSI(%rsp)
 246         movq    %r8,TF_R8(%rsp)
 247         movq    %r9,TF_R9(%rsp)
 248         movq    %rbx,TF_RBX(%rsp)
 249         movq    %rbp,TF_RBP(%rsp)
 250         movq    %r10,TF_R10(%rsp)
 251         movq    %r11,TF_R11(%rsp)
 252         movq    %r12,TF_R12(%rsp)
 253         movq    %r13,TF_R13(%rsp)
 254         movq    %r14,TF_R14(%rsp)
 255         movq    %r15,TF_R15(%rsp)
 256         movl    $TF_HASSEGS,TF_FLAGS(%rsp)
 257         pushfq
 258         andq    $~(PSL_D | PSL_AC),(%rsp)
 259         popfq
 260         FAKE_MCOUNT(TF_RIP(%rsp))
 261 #ifdef KDTRACE_HOOKS
 262         /*
 263          * DTrace Function Boundary Trace (fbt) probes are triggered
 264          * by int3 (0xcc) which causes the #BP (T_BPTFLT) breakpoint
 265          * interrupt. For all other trap types, just handle them in
 266          * the usual way.
 267          */
 268         testb   $SEL_RPL_MASK,TF_CS(%rsp) /* Did we come from kernel? */
 269         jnz     calltrap                /* ignore userland traps */
 270         cmpl    $T_BPTFLT,TF_TRAPNO(%rsp)
 271         jne     calltrap
 272
 273         /* Check if there is no DTrace hook registered. */
 274         cmpq    $0,dtrace_invop_jump_addr
 275         je      calltrap
 276
 277         /*
 278          * Set our jump address for the jump back in the event that
 279          * the breakpoint wasn't caused by DTrace at all.
 280          */
 281         movq    $calltrap,dtrace_invop_calltrap_addr(%rip)
 282
 283         /* Jump to the code hooked in by DTrace. */
 284         jmpq    *dtrace_invop_jump_addr
 285 #endif
 286         .globl  calltrap
 287         .type   calltrap,@function
 288 calltrap:
 289         movq    %rsp,%rdi
 290         call    trap_check
 291         MEXITCOUNT
 292         jmp     doreti                  /* Handle any pending ASTs */
 293
 294         /*
 295          * alltraps_noen_u/k entry points.
 296          * Again, SWAPGS must be already performed by prologue, if needed.
 297          * Unlike alltraps above, we want to leave the interrupts disabled.
 298          * This corresponds to SDT_SYS386IGT on the i386 port.
 299          */
 300         SUPERALIGN_TEXT
 301         .globl  alltraps_noen_u
 302         .type   alltraps_noen_u,@function
 303 alltraps_noen_u:
 304         movq    %rdi,TF_RDI(%rsp)
 305         movq    PCPU(CURPCB),%rdi
 306         andl    $~PCB_FULL_IRET,PCB_FLAGS(%rdi)
 307         jmp     alltraps_noen_save_segs
 308         SUPERALIGN_TEXT
 309         .globl  alltraps_noen_k
 310         .type   alltraps_noen_k,@function
 311 alltraps_noen_k:
 312         lfence
 313         movq    %rdi,TF_RDI(%rsp)
 314 alltraps_noen_save_segs:
 315         SAVE_SEGS
 316         movq    %rdx,TF_RDX(%rsp)
 317         movq    %rax,TF_RAX(%rsp)
 318         movq    %rcx,TF_RCX(%rsp)
 319         testb   $SEL_RPL_MASK,TF_CS(%rsp)
 320         jz      alltraps_pushregs_no_rax
 321         call    handle_ibrs_entry
 322         jmp     alltraps_pushregs_no_rax
 323
 324 IDTVEC(dblfault)
 325         subq    $TF_ERR,%rsp
 326         movl    $T_DOUBLEFLT,TF_TRAPNO(%rsp)
 327         movq    $0,TF_ADDR(%rsp)
 328         movq    $0,TF_ERR(%rsp)
 329         movq    %rdi,TF_RDI(%rsp)
 330         movq    %rsi,TF_RSI(%rsp)
 331         movq    %rdx,TF_RDX(%rsp)
 332         movq    %rcx,TF_RCX(%rsp)
 333         movq    %r8,TF_R8(%rsp)
 334         movq    %r9,TF_R9(%rsp)
 335         movq    %rax,TF_RAX(%rsp)
 336         movq    %rbx,TF_RBX(%rsp)
 337         movq    %rbp,TF_RBP(%rsp)
 338         movq    %r10,TF_R10(%rsp)
 339         movq    %r11,TF_R11(%rsp)
 340         movq    %r12,TF_R12(%rsp)
 341         movq    %r13,TF_R13(%rsp)
 342         movq    %r14,TF_R14(%rsp)
 343         movq    %r15,TF_R15(%rsp)
 344         SAVE_SEGS
 345         movl    $TF_HASSEGS,TF_FLAGS(%rsp)
 346         pushfq
 347         andq    $~(PSL_D | PSL_AC),(%rsp)
 348         popfq
 349         movq    TF_SIZE(%rsp),%rdx
 350         movl    %edx,%eax
 351         shrq    $32,%rdx
 352         movl    $MSR_GSBASE,%ecx
 353         wrmsr
 354         movq    %cr3,%rax
 355         movq    %rax,PCPU(SAVED_UCR3)
 356         movq    PCPU(KCR3),%rax
 357         cmpq    $~0,%rax
 358         je      2f
 359         movq    %rax,%cr3
 360 2:      movq    %rsp,%rdi
 361         call    dblfault_handler
 362 3:      hlt
 363         jmp     3b
 364
 365         ALIGN_TEXT
 366 IDTVEC(page_pti)
 367         testb   $SEL_RPL_MASK,PTI_CS-PTI_ERR(%rsp)
 368         jz      page_k
 369         swapgs
 370         lfence
 371         pushq   %rax
 372         movq    %cr3,%rax
 373         movq    %rax,PCPU(SAVED_UCR3)
 374         cmpq    $~0,PCPU(UCR3)
 375         jne     1f
 376         popq    %rax
 377         jmp     page_u
 378 1:      pushq   %rdx
 379         PTI_UUENTRY has_err=1
 380         jmp     page_u
 381         ALIGN_TEXT
 382 IDTVEC(page)
 383         testb   $SEL_RPL_MASK,TF_CS-TF_ERR(%rsp) /* Did we come from kernel? */
 384         jnz     page_u_swapgs           /* already running with kernel GS.base */
 385 page_k:
 386         lfence
 387         subq    $TF_ERR,%rsp
 388         movq    %rdi,TF_RDI(%rsp)       /* free up GP registers */
 389         movq    %rax,TF_RAX(%rsp)
 390         movq    %rdx,TF_RDX(%rsp)
 391         movq    %rcx,TF_RCX(%rsp)
 392         jmp     page_cr2
 393         ALIGN_TEXT
 394 page_u_swapgs:
 395         swapgs
 396         lfence
 397 page_u:
 398         subq    $TF_ERR,%rsp
 399         movq    %rdi,TF_RDI(%rsp)
 400         movq    %rax,TF_RAX(%rsp)
 401         movq    %rdx,TF_RDX(%rsp)
 402         movq    %rcx,TF_RCX(%rsp)
 403         movq    PCPU(CURPCB),%rdi
 404         andl    $~PCB_FULL_IRET,PCB_FLAGS(%rdi)
 405         movq    PCPU(SAVED_UCR3),%rax
 406         movq    %rax,PCB_SAVED_UCR3(%rdi)
 407         call    handle_ibrs_entry
 408 page_cr2:
 409         movq    %cr2,%rdi               /* preserve %cr2 before ..  */
 410         movq    %rdi,TF_ADDR(%rsp)      /* enabling interrupts. */
 411         SAVE_SEGS
 412         movl    $T_PAGEFLT,TF_TRAPNO(%rsp)
 413         testl   $PSL_I,TF_RFLAGS(%rsp)
 414         jz      alltraps_pushregs_no_rax
 415         sti
 416         jmp     alltraps_pushregs_no_rax
 417
 418         /*
 419          * We have to special-case this one.  If we get a trap in doreti() at
 420          * the iretq stage, we'll reenter with the wrong gs state.  We'll have
 421          * to do a special the swapgs in this case even coming from the kernel.
 422          * XXX linux has a trap handler for their equivalent of load_gs().
 423          *
 424          * On the stack, we have the hardware interrupt frame to return
 425          * to usermode (faulted) and another frame with error code, for
 426          * fault.  For PTI, copy both frames to the main thread stack.
 427          * Handle the potential 16-byte alignment adjustment incurred
 428          * during the second fault by copying both frames independently
 429          * while unwinding the stack in between.
 430          */
 431         .macro PROTF_ENTRY name,trapno
 432 \name\()_pti_doreti:
 433         swapgs
 434         lfence
 435         cmpq    $~0,PCPU(UCR3)
 436         je      1f
 437         pushq   %rax
 438         pushq   %rdx
 439         movq    PCPU(KCR3),%rax
 440         movq    %rax,%cr3
 441         movq    PCPU(RSP0),%rax
 442         subq    $2*PTI_SIZE-3*8,%rax /* no err, %rax, %rdx in faulted frame */
 443         MOVE_STACKS     (PTI_SIZE / 8)
 444         addq    $PTI_SIZE,%rax
 445         movq    PTI_RSP(%rsp),%rsp
 446         MOVE_STACKS     (PTI_SIZE / 8 - 3)
 447         subq    $PTI_SIZE,%rax
 448         movq    %rax,%rsp
 449         popq    %rdx
 450         popq    %rax
 451 1:      swapgs
 452         jmp     X\name
 453 IDTVEC(\name\()_pti)
 454         cmpq    $doreti_iret,PTI_RIP-2*8(%rsp)
 455         je      \name\()_pti_doreti
 456         testb   $SEL_RPL_MASK,PTI_CS-2*8(%rsp) /* %rax, %rdx not yet pushed */
 457         jz      X\name          /* lfence is not needed until %gs: use */
 458         PTI_UENTRY has_err=1
 459         swapgs  /* fence provided by PTI_UENTRY */
 460 IDTVEC(\name)
 461         subq    $TF_ERR,%rsp
 462         movl    $\trapno,TF_TRAPNO(%rsp)
 463         jmp     prot_addrf
 464         .endm
 465
 466         PROTF_ENTRY     missing, T_SEGNPFLT
 467         PROTF_ENTRY     stk, T_STKFLT
 468         PROTF_ENTRY     prot, T_PROTFLT
 469
 470 prot_addrf:
 471         movq    $0,TF_ADDR(%rsp)
 472         movq    %rdi,TF_RDI(%rsp)       /* free up a GP register */
 473         movq    %rax,TF_RAX(%rsp)
 474         movq    %rdx,TF_RDX(%rsp)
 475         movq    %rcx,TF_RCX(%rsp)
 476         movw    %fs,TF_FS(%rsp)
 477         movw    %gs,TF_GS(%rsp)
 478         leaq    doreti_iret(%rip),%rdi
 479         cmpq    %rdi,TF_RIP(%rsp)
 480         je      5f                      /* kernel but with user gsbase!! */
 481         testb   $SEL_RPL_MASK,TF_CS(%rsp) /* Did we come from kernel? */
 482         jz      6f                      /* already running with kernel GS.base */
 483         testb   $CPUID_STDEXT_FSGSBASE,cpu_stdext_feature(%rip)
 484         jz      2f
 485         cmpw    $KUF32SEL,TF_FS(%rsp)
 486         jne     1f
 487         rdfsbase %rax
 488 1:      cmpw    $KUG32SEL,TF_GS(%rsp)
 489         jne     2f
 490         rdgsbase %rdx
 491 2:      swapgs
 492         lfence
 493         movq    PCPU(CURPCB),%rdi
 494         testb   $CPUID_STDEXT_FSGSBASE,cpu_stdext_feature(%rip)
 495         jz      4f
 496         cmpw    $KUF32SEL,TF_FS(%rsp)
 497         jne     3f
 498         movq    %rax,PCB_FSBASE(%rdi)
 499 3:      cmpw    $KUG32SEL,TF_GS(%rsp)
 500         jne     4f
 501         movq    %rdx,PCB_GSBASE(%rdi)
 502         orl     $PCB_FULL_IRET,PCB_FLAGS(%rdi)  /* full iret from user #gp */
 503 4:      call    handle_ibrs_entry
 504         movw    %es,TF_ES(%rsp)
 505         movw    %ds,TF_DS(%rsp)
 506         testl   $PSL_I,TF_RFLAGS(%rsp)
 507         jz      alltraps_pushregs_no_rax
 508         sti
 509         jmp     alltraps_pushregs_no_rax
 510
 511 5:      swapgs
 512 6:      lfence
 513         movq    PCPU(CURPCB),%rdi
 514         jmp     4b
 515
 516 /*
 517  * Fast syscall entry point.  We enter here with just our new %cs/%ss set,
 518  * and the new privilige level.  We are still running on the old user stack
 519  * pointer.  We have to juggle a few things around to find our stack etc.
 520  * swapgs gives us access to our PCPU space only.
 521  *
 522  * We do not support invoking this from a custom segment registers,
 523  * esp. %cs, %ss, %fs, %gs, e.g. using entries from an LDT.
 524  */
 525         SUPERALIGN_TEXT
 526 IDTVEC(fast_syscall_pti)
 527         swapgs
 528         cmpq    $~0,PCPU(UCR3)
 529         je      fast_syscall_common
 530         movq    %rax,PCPU(SCRATCH_RAX)
 531         movq    PCPU(KCR3),%rax
 532         movq    %rax,%cr3
 533         movq    PCPU(SCRATCH_RAX),%rax
 534         jmp     fast_syscall_common
 535         SUPERALIGN_TEXT
 536 IDTVEC(fast_syscall)
 537         swapgs
 538 fast_syscall_common:
 539         movq    %rsp,PCPU(SCRATCH_RSP)
 540         movq    PCPU(RSP0),%rsp
 541         /* Now emulate a trapframe. Make the 8 byte alignment odd for call. */
 542         subq    $TF_SIZE,%rsp
 543         /* defer TF_RSP till we have a spare register */
 544         movq    %r11,TF_RFLAGS(%rsp)
 545         movq    %rcx,TF_RIP(%rsp)       /* %rcx original value is in %r10 */
 546         movq    PCPU(SCRATCH_RSP),%r11  /* %r11 already saved */
 547         movq    %r11,TF_RSP(%rsp)       /* user stack pointer */
 548         /*
 549          * Save a few arg registers early to free them for use in
 550          * handle_ibrs_entry().  %r10 is especially tricky.  It is not an
 551          * arg register, but it holds the arg register %rcx.  Profiling
 552          * preserves %rcx, but may clobber %r10.  Profiling may also
 553          * clobber %r11, but %r11 (original %eflags) has been saved.
 554          */
 555         movq    %rax,TF_RAX(%rsp)       /* syscall number */
 556         movq    %rdx,TF_RDX(%rsp)       /* arg 3 */
 557         movq    %r10,TF_RCX(%rsp)       /* arg 4 */
 558         SAVE_SEGS
 559         call    handle_ibrs_entry
 560         movq    PCPU(CURPCB),%r11
 561         andl    $~PCB_FULL_IRET,PCB_FLAGS(%r11)
 562         sti
 563         movq    $KUDSEL,TF_SS(%rsp)
 564         movq    $KUCSEL,TF_CS(%rsp)
 565         movq    $2,TF_ERR(%rsp)
 566         movq    %rdi,TF_RDI(%rsp)       /* arg 1 */
 567         movq    %rsi,TF_RSI(%rsp)       /* arg 2 */
 568         movq    %r8,TF_R8(%rsp)         /* arg 5 */
 569         movq    %r9,TF_R9(%rsp)         /* arg 6 */
 570         movq    %rbx,TF_RBX(%rsp)       /* C preserved */
 571         movq    %rbp,TF_RBP(%rsp)       /* C preserved */
 572         movq    %r12,TF_R12(%rsp)       /* C preserved */
 573         movq    %r13,TF_R13(%rsp)       /* C preserved */
 574         movq    %r14,TF_R14(%rsp)       /* C preserved */
 575         movq    %r15,TF_R15(%rsp)       /* C preserved */
 576         movl    $TF_HASSEGS,TF_FLAGS(%rsp)
 577         FAKE_MCOUNT(TF_RIP(%rsp))
 578         movq    PCPU(CURTHREAD),%rdi
 579         movq    %rsp,TD_FRAME(%rdi)
 580         movl    TF_RFLAGS(%rsp),%esi
 581         andl    $PSL_T,%esi
 582         call    amd64_syscall
 583 1:      movq    PCPU(CURPCB),%rax
 584         /* Disable interrupts before testing PCB_FULL_IRET. */
 585         cli
 586         testl   $PCB_FULL_IRET,PCB_FLAGS(%rax)
 587         jnz     4f
 588         /* Check for and handle AST's on return to userland. */
 589         movq    PCPU(CURTHREAD),%rax
 590         testl   $TDF_ASTPENDING | TDF_NEEDRESCHED,TD_FLAGS(%rax)
 591         jne     3f
 592         call    handle_ibrs_exit
 593         callq   *mds_handler
 594         /* Restore preserved registers. */
 595         MEXITCOUNT
 596         movq    TF_RDI(%rsp),%rdi       /* bonus; preserve arg 1 */
 597         movq    TF_RSI(%rsp),%rsi       /* bonus: preserve arg 2 */
 598         movq    TF_RDX(%rsp),%rdx       /* return value 2 */
 599         movq    TF_RAX(%rsp),%rax       /* return value 1 */
 600         movq    TF_RFLAGS(%rsp),%r11    /* original %rflags */
 601         movq    TF_RIP(%rsp),%rcx       /* original %rip */
 602         movq    TF_RSP(%rsp),%rsp       /* user stack pointer */
 603         xorl    %r8d,%r8d               /* zero the rest of GPRs */
 604         xorl    %r10d,%r10d
 605         cmpq    $~0,PCPU(UCR3)
 606         je      2f
 607         movq    PCPU(UCR3),%r9
 608         andq    PCPU(UCR3_LOAD_MASK),%r9
 609         movq    %r9,%cr3
 610 2:      xorl    %r9d,%r9d
 611         movq    $PMAP_UCR3_NOMASK,PCPU(UCR3_LOAD_MASK)
 612         swapgs
 613         sysretq
 614
 615 3:      /* AST scheduled. */
 616         sti
 617         movq    %rsp,%rdi
 618         call    ast
 619         jmp     1b
 620
 621 4:      /* Requested full context restore, use doreti for that. */
 622         MEXITCOUNT
 623         jmp     doreti
 624
 625 /*
 626  * Here for CYA insurance, in case a "syscall" instruction gets
 627  * issued from 32 bit compatibility mode. MSR_CSTAR has to point
 628  * to *something* if EFER_SCE is enabled.
 629  */
 630 IDTVEC(fast_syscall32)
 631         sysret
 632
 633 /*
 634  * DB# handler is very similar to NM#, because 'mov/pop %ss' delay
 635  * generation of exception until the next instruction is executed,
 636  * which might be a kernel entry.  So we must execute the handler
 637  * on IST stack and be ready for non-kernel GSBASE.
 638  */
 639 IDTVEC(dbg)
 640         subq    $TF_RIP,%rsp
 641         movl    $(T_TRCTRAP),TF_TRAPNO(%rsp)
 642         movq    $0,TF_ADDR(%rsp)
 643         movq    $0,TF_ERR(%rsp)
 644         movq    %rdi,TF_RDI(%rsp)
 645         movq    %rsi,TF_RSI(%rsp)
 646         movq    %rdx,TF_RDX(%rsp)
 647         movq    %rcx,TF_RCX(%rsp)
 648         movq    %r8,TF_R8(%rsp)
 649         movq    %r9,TF_R9(%rsp)
 650         movq    %rax,TF_RAX(%rsp)
 651         movq    %rbx,TF_RBX(%rsp)
 652         movq    %rbp,TF_RBP(%rsp)
 653         movq    %r10,TF_R10(%rsp)
 654         movq    %r11,TF_R11(%rsp)
 655         movq    %r12,TF_R12(%rsp)
 656         movq    %r13,TF_R13(%rsp)
 657         movq    %r14,TF_R14(%rsp)
 658         movq    %r15,TF_R15(%rsp)
 659         SAVE_SEGS
 660         movl    $TF_HASSEGS,TF_FLAGS(%rsp)
 661         pushfq
 662         andq    $~(PSL_D | PSL_AC),(%rsp)
 663         popfq
 664         testb   $SEL_RPL_MASK,TF_CS(%rsp)
 665         jnz     dbg_fromuserspace
 666         lfence
 667         /*
 668          * We've interrupted the kernel.  See comment in NMI handler about
 669          * registers use.
 670          */
 671         movq    %cr2,%r15
 672         movl    $MSR_GSBASE,%ecx
 673         rdmsr
 674         movq    %rax,%r12
 675         shlq    $32,%rdx
 676         orq     %rdx,%r12
 677         /* Retrieve and load the canonical value for GS.base. */
 678         movq    TF_SIZE(%rsp),%rdx
 679         movl    %edx,%eax
 680         shrq    $32,%rdx
 681         wrmsr
 682         movq    %cr3,%r13
 683         movq    PCPU(KCR3),%rax
 684         cmpq    $~0,%rax
 685         je      1f
 686         movq    %rax,%cr3
 687 1:      testl   $CPUID_STDEXT3_IBPB,cpu_stdext_feature3(%rip)
 688         je      2f
 689         movl    $MSR_IA32_SPEC_CTRL,%ecx
 690         rdmsr
 691         movl    %eax,%r14d
 692         call    handle_ibrs_entry
 693 2:      FAKE_MCOUNT(TF_RIP(%rsp))
 694         movq    %rsp,%rdi
 695         call    trap
 696         MEXITCOUNT
 697         testl   $CPUID_STDEXT3_IBPB,cpu_stdext_feature3(%rip)
 698         je      3f
 699         movl    %r14d,%eax
 700         xorl    %edx,%edx
 701         movl    $MSR_IA32_SPEC_CTRL,%ecx
 702         wrmsr
 703         /*
 704          * Put back the preserved MSR_GSBASE value.
 705          */
 706 3:      movl    $MSR_GSBASE,%ecx
 707         movq    %r12,%rdx
 708         movl    %edx,%eax
 709         shrq    $32,%rdx
 710         wrmsr
 711         movq    %r13,%cr3
 712         movq    %r15,%cr2
 713         RESTORE_REGS
 714         addq    $TF_RIP,%rsp
 715         jmp     doreti_iret
 716 dbg_fromuserspace:
 717         /*
 718          * Switch to kernel GSBASE and kernel page table, and copy frame
 719          * from the IST stack to the normal kernel stack, since trap()
 720          * re-enables interrupts, and since we might trap on DB# while
 721          * in trap().
 722          */
 723         swapgs
 724         lfence
 725         movq    PCPU(KCR3),%rax
 726         cmpq    $~0,%rax
 727         je      1f
 728         movq    %rax,%cr3
 729 1:      movq    PCPU(RSP0),%rax
 730         movl    $TF_SIZE,%ecx
 731         subq    %rcx,%rax
 732         movq    %rax,%rdi
 733         movq    %rsp,%rsi
 734         rep;movsb
 735         movq    %rax,%rsp
 736         call    handle_ibrs_entry
 737         movq    PCPU(CURPCB),%rdi
 738         orl     $PCB_FULL_IRET,PCB_FLAGS(%rdi)
 739         testb   $CPUID_STDEXT_FSGSBASE,cpu_stdext_feature(%rip)
 740         jz      3f
 741         cmpw    $KUF32SEL,TF_FS(%rsp)
 742         jne     2f
 743         rdfsbase %rax
 744         movq    %rax,PCB_FSBASE(%rdi)
 745 2:      cmpw    $KUG32SEL,TF_GS(%rsp)
 746         jne     3f
 747         movl    $MSR_KGSBASE,%ecx
 748         rdmsr
 749         shlq    $32,%rdx
 750         orq     %rdx,%rax
 751         movq    %rax,PCB_GSBASE(%rdi)
 752 3:      jmp     calltrap
 753
 754 /*
 755  * NMI handling is special.
 756  *
 757  * First, NMIs do not respect the state of the processor's RFLAGS.IF
 758  * bit.  The NMI handler may be entered at any time, including when
 759  * the processor is in a critical section with RFLAGS.IF == 0.
 760  * The processor's GS.base value could be invalid on entry to the
 761  * handler.
 762  *
 763  * Second, the processor treats NMIs specially, blocking further NMIs
 764  * until an 'iretq' instruction is executed.  We thus need to execute
 765  * the NMI handler with interrupts disabled, to prevent a nested interrupt
 766  * from executing an 'iretq' instruction and inadvertently taking the
 767  * processor out of NMI mode.
 768  *
 769  * Third, the NMI handler runs on its own stack (tss_ist2). The canonical
 770  * GS.base value for the processor is stored just above the bottom of its
 771  * NMI stack.  For NMIs taken from kernel mode, the current value in
 772  * the processor's GS.base is saved at entry to C-preserved register %r12,
 773  * the canonical value for GS.base is then loaded into the processor, and
 774  * the saved value is restored at exit time.  For NMIs taken from user mode,
 775  * the cheaper 'SWAPGS' instructions are used for swapping GS.base.
 776  */
 777
 778 IDTVEC(nmi)
 779         subq    $TF_RIP,%rsp
 780         movl    $(T_NMI),TF_TRAPNO(%rsp)
 781         movq    $0,TF_ADDR(%rsp)
 782         movq    $0,TF_ERR(%rsp)
 783         movq    %rdi,TF_RDI(%rsp)
 784         movq    %rsi,TF_RSI(%rsp)
 785         movq    %rdx,TF_RDX(%rsp)
 786         movq    %rcx,TF_RCX(%rsp)
 787         movq    %r8,TF_R8(%rsp)
 788         movq    %r9,TF_R9(%rsp)
 789         movq    %rax,TF_RAX(%rsp)
 790         movq    %rbx,TF_RBX(%rsp)
 791         movq    %rbp,TF_RBP(%rsp)
 792         movq    %r10,TF_R10(%rsp)
 793         movq    %r11,TF_R11(%rsp)
 794         movq    %r12,TF_R12(%rsp)
 795         movq    %r13,TF_R13(%rsp)
 796         movq    %r14,TF_R14(%rsp)
 797         movq    %r15,TF_R15(%rsp)
 798         SAVE_SEGS
 799         movl    $TF_HASSEGS,TF_FLAGS(%rsp)
 800         pushfq
 801         andq    $~(PSL_D | PSL_AC),(%rsp)
 802         popfq
 803         xorl    %ebx,%ebx
 804         testb   $SEL_RPL_MASK,TF_CS(%rsp)
 805         jnz     nmi_fromuserspace
 806         /*
 807          * We've interrupted the kernel.  Preserve in callee-saved regs:
 808          * GS.base in %r12,
 809          * %cr3 in %r13,
 810          * possibly lower half of MSR_IA32_SPEC_CTL in %r14d,
 811          * %cr2 in %r15.
 812          */
 813         lfence
 814         movq    %cr2,%r15
 815         movl    $MSR_GSBASE,%ecx
 816         rdmsr
 817         movq    %rax,%r12
 818         shlq    $32,%rdx
 819         orq     %rdx,%r12
 820         /* Retrieve and load the canonical value for GS.base. */
 821         movq    TF_SIZE(%rsp),%rdx
 822         movl    %edx,%eax
 823         shrq    $32,%rdx
 824         wrmsr
 825         movq    %cr3,%r13
 826         movq    PCPU(KCR3),%rax
 827         cmpq    $~0,%rax
 828         je      1f
 829         movq    %rax,%cr3
 830 1:      testl   $CPUID_STDEXT3_IBPB,cpu_stdext_feature3(%rip)
 831         je      nmi_calltrap
 832         movl    $MSR_IA32_SPEC_CTRL,%ecx
 833         rdmsr
 834         movl    %eax,%r14d
 835         call    handle_ibrs_entry
 836         jmp     nmi_calltrap
 837 nmi_fromuserspace:
 838         incl    %ebx
 839         swapgs
 840         lfence
 841         movq    %cr3,%r13
 842         movq    PCPU(KCR3),%rax
 843         cmpq    $~0,%rax
 844         je      1f
 845         movq    %rax,%cr3
 846 1:      call    handle_ibrs_entry
 847         movq    PCPU(CURPCB),%rdi
 848         testq   %rdi,%rdi
 849         jz      3f
 850         orl     $PCB_FULL_IRET,PCB_FLAGS(%rdi)
 851         testb   $CPUID_STDEXT_FSGSBASE,cpu_stdext_feature(%rip)
 852         jz      3f
 853         cmpw    $KUF32SEL,TF_FS(%rsp)
 854         jne     2f
 855         rdfsbase %rax
 856         movq    %rax,PCB_FSBASE(%rdi)
 857 2:      cmpw    $KUG32SEL,TF_GS(%rsp)
 858         jne     3f
 859         movl    $MSR_KGSBASE,%ecx
 860         rdmsr
 861         shlq    $32,%rdx
 862         orq     %rdx,%rax
 863         movq    %rax,PCB_GSBASE(%rdi)
 864 3:
 865 /* Note: this label is also used by ddb and gdb: */
 866 nmi_calltrap:
 867         FAKE_MCOUNT(TF_RIP(%rsp))
 868         movq    %rsp,%rdi
 869         call    trap
 870         MEXITCOUNT
 871 #ifdef HWPMC_HOOKS
 872         /*
 873          * Capture a userspace callchain if needed.
 874          *
 875          * - Check if the current trap was from user mode.
 876          * - Check if the current thread is valid.
 877          * - Check if the thread requires a user call chain to be
 878          *   captured.
 879          *
 880          * We are still in NMI mode at this point.
 881          */
 882         testl   %ebx,%ebx
 883         jz      nocallchain     /* not from userspace */
 884         movq    PCPU(CURTHREAD),%rax
 885         orq     %rax,%rax       /* curthread present? */
 886         jz      nocallchain
 887         /*
 888          * Move execution to the regular kernel stack, because we
 889          * committed to return through doreti.
 890          */
 891         movq    %rsp,%rsi       /* source stack pointer */
 892         movq    $TF_SIZE,%rcx
 893         movq    PCPU(RSP0),%rdx
 894         subq    %rcx,%rdx
 895         movq    %rdx,%rdi       /* destination stack pointer */
 896         shrq    $3,%rcx         /* trap frame size in long words */
 897         pushfq
 898         andq    $~(PSL_D | PSL_AC),(%rsp)
 899         popfq
 900         rep
 901         movsq                   /* copy trapframe */
 902         movq    %rdx,%rsp       /* we are on the regular kstack */
 903
 904         testl   $TDP_CALLCHAIN,TD_PFLAGS(%rax) /* flagged for capture? */
 905         jz      nocallchain
 906         /*
 907          * A user callchain is to be captured, so:
 908          * - Take the processor out of "NMI" mode by faking an "iret",
 909          *   to allow for nested NMI interrupts.
 910          * - Enable interrupts, so that copyin() can work.
 911          */
 912         movl    %ss,%eax
 913         pushq   %rax            /* tf_ss */
 914         pushq   %rdx            /* tf_rsp (on kernel stack) */
 915         pushfq                  /* tf_rflags */
 916         movl    %cs,%eax
 917         pushq   %rax            /* tf_cs */
 918         pushq   $outofnmi       /* tf_rip */
 919         iretq
 920 outofnmi:
 921         /*
 922          * At this point the processor has exited NMI mode and is running
 923          * with interrupts turned off on the normal kernel stack.
 924          *
 925          * If a pending NMI gets recognized at or after this point, it
 926          * will cause a kernel callchain to be traced.
 927          *
 928          * We turn interrupts back on, and call the user callchain capture hook.
 929          */
 930         movq    pmc_hook,%rax
 931         orq     %rax,%rax
 932         jz      nocallchain
 933         movq    PCPU(CURTHREAD),%rdi            /* thread */
 934         movq    $PMC_FN_USER_CALLCHAIN,%rsi     /* command */
 935         movq    %rsp,%rdx                       /* frame */
 936         sti
 937         call    *%rax
 938         cli
 939 nocallchain:
 940 #endif
 941         testl   %ebx,%ebx       /* %ebx != 0 => return to userland */
 942         jnz     doreti_exit
 943         /*
 944          * Restore speculation control MSR, if preserved.
 945          */
 946         testl   $CPUID_STDEXT3_IBPB,cpu_stdext_feature3(%rip)
 947         je      1f
 948         movl    %r14d,%eax
 949         xorl    %edx,%edx
 950         movl    $MSR_IA32_SPEC_CTRL,%ecx
 951         wrmsr
 952         /*
 953          * Put back the preserved MSR_GSBASE value.
 954          */
 955 1:      movl    $MSR_GSBASE,%ecx
 956         movq    %r12,%rdx
 957         movl    %edx,%eax
 958         shrq    $32,%rdx
 959         wrmsr
 960         cmpb    $0, nmi_flush_l1d_sw(%rip)
 961         je      2f
 962         call    flush_l1d_sw            /* bhyve L1TF assist */
 963 2:      movq    %r13,%cr3
 964         movq    %r15,%cr2
 965         RESTORE_REGS
 966         addq    $TF_RIP,%rsp
 967         jmp     doreti_iret
 968
 969 /*
 970  * MC# handling is similar to NMI.
 971  *
 972  * As with NMIs, machine check exceptions do not respect RFLAGS.IF and
 973  * can occur at any time with a GS.base value that does not correspond
 974  * to the privilege level in CS.
 975  *
 976  * Machine checks are not unblocked by iretq, but it is best to run
 977  * the handler with interrupts disabled since the exception may have
 978  * interrupted a critical section.
 979  *
 980  * The MC# handler runs on its own stack (tss_ist3).  The canonical
 981  * GS.base value for the processor is stored just above the bottom of
 982  * its MC# stack.  For exceptions taken from kernel mode, the current
 983  * value in the processor's GS.base is saved at entry to C-preserved
 984  * register %r12, the canonical value for GS.base is then loaded into
 985  * the processor, and the saved value is restored at exit time.  For
 986  * exceptions taken from user mode, the cheaper 'SWAPGS' instructions
 987  * are used for swapping GS.base.
 988  */
 989
 990 IDTVEC(mchk)
 991         subq    $TF_RIP,%rsp
 992         movl    $(T_MCHK),TF_TRAPNO(%rsp)
 993         movq    $0,TF_ADDR(%rsp)
 994         movq    $0,TF_ERR(%rsp)
 995         movq    %rdi,TF_RDI(%rsp)
 996         movq    %rsi,TF_RSI(%rsp)
 997         movq    %rdx,TF_RDX(%rsp)
 998         movq    %rcx,TF_RCX(%rsp)
 999         movq    %r8,TF_R8(%rsp)
1000         movq    %r9,TF_R9(%rsp)
1001         movq    %rax,TF_RAX(%rsp)
1002         movq    %rbx,TF_RBX(%rsp)
1003         movq    %rbp,TF_RBP(%rsp)
1004         movq    %r10,TF_R10(%rsp)
1005         movq    %r11,TF_R11(%rsp)
1006         movq    %r12,TF_R12(%rsp)
1007         movq    %r13,TF_R13(%rsp)
1008         movq    %r14,TF_R14(%rsp)
1009         movq    %r15,TF_R15(%rsp)
1010         SAVE_SEGS
1011         movl    $TF_HASSEGS,TF_FLAGS(%rsp)
1012         pushfq
1013         andq    $~(PSL_D | PSL_AC),(%rsp)
1014         popfq
1015         xorl    %ebx,%ebx
1016         testb   $SEL_RPL_MASK,TF_CS(%rsp)
1017         jnz     mchk_fromuserspace
1018         /*
1019          * We've interrupted the kernel.  See comment in NMI handler about
1020          * registers use.
1021          */
1022         movq    %cr2,%r15
1023         movl    $MSR_GSBASE,%ecx
1024         rdmsr
1025         movq    %rax,%r12
1026         shlq    $32,%rdx
1027         orq     %rdx,%r12
1028         /* Retrieve and load the canonical value for GS.base. */
1029         movq    TF_SIZE(%rsp),%rdx
1030         movl    %edx,%eax
1031         shrq    $32,%rdx
1032         wrmsr
1033         movq    %cr3,%r13
1034         movq    PCPU(KCR3),%rax
1035         cmpq    $~0,%rax
1036         je      1f
1037         movq    %rax,%cr3
1038 1:      testl   $CPUID_STDEXT3_IBPB,cpu_stdext_feature3(%rip)
1039         je      mchk_calltrap
1040         movl    $MSR_IA32_SPEC_CTRL,%ecx
1041         rdmsr
1042         movl    %eax,%r14d
1043         call    handle_ibrs_entry
1044         jmp     mchk_calltrap
1045 mchk_fromuserspace:
1046         incl    %ebx
1047         swapgs
1048         movq    %cr3,%r13
1049         movq    PCPU(KCR3),%rax
1050         cmpq    $~0,%rax
1051         je      1f
1052         movq    %rax,%cr3
1053 1:      call    handle_ibrs_entry
1054 /* Note: this label is also used by ddb and gdb: */
1055 mchk_calltrap:
1056         FAKE_MCOUNT(TF_RIP(%rsp))
1057         movq    %rsp,%rdi
1058         call    mca_intr
1059         MEXITCOUNT
1060         testl   %ebx,%ebx       /* %ebx != 0 => return to userland */
1061         jnz     doreti_exit
1062         /*
1063          * Restore speculation control MSR, if preserved.
1064          */
1065         testl   $CPUID_STDEXT3_IBPB,cpu_stdext_feature3(%rip)
1066         je      1f
1067         movl    %r14d,%eax
1068         xorl    %edx,%edx
1069         movl    $MSR_IA32_SPEC_CTRL,%ecx
1070         wrmsr
1071         /*
1072          * Put back the preserved MSR_GSBASE value.
1073          */
1074 1:      movl    $MSR_GSBASE,%ecx
1075         movq    %r12,%rdx
1076         movl    %edx,%eax
1077         shrq    $32,%rdx
1078         wrmsr
1079         movq    %r13,%cr3
1080         movq    %r15,%cr2
1081         RESTORE_REGS
1082         addq    $TF_RIP,%rsp
1083         jmp     doreti_iret
1084
1085 ENTRY(fork_trampoline)
1086         movq    %r12,%rdi               /* function */
1087         movq    %rbx,%rsi               /* arg1 */
1088         movq    %rsp,%rdx               /* trapframe pointer */
1089         call    fork_exit
1090         MEXITCOUNT
1091         jmp     doreti                  /* Handle any ASTs */
1092
1093 /*
1094  * To efficiently implement classification of trap and interrupt handlers
1095  * for profiling, there must be only trap handlers between the labels btrap
1096  * and bintr, and only interrupt handlers between the labels bintr and
1097  * eintr.  This is implemented (partly) by including files that contain
1098  * some of the handlers.  Before including the files, set up a normal asm
1099  * environment so that the included files doen't need to know that they are
1100  * included.
1101  */
1102
1103 #ifdef COMPAT_FREEBSD32
1104         .data
1105         .p2align 4
1106         .text
1107         SUPERALIGN_TEXT
1108
1109 #include <amd64/ia32/ia32_exception.S>
1110 #endif
1111
1112         .data
1113         .p2align 4
1114         .text
1115         SUPERALIGN_TEXT
1116 MCOUNT_LABEL(bintr)
1117
1118 #include <amd64/amd64/apic_vector.S>
1119
1120 #ifdef DEV_ATPIC
1121         .data
1122         .p2align 4
1123         .text
1124         SUPERALIGN_TEXT
1125
1126 #include <amd64/amd64/atpic_vector.S>
1127 #endif
1128
1129         .text
1130 MCOUNT_LABEL(eintr)
1131
1132 /*
1133  * void doreti(struct trapframe)
1134  *
1135  * Handle return from interrupts, traps and syscalls.
1136  */
1137         .text
1138         SUPERALIGN_TEXT
1139         .type   doreti,@function
1140         .globl  doreti
1141 doreti:
1142         FAKE_MCOUNT($bintr)             /* init "from" bintr -> doreti */
1143         /*
1144          * Check if ASTs can be handled now.
1145          */
1146         testb   $SEL_RPL_MASK,TF_CS(%rsp) /* are we returning to user mode? */
1147         jz      doreti_exit             /* can't handle ASTs now if not */
1148
1149 doreti_ast:
1150         /*
1151          * Check for ASTs atomically with returning.  Disabling CPU
1152          * interrupts provides sufficient locking even in the SMP case,
1153          * since we will be informed of any new ASTs by an IPI.
1154          */
1155         cli
1156         movq    PCPU(CURTHREAD),%rax
1157         testl   $TDF_ASTPENDING | TDF_NEEDRESCHED,TD_FLAGS(%rax)
1158         je      doreti_exit
1159         sti
1160         movq    %rsp,%rdi       /* pass a pointer to the trapframe */
1161         call    ast
1162         jmp     doreti_ast
1163
1164         /*
1165          * doreti_exit: pop registers, iret.
1166          *
1167          *      The segment register pop is a special case, since it may
1168          *      fault if (for example) a sigreturn specifies bad segment
1169          *      registers.  The fault is handled in trap.c.
1170          */
1171 doreti_exit:
1172         MEXITCOUNT
1173         movq    PCPU(CURPCB),%r8
1174
1175         /*
1176          * Do not reload segment registers for kernel.
1177          * Since we do not reload segments registers with sane
1178          * values on kernel entry, descriptors referenced by
1179          * segments registers might be not valid.  This is fatal
1180          * for user mode, but is not a problem for the kernel.
1181          */
1182         testb   $SEL_RPL_MASK,TF_CS(%rsp)
1183         jz      ld_regs
1184         testl   $PCB_FULL_IRET,PCB_FLAGS(%r8)
1185         jz      ld_regs
1186         andl    $~PCB_FULL_IRET,PCB_FLAGS(%r8)
1187         testl   $TF_HASSEGS,TF_FLAGS(%rsp)
1188         je      set_segs
1189
1190 do_segs:
1191         /* Restore %fs and fsbase */
1192         movw    TF_FS(%rsp),%ax
1193         .globl  ld_fs
1194 ld_fs:
1195         movw    %ax,%fs
1196         cmpw    $KUF32SEL,%ax
1197         jne     1f
1198         movl    $MSR_FSBASE,%ecx
1199         movl    PCB_FSBASE(%r8),%eax
1200         movl    PCB_FSBASE+4(%r8),%edx
1201         .globl  ld_fsbase
1202 ld_fsbase:
1203         wrmsr
1204 1:
1205         /* Restore %gs and gsbase */
1206         movw    TF_GS(%rsp),%si
1207         pushfq
1208         cli
1209         movl    $MSR_GSBASE,%ecx
1210         /* Save current kernel %gs base into %r12d:%r13d */
1211         rdmsr
1212         movl    %eax,%r12d
1213         movl    %edx,%r13d
1214         .globl  ld_gs
1215 ld_gs:
1216         movw    %si,%gs
1217         /* Save user %gs base into %r14d:%r15d */
1218         rdmsr
1219         movl    %eax,%r14d
1220         movl    %edx,%r15d
1221         /* Restore kernel %gs base */
1222         movl    %r12d,%eax
1223         movl    %r13d,%edx
1224         wrmsr
1225         popfq
1226         /*
1227          * Restore user %gs base, either from PCB if used for TLS, or
1228          * from the previously saved msr read.
1229          */
1230         movl    $MSR_KGSBASE,%ecx
1231         cmpw    $KUG32SEL,%si
1232         jne     1f
1233         movl    PCB_GSBASE(%r8),%eax
1234         movl    PCB_GSBASE+4(%r8),%edx
1235         jmp     ld_gsbase
1236 1:
1237         movl    %r14d,%eax
1238         movl    %r15d,%edx
1239         .globl  ld_gsbase
1240 ld_gsbase:
1241         wrmsr   /* May trap if non-canonical, but only for TLS. */
1242         .globl  ld_es
1243 ld_es:
1244         movw    TF_ES(%rsp),%es
1245         .globl  ld_ds
1246 ld_ds:
1247         movw    TF_DS(%rsp),%ds
1248 ld_regs:
1249         RESTORE_REGS
1250         testb   $SEL_RPL_MASK,TF_CS(%rsp) /* Did we come from kernel? */
1251         jz      2f                      /* keep running with kernel GS.base */
1252         cli
1253         call    handle_ibrs_exit_rs
1254         callq   *mds_handler
1255         cmpq    $~0,PCPU(UCR3)
1256         je      1f
1257         pushq   %rdx
1258         movq    PCPU(PTI_RSP0),%rdx
1259         subq    $PTI_SIZE,%rdx
1260         movq    %rax,PTI_RAX(%rdx)
1261         popq    %rax
1262         movq    %rax,PTI_RDX(%rdx)
1263         movq    TF_RIP(%rsp),%rax
1264         movq    %rax,PTI_RIP(%rdx)
1265         movq    TF_CS(%rsp),%rax
1266         movq    %rax,PTI_CS(%rdx)
1267         movq    TF_RFLAGS(%rsp),%rax
1268         movq    %rax,PTI_RFLAGS(%rdx)
1269         movq    TF_RSP(%rsp),%rax
1270         movq    %rax,PTI_RSP(%rdx)
1271         movq    TF_SS(%rsp),%rax
1272         movq    %rax,PTI_SS(%rdx)
1273         movq    PCPU(UCR3),%rax
1274         andq    PCPU(UCR3_LOAD_MASK),%rax
1275         movq    $PMAP_UCR3_NOMASK,PCPU(UCR3_LOAD_MASK)
1276         swapgs
1277         movq    %rdx,%rsp
1278         movq    %rax,%cr3
1279         popq    %rdx
1280         popq    %rax
1281         addq    $8,%rsp
1282         jmp     doreti_iret
1283 1:      swapgs
1284 2:      addq    $TF_RIP,%rsp
1285         .globl  doreti_iret
1286 doreti_iret:
1287         iretq
1288
1289 set_segs:
1290         movw    $KUDSEL,%ax
1291         movw    %ax,TF_DS(%rsp)
1292         movw    %ax,TF_ES(%rsp)
1293         movw    $KUF32SEL,TF_FS(%rsp)
1294         movw    $KUG32SEL,TF_GS(%rsp)
1295         jmp     do_segs
1296
1297         /*
1298          * doreti_iret_fault.  Alternative return code for
1299          * the case where we get a fault in the doreti_exit code
1300          * above.  trap() (amd64/amd64/trap.c) catches this specific
1301          * case, sends the process a signal and continues in the
1302          * corresponding place in the code below.
1303          */
1304         ALIGN_TEXT
1305         .globl  doreti_iret_fault
1306 doreti_iret_fault:
1307         subq    $TF_RIP,%rsp            /* space including tf_err, tf_trapno */
1308         movq    %rax,TF_RAX(%rsp)
1309         movq    %rdx,TF_RDX(%rsp)
1310         movq    %rcx,TF_RCX(%rsp)
1311         call    handle_ibrs_entry
1312         testb   $SEL_RPL_MASK,TF_CS(%rsp)
1313         jz      1f
1314         sti
1315 1:
1316         SAVE_SEGS
1317         movl    $TF_HASSEGS,TF_FLAGS(%rsp)
1318         movq    %rdi,TF_RDI(%rsp)
1319         movq    %rsi,TF_RSI(%rsp)
1320         movq    %r8,TF_R8(%rsp)
1321         movq    %r9,TF_R9(%rsp)
1322         movq    %rbx,TF_RBX(%rsp)
1323         movq    %rbp,TF_RBP(%rsp)
1324         movq    %r10,TF_R10(%rsp)
1325         movq    %r11,TF_R11(%rsp)
1326         movq    %r12,TF_R12(%rsp)
1327         movq    %r13,TF_R13(%rsp)
1328         movq    %r14,TF_R14(%rsp)
1329         movq    %r15,TF_R15(%rsp)
1330         movl    $T_PROTFLT,TF_TRAPNO(%rsp)
1331         movq    $0,TF_ERR(%rsp) /* XXX should be the error code */
1332         movq    $0,TF_ADDR(%rsp)
1333         FAKE_MCOUNT(TF_RIP(%rsp))
1334         jmp     calltrap
1335
1336         ALIGN_TEXT
1337         .globl  ds_load_fault
1338 ds_load_fault:
1339         movl    $T_PROTFLT,TF_TRAPNO(%rsp)
1340         testb   $SEL_RPL_MASK,TF_CS(%rsp)
1341         jz      1f
1342         sti
1343 1:
1344         movq    %rsp,%rdi
1345         call    trap
1346         movw    $KUDSEL,TF_DS(%rsp)
1347         jmp     doreti
1348
1349         ALIGN_TEXT
1350         .globl  es_load_fault
1351 es_load_fault:
1352         movl    $T_PROTFLT,TF_TRAPNO(%rsp)
1353         testl   $PSL_I,TF_RFLAGS(%rsp)
1354         jz      1f
1355         sti
1356 1:
1357         movq    %rsp,%rdi
1358         call    trap
1359         movw    $KUDSEL,TF_ES(%rsp)
1360         jmp     doreti
1361
1362         ALIGN_TEXT
1363         .globl  fs_load_fault
1364 fs_load_fault:
1365         testl   $PSL_I,TF_RFLAGS(%rsp)
1366         jz      1f
1367         sti
1368 1:
1369         movl    $T_PROTFLT,TF_TRAPNO(%rsp)
1370         movq    %rsp,%rdi
1371         call    trap
1372         movw    $KUF32SEL,TF_FS(%rsp)
1373         jmp     doreti
1374
1375         ALIGN_TEXT
1376         .globl  gs_load_fault
1377 gs_load_fault:
1378         popfq
1379         movl    $T_PROTFLT,TF_TRAPNO(%rsp)
1380         testl   $PSL_I,TF_RFLAGS(%rsp)
1381         jz      1f
1382         sti
1383 1:
1384         movq    %rsp,%rdi
1385         call    trap
1386         movw    $KUG32SEL,TF_GS(%rsp)
1387         jmp     doreti
1388
1389         ALIGN_TEXT
1390         .globl  fsbase_load_fault
1391 fsbase_load_fault:
1392         movl    $T_PROTFLT,TF_TRAPNO(%rsp)
1393         testl   $PSL_I,TF_RFLAGS(%rsp)
1394         jz      1f
1395         sti
1396 1:
1397         movq    %rsp,%rdi
1398         call    trap
1399         movq    PCPU(CURTHREAD),%r8
1400         movq    TD_PCB(%r8),%r8
1401         movq    $0,PCB_FSBASE(%r8)
1402         jmp     doreti
1403
1404         ALIGN_TEXT
1405         .globl  gsbase_load_fault
1406 gsbase_load_fault:
1407         movl    $T_PROTFLT,TF_TRAPNO(%rsp)
1408         testl   $PSL_I,TF_RFLAGS(%rsp)
1409         jz      1f
1410         sti
1411 1:
1412         movq    %rsp,%rdi
1413         call    trap
1414         movq    PCPU(CURTHREAD),%r8
1415         movq    TD_PCB(%r8),%r8
1416         movq    $0,PCB_GSBASE(%r8)
1417         jmp     doreti
1418
1419 #ifdef HWPMC_HOOKS
1420         ENTRY(end_exceptions)
1421 #endif