sys/amd64/amd64/locore.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  *      from: @(#)locore.s      7.3 (Berkeley) 5/13/91
  37  *      $Id: locore.s,v 1.124 1999/06/18 14:32:13 bde Exp $
  38  *
  39  *              originally from: locore.s, by William F. Jolitz
  40  *
  41  *              Substantially rewritten by David Greenman, Rod Grimes,
  42  *                      Bruce Evans, Wolfgang Solfrank, Poul-Henning Kamp
  43  *                      and many others.
  44  */
  45
  46 #include "opt_bootp.h"
  47 #include "opt_ddb.h"
  48 #include "opt_nfsroot.h"
  49 #include "opt_userconfig.h"
  50
  51 #include <sys/syscall.h>
  52 #include <sys/reboot.h>
  53
  54 #include <machine/asmacros.h>
  55 #include <machine/cputypes.h>
  56 #include <machine/psl.h>
  57 #include <machine/pmap.h>
  58 #include <machine/specialreg.h>
  59
  60 #include "assym.s"
  61
  62 /*
  63  *      XXX
  64  *
  65  * Note: This version greatly munged to avoid various assembler errors
  66  * that may be fixed in newer versions of gas. Perhaps newer versions
  67  * will have more pleasant appearance.
  68  */
  69
  70 /*
  71  * PTmap is recursive pagemap at top of virtual address space.
  72  * Within PTmap, the page directory can be found (third indirection).
  73  */
  74         .globl  _PTmap,_PTD,_PTDpde
  75         .set    _PTmap,(PTDPTDI << PDRSHIFT)
  76         .set    _PTD,_PTmap + (PTDPTDI * PAGE_SIZE)
  77         .set    _PTDpde,_PTD + (PTDPTDI * PDESIZE)
  78
  79 /*
  80  * APTmap, APTD is the alternate recursive pagemap.
  81  * It's used when modifying another process's page tables.
  82  */
  83         .globl  _APTmap,_APTD,_APTDpde
  84         .set    _APTmap,APTDPTDI << PDRSHIFT
  85         .set    _APTD,_APTmap + (APTDPTDI * PAGE_SIZE)
  86         .set    _APTDpde,_PTD + (APTDPTDI * PDESIZE)
  87
  88 /*
  89  * Globals
  90  */
  91         .data
  92         ALIGN_DATA              /* just to be sure */
  93
  94         .globl  HIDENAME(tmpstk)
  95         .space  0x2000          /* space for tmpstk - temporary stack */
  96 HIDENAME(tmpstk):
  97
  98         .globl  _boothowto,_bootdev
  99
 100         .globl  _cpu,_cpu_vendor,_cpu_id,_bootinfo
 101         .globl  _cpu_high, _cpu_feature
 102
 103 _cpu:           .long   0                       /* are we 386, 386sx, or 486 */
 104 _cpu_id:        .long   0                       /* stepping ID */
 105 _cpu_high:      .long   0                       /* highest arg to CPUID */
 106 _cpu_feature:   .long   0                       /* features */
 107 _cpu_vendor:    .space  20                      /* CPU origin code */
 108 _bootinfo:      .space  BOOTINFO_SIZE           /* bootinfo that we can handle */
 109
 110 _KERNend:       .long   0                       /* phys addr end of kernel (just after bss) */
 111 physfree:       .long   0                       /* phys addr of next free page */
 112
 113 #ifdef SMP
 114                 .globl  _cpu0prvpage
 115 cpu0pp:         .long   0                       /* phys addr cpu0 private pg */
 116 _cpu0prvpage:   .long   0                       /* relocated version */
 117
 118                 .globl  _SMPpt
 119 SMPptpa:        .long   0                       /* phys addr SMP page table */
 120 _SMPpt:         .long   0                       /* relocated version */
 121 #endif /* SMP */
 122
 123         .globl  _IdlePTD
 124 _IdlePTD:       .long   0                       /* phys addr of kernel PTD */
 125
 126 #ifdef SMP
 127         .globl  _KPTphys
 128 #endif
 129 _KPTphys:       .long   0                       /* phys addr of kernel page tables */
 130
 131         .globl  _proc0paddr
 132 _proc0paddr:    .long   0                       /* address of proc 0 address space */
 133 p0upa:          .long   0                       /* phys addr of proc0's UPAGES */
 134
 135 vm86phystk:     .long   0                       /* PA of vm86/bios stack */
 136
 137         .globl  _vm86paddr, _vm86pa
 138 _vm86paddr:     .long   0                       /* address of vm86 region */
 139 _vm86pa:        .long   0                       /* phys addr of vm86 region */
 140
 141 #ifdef BDE_DEBUGGER
 142         .globl  _bdb_exists                     /* flag to indicate BDE debugger is present */
 143 _bdb_exists:    .long   0
 144 #endif
 145
 146 #ifdef PC98
 147         .globl  _pc98_system_parameter
 148 _pc98_system_parameter:
 149         .space  0x240
 150 #endif
 151
 152 /**********************************************************************
 153  *
 154  * Some handy macros
 155  *
 156  */
 157
 158 #define R(foo) ((foo)-KERNBASE)
 159
 160 #define ALLOCPAGES(foo) \
 161         movl    R(physfree), %esi ; \
 162         movl    $((foo)*PAGE_SIZE), %eax ; \
 163         addl    %esi, %eax ; \
 164         movl    %eax, R(physfree) ; \
 165         movl    %esi, %edi ; \
 166         movl    $((foo)*PAGE_SIZE),%ecx ; \
 167         xorl    %eax,%eax ; \
 168         cld ; \
 169         rep ; \
 170         stosb
 171
 172 /*
 173  * fillkpt
 174  *      eax = page frame address
 175  *      ebx = index into page table
 176  *      ecx = how many pages to map
 177  *      base = base address of page dir/table
 178  *      prot = protection bits
 179  */
 180 #define fillkpt(base, prot)               \
 181         shll    $2,%ebx                 ; \
 182         addl    base,%ebx               ; \
 183         orl     $PG_V,%eax              ; \
 184         orl     prot,%eax               ; \
 185 1:      movl    %eax,(%ebx)             ; \
 186         addl    $PAGE_SIZE,%eax         ; /* increment physical address */ \
 187         addl    $4,%ebx                 ; /* next pte */ \
 188         loop    1b
 189
 190 /*
 191  * fillkptphys(prot)
 192  *      eax = physical address
 193  *      ecx = how many pages to map
 194  *      prot = protection bits
 195  */
 196 #define fillkptphys(prot)                 \
 197         movl    %eax, %ebx              ; \
 198         shrl    $PAGE_SHIFT, %ebx       ; \
 199         fillkpt(R(_KPTphys), prot)
 200
 201         .text
 202 /**********************************************************************
 203  *
 204  * This is where the bootblocks start us, set the ball rolling...
 205  *
 206  */
 207 NON_GPROF_ENTRY(btext)
 208
 209 #ifdef PC98
 210         /* save SYSTEM PARAMETER for resume (NS/T or other) */
 211         movl    $0xa1400,%esi
 212         movl    $R(_pc98_system_parameter),%edi
 213         movl    $0x0240,%ecx
 214         cld
 215         rep
 216         movsb
 217 #else   /* IBM-PC */
 218 #ifdef BDE_DEBUGGER
 219 #ifdef BIOS_STEALS_3K
 220         cmpl    $0x0375c339,0x95504
 221 #else
 222         cmpl    $0x0375c339,0x96104     /* XXX - debugger signature */
 223 #endif
 224         jne     1f
 225         movb    $1,R(_bdb_exists)
 226 1:
 227 #endif
 228 #endif  /* PC98 */
 229
 230 /* Tell the bios to warmboot next time */
 231         movw    $0x1234,0x472
 232
 233 /* Set up a real frame in case the double return in newboot is executed. */
 234         pushl   %ebp
 235         movl    %esp, %ebp
 236
 237 /* Don't trust what the BIOS gives for eflags. */
 238         pushl   $PSL_KERNEL
 239         popfl
 240
 241 /*
 242  * Don't trust what the BIOS gives for %fs and %gs.  Trust the bootstrap
 243  * to set %cs, %ds, %es and %ss.
 244  */
 245         mov     %ds, %ax
 246         mov     %ax, %fs
 247         mov     %ax, %gs
 248
 249         call    recover_bootinfo
 250
 251 /* Get onto a stack that we can trust. */
 252 /*
 253  * XXX this step is delayed in case recover_bootinfo needs to return via
 254  * the old stack, but it need not be, since recover_bootinfo actually
 255  * returns via the old frame.
 256  */
 257         movl    $R(HIDENAME(tmpstk)),%esp
 258
 259 #ifdef PC98
 260         /* pc98_machine_type & M_EPSON_PC98 */
 261         testb   $0x02,R(_pc98_system_parameter)+220
 262         jz      3f
 263         /* epson_machine_id <= 0x0b */
 264         cmpb    $0x0b,R(_pc98_system_parameter)+224
 265         ja      3f
 266
 267         /* count up memory */
 268         movl    $0x100000,%eax          /* next, talley remaining memory */
 269         movl    $0xFFF-0x100,%ecx
 270 1:      movl    0(%eax),%ebx            /* save location to check */
 271         movl    $0xa55a5aa5,0(%eax)     /* write test pattern */
 272         cmpl    $0xa55a5aa5,0(%eax)     /* does not check yet for rollover */
 273         jne     2f
 274         movl    %ebx,0(%eax)            /* restore memory */
 275         addl    $PAGE_SIZE,%eax
 276         loop    1b
 277 2:      subl    $0x100000,%eax
 278         shrl    $17,%eax
 279         movb    %al,R(_pc98_system_parameter)+1
 280 3:
 281 #endif
 282
 283         call    identify_cpu
 284
 285 /* clear bss */
 286 /*
 287  * XXX this should be done a little earlier.
 288  *
 289  * XXX we don't check that there is memory for our bss and page tables
 290  * before using it.
 291  *
 292  * XXX the boot program somewhat bogusly clears the bss.  We still have
 293  * to do it in case we were unzipped by kzipboot.  Then the boot program
 294  * only clears kzipboot's bss.
 295  *
 296  * XXX the gdt and idt are still somewhere in the boot program.  We
 297  * depend on the convention that the boot program is below 1MB and we
 298  * are above 1MB to keep the gdt and idt  away from the bss and page
 299  * tables.  The idt is only used if BDE_DEBUGGER is enabled.
 300  */
 301         movl    $R(_end),%ecx
 302         movl    $R(_edata),%edi
 303         subl    %edi,%ecx
 304         xorl    %eax,%eax
 305         cld
 306         rep
 307         stosb
 308
 309         call    create_pagetables
 310
 311 /*
 312  * If the CPU has support for VME, turn it on.
 313  */
 314         testl   $CPUID_VME, R(_cpu_feature)
 315         jz      1f
 316         movl    %cr4, %eax
 317         orl     $CR4_VME, %eax
 318         movl    %eax, %cr4
 319 1:
 320
 321 #ifdef BDE_DEBUGGER
 322 /*
 323  * Adjust as much as possible for paging before enabling paging so that the
 324  * adjustments can be traced.
 325  */
 326         call    bdb_prepare_paging
 327 #endif
 328
 329 /* Now enable paging */
 330         movl    R(_IdlePTD), %eax
 331         movl    %eax,%cr3                       /* load ptd addr into mmu */
 332         movl    %cr0,%eax                       /* get control word */
 333         orl     $CR0_PE|CR0_PG,%eax             /* enable paging */
 334         movl    %eax,%cr0                       /* and let's page NOW! */
 335
 336 #ifdef BDE_DEBUGGER
 337 /*
 338  * Complete the adjustments for paging so that we can keep tracing through
 339  * initi386() after the low (physical) addresses for the gdt and idt become
 340  * invalid.
 341  */
 342         call    bdb_commit_paging
 343 #endif
 344
 345         pushl   $begin                          /* jump to high virtualized address */
 346         ret
 347
 348 /* now running relocated at KERNBASE where the system is linked to run */
 349 begin:
 350         /* set up bootstrap stack */
 351         movl    _proc0paddr,%esp        /* location of in-kernel pages */
 352         addl    $UPAGES*PAGE_SIZE,%esp  /* bootstrap stack end location */
 353         xorl    %eax,%eax                       /* mark end of frames */
 354         movl    %eax,%ebp
 355         movl    _proc0paddr,%eax
 356         movl    _IdlePTD, %esi
 357         movl    %esi,PCB_CR3(%eax)
 358
 359         movl    physfree, %esi
 360         pushl   %esi                            /* value of first for init386(first) */
 361         call    _init386                        /* wire 386 chip for unix operation */
 362         popl    %esi
 363
 364         .globl  __ucodesel,__udatasel
 365
 366         pushl   $0                              /* unused */
 367         pushl   __udatasel                      /* ss */
 368         pushl   $0                              /* esp - filled in by execve() */
 369         pushl   $PSL_USER                       /* eflags (IOPL 0, int enab) */
 370         pushl   __ucodesel                      /* cs */
 371         pushl   $0                              /* eip - filled in by execve() */
 372         subl    $(13*4),%esp                    /* space for rest of registers */
 373
 374         pushl   %esp                            /* call main with frame pointer */
 375         call    _mi_startup                     /* autoconfiguration, mountroot etc */
 376
 377         hlt             /* never returns to here */
 378
 379 /*
 380  * When starting init, call this to configure the process for user
 381  * mode.  This will be inherited by other processes.
 382  */
 383 NON_GPROF_ENTRY(prepare_usermode)
 384         /*
 385          * Now we've run main() and determined what cpu-type we are, we can
 386          * enable write protection and alignment checking on i486 cpus and
 387          * above.
 388          */
 389 #if defined(I486_CPU) || defined(I586_CPU) || defined(I686_CPU)
 390         cmpl    $CPUCLASS_386,_cpu_class
 391         je      1f
 392         movl    %cr0,%eax                       /* get control word */
 393         orl     $CR0_WP|CR0_AM,%eax             /* enable i486 features */
 394         movl    %eax,%cr0                       /* and do it */
 395 1:
 396 #endif
 397         /*
 398          * on return from main(), we are process 1
 399          * set up address space and stack so that we can 'return' to user mode
 400          */
 401         movl    __ucodesel,%eax
 402         movl    __udatasel,%ecx
 403
 404 #if 0   /* ds/es/fs are in trap frame */
 405         movl    %cx,%ds
 406         movl    %cx,%es
 407         movl    %cx,%fs
 408 #endif
 409         movl    %cx,%gs                         /* and ds to gs */
 410         ret                                     /* goto user! */
 411
 412
 413 #define LCALL(x,y)      .byte 0x9a ; .long y ; .word x
 414
 415 /*
 416  * Signal trampoline, copied to top of user stack
 417  */
 418 NON_GPROF_ENTRY(sigcode)
 419         call    SIGF_HANDLER(%esp)
 420         lea     SIGF_SC(%esp),%eax              /* scp (the call may have clobbered the */
 421                                                 /* copy at 8(%esp)) */
 422         pushl   %eax
 423         pushl   %eax                            /* junk to fake return address */
 424         movl    $SYS_sigreturn,%eax             /* sigreturn() */
 425         LCALL(0x7,0)                            /* enter kernel with args on stack */
 426         hlt                                     /* never gets here */
 427         ALIGN_TEXT
 428 _esigcode:
 429
 430         .data
 431         .globl  _szsigcode
 432 _szsigcode:
 433         .long   _esigcode-_sigcode
 434         .text
 435
 436 /**********************************************************************
 437  *
 438  * Recover the bootinfo passed to us from the boot program
 439  *
 440  */
 441 recover_bootinfo:
 442         /*
 443          * This code is called in different ways depending on what loaded
 444          * and started the kernel.  This is used to detect how we get the
 445          * arguments from the other code and what we do with them.
 446          *
 447          * Old disk boot blocks:
 448          *      (*btext)(howto, bootdev, cyloffset, esym);
 449          *      [return address == 0, and can NOT be returned to]
 450          *      [cyloffset was not supported by the FreeBSD boot code
 451          *       and always passed in as 0]
 452          *      [esym is also known as total in the boot code, and
 453          *       was never properly supported by the FreeBSD boot code]
 454          *
 455          * Old diskless netboot code:
 456          *      (*btext)(0,0,0,0,&nfsdiskless,0,0,0);
 457          *      [return address != 0, and can NOT be returned to]
 458          *      If we are being booted by this code it will NOT work,
 459          *      so we are just going to halt if we find this case.
 460          *
 461          * New uniform boot code:
 462          *      (*btext)(howto, bootdev, 0, 0, 0, &bootinfo)
 463          *      [return address != 0, and can be returned to]
 464          *
 465          * There may seem to be a lot of wasted arguments in here, but
 466          * that is so the newer boot code can still load very old kernels
 467          * and old boot code can load new kernels.
 468          */
 469
 470         /*
 471          * The old style disk boot blocks fake a frame on the stack and
 472          * did an lret to get here.  The frame on the stack has a return
 473          * address of 0.
 474          */
 475         cmpl    $0,4(%ebp)
 476         je      olddiskboot
 477
 478         /*
 479          * We have some form of return address, so this is either the
 480          * old diskless netboot code, or the new uniform code.  That can
 481          * be detected by looking at the 5th argument, if it is 0
 482          * we are being booted by the new uniform boot code.
 483          */
 484         cmpl    $0,24(%ebp)
 485         je      newboot
 486
 487         /*
 488          * Seems we have been loaded by the old diskless boot code, we
 489          * don't stand a chance of running as the diskless structure
 490          * changed considerably between the two, so just halt.
 491          */
 492          hlt
 493
 494         /*
 495          * We have been loaded by the new uniform boot code.
 496          * Let's check the bootinfo version, and if we do not understand
 497          * it we return to the loader with a status of 1 to indicate this error
 498          */
 499 newboot:
 500         movl    28(%ebp),%ebx           /* &bootinfo.version */
 501         movl    BI_VERSION(%ebx),%eax
 502         cmpl    $1,%eax                 /* We only understand version 1 */
 503         je      1f
 504         movl    $1,%eax                 /* Return status */
 505         leave
 506         /*
 507          * XXX this returns to our caller's caller (as is required) since
 508          * we didn't set up a frame and our caller did.
 509          */
 510         ret
 511
 512 1:
 513         /*
 514          * If we have a kernelname copy it in
 515          */
 516         movl    BI_KERNELNAME(%ebx),%esi
 517         cmpl    $0,%esi
 518         je      2f                      /* No kernelname */
 519         movl    $MAXPATHLEN,%ecx        /* Brute force!!! */
 520         movl    $R(_kernelname),%edi
 521         cmpb    $'/',(%esi)             /* Make sure it starts with a slash */
 522         je      1f
 523         movb    $'/',(%edi)
 524         incl    %edi
 525         decl    %ecx
 526 1:
 527         cld
 528         rep
 529         movsb
 530
 531 2:
 532         /*
 533          * Determine the size of the boot loader's copy of the bootinfo
 534          * struct.  This is impossible to do properly because old versions
 535          * of the struct don't contain a size field and there are 2 old
 536          * versions with the same version number.
 537          */
 538         movl    $BI_ENDCOMMON,%ecx      /* prepare for sizeless version */
 539         testl   $RB_BOOTINFO,8(%ebp)    /* bi_size (and bootinfo) valid? */
 540         je      got_bi_size             /* no, sizeless version */
 541         movl    BI_SIZE(%ebx),%ecx
 542 got_bi_size:
 543
 544         /*
 545          * Copy the common part of the bootinfo struct
 546          */
 547         movl    %ebx,%esi
 548         movl    $R(_bootinfo),%edi
 549         cmpl    $BOOTINFO_SIZE,%ecx
 550         jbe     got_common_bi_size
 551         movl    $BOOTINFO_SIZE,%ecx
 552 got_common_bi_size:
 553         cld
 554         rep
 555         movsb
 556
 557 #ifdef NFS_ROOT
 558 #ifndef BOOTP_NFSV3
 559         /*
 560          * If we have a nfs_diskless structure copy it in
 561          */
 562         movl    BI_NFS_DISKLESS(%ebx),%esi
 563         cmpl    $0,%esi
 564         je      olddiskboot
 565         movl    $R(_nfs_diskless),%edi
 566         movl    $NFSDISKLESS_SIZE,%ecx
 567         cld
 568         rep
 569         movsb
 570         movl    $R(_nfs_diskless_valid),%edi
 571         movl    $1,(%edi)
 572 #endif
 573 #endif
 574
 575         /*
 576          * The old style disk boot.
 577          *      (*btext)(howto, bootdev, cyloffset, esym);
 578          * Note that the newer boot code just falls into here to pick
 579          * up howto and bootdev, cyloffset and esym are no longer used
 580          */
 581 olddiskboot:
 582         movl    8(%ebp),%eax
 583         movl    %eax,R(_boothowto)
 584         movl    12(%ebp),%eax
 585         movl    %eax,R(_bootdev)
 586
 587         ret
 588
 589
 590 /**********************************************************************
 591  *
 592  * Identify the CPU and initialize anything special about it
 593  *
 594  */
 595 identify_cpu:
 596
 597         /* Try to toggle alignment check flag; does not exist on 386. */
 598         pushfl
 599         popl    %eax
 600         movl    %eax,%ecx
 601         orl     $PSL_AC,%eax
 602         pushl   %eax
 603         popfl
 604         pushfl
 605         popl    %eax
 606         xorl    %ecx,%eax
 607         andl    $PSL_AC,%eax
 608         pushl   %ecx
 609         popfl
 610
 611         testl   %eax,%eax
 612         jnz     try486
 613
 614         /* NexGen CPU does not have aligment check flag. */
 615         pushfl
 616         movl    $0x5555, %eax
 617         xorl    %edx, %edx
 618         movl    $2, %ecx
 619         clc
 620         divl    %ecx
 621         jz      trynexgen
 622         popfl
 623         movl    $CPU_386,R(_cpu)
 624         jmp     3f
 625
 626 trynexgen:
 627         popfl
 628         movl    $CPU_NX586,R(_cpu)
 629         movl    $0x4778654e,R(_cpu_vendor)      # store vendor string
 630         movl    $0x72446e65,R(_cpu_vendor+4)
 631         movl    $0x6e657669,R(_cpu_vendor+8)
 632         movl    $0,R(_cpu_vendor+12)
 633         jmp     3f
 634
 635 try486: /* Try to toggle identification flag; does not exist on early 486s. */
 636         pushfl
 637         popl    %eax
 638         movl    %eax,%ecx
 639         xorl    $PSL_ID,%eax
 640         pushl   %eax
 641         popfl
 642         pushfl
 643         popl    %eax
 644         xorl    %ecx,%eax
 645         andl    $PSL_ID,%eax
 646         pushl   %ecx
 647         popfl
 648
 649         testl   %eax,%eax
 650         jnz     trycpuid
 651         movl    $CPU_486,R(_cpu)
 652
 653         /*
 654          * Check Cyrix CPU
 655          * Cyrix CPUs do not change the undefined flags following
 656          * execution of the divide instruction which divides 5 by 2.
 657          *
 658          * Note: CPUID is enabled on M2, so it passes another way.
 659          */
 660         pushfl
 661         movl    $0x5555, %eax
 662         xorl    %edx, %edx
 663         movl    $2, %ecx
 664         clc
 665         divl    %ecx
 666         jnc     trycyrix
 667         popfl
 668         jmp     3f              /* You may use Intel CPU. */
 669
 670 trycyrix:
 671         popfl
 672         /*
 673          * IBM Bluelighting CPU also doesn't change the undefined flags.
 674          * Because IBM doesn't disclose the information for Bluelighting
 675          * CPU, we couldn't distinguish it from Cyrix's (including IBM
 676          * brand of Cyrix CPUs).
 677          */
 678         movl    $0x69727943,R(_cpu_vendor)      # store vendor string
 679         movl    $0x736e4978,R(_cpu_vendor+4)
 680         movl    $0x64616574,R(_cpu_vendor+8)
 681         jmp     3f
 682
 683 trycpuid:       /* Use the `cpuid' instruction. */
 684         xorl    %eax,%eax
 685         .byte   0x0f,0xa2                       # cpuid 0
 686         movl    %eax,R(_cpu_high)               # highest capability
 687         movl    %ebx,R(_cpu_vendor)             # store vendor string
 688         movl    %edx,R(_cpu_vendor+4)
 689         movl    %ecx,R(_cpu_vendor+8)
 690         movb    $0,R(_cpu_vendor+12)
 691
 692         movl    $1,%eax
 693         .byte   0x0f,0xa2                       # cpuid 1
 694         movl    %eax,R(_cpu_id)                 # store cpu_id
 695         movl    %edx,R(_cpu_feature)            # store cpu_feature
 696         rorl    $8,%eax                         # extract family type
 697         andl    $15,%eax
 698         cmpl    $5,%eax
 699         jae     1f
 700
 701         /* less than Pentium; must be 486 */
 702         movl    $CPU_486,R(_cpu)
 703         jmp     3f
 704 1:
 705         /* a Pentium? */
 706         cmpl    $5,%eax
 707         jne     2f
 708         movl    $CPU_586,R(_cpu)
 709         jmp     3f
 710 2:
 711         /* Greater than Pentium...call it a Pentium Pro */
 712         movl    $CPU_686,R(_cpu)
 713 3:
 714         ret
 715
 716
 717 /**********************************************************************
 718  *
 719  * Create the first page directory and its page tables.
 720  *
 721  */
 722
 723 create_pagetables:
 724
 725         testl   $CPUID_PGE, R(_cpu_feature)
 726         jz      1f
 727         movl    %cr4, %eax
 728         orl     $CR4_PGE, %eax
 729         movl    %eax, %cr4
 730 1:
 731
 732 /* Find end of kernel image (rounded up to a page boundary). */
 733         movl    $R(_end),%esi
 734
 735 /* include symbols if loaded and useful */
 736 #ifdef DDB
 737         movl    R(_bootinfo+BI_ESYMTAB),%edi
 738         testl   %edi,%edi
 739         je      over_symalloc
 740         movl    %edi,%esi
 741         movl    $KERNBASE,%edi
 742         addl    %edi,R(_bootinfo+BI_SYMTAB)
 743         addl    %edi,R(_bootinfo+BI_ESYMTAB)
 744 over_symalloc:
 745 #endif
 746
 747 /* If we are told where the end of the kernel space is, believe it. */
 748         movl    R(_bootinfo+BI_KERNEND),%edi
 749         testl   %edi,%edi
 750         je      no_kernend
 751         movl    %edi,%esi
 752 no_kernend:
 753
 754         addl    $PAGE_MASK,%esi
 755         andl    $~PAGE_MASK,%esi
 756         movl    %esi,R(_KERNend)        /* save end of kernel */
 757         movl    %esi,R(physfree)        /* next free page is at end of kernel */
 758
 759 /* Allocate Kernel Page Tables */
 760         ALLOCPAGES(NKPT)
 761         movl    %esi,R(_KPTphys)
 762
 763 /* Allocate Page Table Directory */
 764         ALLOCPAGES(1)
 765         movl    %esi,R(_IdlePTD)
 766
 767 /* Allocate UPAGES */
 768         ALLOCPAGES(UPAGES)
 769         movl    %esi,R(p0upa)
 770         addl    $KERNBASE, %esi
 771         movl    %esi, R(_proc0paddr)
 772
 773         ALLOCPAGES(1)                   /* vm86/bios stack */
 774         movl    %esi,R(vm86phystk)
 775
 776         ALLOCPAGES(3)                   /* pgtable + ext + IOPAGES */
 777         movl    %esi,R(_vm86pa)
 778         addl    $KERNBASE, %esi
 779         movl    %esi, R(_vm86paddr)
 780
 781 #ifdef SMP
 782 /* Allocate cpu0's private data page */
 783         ALLOCPAGES(1)
 784         movl    %esi,R(cpu0pp)
 785         addl    $KERNBASE, %esi
 786         movl    %esi, R(_cpu0prvpage)   /* relocated to KVM space */
 787
 788 /* Allocate SMP page table page */
 789         ALLOCPAGES(1)
 790         movl    %esi,R(SMPptpa)
 791         addl    $KERNBASE, %esi
 792         movl    %esi, R(_SMPpt)         /* relocated to KVM space */
 793 #endif  /* SMP */
 794
 795 /* Map read-only from zero to the end of the kernel text section */
 796         xorl    %eax, %eax
 797 #ifdef BDE_DEBUGGER
 798 /* If the debugger is present, actually map everything read-write. */
 799         cmpl    $0,R(_bdb_exists)
 800         jne     map_read_write
 801 #endif
 802         xorl    %edx,%edx
 803
 804 #if !defined(SMP)
 805         testl   $CPUID_PGE, R(_cpu_feature)
 806         jz      2f
 807         orl     $PG_G,%edx
 808 #endif
 809
 810 2:      movl    $R(_etext),%ecx
 811         addl    $PAGE_MASK,%ecx
 812         shrl    $PAGE_SHIFT,%ecx
 813         fillkptphys(%edx)
 814
 815 /* Map read-write, data, bss and symbols */
 816         movl    $R(_etext),%eax
 817         addl    $PAGE_MASK, %eax
 818         andl    $~PAGE_MASK, %eax
 819 map_read_write:
 820         movl    $PG_RW,%edx
 821 #if !defined(SMP)
 822         testl   $CPUID_PGE, R(_cpu_feature)
 823         jz      1f
 824         orl     $PG_G,%edx
 825 #endif
 826
 827 1:      movl    R(_KERNend),%ecx
 828         subl    %eax,%ecx
 829         shrl    $PAGE_SHIFT,%ecx
 830         fillkptphys(%edx)
 831
 832 /* Map page directory. */
 833         movl    R(_IdlePTD), %eax
 834         movl    $1, %ecx
 835         fillkptphys($PG_RW)
 836
 837 /* Map proc0's UPAGES in the physical way ... */
 838         movl    R(p0upa), %eax
 839         movl    $UPAGES, %ecx
 840         fillkptphys($PG_RW)
 841
 842 /* Map ISA hole */
 843         movl    $ISA_HOLE_START, %eax
 844         movl    $ISA_HOLE_LENGTH>>PAGE_SHIFT, %ecx
 845         fillkptphys($PG_RW)
 846
 847 /* Map space for the vm86 region */
 848         movl    R(vm86phystk), %eax
 849         movl    $4, %ecx
 850         fillkptphys($PG_RW)
 851
 852 /* Map page 0 into the vm86 page table */
 853         movl    $0, %eax
 854         movl    $0, %ebx
 855         movl    $1, %ecx
 856         fillkpt(R(_vm86pa), $PG_RW|PG_U)
 857
 858 /* ...likewise for the ISA hole */
 859         movl    $ISA_HOLE_START, %eax
 860         movl    $ISA_HOLE_START>>PAGE_SHIFT, %ebx
 861         movl    $ISA_HOLE_LENGTH>>PAGE_SHIFT, %ecx
 862         fillkpt(R(_vm86pa), $PG_RW|PG_U)
 863
 864 #ifdef SMP
 865 /* Map cpu0's private page into global kmem (4K @ cpu0prvpage) */
 866         movl    R(cpu0pp), %eax
 867         movl    $1, %ecx
 868         fillkptphys($PG_RW)
 869
 870 /* Map SMP page table page into global kmem FWIW */
 871         movl    R(SMPptpa), %eax
 872         movl    $1, %ecx
 873         fillkptphys($PG_RW)
 874
 875 /* Map the private page into the SMP page table */
 876         movl    R(cpu0pp), %eax
 877         movl    $0, %ebx                /* pte offset = 0 */
 878         movl    $1, %ecx                /* one private page coming right up */
 879         fillkpt(R(SMPptpa), $PG_RW)
 880
 881 /* ... and put the page table table in the pde. */
 882         movl    R(SMPptpa), %eax
 883         movl    $MPPTDI, %ebx
 884         movl    $1, %ecx
 885         fillkpt(R(_IdlePTD), $PG_RW)
 886
 887 /* Fakeup VA for the local apic to allow early traps. */
 888         ALLOCPAGES(1)
 889         movl    %esi, %eax
 890         movl    $(NPTEPG-1), %ebx       /* pte offset = NTEPG-1 */
 891         movl    $1, %ecx                /* one private pt coming right up */
 892         fillkpt(R(SMPptpa), $PG_RW)
 893
 894 /* Initialize mp lock to allow early traps */
 895         movl    $1, R(_mp_lock)
 896 #endif  /* SMP */
 897
 898 /* install a pde for temporary double map of bottom of VA */
 899         movl    R(_KPTphys), %eax
 900         xorl    %ebx, %ebx
 901         movl    $1, %ecx
 902         fillkpt(R(_IdlePTD), $PG_RW)
 903
 904 /* install pde's for pt's */
 905         movl    R(_KPTphys), %eax
 906         movl    $KPTDI, %ebx
 907         movl    $NKPT, %ecx
 908         fillkpt(R(_IdlePTD), $PG_RW)
 909
 910 /* install a pde recursively mapping page directory as a page table */
 911         movl    R(_IdlePTD), %eax
 912         movl    $PTDPTDI, %ebx
 913         movl    $1,%ecx
 914         fillkpt(R(_IdlePTD), $PG_RW)
 915
 916         ret
 917
 918 #ifdef BDE_DEBUGGER
 919 bdb_prepare_paging:
 920         cmpl    $0,R(_bdb_exists)
 921         je      bdb_prepare_paging_exit
 922
 923         subl    $6,%esp
 924
 925         /*
 926          * Copy and convert debugger entries from the bootstrap gdt and idt
 927          * to the kernel gdt and idt.  Everything is still in low memory.
 928          * Tracing continues to work after paging is enabled because the
 929          * low memory addresses remain valid until everything is relocated.
 930          * However, tracing through the setidt() that initializes the trace
 931          * trap will crash.
 932          */
 933         sgdt    (%esp)
 934         movl    2(%esp),%esi            /* base address of bootstrap gdt */
 935         movl    $R(_gdt),%edi
 936         movl    %edi,2(%esp)            /* prepare to load kernel gdt */
 937         movl    $8*18/4,%ecx
 938         cld
 939         rep                             /* copy gdt */
 940         movsl
 941         movl    $R(_gdt),-8+2(%edi)     /* adjust gdt self-ptr */
 942         movb    $0x92,-8+5(%edi)
 943         lgdt    (%esp)
 944
 945         sidt    (%esp)
 946         movl    2(%esp),%esi            /* base address of current idt */
 947         movl    8+4(%esi),%eax          /* convert dbg descriptor to ... */
 948         movw    8(%esi),%ax
 949         movl    %eax,R(bdb_dbg_ljmp+1)  /* ... immediate offset ... */
 950         movl    8+2(%esi),%eax
 951         movw    %ax,R(bdb_dbg_ljmp+5)   /* ... and selector for ljmp */
 952         movl    24+4(%esi),%eax         /* same for bpt descriptor */
 953         movw    24(%esi),%ax
 954         movl    %eax,R(bdb_bpt_ljmp+1)
 955         movl    24+2(%esi),%eax
 956         movw    %ax,R(bdb_bpt_ljmp+5)
 957         movl    R(_idt),%edi
 958         movl    %edi,2(%esp)            /* prepare to load kernel idt */
 959         movl    $8*4/4,%ecx
 960         cld
 961         rep                             /* copy idt */
 962         movsl
 963         lidt    (%esp)
 964
 965         addl    $6,%esp
 966
 967 bdb_prepare_paging_exit:
 968         ret
 969
 970 /* Relocate debugger gdt entries and gdt and idt pointers. */
 971 bdb_commit_paging:
 972         cmpl    $0,_bdb_exists
 973         je      bdb_commit_paging_exit
 974
 975         movl    $_gdt+8*9,%eax          /* adjust slots 9-17 */
 976         movl    $9,%ecx
 977 reloc_gdt:
 978         movb    $KERNBASE>>24,7(%eax)   /* top byte of base addresses, was 0, */
 979         addl    $8,%eax                 /* now KERNBASE>>24 */
 980         loop    reloc_gdt
 981
 982         subl    $6,%esp
 983         sgdt    (%esp)
 984         addl    $KERNBASE,2(%esp)
 985         lgdt    (%esp)
 986         sidt    (%esp)
 987         addl    $KERNBASE,2(%esp)
 988         lidt    (%esp)
 989         addl    $6,%esp
 990
 991         int     $3
 992
 993 bdb_commit_paging_exit:
 994         ret
 995
 996 #endif /* BDE_DEBUGGER */