sys/amd64/amd64/locore.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  *      from: @(#)locore.s      7.3 (Berkeley) 5/13/91
  37  * $FreeBSD$
  38  *
  39  *              originally from: locore.s, by William F. Jolitz
  40  *
  41  *              Substantially rewritten by David Greenman, Rod Grimes,
  42  *                      Bruce Evans, Wolfgang Solfrank, Poul-Henning Kamp
  43  *                      and many others.
  44  */
  45
  46 #include "opt_bootp.h"
  47 #include "opt_ddb.h"
  48 #include "opt_nfsroot.h"
  49 #include "opt_userconfig.h"
  50
  51 #include <sys/syscall.h>
  52 #include <sys/reboot.h>
  53
  54 #include <machine/asmacros.h>
  55 #include <machine/cputypes.h>
  56 #include <machine/psl.h>
  57 #include <machine/pmap.h>
  58 #include <machine/specialreg.h>
  59
  60 #include "assym.s"
  61
  62 /*
  63  *      XXX
  64  *
  65  * Note: This version greatly munged to avoid various assembler errors
  66  * that may be fixed in newer versions of gas. Perhaps newer versions
  67  * will have more pleasant appearance.
  68  */
  69
  70 /*
  71  * PTmap is recursive pagemap at top of virtual address space.
  72  * Within PTmap, the page directory can be found (third indirection).
  73  */
  74         .globl  _PTmap,_PTD,_PTDpde
  75         .set    _PTmap,(PTDPTDI << PDRSHIFT)
  76         .set    _PTD,_PTmap + (PTDPTDI * PAGE_SIZE)
  77         .set    _PTDpde,_PTD + (PTDPTDI * PDESIZE)
  78
  79 /*
  80  * APTmap, APTD is the alternate recursive pagemap.
  81  * It's used when modifying another process's page tables.
  82  */
  83         .globl  _APTmap,_APTD,_APTDpde
  84         .set    _APTmap,APTDPTDI << PDRSHIFT
  85         .set    _APTD,_APTmap + (APTDPTDI * PAGE_SIZE)
  86         .set    _APTDpde,_PTD + (APTDPTDI * PDESIZE)
  87
  88 /*
  89  * Globals
  90  */
  91         .data
  92         ALIGN_DATA              /* just to be sure */
  93
  94         .globl  HIDENAME(tmpstk)
  95         .space  0x2000          /* space for tmpstk - temporary stack */
  96 HIDENAME(tmpstk):
  97
  98         .globl  _boothowto,_bootdev
  99
 100         .globl  _cpu,_cpu_vendor,_cpu_id,_bootinfo
 101         .globl  _cpu_high, _cpu_feature
 102
 103 _cpu:           .long   0                       /* are we 386, 386sx, or 486 */
 104 _cpu_id:        .long   0                       /* stepping ID */
 105 _cpu_high:      .long   0                       /* highest arg to CPUID */
 106 _cpu_feature:   .long   0                       /* features */
 107 _cpu_vendor:    .space  20                      /* CPU origin code */
 108 _bootinfo:      .space  BOOTINFO_SIZE           /* bootinfo that we can handle */
 109
 110 _KERNend:       .long   0                       /* phys addr end of kernel (just after bss) */
 111 physfree:       .long   0                       /* phys addr of next free page */
 112
 113 #ifdef SMP
 114                 .globl  _cpu0prvpage
 115 cpu0pp:         .long   0                       /* phys addr cpu0 private pg */
 116 _cpu0prvpage:   .long   0                       /* relocated version */
 117
 118                 .globl  _SMPpt
 119 SMPptpa:        .long   0                       /* phys addr SMP page table */
 120 _SMPpt:         .long   0                       /* relocated version */
 121 #endif /* SMP */
 122
 123         .globl  _IdlePTD
 124 _IdlePTD:       .long   0                       /* phys addr of kernel PTD */
 125
 126 #ifdef SMP
 127         .globl  _KPTphys
 128 #endif
 129 _KPTphys:       .long   0                       /* phys addr of kernel page tables */
 130
 131         .globl  _proc0paddr
 132 _proc0paddr:    .long   0                       /* address of proc 0 address space */
 133 p0upa:          .long   0                       /* phys addr of proc0's UPAGES */
 134
 135 vm86phystk:     .long   0                       /* PA of vm86/bios stack */
 136
 137         .globl  _vm86paddr, _vm86pa
 138 _vm86paddr:     .long   0                       /* address of vm86 region */
 139 _vm86pa:        .long   0                       /* phys addr of vm86 region */
 140
 141 #ifdef BDE_DEBUGGER
 142         .globl  _bdb_exists                     /* flag to indicate BDE debugger is present */
 143 _bdb_exists:    .long   0
 144 #endif
 145
 146 #ifdef PC98
 147         .globl  _pc98_system_parameter
 148 _pc98_system_parameter:
 149         .space  0x240
 150 #endif
 151
 152 /**********************************************************************
 153  *
 154  * Some handy macros
 155  *
 156  */
 157
 158 #define R(foo) ((foo)-KERNBASE)
 159
 160 #define ALLOCPAGES(foo) \
 161         movl    R(physfree), %esi ; \
 162         movl    $((foo)*PAGE_SIZE), %eax ; \
 163         addl    %esi, %eax ; \
 164         movl    %eax, R(physfree) ; \
 165         movl    %esi, %edi ; \
 166         movl    $((foo)*PAGE_SIZE),%ecx ; \
 167         xorl    %eax,%eax ; \
 168         cld ; \
 169         rep ; \
 170         stosb
 171
 172 /*
 173  * fillkpt
 174  *      eax = page frame address
 175  *      ebx = index into page table
 176  *      ecx = how many pages to map
 177  *      base = base address of page dir/table
 178  *      prot = protection bits
 179  */
 180 #define fillkpt(base, prot)               \
 181         shll    $2,%ebx                 ; \
 182         addl    base,%ebx               ; \
 183         orl     $PG_V,%eax              ; \
 184         orl     prot,%eax               ; \
 185 1:      movl    %eax,(%ebx)             ; \
 186         addl    $PAGE_SIZE,%eax         ; /* increment physical address */ \
 187         addl    $4,%ebx                 ; /* next pte */ \
 188         loop    1b
 189
 190 /*
 191  * fillkptphys(prot)
 192  *      eax = physical address
 193  *      ecx = how many pages to map
 194  *      prot = protection bits
 195  */
 196 #define fillkptphys(prot)                 \
 197         movl    %eax, %ebx              ; \
 198         shrl    $PAGE_SHIFT, %ebx       ; \
 199         fillkpt(R(_KPTphys), prot)
 200
 201         .text
 202 /**********************************************************************
 203  *
 204  * This is where the bootblocks start us, set the ball rolling...
 205  *
 206  */
 207 NON_GPROF_ENTRY(btext)
 208
 209 #ifdef PC98
 210         /* save SYSTEM PARAMETER for resume (NS/T or other) */
 211         movl    $0xa1400,%esi
 212         movl    $R(_pc98_system_parameter),%edi
 213         movl    $0x0240,%ecx
 214         cld
 215         rep
 216         movsb
 217 #else   /* IBM-PC */
 218 #ifdef BDE_DEBUGGER
 219 #ifdef BIOS_STEALS_3K
 220         cmpl    $0x0375c339,0x95504
 221 #else
 222         cmpl    $0x0375c339,0x96104     /* XXX - debugger signature */
 223 #endif
 224         jne     1f
 225         movb    $1,R(_bdb_exists)
 226 1:
 227 #endif
 228 #endif  /* PC98 */
 229
 230 /* Tell the bios to warmboot next time */
 231         movw    $0x1234,0x472
 232
 233 /* Set up a real frame in case the double return in newboot is executed. */
 234         pushl   %ebp
 235         movl    %esp, %ebp
 236
 237 /* Don't trust what the BIOS gives for eflags. */
 238         pushl   $PSL_KERNEL
 239         popfl
 240
 241 /*
 242  * Don't trust what the BIOS gives for %fs and %gs.  Trust the bootstrap
 243  * to set %cs, %ds, %es and %ss.
 244  */
 245         mov     %ds, %ax
 246         mov     %ax, %fs
 247         mov     %ax, %gs
 248
 249         call    recover_bootinfo
 250
 251 /* Get onto a stack that we can trust. */
 252 /*
 253  * XXX this step is delayed in case recover_bootinfo needs to return via
 254  * the old stack, but it need not be, since recover_bootinfo actually
 255  * returns via the old frame.
 256  */
 257         movl    $R(HIDENAME(tmpstk)),%esp
 258
 259 #ifdef PC98
 260         /* pc98_machine_type & M_EPSON_PC98 */
 261         testb   $0x02,R(_pc98_system_parameter)+220
 262         jz      3f
 263         /* epson_machine_id <= 0x0b */
 264         cmpb    $0x0b,R(_pc98_system_parameter)+224
 265         ja      3f
 266
 267         /* count up memory */
 268         movl    $0x100000,%eax          /* next, talley remaining memory */
 269         movl    $0xFFF-0x100,%ecx
 270 1:      movl    0(%eax),%ebx            /* save location to check */
 271         movl    $0xa55a5aa5,0(%eax)     /* write test pattern */
 272         cmpl    $0xa55a5aa5,0(%eax)     /* does not check yet for rollover */
 273         jne     2f
 274         movl    %ebx,0(%eax)            /* restore memory */
 275         addl    $PAGE_SIZE,%eax
 276         loop    1b
 277 2:      subl    $0x100000,%eax
 278         shrl    $17,%eax
 279         movb    %al,R(_pc98_system_parameter)+1
 280 3:
 281 #endif
 282
 283         call    identify_cpu
 284
 285 /* clear bss */
 286 /*
 287  * XXX this should be done a little earlier.
 288  *
 289  * XXX we don't check that there is memory for our bss and page tables
 290  * before using it.
 291  *
 292  * XXX the boot program somewhat bogusly clears the bss.  We still have
 293  * to do it in case we were unzipped by kzipboot.  Then the boot program
 294  * only clears kzipboot's bss.
 295  *
 296  * XXX the gdt and idt are still somewhere in the boot program.  We
 297  * depend on the convention that the boot program is below 1MB and we
 298  * are above 1MB to keep the gdt and idt  away from the bss and page
 299  * tables.  The idt is only used if BDE_DEBUGGER is enabled.
 300  */
 301         movl    $R(_end),%ecx
 302         movl    $R(_edata),%edi
 303         subl    %edi,%ecx
 304         xorl    %eax,%eax
 305         cld
 306         rep
 307         stosb
 308
 309         call    create_pagetables
 310
 311 /*
 312  * If the CPU has support for VME, turn it on.
 313  */
 314         testl   $CPUID_VME, R(_cpu_feature)
 315         jz      1f
 316         movl    %cr4, %eax
 317         orl     $CR4_VME, %eax
 318         movl    %eax, %cr4
 319 1:
 320
 321 #ifdef BDE_DEBUGGER
 322 /*
 323  * Adjust as much as possible for paging before enabling paging so that the
 324  * adjustments can be traced.
 325  */
 326         call    bdb_prepare_paging
 327 #endif
 328
 329 /* Now enable paging */
 330         movl    R(_IdlePTD), %eax
 331         movl    %eax,%cr3                       /* load ptd addr into mmu */
 332         movl    %cr0,%eax                       /* get control word */
 333         orl     $CR0_PE|CR0_PG,%eax             /* enable paging */
 334         movl    %eax,%cr0                       /* and let's page NOW! */
 335
 336 #ifdef BDE_DEBUGGER
 337 /*
 338  * Complete the adjustments for paging so that we can keep tracing through
 339  * initi386() after the low (physical) addresses for the gdt and idt become
 340  * invalid.
 341  */
 342         call    bdb_commit_paging
 343 #endif
 344
 345         pushl   $begin                          /* jump to high virtualized address */
 346         ret
 347
 348 /* now running relocated at KERNBASE where the system is linked to run */
 349 begin:
 350         /* set up bootstrap stack */
 351         movl    _proc0paddr,%esp        /* location of in-kernel pages */
 352         addl    $UPAGES*PAGE_SIZE,%esp  /* bootstrap stack end location */
 353         xorl    %eax,%eax                       /* mark end of frames */
 354         movl    %eax,%ebp
 355         movl    _proc0paddr,%eax
 356         movl    _IdlePTD, %esi
 357         movl    %esi,PCB_CR3(%eax)
 358
 359         movl    physfree, %esi
 360         pushl   %esi                            /* value of first for init386(first) */
 361         call    _init386                        /* wire 386 chip for unix operation */
 362         popl    %esi
 363
 364         .globl  __ucodesel,__udatasel
 365
 366         pushl   $0                              /* unused */
 367         pushl   __udatasel                      /* ss */
 368         pushl   $0                              /* esp - filled in by execve() */
 369         pushl   $PSL_USER                       /* eflags (IOPL 0, int enab) */
 370         pushl   __ucodesel                      /* cs */
 371         pushl   $0                              /* eip - filled in by execve() */
 372         subl    $(13*4),%esp                    /* space for rest of registers */
 373
 374         pushl   %esp                            /* call main with frame pointer */
 375         call    _mi_startup                     /* autoconfiguration, mountroot etc */
 376
 377         hlt             /* never returns to here */
 378
 379 /*
 380  * When starting init, call this to configure the process for user
 381  * mode.  This will be inherited by other processes.
 382  */
 383 NON_GPROF_ENTRY(prepare_usermode)
 384         /*
 385          * Now we've run main() and determined what cpu-type we are, we can
 386          * enable write protection and alignment checking on i486 cpus and
 387          * above.
 388          */
 389 #if defined(I486_CPU) || defined(I586_CPU) || defined(I686_CPU)
 390         cmpl    $CPUCLASS_386,_cpu_class
 391         je      1f
 392         movl    %cr0,%eax                       /* get control word */
 393         orl     $CR0_WP|CR0_AM,%eax             /* enable i486 features */
 394         movl    %eax,%cr0                       /* and do it */
 395 1:
 396 #endif
 397         /*
 398          * on return from main(), we are process 1
 399          * set up address space and stack so that we can 'return' to user mode
 400          */
 401         movl    __ucodesel,%eax
 402         movl    __udatasel,%ecx
 403
 404 #if 0   /* ds/es/fs are in trap frame */
 405         movl    %cx,%ds
 406         movl    %cx,%es
 407         movl    %cx,%fs
 408 #endif
 409         movl    %cx,%gs                         /* and ds to gs */
 410         ret                                     /* goto user! */
 411
 412
 413 /*
 414  * Signal trampoline, copied to top of user stack
 415  */
 416 NON_GPROF_ENTRY(sigcode)
 417         call    SIGF_HANDLER(%esp)              /* call signal handler */
 418         movl    SIGF_SIGRET(%esp),%eax          /* Get sigreturn cookie */
 419         cmpl    $0x0ABCDEF0,%eax                /* New one? */
 420         jne     3f
 421 /* New signalling code */
 422         lea     SIGF_UC(%esp),%eax              /* get ucontext */
 423         pushl   %eax
 424         testl   $PSL_VM,UC_EFLAGS(%eax)
 425         jne     1f
 426         movl    UC_GS(%eax),%gs                 /* restore %gs */
 427 1:
 428         movl    $SYS_sigreturn,%eax
 429         pushl   %eax                            /* junk to fake return addr. */
 430         int     $0x80                           /* enter kernel with args */
 431                                                 /* on stack */
 432 2:
 433         jmp     2b
 434 /* Old signalling code */
 435 3:
 436         lea     SIGF_SC(%esp),%eax              /* get sigcontext */
 437         pushl   %eax
 438         testl   $PSL_VM,SC_PS(%eax)
 439         jne     4f
 440         movl    SC_GS(%eax),%gs                 /* restore %gs */
 441 4:
 442         movl    $SYS_osigreturn,%eax
 443         pushl   %eax                            /* junk to fake return addr. */
 444         int     $0x80                           /* enter kernel with args */
 445                                                 /* on stack */
 446 5:
 447         jmp     5b
 448
 449         ALIGN_TEXT
 450 _esigcode:
 451
 452         .data
 453         .globl  _szsigcode
 454 _szsigcode:
 455         .long   _esigcode-_sigcode
 456         .text
 457
 458 /**********************************************************************
 459  *
 460  * Recover the bootinfo passed to us from the boot program
 461  *
 462  */
 463 recover_bootinfo:
 464         /*
 465          * This code is called in different ways depending on what loaded
 466          * and started the kernel.  This is used to detect how we get the
 467          * arguments from the other code and what we do with them.
 468          *
 469          * Old disk boot blocks:
 470          *      (*btext)(howto, bootdev, cyloffset, esym);
 471          *      [return address == 0, and can NOT be returned to]
 472          *      [cyloffset was not supported by the FreeBSD boot code
 473          *       and always passed in as 0]
 474          *      [esym is also known as total in the boot code, and
 475          *       was never properly supported by the FreeBSD boot code]
 476          *
 477          * Old diskless netboot code:
 478          *      (*btext)(0,0,0,0,&nfsdiskless,0,0,0);
 479          *      [return address != 0, and can NOT be returned to]
 480          *      If we are being booted by this code it will NOT work,
 481          *      so we are just going to halt if we find this case.
 482          *
 483          * New uniform boot code:
 484          *      (*btext)(howto, bootdev, 0, 0, 0, &bootinfo)
 485          *      [return address != 0, and can be returned to]
 486          *
 487          * There may seem to be a lot of wasted arguments in here, but
 488          * that is so the newer boot code can still load very old kernels
 489          * and old boot code can load new kernels.
 490          */
 491
 492         /*
 493          * The old style disk boot blocks fake a frame on the stack and
 494          * did an lret to get here.  The frame on the stack has a return
 495          * address of 0.
 496          */
 497         cmpl    $0,4(%ebp)
 498         je      olddiskboot
 499
 500         /*
 501          * We have some form of return address, so this is either the
 502          * old diskless netboot code, or the new uniform code.  That can
 503          * be detected by looking at the 5th argument, if it is 0
 504          * we are being booted by the new uniform boot code.
 505          */
 506         cmpl    $0,24(%ebp)
 507         je      newboot
 508
 509         /*
 510          * Seems we have been loaded by the old diskless boot code, we
 511          * don't stand a chance of running as the diskless structure
 512          * changed considerably between the two, so just halt.
 513          */
 514          hlt
 515
 516         /*
 517          * We have been loaded by the new uniform boot code.
 518          * Let's check the bootinfo version, and if we do not understand
 519          * it we return to the loader with a status of 1 to indicate this error
 520          */
 521 newboot:
 522         movl    28(%ebp),%ebx           /* &bootinfo.version */
 523         movl    BI_VERSION(%ebx),%eax
 524         cmpl    $1,%eax                 /* We only understand version 1 */
 525         je      1f
 526         movl    $1,%eax                 /* Return status */
 527         leave
 528         /*
 529          * XXX this returns to our caller's caller (as is required) since
 530          * we didn't set up a frame and our caller did.
 531          */
 532         ret
 533
 534 1:
 535         /*
 536          * If we have a kernelname copy it in
 537          */
 538         movl    BI_KERNELNAME(%ebx),%esi
 539         cmpl    $0,%esi
 540         je      2f                      /* No kernelname */
 541         movl    $MAXPATHLEN,%ecx        /* Brute force!!! */
 542         movl    $R(_kernelname),%edi
 543         cmpb    $'/',(%esi)             /* Make sure it starts with a slash */
 544         je      1f
 545         movb    $'/',(%edi)
 546         incl    %edi
 547         decl    %ecx
 548 1:
 549         cld
 550         rep
 551         movsb
 552
 553 2:
 554         /*
 555          * Determine the size of the boot loader's copy of the bootinfo
 556          * struct.  This is impossible to do properly because old versions
 557          * of the struct don't contain a size field and there are 2 old
 558          * versions with the same version number.
 559          */
 560         movl    $BI_ENDCOMMON,%ecx      /* prepare for sizeless version */
 561         testl   $RB_BOOTINFO,8(%ebp)    /* bi_size (and bootinfo) valid? */
 562         je      got_bi_size             /* no, sizeless version */
 563         movl    BI_SIZE(%ebx),%ecx
 564 got_bi_size:
 565
 566         /*
 567          * Copy the common part of the bootinfo struct
 568          */
 569         movl    %ebx,%esi
 570         movl    $R(_bootinfo),%edi
 571         cmpl    $BOOTINFO_SIZE,%ecx
 572         jbe     got_common_bi_size
 573         movl    $BOOTINFO_SIZE,%ecx
 574 got_common_bi_size:
 575         cld
 576         rep
 577         movsb
 578
 579 #ifdef NFS_ROOT
 580 #ifndef BOOTP_NFSV3
 581         /*
 582          * If we have a nfs_diskless structure copy it in
 583          */
 584         movl    BI_NFS_DISKLESS(%ebx),%esi
 585         cmpl    $0,%esi
 586         je      olddiskboot
 587         movl    $R(_nfs_diskless),%edi
 588         movl    $NFSDISKLESS_SIZE,%ecx
 589         cld
 590         rep
 591         movsb
 592         movl    $R(_nfs_diskless_valid),%edi
 593         movl    $1,(%edi)
 594 #endif
 595 #endif
 596
 597         /*
 598          * The old style disk boot.
 599          *      (*btext)(howto, bootdev, cyloffset, esym);
 600          * Note that the newer boot code just falls into here to pick
 601          * up howto and bootdev, cyloffset and esym are no longer used
 602          */
 603 olddiskboot:
 604         movl    8(%ebp),%eax
 605         movl    %eax,R(_boothowto)
 606         movl    12(%ebp),%eax
 607         movl    %eax,R(_bootdev)
 608
 609         ret
 610
 611
 612 /**********************************************************************
 613  *
 614  * Identify the CPU and initialize anything special about it
 615  *
 616  */
 617 identify_cpu:
 618
 619         /* Try to toggle alignment check flag; does not exist on 386. */
 620         pushfl
 621         popl    %eax
 622         movl    %eax,%ecx
 623         orl     $PSL_AC,%eax
 624         pushl   %eax
 625         popfl
 626         pushfl
 627         popl    %eax
 628         xorl    %ecx,%eax
 629         andl    $PSL_AC,%eax
 630         pushl   %ecx
 631         popfl
 632
 633         testl   %eax,%eax
 634         jnz     try486
 635
 636         /* NexGen CPU does not have aligment check flag. */
 637         pushfl
 638         movl    $0x5555, %eax
 639         xorl    %edx, %edx
 640         movl    $2, %ecx
 641         clc
 642         divl    %ecx
 643         jz      trynexgen
 644         popfl
 645         movl    $CPU_386,R(_cpu)
 646         jmp     3f
 647
 648 trynexgen:
 649         popfl
 650         movl    $CPU_NX586,R(_cpu)
 651         movl    $0x4778654e,R(_cpu_vendor)      # store vendor string
 652         movl    $0x72446e65,R(_cpu_vendor+4)
 653         movl    $0x6e657669,R(_cpu_vendor+8)
 654         movl    $0,R(_cpu_vendor+12)
 655         jmp     3f
 656
 657 try486: /* Try to toggle identification flag; does not exist on early 486s. */
 658         pushfl
 659         popl    %eax
 660         movl    %eax,%ecx
 661         xorl    $PSL_ID,%eax
 662         pushl   %eax
 663         popfl
 664         pushfl
 665         popl    %eax
 666         xorl    %ecx,%eax
 667         andl    $PSL_ID,%eax
 668         pushl   %ecx
 669         popfl
 670
 671         testl   %eax,%eax
 672         jnz     trycpuid
 673         movl    $CPU_486,R(_cpu)
 674
 675         /*
 676          * Check Cyrix CPU
 677          * Cyrix CPUs do not change the undefined flags following
 678          * execution of the divide instruction which divides 5 by 2.
 679          *
 680          * Note: CPUID is enabled on M2, so it passes another way.
 681          */
 682         pushfl
 683         movl    $0x5555, %eax
 684         xorl    %edx, %edx
 685         movl    $2, %ecx
 686         clc
 687         divl    %ecx
 688         jnc     trycyrix
 689         popfl
 690         jmp     3f              /* You may use Intel CPU. */
 691
 692 trycyrix:
 693         popfl
 694         /*
 695          * IBM Bluelighting CPU also doesn't change the undefined flags.
 696          * Because IBM doesn't disclose the information for Bluelighting
 697          * CPU, we couldn't distinguish it from Cyrix's (including IBM
 698          * brand of Cyrix CPUs).
 699          */
 700         movl    $0x69727943,R(_cpu_vendor)      # store vendor string
 701         movl    $0x736e4978,R(_cpu_vendor+4)
 702         movl    $0x64616574,R(_cpu_vendor+8)
 703         jmp     3f
 704
 705 trycpuid:       /* Use the `cpuid' instruction. */
 706         xorl    %eax,%eax
 707         .byte   0x0f,0xa2                       # cpuid 0
 708         movl    %eax,R(_cpu_high)               # highest capability
 709         movl    %ebx,R(_cpu_vendor)             # store vendor string
 710         movl    %edx,R(_cpu_vendor+4)
 711         movl    %ecx,R(_cpu_vendor+8)
 712         movb    $0,R(_cpu_vendor+12)
 713
 714         movl    $1,%eax
 715         .byte   0x0f,0xa2                       # cpuid 1
 716         movl    %eax,R(_cpu_id)                 # store cpu_id
 717         movl    %edx,R(_cpu_feature)            # store cpu_feature
 718         rorl    $8,%eax                         # extract family type
 719         andl    $15,%eax
 720         cmpl    $5,%eax
 721         jae     1f
 722
 723         /* less than Pentium; must be 486 */
 724         movl    $CPU_486,R(_cpu)
 725         jmp     3f
 726 1:
 727         /* a Pentium? */
 728         cmpl    $5,%eax
 729         jne     2f
 730         movl    $CPU_586,R(_cpu)
 731         jmp     3f
 732 2:
 733         /* Greater than Pentium...call it a Pentium Pro */
 734         movl    $CPU_686,R(_cpu)
 735 3:
 736         ret
 737
 738
 739 /**********************************************************************
 740  *
 741  * Create the first page directory and its page tables.
 742  *
 743  */
 744
 745 create_pagetables:
 746
 747         testl   $CPUID_PGE, R(_cpu_feature)
 748         jz      1f
 749         movl    %cr4, %eax
 750         orl     $CR4_PGE, %eax
 751         movl    %eax, %cr4
 752 1:
 753
 754 /* Find end of kernel image (rounded up to a page boundary). */
 755         movl    $R(_end),%esi
 756
 757 /* include symbols if loaded and useful */
 758 #ifdef DDB
 759         movl    R(_bootinfo+BI_ESYMTAB),%edi
 760         testl   %edi,%edi
 761         je      over_symalloc
 762         movl    %edi,%esi
 763         movl    $KERNBASE,%edi
 764         addl    %edi,R(_bootinfo+BI_SYMTAB)
 765         addl    %edi,R(_bootinfo+BI_ESYMTAB)
 766 over_symalloc:
 767 #endif
 768
 769 /* If we are told where the end of the kernel space is, believe it. */
 770         movl    R(_bootinfo+BI_KERNEND),%edi
 771         testl   %edi,%edi
 772         je      no_kernend
 773         movl    %edi,%esi
 774 no_kernend:
 775
 776         addl    $PAGE_MASK,%esi
 777         andl    $~PAGE_MASK,%esi
 778         movl    %esi,R(_KERNend)        /* save end of kernel */
 779         movl    %esi,R(physfree)        /* next free page is at end of kernel */
 780
 781 /* Allocate Kernel Page Tables */
 782         ALLOCPAGES(NKPT)
 783         movl    %esi,R(_KPTphys)
 784
 785 /* Allocate Page Table Directory */
 786         ALLOCPAGES(1)
 787         movl    %esi,R(_IdlePTD)
 788
 789 /* Allocate UPAGES */
 790         ALLOCPAGES(UPAGES)
 791         movl    %esi,R(p0upa)
 792         addl    $KERNBASE, %esi
 793         movl    %esi, R(_proc0paddr)
 794
 795         ALLOCPAGES(1)                   /* vm86/bios stack */
 796         movl    %esi,R(vm86phystk)
 797
 798         ALLOCPAGES(3)                   /* pgtable + ext + IOPAGES */
 799         movl    %esi,R(_vm86pa)
 800         addl    $KERNBASE, %esi
 801         movl    %esi, R(_vm86paddr)
 802
 803 #ifdef SMP
 804 /* Allocate cpu0's private data page */
 805         ALLOCPAGES(1)
 806         movl    %esi,R(cpu0pp)
 807         addl    $KERNBASE, %esi
 808         movl    %esi, R(_cpu0prvpage)   /* relocated to KVM space */
 809
 810 /* Allocate SMP page table page */
 811         ALLOCPAGES(1)
 812         movl    %esi,R(SMPptpa)
 813         addl    $KERNBASE, %esi
 814         movl    %esi, R(_SMPpt)         /* relocated to KVM space */
 815 #endif  /* SMP */
 816
 817 /* Map read-only from zero to the end of the kernel text section */
 818         xorl    %eax, %eax
 819 #ifdef BDE_DEBUGGER
 820 /* If the debugger is present, actually map everything read-write. */
 821         cmpl    $0,R(_bdb_exists)
 822         jne     map_read_write
 823 #endif
 824         xorl    %edx,%edx
 825
 826 #if !defined(SMP)
 827         testl   $CPUID_PGE, R(_cpu_feature)
 828         jz      2f
 829         orl     $PG_G,%edx
 830 #endif
 831
 832 2:      movl    $R(_etext),%ecx
 833         addl    $PAGE_MASK,%ecx
 834         shrl    $PAGE_SHIFT,%ecx
 835         fillkptphys(%edx)
 836
 837 /* Map read-write, data, bss and symbols */
 838         movl    $R(_etext),%eax
 839         addl    $PAGE_MASK, %eax
 840         andl    $~PAGE_MASK, %eax
 841 map_read_write:
 842         movl    $PG_RW,%edx
 843 #if !defined(SMP)
 844         testl   $CPUID_PGE, R(_cpu_feature)
 845         jz      1f
 846         orl     $PG_G,%edx
 847 #endif
 848
 849 1:      movl    R(_KERNend),%ecx
 850         subl    %eax,%ecx
 851         shrl    $PAGE_SHIFT,%ecx
 852         fillkptphys(%edx)
 853
 854 /* Map page directory. */
 855         movl    R(_IdlePTD), %eax
 856         movl    $1, %ecx
 857         fillkptphys($PG_RW)
 858
 859 /* Map proc0's UPAGES in the physical way ... */
 860         movl    R(p0upa), %eax
 861         movl    $UPAGES, %ecx
 862         fillkptphys($PG_RW)
 863
 864 /* Map ISA hole */
 865         movl    $ISA_HOLE_START, %eax
 866         movl    $ISA_HOLE_LENGTH>>PAGE_SHIFT, %ecx
 867         fillkptphys($PG_RW)
 868
 869 /* Map space for the vm86 region */
 870         movl    R(vm86phystk), %eax
 871         movl    $4, %ecx
 872         fillkptphys($PG_RW)
 873
 874 /* Map page 0 into the vm86 page table */
 875         movl    $0, %eax
 876         movl    $0, %ebx
 877         movl    $1, %ecx
 878         fillkpt(R(_vm86pa), $PG_RW|PG_U)
 879
 880 /* ...likewise for the ISA hole */
 881         movl    $ISA_HOLE_START, %eax
 882         movl    $ISA_HOLE_START>>PAGE_SHIFT, %ebx
 883         movl    $ISA_HOLE_LENGTH>>PAGE_SHIFT, %ecx
 884         fillkpt(R(_vm86pa), $PG_RW|PG_U)
 885
 886 #ifdef SMP
 887 /* Map cpu0's private page into global kmem (4K @ cpu0prvpage) */
 888         movl    R(cpu0pp), %eax
 889         movl    $1, %ecx
 890         fillkptphys($PG_RW)
 891
 892 /* Map SMP page table page into global kmem FWIW */
 893         movl    R(SMPptpa), %eax
 894         movl    $1, %ecx
 895         fillkptphys($PG_RW)
 896
 897 /* Map the private page into the SMP page table */
 898         movl    R(cpu0pp), %eax
 899         movl    $0, %ebx                /* pte offset = 0 */
 900         movl    $1, %ecx                /* one private page coming right up */
 901         fillkpt(R(SMPptpa), $PG_RW)
 902
 903 /* ... and put the page table table in the pde. */
 904         movl    R(SMPptpa), %eax
 905         movl    $MPPTDI, %ebx
 906         movl    $1, %ecx
 907         fillkpt(R(_IdlePTD), $PG_RW)
 908
 909 /* Fakeup VA for the local apic to allow early traps. */
 910         ALLOCPAGES(1)
 911         movl    %esi, %eax
 912         movl    $(NPTEPG-1), %ebx       /* pte offset = NTEPG-1 */
 913         movl    $1, %ecx                /* one private pt coming right up */
 914         fillkpt(R(SMPptpa), $PG_RW)
 915
 916 /* Initialize mp lock to allow early traps */
 917         movl    $1, R(_mp_lock)
 918 #endif  /* SMP */
 919
 920 /* install a pde for temporary double map of bottom of VA */
 921         movl    R(_KPTphys), %eax
 922         xorl    %ebx, %ebx
 923         movl    $1, %ecx
 924         fillkpt(R(_IdlePTD), $PG_RW)
 925
 926 /* install pde's for pt's */
 927         movl    R(_KPTphys), %eax
 928         movl    $KPTDI, %ebx
 929         movl    $NKPT, %ecx
 930         fillkpt(R(_IdlePTD), $PG_RW)
 931
 932 /* install a pde recursively mapping page directory as a page table */
 933         movl    R(_IdlePTD), %eax
 934         movl    $PTDPTDI, %ebx
 935         movl    $1,%ecx
 936         fillkpt(R(_IdlePTD), $PG_RW)
 937
 938         ret
 939
 940 #ifdef BDE_DEBUGGER
 941 bdb_prepare_paging:
 942         cmpl    $0,R(_bdb_exists)
 943         je      bdb_prepare_paging_exit
 944
 945         subl    $6,%esp
 946
 947         /*
 948          * Copy and convert debugger entries from the bootstrap gdt and idt
 949          * to the kernel gdt and idt.  Everything is still in low memory.
 950          * Tracing continues to work after paging is enabled because the
 951          * low memory addresses remain valid until everything is relocated.
 952          * However, tracing through the setidt() that initializes the trace
 953          * trap will crash.
 954          */
 955         sgdt    (%esp)
 956         movl    2(%esp),%esi            /* base address of bootstrap gdt */
 957         movl    $R(_gdt),%edi
 958         movl    %edi,2(%esp)            /* prepare to load kernel gdt */
 959         movl    $8*18/4,%ecx
 960         cld
 961         rep                             /* copy gdt */
 962         movsl
 963         movl    $R(_gdt),-8+2(%edi)     /* adjust gdt self-ptr */
 964         movb    $0x92,-8+5(%edi)
 965         lgdt    (%esp)
 966
 967         sidt    (%esp)
 968         movl    2(%esp),%esi            /* base address of current idt */
 969         movl    8+4(%esi),%eax          /* convert dbg descriptor to ... */
 970         movw    8(%esi),%ax
 971         movl    %eax,R(bdb_dbg_ljmp+1)  /* ... immediate offset ... */
 972         movl    8+2(%esi),%eax
 973         movw    %ax,R(bdb_dbg_ljmp+5)   /* ... and selector for ljmp */
 974         movl    24+4(%esi),%eax         /* same for bpt descriptor */
 975         movw    24(%esi),%ax
 976         movl    %eax,R(bdb_bpt_ljmp+1)
 977         movl    24+2(%esi),%eax
 978         movw    %ax,R(bdb_bpt_ljmp+5)
 979         movl    R(_idt),%edi
 980         movl    %edi,2(%esp)            /* prepare to load kernel idt */
 981         movl    $8*4/4,%ecx
 982         cld
 983         rep                             /* copy idt */
 984         movsl
 985         lidt    (%esp)
 986
 987         addl    $6,%esp
 988
 989 bdb_prepare_paging_exit:
 990         ret
 991
 992 /* Relocate debugger gdt entries and gdt and idt pointers. */
 993 bdb_commit_paging:
 994         cmpl    $0,_bdb_exists
 995         je      bdb_commit_paging_exit
 996
 997         movl    $_gdt+8*9,%eax          /* adjust slots 9-17 */
 998         movl    $9,%ecx
 999 reloc_gdt:
1000         movb    $KERNBASE>>24,7(%eax)   /* top byte of base addresses, was 0, */
1001         addl    $8,%eax                 /* now KERNBASE>>24 */
1002         loop    reloc_gdt
1003
1004         subl    $6,%esp
1005         sgdt    (%esp)
1006         addl    $KERNBASE,2(%esp)
1007         lgdt    (%esp)
1008         sidt    (%esp)
1009         addl    $KERNBASE,2(%esp)
1010         lidt    (%esp)
1011         addl    $6,%esp
1012
1013         int     $3
1014
1015 bdb_commit_paging_exit:
1016         ret
1017
1018 #endif /* BDE_DEBUGGER */